autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.5svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [5], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  63 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  64 : ${CFLAGS=}
  65 : ${CXXFLAGS=}
  66
  67 dnl We need to check for the compiler up here to avoid anything else
  68 dnl starting with a different one.
  69 AC_PROG_CC(clang gcc)
  70 AC_PROG_CXX(clang++ g++)
  71 AC_PROG_CPP
  72
  73 dnl If CXX is Clang, check that it can find and parse C++ standard library
  74 dnl headers.
  75 if test "$CXX" = "clang++" ; then
  76   AC_MSG_CHECKING([whether clang works])
  77   AC_LANG_PUSH([C++])
  78   dnl Note that space between 'include' and '(' is required.  There's a broken
  79   dnl regex in aclocal that otherwise will think that we call m4's include
  80   dnl builtin.
  81   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  82 #if __has_include (<cxxabi.h>)
  83 #include <cxxabi.h>
  84 #endif
  85 #if __has_include (<unwind.h>)
  86 #include <unwind.h>
  87 #endif
  88 ]])],
  89 [
  90   AC_MSG_RESULT([yes])
  91 ],
  92 [
  93   AC_MSG_RESULT([no])
  94   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
  95 ])
  96   AC_LANG_POP([C++])
  97 fi
  98
  99 dnl Set up variables that track whether the host compiler is GCC or Clang where
 100 dnl we can effectively sanity check them. We don't try to sanity check all the
 101 dnl other possible compilers.
 102 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 103 AC_LANG_PUSH([C++])
 104 llvm_cv_cxx_compiler=unknown
 105 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 106                                     #error
 107                                     #endif
 108                                     ]])],
 109                   llvm_cv_cxx_compiler=clang,
 110                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 111                                                        #error
 112                                                        #endif
 113                                                        ]])],
 114                                      llvm_cv_cxx_compiler=gcc, [])])
 115 AC_LANG_POP([C++])
 116 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 117
 118 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 119 dnl be bypassed by passing a flag if necessary on a platform.
 120 AC_ARG_ENABLE(compiler-version-checks,
 121               AS_HELP_STRING([--enable-compiler-version-checks],
 122                              [Check the version of the host compiler (default is YES)]),,
 123                              enableval=default)
 124 case "$enableval" in
 125   no)
 126     ;;
 127   yes|default)
 128     AC_LANG_PUSH([C++])
 129     case "$llvm_cv_cxx_compiler" in
 130     clang)
 131       AC_MSG_CHECKING([whether Clang is new enough])
 132       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 133 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 134 #error This version of Clang is too old to build LLVM
 135 #endif
 136 ]])],
 137           [AC_MSG_RESULT([yes])],
 138           [AC_MSG_RESULT([no])
 139            AC_MSG_ERROR([
 140 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 141 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 142 bypass these sanity checks.])])
 143
 144       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 145       dnl are sometimes deeply confusing though. Here we test for an obvious
 146       dnl incomplete feature in 4.6's standard library that was completed in
 147       dnl 4.7's.
 148       AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 149       llvm_cv_old_cxxflags="$CXXFLAGS"
 150       CXXFLAGS="$CXXFLAGS -std=c++0x"
 151       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 152 #include <atomic>
 153 std::atomic<float> x(0.0f);
 154 int main() { return (float)x; }
 155 ]])],
 156           [AC_MSG_RESULT([yes])],
 157           [AC_MSG_RESULT([no])
 158            AC_MSG_ERROR([
 159 We detected a missing feature in the standard C++ library that was known to be
 160 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 161 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 162 than 4.7. You will need to update your system and ensure Clang uses the newer
 163 standard library.
 164
 165 If this error is incorrect or you need to force things to work, you may pass
 166 '--disable-compiler-version-checks' to configure to bypass this test.])])
 167       ;;
 168     gcc)
 169       AC_MSG_CHECKING([whether GCC is new enough])
 170       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 171 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 172 #error This version of GCC is too old to build LLVM
 173 #endif
 174 ]])],
 175           [AC_MSG_RESULT([yes])],
 176           [AC_MSG_RESULT([no])
 177            AC_MSG_ERROR([
 178 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 179 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 180 bypass these sanity checks.])])
 181       ;;
 182     unknown)
 183       ;;
 184     esac
 185     AC_LANG_POP([C++])
 186     ;;
 187   *)
 188     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 189     ;;
 190 esac
 191
 192 dnl Configure all of the projects present in our source tree. While we could
 193 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 194 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 195 dnl Instead we match on the known projects.
 196
 197 dnl
 198 dnl One tricky part of doing this is that some projects depend upon other
 199 dnl projects.  For example, several projects rely upon the LLVM test suite.
 200 dnl We want to configure those projects first so that their object trees are
 201 dnl created before running the configure scripts of projects that depend upon
 202 dnl them.
 203 dnl
 204
 205 dnl Several projects use the LLVM test suite, so configure it next.
 206 if test -d ${srcdir}/projects/test-suite ; then
 207   AC_CONFIG_SUBDIRS([projects/test-suite])
 208 fi
 209
 210 dnl llvm-test is the old name of the test-suite, kept here for backwards
 211 dnl compatibility
 212 if test -d ${srcdir}/projects/llvm-test ; then
 213   AC_CONFIG_SUBDIRS([projects/llvm-test])
 214 fi
 215
 216 dnl Some projects use poolalloc; configure that next
 217 if test -d ${srcdir}/projects/poolalloc ; then
 218   AC_CONFIG_SUBDIRS([projects/poolalloc])
 219 fi
 220
 221 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 222   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 223 fi
 224
 225 dnl Check for all other projects
 226 for i in `ls ${srcdir}/projects`
 227 do
 228   if test -d ${srcdir}/projects/${i} ; then
 229     case ${i} in
 230       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 231       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 232       compiler-rt)       ;;
 233       test-suite)     ;;
 234       llvm-test)      ;;
 235       poolalloc)      ;;
 236       llvm-poolalloc) ;;
 237       *)
 238         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 239         ;;
 240     esac
 241   fi
 242 done
 243
 244 dnl Disable the build of polly, even if it is checked out into tools/polly.
 245 AC_ARG_ENABLE(polly,
 246               AS_HELP_STRING([--enable-polly],
 247                              [Use polly if available (default is YES)]),,
 248                              enableval=default)
 249 case "$enableval" in
 250   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 251   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 252   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 253   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 254 esac
 255
 256
 257 dnl Check if polly is checked out into tools/polly and configure it if
 258 dnl available.
 259 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 260   AC_SUBST(LLVM_HAS_POLLY,1)
 261   AC_CONFIG_SUBDIRS([tools/polly])
 262 fi
 263
 264 dnl===-----------------------------------------------------------------------===
 265 dnl===
 266 dnl=== SECTION 2: Architecture, target, and host checks
 267 dnl===
 268 dnl===-----------------------------------------------------------------------===
 269
 270 dnl Check the target for which we're compiling and the host that will do the
 271 dnl compilations. This will tell us which LLVM compiler will be used for
 272 dnl compiling SSA into object code. This needs to be done early because
 273 dnl following tests depend on it.
 274 AC_CANONICAL_TARGET
 275
 276 dnl Determine the platform type and cache its value. This helps us configure
 277 dnl the System library to the correct build platform.
 278 AC_CACHE_CHECK([type of operating system we're going to host on],
 279                [llvm_cv_os_type],
 280 [case $host in
 281   *-*-aix*)
 282     llvm_cv_link_all_option="-Wl,--whole-archive"
 283     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 284     llvm_cv_os_type="AIX"
 285     llvm_cv_platform_type="Unix" ;;
 286   *-*-irix*)
 287     llvm_cv_link_all_option="-Wl,--whole-archive"
 288     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 289     llvm_cv_os_type="IRIX"
 290     llvm_cv_platform_type="Unix" ;;
 291   *-*-cygwin*)
 292     llvm_cv_link_all_option="-Wl,--whole-archive"
 293     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 294     llvm_cv_os_type="Cygwin"
 295     llvm_cv_platform_type="Unix" ;;
 296   *-*-darwin*)
 297     llvm_cv_link_all_option="-Wl,-all_load"
 298     llvm_cv_no_link_all_option="-Wl,-noall_load"
 299     llvm_cv_os_type="Darwin"
 300     llvm_cv_platform_type="Unix" ;;
 301   *-*-minix*)
 302     llvm_cv_link_all_option="-Wl,-all_load"
 303     llvm_cv_no_link_all_option="-Wl,-noall_load"
 304     llvm_cv_os_type="Minix"
 305     llvm_cv_platform_type="Unix" ;;
 306   *-*-freebsd*)
 307     llvm_cv_link_all_option="-Wl,--whole-archive"
 308     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 309     llvm_cv_os_type="FreeBSD"
 310     llvm_cv_platform_type="Unix" ;;
 311   *-*-kfreebsd-gnu)
 312     llvm_cv_link_all_option="-Wl,--whole-archive"
 313     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 314     llvm_cv_os_type="GNU/kFreeBSD"
 315     llvm_cv_platform_type="Unix" ;;
 316   *-*-openbsd*)
 317     llvm_cv_link_all_option="-Wl,--whole-archive"
 318     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 319     llvm_cv_os_type="OpenBSD"
 320     llvm_cv_platform_type="Unix" ;;
 321   *-*-netbsd*)
 322     llvm_cv_link_all_option="-Wl,--whole-archive"
 323     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 324     llvm_cv_os_type="NetBSD"
 325     llvm_cv_platform_type="Unix" ;;
 326   *-*-dragonfly*)
 327     llvm_cv_link_all_option="-Wl,--whole-archive"
 328     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 329     llvm_cv_os_type="DragonFly"
 330     llvm_cv_platform_type="Unix" ;;
 331   *-*-hpux*)
 332     llvm_cv_link_all_option="-Wl,--whole-archive"
 333     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 334     llvm_cv_os_type="HP-UX"
 335     llvm_cv_platform_type="Unix" ;;
 336   *-*-interix*)
 337     llvm_cv_link_all_option="-Wl,--whole-archive"
 338     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 339     llvm_cv_os_type="Interix"
 340     llvm_cv_platform_type="Unix" ;;
 341   *-*-linux*)
 342     llvm_cv_link_all_option="-Wl,--whole-archive"
 343     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 344     llvm_cv_os_type="Linux"
 345     llvm_cv_platform_type="Unix" ;;
 346   *-*-gnu*)
 347     llvm_cv_link_all_option="-Wl,--whole-archive"
 348     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 349     llvm_cv_os_type="GNU"
 350     llvm_cv_platform_type="Unix" ;;
 351   *-*-solaris*)
 352     llvm_cv_link_all_option="-Wl,-z,allextract"
 353     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 354     llvm_cv_os_type="SunOS"
 355     llvm_cv_platform_type="Unix" ;;
 356   *-*-auroraux*)
 357     llvm_cv_link_all_option="-Wl,-z,allextract"
 358     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 359     llvm_cv_os_type="AuroraUX"
 360     llvm_cv_platform_type="Unix" ;;
 361   *-*-win32*)
 362     llvm_cv_link_all_option="-Wl,--whole-archive"
 363     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 364     llvm_cv_os_type="Win32"
 365     llvm_cv_platform_type="Win32" ;;
 366   *-*-mingw*)
 367     llvm_cv_link_all_option="-Wl,--whole-archive"
 368     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 369     llvm_cv_os_type="MingW"
 370     llvm_cv_platform_type="Win32" ;;
 371   *-*-haiku*)
 372     llvm_cv_link_all_option="-Wl,--whole-archive"
 373     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 374     llvm_cv_os_type="Haiku"
 375     llvm_cv_platform_type="Unix" ;;
 376   *-unknown-eabi*)
 377     llvm_cv_link_all_option="-Wl,--whole-archive"
 378     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 379     llvm_cv_os_type="Freestanding"
 380     llvm_cv_platform_type="Unix" ;;
 381   *-unknown-elf*)
 382     llvm_cv_link_all_option="-Wl,--whole-archive"
 383     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 384     llvm_cv_os_type="Freestanding"
 385     llvm_cv_platform_type="Unix" ;;
 386   *)
 387     llvm_cv_link_all_option=""
 388     llvm_cv_no_link_all_option=""
 389     llvm_cv_os_type="Unknown"
 390     llvm_cv_platform_type="Unknown" ;;
 391 esac])
 392
 393 AC_CACHE_CHECK([type of operating system we're going to target],
 394                [llvm_cv_target_os_type],
 395 [case $target in
 396   *-*-aix*)
 397     llvm_cv_target_os_type="AIX" ;;
 398   *-*-irix*)
 399     llvm_cv_target_os_type="IRIX" ;;
 400   *-*-cygwin*)
 401     llvm_cv_target_os_type="Cygwin" ;;
 402   *-*-darwin*)
 403     llvm_cv_target_os_type="Darwin" ;;
 404   *-*-minix*)
 405     llvm_cv_target_os_type="Minix" ;;
 406   *-*-freebsd*)
 407     llvm_cv_target_os_type="FreeBSD" ;;
 408   *-*-kfreebsd-gnu)
 409     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 410   *-*-openbsd*)
 411     llvm_cv_target_os_type="OpenBSD" ;;
 412   *-*-netbsd*)
 413     llvm_cv_target_os_type="NetBSD" ;;
 414   *-*-dragonfly*)
 415     llvm_cv_target_os_type="DragonFly" ;;
 416   *-*-hpux*)
 417     llvm_cv_target_os_type="HP-UX" ;;
 418   *-*-interix*)
 419     llvm_cv_target_os_type="Interix" ;;
 420   *-*-linux*)
 421     llvm_cv_target_os_type="Linux" ;;
 422   *-*-gnu*)
 423     llvm_cv_target_os_type="GNU" ;;
 424   *-*-solaris*)
 425     llvm_cv_target_os_type="SunOS" ;;
 426   *-*-auroraux*)
 427     llvm_cv_target_os_type="AuroraUX" ;;
 428   *-*-win32*)
 429     llvm_cv_target_os_type="Win32" ;;
 430   *-*-mingw*)
 431     llvm_cv_target_os_type="MingW" ;;
 432   *-*-haiku*)
 433     llvm_cv_target_os_type="Haiku" ;;
 434   *-*-rtems*)
 435     llvm_cv_target_os_type="RTEMS" ;;
 436   *-*-nacl*)
 437     llvm_cv_target_os_type="NativeClient" ;;
 438   *-unknown-eabi*)
 439     llvm_cv_target_os_type="Freestanding" ;;
 440   *)
 441     llvm_cv_target_os_type="Unknown" ;;
 442 esac])
 443
 444 dnl Make sure we aren't attempting to configure for an unknown system
 445 if test "$llvm_cv_os_type" = "Unknown" ; then
 446   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 447 fi
 448
 449 dnl Set the "OS" Makefile variable based on the platform type so the
 450 dnl makefile can configure itself to specific build hosts
 451 AC_SUBST(OS,$llvm_cv_os_type)
 452 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 453 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 454
 455 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 456 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 457 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 458
 459 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 460 dnl This is used by lib/Support to determine the basic kind of implementation
 461 dnl to use.
 462 case $llvm_cv_platform_type in
 463   Unix)
 464     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 465     AC_SUBST(LLVM_ON_UNIX,[1])
 466     AC_SUBST(LLVM_ON_WIN32,[0])
 467     ;;
 468   Win32)
 469     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 470     AC_SUBST(LLVM_ON_UNIX,[0])
 471     AC_SUBST(LLVM_ON_WIN32,[1])
 472     ;;
 473 esac
 474
 475 dnl Determine what our target architecture is and configure accordingly.
 476 dnl This will allow Makefiles to make a distinction between the hardware and
 477 dnl the OS.
 478 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 479 [case $target in
 480   i?86-*)                 llvm_cv_target_arch="x86" ;;
 481   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 482   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 483   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 484   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 485   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 486   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 487   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 488   xcore-*)                llvm_cv_target_arch="XCore" ;;
 489   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 490   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 491   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 492   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 493   *)                      llvm_cv_target_arch="Unknown" ;;
 494 esac])
 495
 496 if test "$llvm_cv_target_arch" = "Unknown" ; then
 497   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 498 fi
 499
 500 dnl Determine the LLVM native architecture for the target
 501 case "$llvm_cv_target_arch" in
 502     x86)     LLVM_NATIVE_ARCH="X86" ;;
 503     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 504     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 505 esac
 506
 507 dnl Define a substitution, ARCH, for the target architecture
 508 AC_SUBST(ARCH,$llvm_cv_target_arch)
 509
 510 dnl Determine what our host architecture.
 511 dnl This will allow MCJIT regress tests runs only for supported
 512 dnl platforms.
 513 case $host in
 514   i?86-*)                 host_arch="x86" ;;
 515   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 516   sparc*-*)               host_arch="Sparc" ;;
 517   powerpc*-*)             host_arch="PowerPC" ;;
 518   arm*-*)                 host_arch="ARM" ;;
 519   aarch64*-*)             host_arch="AArch64" ;;
 520   mips-* | mips64-*)      host_arch="Mips" ;;
 521   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 522   xcore-*)                host_arch="XCore" ;;
 523   msp430-*)               host_arch="MSP430" ;;
 524   hexagon-*)              host_arch="Hexagon" ;;
 525   s390x-*)                host_arch="SystemZ" ;;
 526   *)                      host_arch="Unknown" ;;
 527 esac
 528
 529 if test "$host_arch" = "Unknown" ; then
 530   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 531 fi
 532
 533 AC_SUBST(HOST_ARCH,$host_arch)
 534
 535 dnl Check for build platform executable suffix if we're cross-compiling
 536 if test "$cross_compiling" = yes; then
 537   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 538   AC_BUILD_EXEEXT
 539   ac_build_prefix=${build_alias}-
 540   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 541   if test -z "$BUILD_CXX"; then
 542      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 543      if test -z "$BUILD_CXX"; then
 544        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 545      fi
 546   fi
 547 else
 548   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 549 fi
 550
 551 dnl Check to see if there's a .svn or .git directory indicating that this
 552 dnl build is being done from a checkout. This sets up several defaults for
 553 dnl the command line switches. When we build with a checkout directory,
 554 dnl we get a debug with assertions turned on. Without, we assume a source
 555 dnl release and we get an optimized build without assertions.
 556 dnl See --enable-optimized and --enable-assertions below
 557 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 558   cvsbuild="yes"
 559   optimize="no"
 560   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 561 else
 562   cvsbuild="no"
 563   optimize="yes"
 564 fi
 565
 566 dnl===-----------------------------------------------------------------------===
 567 dnl===
 568 dnl=== SECTION 3: Command line arguments for the configure script.
 569 dnl===
 570 dnl===-----------------------------------------------------------------------===
 571
 572 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 573 AC_ARG_ENABLE(libcpp,
 574               AS_HELP_STRING([--enable-libcpp],
 575                              [Use libc++ if available (default is NO)]),,
 576                              enableval=default)
 577 case "$enableval" in
 578   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 579   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 580   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 581   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 582 esac
 583
 584 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 585 AC_ARG_ENABLE(cxx11,
 586               AS_HELP_STRING([--enable-cxx11],
 587                              [Use c++11 if available (default is NO)]),,
 588                              enableval=default)
 589 case "$enableval" in
 590   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 591   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 592   default) AC_SUBST(ENABLE_CXX11,[0]);;
 593   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 594 esac
 595
 596 dnl --enable-fission : check whether or not to use -gsplit-dwarf on the command
 597 dnl line
 598 AC_ARG_ENABLE(split-dwarf,
 599               AS_HELP_STRING([--enable-split-dwarf],
 600                              [Use split-dwarf if available (default is NO)]),,
 601                              enableval=default)
 602 case "$enableval" in
 603   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 604   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 605   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 606   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 607 esac
 608
 609 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 610 clang_arcmt="yes"
 611 AC_ARG_ENABLE(clang-arcmt,
 612               AS_HELP_STRING([--enable-clang-arcmt],
 613                              [Enable building of clang ARCMT (default is YES)]),
 614                              clang_arcmt="$enableval",
 615                              enableval="yes")
 616 case "$enableval" in
 617   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 618   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 619   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 620   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 621 esac
 622
 623 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 624 clang_static_analyzer="yes"
 625 AC_ARG_ENABLE(clang-static-analyzer,
 626               AS_HELP_STRING([--enable-clang-static-analyzer],
 627                              [Enable building of clang Static Analyzer (default is YES)]),
 628                              clang_static_analyzer="$enableval",
 629                              enableval="yes")
 630 case "$enableval" in
 631   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 632   no)
 633     if test ${clang_arcmt} != "no" ; then
 634       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 635     fi
 636     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 637     ;;
 638   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 639   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 640 esac
 641
 642 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 643 AC_ARG_ENABLE(clang-rewriter,
 644               AS_HELP_STRING([--enable-clang-rewriter],
 645                              [Enable building of clang rewriter (default is YES)]),,
 646                              enableval="yes")
 647 case "$enableval" in
 648   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 649   no)
 650     if test ${clang_arcmt} != "no" ; then
 651       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 652     fi
 653     if test ${clang_static_analyzer} != "no" ; then
 654       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 655     fi
 656     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 657     ;;
 658   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 659   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 660 esac
 661
 662 dnl --enable-optimized : check whether they want to do an optimized build:
 663 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 664  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 665 if test ${enableval} = "no" ; then
 666   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 667 else
 668   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 669 fi
 670
 671 dnl --enable-profiling : check whether they want to do a profile build:
 672 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 673  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 674 if test ${enableval} = "no" ; then
 675   AC_SUBST(ENABLE_PROFILING,[[]])
 676 else
 677   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 678 fi
 679
 680 dnl --enable-assertions : check whether they want to turn on assertions or not:
 681 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 682   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 683 if test ${enableval} = "yes" ; then
 684   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 685 else
 686   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 687 fi
 688
 689 dnl --enable-werror : check whether we want Werror on by default
 690 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 691   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 692 case "$enableval" in
 693   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 694   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 695   default) AC_SUBST(ENABLE_WERROR,[0]);;
 696   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 697 esac
 698
 699 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 700 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 701   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 702 if test ${enableval} = "yes" ; then
 703   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 704   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 705 else
 706   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 707   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 708 fi
 709
 710 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 711 AC_ARG_ENABLE(debug-runtime,
 712    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 713 if test ${enableval} = "no" ; then
 714   AC_SUBST(DEBUG_RUNTIME,[[]])
 715 else
 716   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 717 fi
 718
 719 dnl --enable-debug-symbols : should even optimized compiler libraries
 720 dnl have debug symbols?
 721 AC_ARG_ENABLE(debug-symbols,
 722    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 723 if test ${enableval} = "no" ; then
 724   AC_SUBST(DEBUG_SYMBOLS,[[]])
 725 else
 726   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 727 fi
 728
 729 dnl --enable-keep-symbols : do not strip installed executables
 730 AC_ARG_ENABLE(keep-symbols,
 731    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 732 if test ${enableval} = "no" ; then
 733   AC_SUBST(KEEP_SYMBOLS,[[]])
 734 else
 735   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 736 fi
 737
 738 dnl --enable-jit: check whether they want to enable the jit
 739 AC_ARG_ENABLE(jit,
 740   AS_HELP_STRING(--enable-jit,
 741                  [Enable Just In Time Compiling (default is YES)]),,
 742   enableval=default)
 743 if test ${enableval} = "no"
 744 then
 745   AC_SUBST(JIT,[[]])
 746 else
 747   case "$llvm_cv_target_arch" in
 748     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 749     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 750     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 751     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 752     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 753     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 754     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 755     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 756     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 757     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 758     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 759     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 760     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 761   esac
 762 fi
 763
 764 dnl Allow enablement of building and installing docs
 765 AC_ARG_ENABLE(docs,
 766               AS_HELP_STRING([--enable-docs],
 767                              [Build documents (default is YES)]),,
 768                              enableval=default)
 769 case "$enableval" in
 770   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 771   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 772   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 773   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 774 esac
 775
 776 dnl Allow enablement of doxygen generated documentation
 777 AC_ARG_ENABLE(doxygen,
 778               AS_HELP_STRING([--enable-doxygen],
 779                              [Build doxygen documentation (default is NO)]),,
 780                              enableval=default)
 781 case "$enableval" in
 782   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 783   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 784   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 785   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 786 esac
 787
 788 dnl Allow disablement of threads
 789 AC_ARG_ENABLE(threads,
 790               AS_HELP_STRING([--enable-threads],
 791                              [Use threads if available (default is YES)]),,
 792                              enableval=default)
 793 case "$enableval" in
 794   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 795   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 796   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 797   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 798 esac
 799 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 800                    [Define if threads enabled])
 801
 802 dnl Allow disablement of pthread.h
 803 AC_ARG_ENABLE(pthreads,
 804               AS_HELP_STRING([--enable-pthreads],
 805                              [Use pthreads if available (default is YES)]),,
 806                              enableval=default)
 807 case "$enableval" in
 808   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 809   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 810   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 811   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 812 esac
 813
 814 dnl Allow disablement of zlib
 815 AC_ARG_ENABLE(zlib,
 816               AS_HELP_STRING([--enable-zlib],
 817                              [Use zlib for compression/decompression if
 818                               available (default is YES)]),,
 819                               enableval=default)
 820 case "$enableval" in
 821   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 822   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 823   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 824   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 825 esac
 826 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 827                    [Define if zlib is enabled])
 828
 829 dnl Allow building without position independent code
 830 AC_ARG_ENABLE(pic,
 831   AS_HELP_STRING([--enable-pic],
 832                  [Build LLVM with Position Independent Code (default is YES)]),,
 833                  enableval=default)
 834 case "$enableval" in
 835   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 836   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 837   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 838   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 839 esac
 840 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 841                    [Define if position independent code is enabled])
 842
 843 dnl Allow building a shared library and linking tools against it.
 844 AC_ARG_ENABLE(shared,
 845   AS_HELP_STRING([--enable-shared],
 846                  [Build a shared library and link tools against it (default is NO)]),,
 847                  enableval=default)
 848 case "$enableval" in
 849   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 850   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 851   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 852   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 853 esac
 854
 855 dnl Allow libstdc++ is embedded in LLVM.dll.
 856 AC_ARG_ENABLE(embed-stdcxx,
 857   AS_HELP_STRING([--enable-embed-stdcxx],
 858                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 859                  enableval=default)
 860 case "$enableval" in
 861   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 862   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 863   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 864   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 865 esac
 866
 867 dnl Enable embedding timestamp information into build.
 868 AC_ARG_ENABLE(timestamps,
 869   AS_HELP_STRING([--enable-timestamps],
 870                  [Enable embedding timestamp information in build (default is YES)]),,
 871                  enableval=default)
 872 case "$enableval" in
 873   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 874   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 875   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 876   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 877 esac
 878 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 879                    [Define if timestamp information (e.g., __DATE__) is allowed])
 880
 881 dnl Enable support for showing backtraces.
 882 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
 883   [--enable-backtraces],
 884   [Enable embedding backtraces on crash (default is YES)]),
 885   [case "$enableval" in
 886     yes) llvm_cv_enable_backtraces="yes" ;;
 887     no)  llvm_cv_enable_backtraces="no"  ;;
 888     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 889   esac],
 890   llvm_cv_enable_backtraces="yes")
 891 if test "$llvm_cv_enable_backtraces" = "yes" ; then
 892   AC_DEFINE([ENABLE_BACKTRACES],[1],
 893             [Define if you want backtraces on crash])
 894 fi
 895
 896 dnl Enable installing platform specific signal handling overrides, for improved
 897 dnl CrashRecovery support or interaction with crash reporting software. This
 898 dnl support may be inappropriate for some clients embedding LLVM as a library.
 899 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
 900   [--enable-crash-overrides],
 901   [Enable crash handling overrides (default is YES)]),
 902   [case "$enableval" in
 903     yes) llvm_cv_enable_crash_overrides="yes" ;;
 904     no)  llvm_cv_enable_crash_overrides="no"  ;;
 905     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
 906   esac],
 907   llvm_cv_enable_crash_overrides="yes")
 908 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
 909   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
 910             [Define to enable crash handling overrides])
 911 fi
 912
 913 dnl Allow specific targets to be specified for building (or not)
 914 TARGETS_TO_BUILD=""
 915 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 916     [Build specific host targets: all or target1,target2,... Valid targets are:
 917      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 918      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 919     enableval=all)
 920 if test "$enableval" = host-only ; then
 921   enableval=host
 922 fi
 923 case "$enableval" in
 924   all) TARGETS_TO_BUILD="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600" ;;
 925   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 926       case "$a_target" in
 927         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 928         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 929         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 930         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 931         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 932         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 933         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 934         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 935         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 936         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 937         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 938         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 939         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 940         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 941         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 942         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 943         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 944         host) case "$llvm_cv_target_arch" in
 945             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 946             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 947             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 948             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 949             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 950             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 951             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 952             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 953             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 954             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 955             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 956             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 957             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 958           esac ;;
 959         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 960       esac
 961   done
 962   ;;
 963 esac
 964
 965 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 966     [Build experimental host targets: disable or target1,target2,...
 967      (default=disable)]),,
 968     enableval=disable)
 969
 970 if test ${enableval} != "disable"
 971 then
 972   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 973 fi
 974
 975 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 976
 977 dnl Determine whether we are building LLVM support for the native architecture.
 978 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 979 for a_target in $TARGETS_TO_BUILD; do
 980   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 981     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 982       [LLVM architecture name for the native architecture, if available])
 983     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 984     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 985     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 986     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 987     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 988       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 989     fi
 990     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 991       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 992     fi
 993     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 994       [LLVM name for the native Target init function, if available])
 995     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 996       [LLVM name for the native TargetInfo init function, if available])
 997     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 998       [LLVM name for the native target MC init function, if available])
 999     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1000       [LLVM name for the native AsmPrinter init function, if available])
