autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.6svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 225   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 226   mips-*)                 llvm_cv_target_arch="Mips" ;;
 227   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 228   xcore-*)                llvm_cv_target_arch="XCore" ;;
 229   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 230   *)                      llvm_cv_target_arch="Unknown" ;;
 231 esac])
 232
 233 if test "$llvm_cv_target_arch" = "Unknown" ; then
 234   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 235 fi
 236
 237 dnl Define a substitution, ARCH, for the target architecture
 238 AC_SUBST(ARCH,$llvm_cv_target_arch)
 239
 240 dnl Check for the endianness of the target
 241 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 242
 243 dnl Check for build platform executable suffix if we're crosscompiling
 244 if test "$cross_compiling" = yes; then
 245   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 246   AC_BUILD_EXEEXT
 247   ac_build_prefix=${build_alias}-
 248   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 249   if test -z "$BUILD_CXX"; then
 250      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 251      if test -z "$BUILD_CXX"; then
 252        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 253      fi
 254   fi
 255 else
 256   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 257 fi
 258
 259 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 260 dnl that this build is being done from a checkout. This sets up several
 261 dnl defaults for the command line switches. When we build with a CVS directory,
 262 dnl we get a debug with assertions turned on. Without, we assume a source
 263 dnl release and we get an optimized build without assertions.
 264 dnl See --enable-optimized and --enable-assertions below
 265 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 266   cvsbuild="yes"
 267   optimize="no"
 268   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 269 else
 270   cvsbuild="no"
 271   optimize="yes"
 272 fi
 273
 274 dnl===-----------------------------------------------------------------------===
 275 dnl===
 276 dnl=== SECTION 3: Command line arguments for the configure script.
 277 dnl===
 278 dnl===-----------------------------------------------------------------------===
 279
 280 dnl --enable-optimized : check whether they want to do an optimized build:
 281 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 282  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 283 if test ${enableval} = "no" ; then
 284   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 285 else
 286   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 287 fi
 288
 289 dnl --enable-profiling : check whether they want to do a profile build:
 290 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 291  [--enable-profiling,Compile with profiling enabled (default is NO)]),,enableval="no")
 292 if test ${enableval} = "no" ; then
 293   AC_SUBST(ENABLE_PROFILING,[[]])
 294 else
 295   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 296 fi
 297
 298 dnl --enable-assertions : check whether they want to turn on assertions or not:
 299 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 300   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 301 if test ${enableval} = "yes" ; then
 302   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 303 else
 304   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 305 fi
 306
 307 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 308 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 309   [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 310 if test ${enableval} = "yes" ; then
 311   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 312   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 313 else
 314   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 315   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 316 fi
 317
 318 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 319 AC_ARG_ENABLE(debug-runtime,
 320    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 321 if test ${enableval} = "no" ; then
 322   AC_SUBST(DEBUG_RUNTIME,[[]])
 323 else
 324   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 325 fi
 326
 327 dnl --enable-jit: check whether they want to enable the jit
 328 AC_ARG_ENABLE(jit,
 329   AS_HELP_STRING(--enable-jit,
 330                  [Enable Just In Time Compiling (default is YES)]),,
 331   enableval=default)
 332 if test ${enableval} = "no"
 333 then
 334   AC_SUBST(JIT,[[]])
 335 else
 336   case "$llvm_cv_target_arch" in
 337     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 338     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 339     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 340     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 341     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 342     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 343     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 344     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 345     PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 346     XCore)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 347     MSP430)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 348     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 349   esac
 350 fi
 351
 352 dnl Allow enablement of doxygen generated documentation
 353 AC_ARG_ENABLE(doxygen,
 354               AS_HELP_STRING([--enable-doxygen],
 355                              [Build doxygen documentation (default is NO)]),,
 356                              enableval=default)
 357 case "$enableval" in
 358   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 359   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 360   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 361   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 362 esac
 363
 364 dnl Allow disablement of threads
 365 AC_ARG_ENABLE(threads,
 366               AS_HELP_STRING([--enable-threads],
 367                              [Use threads if available (default is YES)]),,
 368                              enableval=default)
 369 case "$enableval" in
 370   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 371   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 372   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 373   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 374 esac
 375
 376 dnl Allow building without position independent code
 377 AC_ARG_ENABLE(pic,
 378   AS_HELP_STRING([--enable-pic],
 379                  [Build LLVM with Position Independent Code (default is YES)]),,
 380                  enableval=default)
 381 case "$enableval" in
 382   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 383   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 384   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 385   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 386 esac
 387 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 388                    [Define if position independent code is enabled])
 389
 390 dnl Allow specific targets to be specified for building (or not)
 391 TARGETS_TO_BUILD=""
 392 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 393     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 394     enableval=all)
 395 case "$enableval" in
 396   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 XCore MSP430 CBackend MSIL CppBackend" ;;
 397   host-only)
 398     case "$llvm_cv_target_arch" in
 399       x86)     TARGETS_TO_BUILD="X86" ;;
 400       x86_64)  TARGETS_TO_BUILD="X86" ;;
 401       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 402       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 403       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 404       IA64)    TARGETS_TO_BUILD="IA64" ;;
 405       ARM)     TARGETS_TO_BUILD="ARM" ;;
 406       Mips)    TARGETS_TO_BUILD="Mips" ;;
 407       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 408       PIC16)   TARGETS_TO_BUILD="PIC16" ;;
 409       XCore)   TARGETS_TO_BUILD="XCore" ;;
 410       MSP430)  TARGETS_TO_BUILD="MSP430" ;;
 411       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 412     esac
 413     ;;
 414   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 415       case "$a_target" in
 416         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 417         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 418         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 419         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 420         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 421         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 422         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 423         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 424         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 425         pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 426         xcore)   TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 427         msp430)  TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 428         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 429         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 430         cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 431         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 432       esac
 433   done
 434   ;;
 435 esac
 436 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 437
 438 dnl Prevent the CBackend from using printf("%a") for floating point so older
 439 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 440 dnl can still compile the CBE's output
 441 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 442   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 443   enableval=default)
 444 case "$enableval" in
 445   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 446   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 447   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 448   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 449 esac
 450 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 451                    [Define if CBE is enabled for printf %a output])
 452
 453 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 454 AC_ARG_WITH(llvmgccdir,
 455   AS_HELP_STRING([--with-llvmgccdir],
 456     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 457     withval=default)
 458 case "$withval" in
 459   default) WITH_LLVMGCCDIR=default ;;
 460   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 461   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 462 esac
 463
 464 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 465 AC_ARG_WITH(llvmgcc,
 466   AS_HELP_STRING([--with-llvmgcc],
 467     [Specify location of llvm-gcc driver (default searches PATH)]),
 468     LLVMGCC=$with_llvmgcc
 469       WITH_LLVMGCCDIR="",)
 470
 471 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 472 AC_ARG_WITH(llvmgxx,
 473   AS_HELP_STRING([--with-llvmgxx],
 474     [Specify location of llvm-g++ driver (default searches PATH)]),
 475     LLVMGXX=$with_llvmgxx
 476     WITH_LLVMGCCDIR="",)
 477
 478 if test -n "$LLVMGCC"; then
 479    LLVMGCCCOMMAND="$LLVMGCC"
 480 fi
 481
 482 if test -n "$LLVMGXX"; then
 483    LLVMGXXCOMMAND="$LLVMGXX"
 484 fi
 485
 486 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 487    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 488 fi
 489
 490 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 491    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 492 fi
 493
 494 dnl Specify extra build options
 495 AC_ARG_WITH(extra-options,
 496   AS_HELP_STRING([--with-extra-options],
 497                  [Specify additional options to compile LLVM with]),,
 498                  withval=default)
 499 case "$withval" in
 500   default) EXTRA_OPTIONS= ;;
 501   *) EXTRA_OPTIONS=$withval ;;
 502 esac
 503 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 504
 505 dnl Allow specific bindings to be specified for building (or not)
 506 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 507     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 508     enableval=default)
 509 BINDINGS_TO_BUILD=""
 510 case "$enableval" in
 511   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 512   all ) BINDINGS_TO_BUILD="ocaml" ;;
 513   none | no) BINDINGS_TO_BUILD="" ;;
 514   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 515       case "$a_binding" in
 516         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 517         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 518       esac
 519   done
 520   ;;
 521 esac
 522
 523 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 524 dnl script for bindings/ocaml/configure, except that its auto value depends on
 525 dnl OCAMLC, which is found here to support tests.
 526 AC_ARG_WITH([ocaml-libdir],
 527   [AS_HELP_STRING([--with-ocaml-libdir],
 528     [Specify install location for ocaml bindings (default is stdlib)])],
 529   [],
 530   [withval=auto])
 531 case "$withval" in
 532   auto) with_ocaml_libdir="$withval" ;;
 533   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 534   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 535 esac
 536
 537 dnl Allow linking of LLVM with GPLv3 binutils code.
 538 AC_ARG_WITH(binutils-include,
 539   AS_HELP_STRING([--with-binutils-include],
 540     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 541   withval=default)
 542 case "$withval" in
 543   default) WITH_BINUTILS_INCDIR=default ;;
 544   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 545   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 546 esac
 547 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 548   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 549   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 550      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 551      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 552   fi
 553 fi
 554
 555 dnl===-----------------------------------------------------------------------===
 556 dnl===
 557 dnl=== SECTION 4: Check for programs we need and that they are the right version
 558 dnl===
 559 dnl===-----------------------------------------------------------------------===
 560
 561 dnl Check for compilation tools
 562 AC_PROG_CPP
 563 AC_PROG_CC(gcc)
 564 AC_PROG_CXX(g++)
 565
 566 AC_PROG_NM
 567 AC_SUBST(NM)
 568
 569 dnl Check for the tools that the makefiles require
 570 AC_CHECK_GNU_MAKE
 571 AC_PROG_LN_S
 572 AC_PATH_PROG(CMP, [cmp], [cmp])
 573 AC_PATH_PROG(CP, [cp], [cp])
 574 AC_PATH_PROG(DATE, [date], [date])
 575 AC_PATH_PROG(FIND, [find], [find])
 576 AC_PATH_PROG(GREP, [grep], [grep])
 577 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 578 AC_PATH_PROG(MV,   [mv],   [mv])
 579 AC_PROG_RANLIB
 580 AC_PATH_PROG(RM,   [rm],   [rm])
 581 AC_PATH_PROG(SED,  [sed],  [sed])
 582 AC_PATH_PROG(TAR,  [tar],  [gtar])
 583 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 584
 585 dnl Looking for misc. graph plotting software
 586 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 587 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 588   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 589   dnl If we're targeting for mingw we should emit windows paths, not msys
 590   if test "$llvm_cv_os_type" = "MingW" ; then
 591     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 592   fi
 593   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 594    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 595 fi
 596 AC_PATH_PROG(DOT, [dot], [echo dot])
 597 if test "$DOT" != "echo dot" ; then
 598   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 599   dnl If we're targeting for mingw we should emit windows paths, not msys
 600   if test "$llvm_cv_os_type" = "MingW" ; then
 601     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 602   fi
 603   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 604    [Define to path to dot program if found or 'echo dot' otherwise])
 605 fi
 606 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 607 if test "$GV" != "echo gv" ; then
 608   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 609   dnl If we're targeting for mingw we should emit windows paths, not msys
 610   if test "$llvm_cv_os_type" = "MingW" ; then
 611     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 612   fi
 613   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 614    [Define to path to gv program if found or 'echo gv' otherwise])
 615 fi
 616 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 617 if test "$DOTTY" != "echo dotty" ; then
 618   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 619   dnl If we're targeting for mingw we should emit windows paths, not msys
 620   if test "$llvm_cv_os_type" = "MingW" ; then
 621     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 622   fi
 623   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 624    [Define to path to dotty program if found or 'echo dotty' otherwise])
 625 fi
 626
 627 dnl Look for a sufficiently recent version of Perl.
 628 LLVM_PROG_PERL([5.006])
 629 AC_SUBST(PERL)
 630 if test x"$PERL" = xnone; then
 631    AC_SUBST(HAVE_PERL,0)
 632    AC_MSG_ERROR([perl is required but was not found, please install it])
 633 else
 634    AC_SUBST(HAVE_PERL,1)
 635 fi
 636
 637 dnl Find the install program
 638 AC_PROG_INSTALL
 639
 640 dnl Checks for documentation and testing tools that we can do without. If these
 641 dnl are not found then they are set to "true" which always succeeds but does
 642 dnl nothing. This just lets the build output show that we could have done
 643 dnl something if the tool was available.
 644 AC_PATH_PROG(BZIP2, [bzip2])
 645 AC_PATH_PROG(DOXYGEN, [doxygen])
 646 AC_PATH_PROG(GROFF, [groff])
 647 AC_PATH_PROG(GZIP, [gzip])
 648 AC_PATH_PROG(POD2HTML, [pod2html])
 649 AC_PATH_PROG(POD2MAN, [pod2man])
 650 AC_PATH_PROG(RUNTEST, [runtest])
 651 DJ_AC_PATH_TCLSH
 652 AC_PATH_PROG(ZIP, [zip])
 653 AC_PATH_PROGS(OCAMLC, [ocamlc])
 654 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 655 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 656 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 657 AC_PATH_PROGS(GAS, [gas as])
 658
 659 dnl Determine whether the linker supports the -R option.
 660 AC_LINK_USE_R
 661
 662 dnl Determine whether the linker supports the -export-dynamic option.
 663 AC_LINK_EXPORT_DYNAMIC
 664
 665 dnl Check for libtool and the library that has dlopen function (which must come
 666 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 667 dnl libtool).
 668 AC_LIBTOOL_DLOPEN
 669 AC_LIB_LTDL
 670 AC_PROG_LIBTOOL
 671
 672 if test "$lt_cv_dlopen_self" = "yes" ; then
 673   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 674               [Define if dlopen(0) will open the symbols of the program])
 675 fi
 676
 677
 678 if test "$WITH_LLVMGCCDIR" = "default" ; then
 679   LLVMGCC="llvm-gcc${EXEEXT}"
 680   LLVMGXX="llvm-g++${EXEEXT}"
 681   LLVMGCCCOMMAND="$LLVMGCC"
 682   LLVMGXXCOMMAND="$LLVMGXX"
 683   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 684   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 685   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 686   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 687 else
 688   if test -z "$LLVMGCC"; then
 689     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 690     LLVMGCCCOMMAND="$LLVMGCC"
 691   fi
 692   if test -z "$LLVMGXX"; then
 693     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 694     LLVMGXXCOMMAND="$LLVMGXX"
 695   fi
 696
 697   AC_SUBST(LLVMGCC,$LLVMGCC)
 698   AC_SUBST(LLVMGXX,$LLVMGXX)
 699   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 700   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 701 fi
 702
 703
 704 AC_MSG_CHECKING([tool compatibility])
 705
 706 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 707 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 708 dnl to support those options.
 709 dnl "icc" emits gcc signatures
 710 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 711 ICC=no
 712 IXX=no
 713 case $CC in
 714   icc*|icpc*)
 715     ICC=yes
 716     IXX=yes
 717     ;;
 718    *)
 719     ;;
 720 esac
 721
 722 if test "$GCC" != "yes" && test "$ICC" != "yes"
 723 then
 724   AC_MSG_ERROR([gcc|icc required but not found])
 725 fi
 726
 727 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 728 if test "$GXX" != "yes" && test "$IXX" != "yes"
 729 then
 730   AC_MSG_ERROR([g++|icc required but not found])
 731 fi
 732
 733 dnl Verify that GCC is version 3.0 or higher
 734 if test "$GCC" = "yes"
 735 then
 736   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 737 #error Unsupported GCC version
 738 #endif
 739 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 740 fi
 741
 742 dnl Check for GNU Make.  We use its extensions, so don't build without it
 743 if test -z "$llvm_cv_gnu_make_command"
 744 then
 745   AC_MSG_ERROR([GNU Make required but not found])
 746 fi
 747
 748 dnl Tool compatibility is okay if we make it here.
 749 AC_MSG_RESULT([ok])
 750
 751 dnl===-----------------------------------------------------------------------===
 752 dnl===
 753 dnl=== SECTION 5: Check for libraries
 754 dnl===
 755 dnl===-----------------------------------------------------------------------===
 756
 757 dnl libelf is for sparc only; we can ignore it if we don't have it
 758 AC_CHECK_LIB(elf, elf_begin)
 759 AC_CHECK_LIB(m,sin)
 760 if test "$llvm_cv_os_type" = "MingW" ; then
 761   AC_CHECK_LIB(imagehlp, main)
 762   AC_CHECK_LIB(psapi, main)
 763 fi
 764
 765 dnl dlopen() is required for plugin support.
 766 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 767                [Define if dlopen() is available on this platform.]),
 768                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 769
 770 dnl libffi is optional; used to call external functions from the interpreter
 771 AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 772                [Define if libffi is available on this platform.]),
 773                AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 774
 775 dnl mallinfo is optional; the code can compile (minus features) without it
 776 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 777                [Define if mallinfo() is available on this platform.]))
 778
 779 dnl pthread locking functions are optional - but llvm will not be thread-safe
 780 dnl without locks.
 781 if test "$ENABLE_THREADS" -eq 1 ; then
 782   AC_CHECK_LIB(pthread,pthread_mutex_init)
 783   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 784                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 785                            [Have pthread_mutex_lock]))
 786 fi
 787
 788 dnl Allow extra x86-disassembler library
 789 AC_ARG_WITH(udis86,
 790   AS_HELP_STRING([--with-udis86=<path>],
 791     [Use udis86 external x86 disassembler library]),
 792     [
 793       AC_SUBST(USE_UDIS86, [1])
 794       case "$withval" in
 795         /usr/lib|yes) ;;
 796         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 797       esac
 798       AC_CHECK_LIB(udis86, ud_init, [], [
 799         echo "Error! You need to have libudis86 around."
 800         exit -1
 801       ])
 802     ],
 803     AC_SUBST(USE_UDIS86, [0]))
 804 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 805                    [Define if use udis86 library])
 806
 807 dnl===-----------------------------------------------------------------------===
 808 dnl===
 809 dnl=== SECTION 6: Check for header files
 810 dnl===
 811 dnl===-----------------------------------------------------------------------===
 812
 813 dnl First, use autoconf provided macros for specific headers that we need
 814 dnl We don't check for ancient stuff or things that are guaranteed to be there
 815 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 816 dnl Generally we're looking for POSIX headers.
 817 AC_HEADER_DIRENT
 818 AC_HEADER_MMAP_ANONYMOUS
 819 AC_HEADER_STAT
 820 AC_HEADER_STDC
 821 AC_HEADER_SYS_WAIT
 822 AC_HEADER_TIME
 823
 824 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 825 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
 826 AC_CHECK_HEADERS([utime.h windows.h])
 827 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 828 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
 829 if test "$ENABLE_THREADS" -eq 1 ; then
 830   AC_CHECK_HEADERS(pthread.h,
 831                    AC_SUBST(HAVE_PTHREAD, 1),
 832                    AC_SUBST(HAVE_PTHREAD, 0))
 833 else
 834   AC_SUBST(HAVE_PTHREAD, 0)
 835 fi
 836
 837 dnl Try to find ffi.h.
 838 AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
 839
 840 dnl===-----------------------------------------------------------------------===
 841 dnl===
 842 dnl=== SECTION 7: Check for types and structures
 843 dnl===
 844 dnl===-----------------------------------------------------------------------===
 845
 846 AC_HUGE_VAL_CHECK
 847 AC_TYPE_PID_T
 848 AC_TYPE_SIZE_T
 849 AC_TYPE_SIGNAL
 850 AC_STRUCT_TM
 851 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 852 AC_CHECK_TYPES([uint64_t],,
 853          AC_CHECK_TYPES([u_int64_t],,
 854          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 855
 856 dnl===-----------------------------------------------------------------------===
 857 dnl===
 858 dnl=== SECTION 8: Check for specific functions needed
 859 dnl===
 860 dnl===-----------------------------------------------------------------------===
 861
 862 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 863 AC_CHECK_FUNCS([powf fmodf strtof round ])
 864 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 865 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 866 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 867 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 868 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 869 AC_C_PRINTF_A
 870 AC_FUNC_ALLOCA
 871 AC_FUNC_RAND48
 872
 873 dnl Check for variations in the Standard C++ library and STL. These macros are
 874 dnl provided by LLVM in the autoconf/m4 directory.
 875 AC_CXX_HAVE_STD_ITERATOR
 876 AC_CXX_HAVE_BI_ITERATOR
 877 AC_CXX_HAVE_FWD_ITERATOR
 878 AC_FUNC_ISNAN
 879 AC_FUNC_ISINF
 880
 881 dnl Check for mmap support.We also need to know if /dev/zero is required to
 882 dnl be opened for allocating RWX memory.
 883 dnl Make sure we aren't attempting to configure for an unknown system
 884 if test "$llvm_cv_platform_type" = "Unix" ; then
 885   AC_FUNC_MMAP
 886   AC_FUNC_MMAP_FILE
 887   AC_NEED_DEV_ZERO_FOR_MMAP
 888
 889   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 890   then
 891     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 892   fi
 893   if test "$ac_cv_func_mmap_file" = "no"
 894   then
 895     AC_MSG_WARN([mmap() of files required but not found])
 896   fi
 897 fi
 898
 899 dnl atomic builtins are required for threading support.
 900 if test "$ENABLE_THREADS" -eq 1 ; then
 901   AC_MSG_CHECKING(for GCC atomic builtins)
 902   AC_LINK_IFELSE(
 903         AC_LANG_SOURCE(
 904           [[int main() {
 905               volatile unsigned long val = 1;
 906               __sync_synchronize();
 907               __sync_val_compare_and_swap(&val, 1, 0);
 908               return 0;
 909             }
 910           ]]),
 911         AC_MSG_RESULT(yes),
 912         AC_MSG_RESULT(no)
 913         AC_SUBST(ENABLE_THREADS, [0])
 914         AC_MSG_WARN([Threading support disabled because atomic builtins are missing]))
 915 fi
 916
 917 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 918
 919 dnl===-----------------------------------------------------------------------===
 920 dnl===
 921 dnl=== SECTION 9: Additional checks, variables, etc.
 922 dnl===
 923 dnl===-----------------------------------------------------------------------===
 924
 925 dnl Check, whether __dso_handle is present
 926 AC_CHECK_FUNCS([__dso_handle])
 927
 928 dnl See if the llvm-gcc executable can compile to LLVM assembly
 929 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 930 [llvm_cv_llvmgcc_sanity="no"
 931 if test -x "$LLVMGCC" ; then
 932   cp /dev/null conftest.c
 933   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 934       grep 'target datalayout =' > /dev/null 2>&1
 935   if test $? -eq 0 ; then
 936     llvm_cv_llvmgcc_sanity="yes"
 937   fi
 938   rm conftest.c
 939 fi])
 940
 941 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 942 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 943   AC_MSG_CHECKING([llvm-gcc component support])
 944   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 945   AC_SUBST(LLVMCC1,$llvmcc1path)
 946   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 947   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 948   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 949   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 950   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 951   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 952   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 953   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 954   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 955   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 956   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
 957   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 958   AC_MSG_RESULT([ok])
 959 fi
 960
 961 dnl Propagate the shared library extension that the libltdl checks did to
 962 dnl the Makefiles so we can use it there too
 963 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 964
 965 # Translate the various configuration directories and other basic
 966 # information into substitutions that will end up in Makefile.config.in
 967 # that these configured values can be used by the makefiles
 968 if test "${prefix}" = "NONE" ; then
 969   prefix="/usr/local"
 970 fi
 971 eval LLVM_PREFIX="${prefix}";
 972 eval LLVM_BINDIR="${prefix}/bin";
 973 eval LLVM_LIBDIR="${prefix}/lib";
 974 eval LLVM_DATADIR="${prefix}/share/llvm";
 975 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 976 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 977 eval LLVM_INCLUDEDIR="${prefix}/include";
 978 eval LLVM_INFODIR="${prefix}/info";
 979 eval LLVM_MANDIR="${prefix}/man";
 980 LLVM_CONFIGTIME=`date`
 981 AC_SUBST(LLVM_PREFIX)
 982 AC_SUBST(LLVM_BINDIR)
 983 AC_SUBST(LLVM_LIBDIR)
 984 AC_SUBST(LLVM_DATADIR)
 985 AC_SUBST(LLVM_DOCSDIR)
 986 AC_SUBST(LLVM_ETCDIR)
 987 AC_SUBST(LLVM_INCLUDEDIR)
 988 AC_SUBST(LLVM_INFODIR)
 989 AC_SUBST(LLVM_MANDIR)
 990 AC_SUBST(LLVM_CONFIGTIME)
 991
 992 # Place the various directores into the config.h file as #defines so that we
 993 # can know about the installation paths within LLVM.
 994 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 995                    [Installation prefix directory])
 996 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 997                    [Installation directory for binary executables])
 998 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 999                    [Installation directory for libraries])