1001     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1002       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1003        [LLVM name for the native AsmParser init function, if available])
1004     fi
1005     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1006       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1007        [LLVM name for the native Disassembler init function, if available])
1008     fi
1009   fi
1010 done
1011
1012 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1013 dnl target feature def files.
1014 LLVM_ENUM_TARGETS=""
1015 LLVM_ENUM_ASM_PRINTERS=""
1016 LLVM_ENUM_ASM_PARSERS=""
1017 LLVM_ENUM_DISASSEMBLERS=""
1018 for target_to_build in $TARGETS_TO_BUILD; do
1019   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1020   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1021     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1022   fi
1023   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1024     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1025   fi
1026   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1027     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1028   fi
1029 done
1030 AC_SUBST(LLVM_ENUM_TARGETS)
1031 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1032 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1033 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1034
1035 dnl Override the option to use for optimized builds.
1036 AC_ARG_WITH(optimize-option,
1037   AS_HELP_STRING([--with-optimize-option],
1038                  [Select the compiler options to use for optimized builds]),,
1039                  withval=default)
1040 AC_MSG_CHECKING([optimization flags])
1041 case "$withval" in
1042   default)
1043     case "$llvm_cv_os_type" in
1044     FreeBSD) optimize_option=-O2 ;;
1045     MingW) optimize_option=-O2 ;;
1046     *)     optimize_option=-O3 ;;
1047     esac ;;
1048   *) optimize_option="$withval" ;;
1049 esac
1050 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1051 AC_MSG_RESULT([$optimize_option])
1052
1053 dnl Specify extra build options
1054 AC_ARG_WITH(extra-options,
1055   AS_HELP_STRING([--with-extra-options],
1056                  [Specify additional options to compile LLVM with]),,
1057                  withval=default)
1058 case "$withval" in
1059   default) EXTRA_OPTIONS= ;;
1060   *) EXTRA_OPTIONS=$withval ;;
1061 esac
1062 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1063
1064 dnl Specify extra linker build options
1065 AC_ARG_WITH(extra-ld-options,
1066   AS_HELP_STRING([--with-extra-ld-options],
1067                  [Specify additional options to link LLVM with]),,
1068                  withval=default)
1069 case "$withval" in
1070   default) EXTRA_LD_OPTIONS= ;;
1071   *) EXTRA_LD_OPTIONS=$withval ;;
1072 esac
1073 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1074
1075 dnl Allow specific bindings to be specified for building (or not)
1076 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1077     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1078     enableval=default)
1079 BINDINGS_TO_BUILD=""
1080 case "$enableval" in
1081   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1082   all ) BINDINGS_TO_BUILD="ocaml" ;;
1083   none | no) BINDINGS_TO_BUILD="" ;;
1084   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1085       case "$a_binding" in
1086         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1087         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1088       esac
1089   done
1090   ;;
1091 esac
1092
1093 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1094 dnl script for bindings/ocaml/configure, except that its auto value depends on
1095 dnl OCAMLC, which is found here to support tests.
1096 AC_ARG_WITH([ocaml-libdir],
1097   [AS_HELP_STRING([--with-ocaml-libdir],
1098     [Specify install location for ocaml bindings (default is stdlib)])],
1099   [],
1100   [withval=auto])
1101 case "$withval" in
1102   auto) with_ocaml_libdir="$withval" ;;
1103   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1104   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1105 esac
1106
1107 AC_ARG_WITH(clang-srcdir,
1108   AS_HELP_STRING([--with-clang-srcdir],
1109     [Directory to the out-of-tree Clang source]),,
1110     withval="-")
1111 case "$withval" in
1112   -) clang_src_root="" ;;
1113   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1114   *) clang_src_root="$ac_pwd/$withval" ;;
1115 esac
1116 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1117
1118 AC_ARG_WITH(clang-resource-dir,
1119   AS_HELP_STRING([--with-clang-resource-dir],
1120     [Relative directory from the Clang binary for resource files]),,
1121     withval="")
1122 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1123                    [Relative directory for resource files])
1124
1125 AC_ARG_WITH(c-include-dirs,
1126   AS_HELP_STRING([--with-c-include-dirs],
1127     [Colon separated list of directories clang will search for headers]),,
1128     withval="")
1129 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1130                    [Directories clang will search for headers])
1131
1132 # Clang normally uses the system c++ headers and libraries. With this option,
1133 # clang will use the ones provided by a gcc installation instead. This option should
1134 # be passed the same value that was used with --prefix when configuring gcc.
1135 AC_ARG_WITH(gcc-toolchain,
1136   AS_HELP_STRING([--with-gcc-toolchain],
1137     [Directory where gcc is installed.]),,
1138     withval="")
1139 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1140                    [Directory where gcc is installed.])
1141
1142 AC_ARG_WITH(default-sysroot,
1143   AS_HELP_STRING([--with-default-sysroot],
1144     [Add --sysroot=<path> to all compiler invocations.]),,
1145     withval="")
1146 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1147                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1148
1149 dnl Allow linking of LLVM with GPLv3 binutils code.
1150 AC_ARG_WITH(binutils-include,
1151   AS_HELP_STRING([--with-binutils-include],
1152     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1153   withval=default)
1154 case "$withval" in
1155   default) WITH_BINUTILS_INCDIR=default ;;
1156   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1157   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1158 esac
1159 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1160   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1161   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1162      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1163      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1164   fi
1165 fi
1166
1167 dnl Specify the URL where bug reports should be submitted.
1168 AC_ARG_WITH(bug-report-url,
1169   AS_HELP_STRING([--with-bug-report-url],
1170     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1171     withval="http://llvm.org/bugs/")
1172 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1173                    [Bug report URL.])
1174
1175 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1176 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1177   [--enable-terminfo],
1178   [Query the terminfo database if available (default is YES)]),
1179   [case "$enableval" in
1180     yes) llvm_cv_enable_terminfo="yes" ;;
1181     no)  llvm_cv_enable_terminfo="no"  ;;
1182     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1183   esac],
1184   llvm_cv_enable_terminfo="yes")
1185
1186 dnl --enable-libffi : check whether the user wants to turn off libffi:
1187 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1188   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1189   [case "$enableval" in
1190     yes) llvm_cv_enable_libffi="yes" ;;
1191     no)  llvm_cv_enable_libffi="no"  ;;
1192     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1193   esac],
1194   llvm_cv_enable_libffi=no)
1195
1196 AC_ARG_WITH(internal-prefix,
1197   AS_HELP_STRING([--with-internal-prefix],
1198     [Installation directory for internal files]),,
1199     withval="")
1200 AC_SUBST(INTERNAL_PREFIX,[$withval])
1201
1202 dnl===-----------------------------------------------------------------------===
1203 dnl===
1204 dnl=== SECTION 4: Check for programs we need and that they are the right version
1205 dnl===
1206 dnl===-----------------------------------------------------------------------===
1207
1208 AC_PROG_NM
1209 AC_SUBST(NM)
1210
1211 dnl Check for the tools that the makefiles require
1212 AC_CHECK_GNU_MAKE
1213 AC_PROG_LN_S
1214 AC_PATH_PROG(CMP, [cmp], [cmp])
1215 AC_PATH_PROG(CP, [cp], [cp])
1216 AC_PATH_PROG(DATE, [date], [date])
1217 AC_PATH_PROG(FIND, [find], [find])
1218 AC_PATH_PROG(GREP, [grep], [grep])
1219 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1220 AC_PATH_PROG(MV,   [mv],   [mv])
1221 AC_PROG_RANLIB
1222 AC_CHECK_TOOL(AR, ar, false)
1223 AC_PATH_PROG(RM,   [rm],   [rm])
1224 AC_PATH_PROG(SED,  [sed],  [sed])
1225 AC_PATH_PROG(TAR,  [tar],  [gtar])
1226 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1227
1228 dnl Looking for misc. graph plotting software
1229 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1230 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1231   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1232   dnl If we're targeting for mingw we should emit windows paths, not msys
1233   if test "$llvm_cv_os_type" = "MingW" ; then
1234     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1235   fi
1236   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1237    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1238 fi
1239 AC_PATH_PROG(DOT, [dot], [echo dot])
1240 if test "$DOT" != "echo dot" ; then
1241   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1242   dnl If we're targeting for mingw we should emit windows paths, not msys
1243   if test "$llvm_cv_os_type" = "MingW" ; then
1244     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1245   fi
1246   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1247    [Define to path to dot program if found or 'echo dot' otherwise])
1248 fi
1249 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1250 if test "$FDP" != "echo fdp" ; then
1251   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1252   dnl If we're targeting for mingw we should emit windows paths, not msys
1253   if test "$llvm_cv_os_type" = "MingW" ; then
1254     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1255   fi
1256   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1257    [Define to path to fdp program if found or 'echo fdp' otherwise])
1258 fi
1259 AC_PATH_PROG(NEATO, [neato], [echo neato])
1260 if test "$NEATO" != "echo neato" ; then
1261   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1262   dnl If we're targeting for mingw we should emit windows paths, not msys
1263   if test "$llvm_cv_os_type" = "MingW" ; then
1264     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1265   fi
1266   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1267    [Define to path to neato program if found or 'echo neato' otherwise])
1268 fi
1269 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1270 if test "$TWOPI" != "echo twopi" ; then
1271   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1272   dnl If we're targeting for mingw we should emit windows paths, not msys
1273   if test "$llvm_cv_os_type" = "MingW" ; then
1274     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1275   fi
1276   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1277    [Define to path to twopi program if found or 'echo twopi' otherwise])
1278 fi
1279 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1280 if test "$CIRCO" != "echo circo" ; then
1281   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1282   dnl If we're targeting for mingw we should emit windows paths, not msys
1283   if test "$llvm_cv_os_type" = "MingW" ; then
1284     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1285   fi
1286   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1287    [Define to path to circo program if found or 'echo circo' otherwise])
1288 fi
1289 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1290 if test "$GV" != "echo gv" ; then
1291   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1292   dnl If we're targeting for mingw we should emit windows paths, not msys
1293   if test "$llvm_cv_os_type" = "MingW" ; then
1294     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1295   fi
1296   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1297    [Define to path to gv program if found or 'echo gv' otherwise])
1298 fi
1299 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1300 if test "$DOTTY" != "echo dotty" ; then
1301   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1302   dnl If we're targeting for mingw we should emit windows paths, not msys
1303   if test "$llvm_cv_os_type" = "MingW" ; then
1304     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1305   fi
1306   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1307    [Define to path to dotty program if found or 'echo dotty' otherwise])
1308 fi
1309 AC_PATH_PROGS(XDOT, [xdot xdot.py], [echo xdot])
1310 if test "$XDOT" != "echo xdot" ; then
1311   AC_DEFINE([HAVE_XDOT],[1],[Define if the xdot program is available])
1312   dnl If we're targeting for mingw we should emit windows paths, not msys
1313   if test "$llvm_cv_os_type" = "MingW" ; then
1314     XDOT=`echo $XDOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1315   fi
1316   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT],"$XDOT${EXEEXT}",
1317    [Define to path to xdot program if found or 'echo xdot' otherwise])
1318 fi
1319
1320 dnl Find the install program
1321 AC_PROG_INSTALL
1322 dnl Prepend src dir to install path dir if it's a relative path
1323 dnl This is a hack for installs that take place in something other
1324 dnl than the top level.
1325 case "$INSTALL" in
1326  [[\\/$]]* | ?:[[\\/]]* ) ;;
1327  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1328 esac
1329
1330 dnl Checks for documentation and testing tools that we can do without. If these
1331 dnl are not found then they are set to "true" which always succeeds but does
1332 dnl nothing. This just lets the build output show that we could have done
1333 dnl something if the tool was available.
1334 AC_PATH_PROG(BZIP2, [bzip2])
1335 AC_PATH_PROG(CAT, [cat])
1336 AC_PATH_PROG(DOXYGEN, [doxygen])
1337 AC_PATH_PROG(GROFF, [groff])
1338 AC_PATH_PROG(GZIPBIN, [gzip])
1339 AC_PATH_PROG(PDFROFF, [pdfroff])
1340 AC_PATH_PROG(ZIP, [zip])
1341 AC_PATH_PROGS(OCAMLC, [ocamlc])
1342 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1343 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1344 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1345 AC_PATH_PROGS(GAS, [gas as])
1346
1347 dnl Get the version of the linker in use.
1348 AC_LINK_GET_VERSION
1349
1350 dnl Determine whether the linker supports the -R option.
1351 AC_LINK_USE_R
1352
1353 dnl Determine whether the compiler supports the -rdynamic option.
1354 AC_LINK_EXPORT_DYNAMIC
1355
1356 dnl Determine whether the linker supports the --version-script option.
1357 AC_LINK_VERSION_SCRIPT
1358
1359 dnl Check for libtool and the library that has dlopen function (which must come
1360 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1361 dnl libtool).
1362 AC_LIBTOOL_DLOPEN
1363 AC_LIB_LTDL
1364
1365 AC_MSG_CHECKING([tool compatibility])
1366
1367 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1368 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1369 dnl to support those options.
1370 dnl "icc" emits gcc signatures
1371 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1372 ICC=no
1373 IXX=no
1374 case $CC in
1375   icc*|icpc*)
1376     ICC=yes
1377     IXX=yes
1378     ;;
1379    *)
1380     ;;
1381 esac
1382
1383 if test "$GCC" != "yes" && test "$ICC" != "yes"
1384 then
1385   AC_MSG_ERROR([gcc|icc required but not found])
1386 fi
1387
1388 dnl Ensure that compilation tools are compatible with GCC extensions
1389 if test "$GXX" != "yes" && test "$IXX" != "yes"
1390 then
1391   AC_MSG_ERROR([g++|clang++|icc required but not found])
1392 fi
1393
1394 dnl Verify that GCC is version 3.0 or higher
1395 if test "$GCC" = "yes"
1396 then
1397   AC_COMPILE_IFELSE(
1398 [
1399   AC_LANG_SOURCE([[
1400     #if !defined(__GNUC__) || __GNUC__ < 3
1401     #error Unsupported GCC version
1402     #endif
1403   ]])
1404 ],
1405 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1406 fi
1407
1408 dnl Check for GNU Make.  We use its extensions, so don't build without it
1409 if test -z "$llvm_cv_gnu_make_command"
1410 then
1411   AC_MSG_ERROR([GNU Make required but not found])
1412 fi
1413
1414 dnl Tool compatibility is okay if we make it here.
1415 AC_MSG_RESULT([ok])
1416
1417 dnl Check optional compiler flags.
1418 AC_MSG_CHECKING([optional compiler flags])
1419 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1420 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1421 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1422
1423 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1424 dnl false positives, so disable it.
1425 NO_UNINITIALIZED=
1426 NO_MAYBE_UNINITIALIZED=
1427 if test "$GXX" = "yes"
1428 then
1429   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1430   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1431   dnl known to be uninitialized from cases which might be uninitialized.  We
1432   dnl still want to catch the first kind of errors.
1433   if test -z "$NO_MAYBE_UNINITIALIZED"
1434   then
1435     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1436   fi
1437 fi
1438 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1439
1440 AC_ARG_WITH([python],
1441             [AS_HELP_STRING([--with-python], [path to python])],
1442             [PYTHON="$withval"])
1443
1444 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1445   AC_MSG_CHECKING([for python])
1446   AC_MSG_RESULT([user defined: $with_python])
1447 else
1448   if test -n "$PYTHON" ; then
1449     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1450   fi
1451
1452   AC_PATH_PROG([PYTHON], [python python2 python26],
1453                [AC_MSG_RESULT([not found])
1454                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1455 fi
1456
1457 AC_MSG_CHECKING([for python >= 2.5])
1458 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1459 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1460 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1461 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1462 if test "$ac_python_version_major" -gt "2" || \
1463    (test "$ac_python_version_major" -eq "2" && \
1464     test "$ac_python_version_minor" -ge "5") ; then
1465   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1466 else
1467   AC_MSG_RESULT([not found])
1468   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1469 fi
1470
1471 dnl===-----------------------------------------------------------------------===
1472 dnl===
1473 dnl=== SECTION 5: Check for libraries
1474 dnl===
1475 dnl===-----------------------------------------------------------------------===
1476
1477 AC_CHECK_LIB(m,sin)
1478 if test "$llvm_cv_os_type" = "MingW" ; then
1479   AC_CHECK_LIB(imagehlp, main)
1480   AC_CHECK_LIB(psapi, main)
1481   AC_CHECK_LIB(shell32, main)
1482 fi
1483
1484 dnl dlopen() is required for plugin support.
1485 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1486                [Define if dlopen() is available on this platform.]),
1487                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1488
1489 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1490 dnl macros to detect whether clock_gettime is available, this just finds the
1491 dnl right libraries to link with.
1492 AC_SEARCH_LIBS(clock_gettime,rt)
1493
1494 dnl The curses library is optional; used for querying terminal info
1495 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1496   dnl We need the has_color functionality in curses for it to be useful.
1497   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1498                  AC_DEFINE([HAVE_TERMINFO],[1],
1499                            [Define if the setupterm() function is supported this platform.]))
1500 fi
1501
1502 dnl libffi is optional; used to call external functions from the interpreter
1503 if test "$llvm_cv_enable_libffi" = "yes" ; then
1504   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1505                  [Define if libffi is available on this platform.]),
1506                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1507 fi
1508
1509 dnl mallinfo is optional; the code can compile (minus features) without it
1510 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1511                [Define if mallinfo() is available on this platform.]))
1512
1513 dnl pthread locking functions are optional - but llvm will not be thread-safe
1514 dnl without locks.
1515 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1516   AC_CHECK_LIB(pthread, pthread_mutex_init)
1517   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1518                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1519                            [Have pthread_mutex_lock]))
1520   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1521                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1522                  [Have pthread_rwlock_init]))
1523   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1524                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1525                  [Have pthread_getspecific]))
1526 fi
1527
1528 dnl zlib is optional; used for compression/uncompression
1529 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1530   AC_CHECK_LIB(z, compress2)
1531 fi
1532
1533 dnl Allow extra x86-disassembler library
1534 AC_ARG_WITH(udis86,
1535   AS_HELP_STRING([--with-udis86=<path>],
1536     [Use udis86 external x86 disassembler library]),
1537     [
1538       AC_SUBST(USE_UDIS86, [1])
1539       case "$withval" in
1540         /usr/lib|yes) ;;
1541         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1542       esac
1543       AC_CHECK_LIB(udis86, ud_init, [], [
1544         echo "Error! You need to have libudis86 around."
1545         exit -1
1546       ])
1547     ],
1548     AC_SUBST(USE_UDIS86, [0]))
1549 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1550                    [Define if use udis86 library])
1551
1552 dnl Allow OProfile support for JIT output.
1553 AC_ARG_WITH(oprofile,
1554   AS_HELP_STRING([--with-oprofile=<prefix>],
1555     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1556     [
1557       AC_SUBST(USE_OPROFILE, [1])
1558       case "$withval" in
1559         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1560         no) llvm_cv_oppath=
1561             AC_SUBST(USE_OPROFILE, [0]) ;;
1562         *) llvm_cv_oppath="${withval}/lib/oprofile"
1563            CPPFLAGS="-I${withval}/include";;
1564       esac
1565       case $llvm_cv_os_type in
1566         Linux)
1567           if test -n "$llvm_cv_oppath" ; then
1568             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1569             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1570             dnl libbfd is not included properly in libopagent in some Debian
1571             dnl versions.  If libbfd isn't found at all, we assume opagent works
1572             dnl anyway.
1573             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1574             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1575               echo "Error! You need to have libopagent around."
1576               exit -1
1577             ])
1578             AC_CHECK_HEADER([opagent.h], [], [
1579               echo "Error! You need to have opagent.h around."
1580               exit -1
1581               ])
1582           fi ;;
1583         *)
1584           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1585       esac
1586     ],
1587     [
1588       AC_SUBST(USE_OPROFILE, [0])
1589     ])
1590 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1591                    [Define if we have the oprofile JIT-support library])
1592
1593 dnl Enable support for Intel JIT Events API.
1594 AC_ARG_WITH(intel-jitevents,
1595   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1596     [
1597        case "$withval" in
1598           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1599           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1600           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1601        esac
1602
1603       case $llvm_cv_os_type in
1604         Linux|Win32|Cygwin|MingW) ;;
1605         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1606       esac
1607
1608       case "$llvm_cv_target_arch" in
1609         x86|x86_64) ;;
1610         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1611       esac
1612     ],
1613     [
1614       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1615     ])
1616 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1617                    [Define if we have the Intel JIT API runtime support library])
1618
1619 dnl Check for libxml2
1620 dnl Right now we're just checking for the existence, we could also check for a
1621 dnl particular version via --version on xml2-config
1622 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1623
1624 AC_MSG_CHECKING(for libxml2 includes)
1625 if test "x$XML2CONFIG" = "x"; then
1626  AC_MSG_RESULT(xml2-config not found)
1627 else
1628  LIBXML2_INC=`$XML2CONFIG --cflags`
1629  AC_MSG_RESULT($LIBXML2_INC)
1630  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1631                                 LIBXML2_LIBS="-lxml2"])
1632 fi
1633 AC_SUBST(LIBXML2_LIBS)
1634 AC_SUBST(LIBXML2_INC)
1635
1636 dnl===-----------------------------------------------------------------------===
1637 dnl===
1638 dnl=== SECTION 6: Check for header files
1639 dnl===
1640 dnl===-----------------------------------------------------------------------===
1641
1642 dnl First, use autoconf provided macros for specific headers that we need
1643 dnl We don't check for ancient stuff or things that are guaranteed to be there
1644 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1645 dnl Generally we're looking for POSIX headers.
1646 AC_HEADER_DIRENT
1647 AC_HEADER_MMAP_ANONYMOUS
1648 AC_HEADER_STAT
1649 AC_HEADER_SYS_WAIT
1650 AC_HEADER_TIME
1651
1652 AC_LANG_PUSH([C++])
1653 AC_CHECK_HEADERS([cxxabi.h])
1654 AC_LANG_POP([C++])
1655 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1656 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1657 AC_CHECK_HEADERS([utime.h])
1658 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1659 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1660 AC_CHECK_HEADERS([valgrind/valgrind.h])
1661 AC_CHECK_HEADERS([fenv.h])
1662 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1663 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1664   AC_CHECK_HEADERS(pthread.h,
1665                    AC_SUBST(HAVE_PTHREAD, 1),
1666                    AC_SUBST(HAVE_PTHREAD, 0))
1667 else
1668   AC_SUBST(HAVE_PTHREAD, 0)
1669 fi
1670 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1671   AC_CHECK_HEADERS(zlib.h,
1672                    AC_SUBST(HAVE_LIBZ, 1),
1673                    AC_SUBST(HAVE_LIBZ, 0))
1674 else
1675   AC_SUBST(HAVE_LIBZ, 0)
1676 fi
1677
1678 dnl Try to find ffi.h.
1679 if test "$llvm_cv_enable_libffi" = "yes" ; then
1680   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1681 fi
1682
1683 dnl Try to find Darwin specific crash reporting libraries.
1684 AC_CHECK_HEADERS([CrashReporterClient.h])
1685
1686 dnl Try to find Darwin specific crash reporting global.
1687 AC_MSG_CHECKING([__crashreporter_info__])
1688 AC_LINK_IFELSE(
1689 [
1690   AC_LANG_SOURCE([[
1691     extern const char *__crashreporter_info__;
1692     int main() {
1693       __crashreporter_info__ = "test";
1694       return 0;
1695     }
1696   ]])
1697 ],
1698 [
1699   AC_MSG_RESULT([yes])
1700   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1701 ],
1702 [
1703   AC_MSG_RESULT([no])
1704   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1705 ])
1706
1707 dnl===-----------------------------------------------------------------------===
1708 dnl===
1709 dnl=== SECTION 7: Check for types and structures
1710 dnl===
1711 dnl===-----------------------------------------------------------------------===
1712
1713 AC_HUGE_VAL_CHECK
1714 AC_TYPE_PID_T
1715 AC_TYPE_SIZE_T
1716 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1717 AC_STRUCT_TM
1718 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1719 AC_CHECK_TYPES([uint64_t],,
1720          AC_CHECK_TYPES([u_int64_t],,
1721          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1722
1723 dnl===-----------------------------------------------------------------------===
1724 dnl===
1725 dnl=== SECTION 8: Check for specific functions needed
1726 dnl===
1727 dnl===-----------------------------------------------------------------------===
1728
1729 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1730 AC_CHECK_FUNCS([powf fmodf strtof round ])
1731 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1732 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1733 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1734 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1735 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1736 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1737 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1738 AC_CHECK_FUNCS([futimes futimens])
1739 AC_C_PRINTF_A
1740 AC_FUNC_RAND48
1741
1742 dnl Check the declaration "Secure API" on Windows environments.
1743 AC_CHECK_DECLS([strerror_s])
1744
1745 dnl Check symbols in libgcc.a for JIT on Mingw.
1746 if test "$llvm_cv_os_type" = "MingW" ; then
1747   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1748   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1749   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1750   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1751
1752   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1753   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1754   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1755   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1756   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1757   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1758   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1759   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1760   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1761   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1762
1763   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1764   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1765 fi
1766
1767 dnl Check Win32 API EnumerateLoadedModules.
1768 if test "$llvm_cv_os_type" = "MingW" ; then
1769   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1770   AC_COMPILE_IFELSE(
1771 [
1772   AC_LANG_SOURCE([[
1773     #include <windows.h>
1774     #include <imagehlp.h>
1775     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1776     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1777   ]])
1778 ],
1779 [
1780   AC_MSG_RESULT([yes])
1781   llvm_cv_win32_elmcb_pcstr="PCSTR"
1782 ],
1783 [
1784   AC_MSG_RESULT([no])
1785   llvm_cv_win32_elmcb_pcstr="PSTR"
1786 ])
1787   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1788 fi
1789
1790 dnl Check for variations in the Standard C++ library and STL. These macros are
1791 dnl provided by LLVM in the autoconf/m4 directory.
1792 AC_FUNC_ISNAN
1793 AC_FUNC_ISINF
1794
1795 dnl Check for mmap support.We also need to know if /dev/zero is required to
1796 dnl be opened for allocating RWX memory.
1797 dnl Make sure we aren't attempting to configure for an unknown system
1798 if test "$llvm_cv_platform_type" = "Unix" ; then
1799   AC_FUNC_MMAP
1800   AC_FUNC_MMAP_FILE
1801   AC_NEED_DEV_ZERO_FOR_MMAP
1802
1803   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1804   then
1805     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1806   fi
1807   if test "$ac_cv_func_mmap_file" = "no"
1808   then
1809     AC_MSG_WARN([mmap() of files required but not found])
1810   fi
1811 fi
1812
1813 dnl atomic builtins are required for threading support.
1814 AC_MSG_CHECKING(for GCC atomic builtins)
1815 dnl Since we'll be using these atomic builtins in C++ files we should test
1816 dnl the C++ compiler.
1817 AC_LANG_PUSH([C++])
1818 AC_LINK_IFELSE(
1819 [
1820   AC_LANG_SOURCE([[
1821     int main() {
1822       volatile unsigned long val = 1;
1823       __sync_synchronize();
1824       __sync_val_compare_and_swap(&val, 1, 0);
1825       __sync_add_and_fetch(&val, 1);
1826       __sync_sub_and_fetch(&val, 1);
1827       return 0;
1828     }
1829   ]])
1830 ],
1831 [
1832   AC_MSG_RESULT([yes])
1833   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1834 ],
1835 [
1836   AC_MSG_RESULT([no])
1837   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1838   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1839 ])
1840 AC_LANG_POP([C++])
1841
1842 dnl===-----------------------------------------------------------------------===
1843 dnl===
1844 dnl=== SECTION 9: Additional checks, variables, etc.
1845 dnl===
1846 dnl===-----------------------------------------------------------------------===
1847
1848 dnl Handle 32-bit linux systems running a 64-bit kernel.
1849 dnl This has to come after section 4 because it invokes the compiler.
1850 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1851   AC_IS_LINUX_MIXED
1852   if test "$llvm_cv_linux_mixed" = "yes"; then
1853     llvm_cv_target_arch="x86"
1854     ARCH="x86"
1855   fi
1856 fi
1857
1858 dnl Check whether __dso_handle is present
1859 AC_CHECK_FUNCS([__dso_handle])
1860
1861 dnl Propagate the shared library extension that the libltdl checks did to
1862 dnl the Makefiles so we can use it there too
1863 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1864
1865 dnl Propagate the run-time library path variable that the libltdl
1866 dnl checks found to the Makefiles so we can use it there too
1867 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1868
1869 dnl Translate the various configuration directories and other basic
1870 dnl information into substitutions that will end up in Makefile.config.in
1871 dnl that these configured values can be used by the makefiles
1872 if test "${prefix}" = "NONE" ; then
1873   prefix="/usr/local"
1874 fi
1875 eval LLVM_PREFIX="${prefix}";
1876 eval LLVM_BINDIR="${prefix}/bin";
1877 eval LLVM_DATADIR="${prefix}/share/llvm";
1878 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1879 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1880 eval LLVM_INCLUDEDIR="${prefix}/include";
1881 eval LLVM_INFODIR="${prefix}/info";
1882 eval LLVM_MANDIR="${prefix}/man";
1883 LLVM_CONFIGTIME=`date`
1884 AC_SUBST(LLVM_PREFIX)
1885 AC_SUBST(LLVM_BINDIR)
1886 AC_SUBST(LLVM_DATADIR)
1887 AC_SUBST(LLVM_DOCSDIR)
1888 AC_SUBST(LLVM_ETCDIR)
1889 AC_SUBST(LLVM_INCLUDEDIR)
1890 AC_SUBST(LLVM_INFODIR)
1891 AC_SUBST(LLVM_MANDIR)
1892 AC_SUBST(LLVM_CONFIGTIME)
1893
1894 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1895 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1896   LLVM_CONFIGTIME="(timestamp not enabled)"
1897 fi
1898
1899 dnl Place the various directories into the config.h file as #defines so that we
1900 dnl can know about the installation paths within LLVM.
1901 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1902                    [Installation prefix directory])
1903 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1904                    [Installation directory for binary executables])
1905 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1906                    [Installation directory for data files])
1907 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1908                    [Installation directory for documentation])
1909 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1910                    [Installation directory for config files])
1911 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1912                    [Installation directory for include files])
1913 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1914                    [Installation directory for .info files])
1915 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1916                    [Installation directory for man pages])
1917 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1918                    [Time at which LLVM was configured])
1919 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1920                    [Host triple LLVM will be executed on])
1921 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1922                    [Target triple LLVM will generate code for by default])
1923
1924 dnl Determine which bindings to build.
1925 if test "$BINDINGS_TO_BUILD" = auto ; then
1926   BINDINGS_TO_BUILD=""
1927   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1928     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1929   fi
1930 fi
1931 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1932
1933 dnl This isn't really configurey, but it avoids having to repeat the list in
1934 dnl other files.
1935 AC_SUBST(ALL_BINDINGS,ocaml)
1936
1937 dnl Do any work necessary to ensure that bindings have what they need.
1938 binding_prereqs_failed=0
1939 for a_binding in $BINDINGS_TO_BUILD ; do
1940   case "$a_binding" in
1941   ocaml)
1942     if test "x$OCAMLC" = x ; then
1943       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1944       binding_prereqs_failed=1
1945     fi
1946     if test "x$OCAMLDEP" = x ; then
1947       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1948       binding_prereqs_failed=1
1949     fi
1950     if test "x$OCAMLOPT" = x ; then
1951       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1952       dnl ocamlopt is optional!
1953     fi
1954     if test "x$with_ocaml_libdir" != xauto ; then
1955       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1956     else
1957       ocaml_stdlib="`"$OCAMLC" -where`"
1958       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1959       then
1960         # ocaml stdlib is beneath our prefix; use stdlib
1961         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1962       else
1963         # ocaml stdlib is outside our prefix; use libdir/ocaml
1964         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
1965       fi
1966     fi
1967     ;;
1968   esac
1969 done
1970 if test "$binding_prereqs_failed" = 1 ; then
1971   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1972 fi
1973
1974 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1975 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1976
1977 dnl Determine linker rpath flag
1978 if test "$llvm_cv_link_use_r" = "yes" ; then
1979   RPATH="-Wl,-R"
1980 else
1981   RPATH="-Wl,-rpath"
1982 fi
1983 AC_SUBST(RPATH)
1984
1985 dnl Determine linker rdynamic flag
1986 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1987   RDYNAMIC="-rdynamic"
1988 else
1989   RDYNAMIC=""
1990 fi
1991 AC_SUBST(RDYNAMIC)
1992
1993 dnl===-----------------------------------------------------------------------===
1994 dnl===
1995 dnl=== SECTION 10: Specify the output files and generate it
1996 dnl===
1997 dnl===-----------------------------------------------------------------------===
1998
1999 dnl Configure header files
2000 dnl WARNING: dnl If you add or remove any of the following config headers, then
2001 dnl you MUST also update Makefile so that the variable FilesToConfig
2002 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2003 dnl files can be updated automatically when their *.in sources change.
2004 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2005 AH_TOP([#ifndef CONFIG_H
2006 #define CONFIG_H])
2007 AH_BOTTOM([#endif])
2008
2009 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2010 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2011 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2012 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2013 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2014
2015 dnl Configure the makefile's configuration data
2016 AC_CONFIG_FILES([Makefile.config])
2017
2018 dnl Configure the RPM spec file for LLVM
2019 AC_CONFIG_FILES([llvm.spec])
2020
2021 dnl Configure doxygen's configuration file
2022 AC_CONFIG_FILES([docs/doxygen.cfg])
2023
2024 dnl Configure clang, if present
2025 if test "${clang_src_root}" = ""; then
2026   clang_src_root="$srcdir/tools/clang"
2027 fi
2028 if test -f ${clang_src_root}/README.txt; then
2029   dnl Use variables to stay under 80 columns.
2030   configh="include/clang/Config/config.h"
2031   doxy="docs/doxygen.cfg"
2032   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2033   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2034 fi
2035
2036 dnl OCaml findlib META file
2037 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2038
2039 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2040 test "x$program_prefix" = "xNONE" && program_prefix=""
2041 AC_SUBST([program_prefix])
2042
2043
2044 dnl Do special configuration of Makefiles
2045 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2046 AC_CONFIG_MAKEFILE(Makefile)
2047 AC_CONFIG_MAKEFILE(Makefile.common)
2048 AC_CONFIG_MAKEFILE(examples/Makefile)
2049 AC_CONFIG_MAKEFILE(lib/Makefile)
2050 AC_CONFIG_MAKEFILE(test/Makefile)
2051 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2052 AC_CONFIG_MAKEFILE(unittests/Makefile)
2053 AC_CONFIG_MAKEFILE(tools/Makefile)
2054 AC_CONFIG_MAKEFILE(utils/Makefile)
2055 AC_CONFIG_MAKEFILE(projects/Makefile)
2056 AC_CONFIG_MAKEFILE(bindings/Makefile)
2057 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2058
2059 dnl Finally, crank out the output
2060 AC_OUTPUT