1000 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1001                    [Installation directory for data files])
1002 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1003                    [Installation directory for documentation])
1004 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1005                    [Installation directory for config files])
1006 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1007                    [Installation directory for include files])
1008 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1009                    [Installation directory for .info files])
1010 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1011                    [Installation directory for man pages])
1012 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1013                    [Time at which LLVM was configured])
1014 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1015                    [Host triple we were built on])
1016
1017 # Determine which bindings to build.
1018 if test "$BINDINGS_TO_BUILD" = auto ; then
1019   BINDINGS_TO_BUILD=""
1020   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1021     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1022   fi
1023 fi
1024 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1025
1026 # This isn't really configurey, but it avoids having to repeat the list in
1027 # other files.
1028 AC_SUBST(ALL_BINDINGS,ocaml)
1029
1030 # Do any work necessary to ensure that bindings have what they need.
1031 binding_prereqs_failed=0
1032 for a_binding in $BINDINGS_TO_BUILD ; do
1033   case "$a_binding" in
1034   ocaml)
1035     if test "x$OCAMLC" = x ; then
1036       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1037       binding_prereqs_failed=1
1038     fi
1039     if test "x$OCAMLDEP" = x ; then
1040       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1041       binding_prereqs_failed=1
1042     fi
1043     if test "x$OCAMLOPT" = x ; then
1044       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1045       dnl ocamlopt is optional!
1046     fi
1047     if test "x$with_ocaml_libdir" != xauto ; then
1048       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1049     else
1050       ocaml_stdlib="`"$OCAMLC" -where`"
1051       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1052       then
1053         # ocaml stdlib is beneath our prefix; use stdlib
1054         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1055       else
1056         # ocaml stdlib is outside our prefix; use libdir/ocaml
1057         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1058       fi
1059     fi
1060     ;;
1061   esac
1062 done
1063 if test "$binding_prereqs_failed" = 1 ; then
1064   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1065 fi
1066
1067 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1068 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1069
1070 dnl Determine linker rpath flag
1071 if test "$llvm_cv_link_use_r" = "yes" ; then
1072   RPATH="-Wl,-R"
1073 else
1074   RPATH="-Wl,-rpath"
1075 fi
1076 AC_SUBST(RPATH)
1077
1078 dnl Determine linker rdynamic flag
1079 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1080   RDYNAMIC="-Wl,-export-dynamic"
1081 else
1082   RDYNAMIC=""
1083 fi
1084 AC_SUBST(RDYNAMIC)
1085
1086 dnl===-----------------------------------------------------------------------===
1087 dnl===
1088 dnl=== SECTION 10: Specify the output files and generate it
1089 dnl===
1090 dnl===-----------------------------------------------------------------------===
1091
1092 dnl Configure header files
1093 dnl WARNING: dnl If you add or remove any of the following config headers, then
1094 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1095 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1096 dnl files can be updated automatically when their *.in sources change.
1097 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1098 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1099 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1100
1101 dnl Configure the makefile's configuration data
1102 AC_CONFIG_FILES([Makefile.config])
1103
1104 dnl Configure the RPM spec file for LLVM
1105 AC_CONFIG_FILES([llvm.spec])
1106
1107 dnl Configure doxygen's configuration file
1108 AC_CONFIG_FILES([docs/doxygen.cfg])
1109
1110 dnl Configure llvmc's Base plugin
1111 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1112
1113 dnl Do the first stage of configuration for llvm-config.in.
1114 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1115
1116 dnl Do special configuration of Makefiles
1117 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1118 AC_CONFIG_MAKEFILE(Makefile)
1119 AC_CONFIG_MAKEFILE(Makefile.common)
1120 AC_CONFIG_MAKEFILE(examples/Makefile)
1121 AC_CONFIG_MAKEFILE(lib/Makefile)
1122 AC_CONFIG_MAKEFILE(runtime/Makefile)
1123 AC_CONFIG_MAKEFILE(test/Makefile)
1124 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1125 AC_CONFIG_MAKEFILE(unittests/Makefile)
1126 AC_CONFIG_MAKEFILE(tools/Makefile)
1127 AC_CONFIG_MAKEFILE(utils/Makefile)
1128 AC_CONFIG_MAKEFILE(projects/Makefile)
1129 AC_CONFIG_MAKEFILE(bindings/Makefile)
1130 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1131
1132 dnl Finally, crank out the output
1133 AC_OUTPUT