autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34
  35 AC_INIT([LLVM],[3.8.0svn],[http://llvm.org/bugs/])
  36
  37 LLVM_VERSION_MAJOR=3
  38 LLVM_VERSION_MINOR=8
  39 LLVM_VERSION_PATCH=0
  40 LLVM_VERSION_SUFFIX=svn
  41
  42 AC_DEFINE_UNQUOTED([LLVM_VERSION_MAJOR], $LLVM_VERSION_MAJOR, [Major version of the LLVM API])
  43 AC_DEFINE_UNQUOTED([LLVM_VERSION_MINOR], $LLVM_VERSION_MINOR, [Minor version of the LLVM API])
  44 AC_DEFINE_UNQUOTED([LLVM_VERSION_PATCH], $LLVM_VERSION_PATCH, [Patch version of the LLVM API])
  45 AC_DEFINE_UNQUOTED([LLVM_VERSION_STRING], "$PACKAGE_VERSION", [LLVM version string])
  46
  47 AC_SUBST([LLVM_VERSION_MAJOR])
  48 AC_SUBST([LLVM_VERSION_MINOR])
  49 AC_SUBST([LLVM_VERSION_PATCH])
  50 AC_SUBST([LLVM_VERSION_SUFFIX])
  51
  52 dnl Provide a copyright substitution and ensure the copyright notice is included
  53 dnl in the output of --version option of the generated configure script.
  54 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2015 University of Illinois at Urbana-Champaign."])
  55 AC_COPYRIGHT([Copyright (c) 2003-2015 University of Illinois at Urbana-Champaign.])
  56
  57 dnl Indicate that we require autoconf 2.60 or later.
  58 AC_PREREQ(2.60)
  59
  60 dnl Verify that the source directory is valid. This makes sure that we are
  61 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  62 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  63
  64 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  65 dnl various tools where the m4 autoconf macros are.
  66 AC_CONFIG_AUX_DIR([autoconf])
  67
  68 dnl Quit if the source directory has already been configured.
  69 dnl NOTE: This relies upon undocumented autoconf behavior.
  70 if test ${srcdir} != "." ; then
  71   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  72     AC_MSG_ERROR([Already configured in ${srcdir}])
  73   fi
  74 fi
  75
  76 dnl Quit if it is an in-source build
  77 if test ${srcdir} == "." ; then
  78   AC_MSG_ERROR([In-source builds are not allowed. Please configure from a separate build directory!])
  79 fi
  80
  81 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  82 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  83 : ${CFLAGS=}
  84 : ${CXXFLAGS=}
  85
  86 dnl We need to check for the compiler up here to avoid anything else
  87 dnl starting with a different one.
  88 AC_PROG_CC(clang gcc)
  89 AC_PROG_CXX(clang++ g++)
  90 AC_PROG_CPP
  91
  92 dnl If CXX is Clang, check that it can find and parse C++ standard library
  93 dnl headers.
  94 if test "$CXX" = "clang++" ; then
  95   AC_MSG_CHECKING([whether clang works])
  96   AC_LANG_PUSH([C++])
  97   dnl Note that space between 'include' and '(' is required.  There's a broken
  98   dnl regex in aclocal that otherwise will think that we call m4's include
  99   dnl builtin.
 100   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
 101 #if __has_include (<cxxabi.h>)
 102 #include <cxxabi.h>
 103 #endif
 104 #if __has_include (<unwind.h>)
 105 #include <unwind.h>
 106 #endif
 107 ]])],
 108 [
 109   AC_MSG_RESULT([yes])
 110 ],
 111 [
 112   AC_MSG_RESULT([no])
 113   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler LLVM_SRC_DIR/configure ...])
 114 ])
 115   AC_LANG_POP([C++])
 116 fi
 117
 118 dnl Set up variables that track whether the host compiler is GCC or Clang where
 119 dnl we can effectively sanity check them. We don't try to sanity check all the
 120 dnl other possible compilers.
 121 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 122 AC_LANG_PUSH([C++])
 123 llvm_cv_cxx_compiler=unknown
 124 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 125                                     #error
 126                                     #endif
 127                                     ]])],
 128                   llvm_cv_cxx_compiler=clang,
 129                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 130                                                        #error
 131                                                        #endif
 132                                                        ]])],
 133                                      llvm_cv_cxx_compiler=gcc, [])])
 134 AC_LANG_POP([C++])
 135 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 136
 137 dnl Configure all of the projects present in our source tree. While we could
 138 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 139 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 140 dnl Instead we match on the known projects.
 141
 142 dnl
 143 dnl One tricky part of doing this is that some projects depend upon other
 144 dnl projects.  For example, several projects rely upon the LLVM test suite.
 145 dnl We want to configure those projects first so that their object trees are
 146 dnl created before running the configure scripts of projects that depend upon
 147 dnl them.
 148 dnl
 149
 150 dnl Several projects use the LLVM test suite, so configure it next.
 151 if test -d ${srcdir}/projects/test-suite ; then
 152   AC_CONFIG_SUBDIRS([projects/test-suite])
 153 fi
 154
 155 dnl llvm-test is the old name of the test-suite, kept here for backwards
 156 dnl compatibility
 157 if test -d ${srcdir}/projects/llvm-test ; then
 158   AC_CONFIG_SUBDIRS([projects/llvm-test])
 159 fi
 160
 161 dnl Some projects use poolalloc; configure that next
 162 if test -d ${srcdir}/projects/poolalloc ; then
 163   AC_CONFIG_SUBDIRS([projects/poolalloc])
 164 fi
 165
 166 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 167   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 168 fi
 169
 170 dnl Check for all other projects
 171 for i in `ls ${srcdir}/projects`
 172 do
 173   if test -d ${srcdir}/projects/${i} ; then
 174     case ${i} in
 175       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 176       compiler-rt)       ;;
 177       test-suite)     ;;
 178       llvm-test)      ;;
 179       poolalloc)      ;;
 180       llvm-poolalloc) ;;
 181       *)
 182         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 183         ;;
 184     esac
 185   fi
 186 done
 187
 188 dnl Disable the build of polly, even if it is checked out into tools/polly.
 189 AC_ARG_ENABLE(polly,
 190               AS_HELP_STRING([--enable-polly],
 191                              [Use polly if available (default is YES)]),,
 192                              enableval=default)
 193 case "$enableval" in
 194   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 195   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 196   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 197   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 198 esac
 199
 200
 201 dnl Check if polly is checked out into tools/polly and configure it if
 202 dnl available.
 203 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 204   AC_SUBST(LLVM_HAS_POLLY,1)
 205   AC_CONFIG_SUBDIRS([tools/polly])
 206 fi
 207
 208 dnl===-----------------------------------------------------------------------===
 209 dnl===
 210 dnl=== SECTION 2: Architecture, target, and host checks
 211 dnl===
 212 dnl===-----------------------------------------------------------------------===
 213
 214 dnl Check the target for which we're compiling and the host that will do the
 215 dnl compilations. This will tell us which LLVM compiler will be used for
 216 dnl compiling SSA into object code. This needs to be done early because
 217 dnl following tests depend on it.
 218 AC_CANONICAL_TARGET
 219
 220 dnl Determine the platform type and cache its value. This helps us configure
 221 dnl the System library to the correct build platform.
 222 AC_CACHE_CHECK([type of operating system we're going to host on],
 223                [llvm_cv_os_type],
 224 [case $host in
 225   *-*-aix*)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="AIX"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-irix*)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="IRIX"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-cygwin*)
 236     llvm_cv_link_all_option="-Wl,--whole-archive"
 237     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 238     llvm_cv_os_type="Cygwin"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-darwin*)
 241     llvm_cv_link_all_option="-Wl,-all_load"
 242     llvm_cv_no_link_all_option="-Wl,-noall_load"
 243     llvm_cv_os_type="Darwin"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-minix*)
 246     llvm_cv_link_all_option="-Wl,-all_load"
 247     llvm_cv_no_link_all_option="-Wl,-noall_load"
 248     llvm_cv_os_type="Minix"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-freebsd*)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="FreeBSD"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-kfreebsd-gnu)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="GNU/kFreeBSD"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-openbsd*)
 261     llvm_cv_link_all_option="-Wl,--whole-archive"
 262     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 263     llvm_cv_os_type="OpenBSD"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-netbsd*)
 266     llvm_cv_link_all_option="-Wl,--whole-archive"
 267     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 268     llvm_cv_os_type="NetBSD"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-dragonfly*)
 271     llvm_cv_link_all_option="-Wl,--whole-archive"
 272     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 273     llvm_cv_os_type="DragonFly"
 274     llvm_cv_platform_type="Unix" ;;
 275   *-*-bitrig*)
 276     llvm_cv_link_all_option="-Wl,--whole-archive"
 277     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 278     llvm_cv_os_type="Bitrig"
 279     llvm_cv_platform_type="Unix" ;;
 280   *-*-hpux*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="HP-UX"
 284     llvm_cv_platform_type="Unix" ;;
 285   *-*-interix*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="Interix"
 289     llvm_cv_platform_type="Unix" ;;
 290   *-*-linux*)
 291     llvm_cv_link_all_option="-Wl,--whole-archive"
 292     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 293     llvm_cv_os_type="Linux"
 294     llvm_cv_platform_type="Unix" ;;
 295   *-*-gnu*)
 296     llvm_cv_link_all_option="-Wl,--whole-archive"
 297     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 298     llvm_cv_os_type="GNU"
 299     llvm_cv_platform_type="Unix" ;;
 300   *-*-solaris*)
 301     llvm_cv_link_all_option="-Wl,-z,allextract"
 302     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 303     llvm_cv_os_type="SunOS"
 304     llvm_cv_platform_type="Unix" ;;
 305   *-*-win32*)
 306     llvm_cv_link_all_option="-Wl,--whole-archive"
 307     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 308     llvm_cv_os_type="Win32"
 309     llvm_cv_platform_type="Win32" ;;
 310   *-*-mingw*)
 311     llvm_cv_link_all_option="-Wl,--whole-archive"
 312     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 313     llvm_cv_os_type="MingW"
 314     llvm_cv_platform_type="Win32" ;;
 315   *-*-haiku*)
 316     llvm_cv_link_all_option="-Wl,--whole-archive"
 317     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 318     llvm_cv_os_type="Haiku"
 319     llvm_cv_platform_type="Unix" ;;
 320   *-unknown-eabi*)
 321     llvm_cv_link_all_option="-Wl,--whole-archive"
 322     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 323     llvm_cv_os_type="Freestanding"
 324     llvm_cv_platform_type="Unix" ;;
 325   *-unknown-elf*)
 326     llvm_cv_link_all_option="-Wl,--whole-archive"
 327     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 328     llvm_cv_os_type="Freestanding"
 329     llvm_cv_platform_type="Unix" ;;
 330   *)
 331     llvm_cv_link_all_option=""
 332     llvm_cv_no_link_all_option=""
 333     llvm_cv_os_type="Unknown"
 334     llvm_cv_platform_type="Unknown" ;;
 335 esac])
 336
 337 AC_CACHE_CHECK([type of operating system we're going to target],
 338                [llvm_cv_target_os_type],
 339 [case $target in
 340   *-*-aix*)
 341     llvm_cv_target_os_type="AIX" ;;
 342   *-*-irix*)
 343     llvm_cv_target_os_type="IRIX" ;;
 344   *-*-cygwin*)
 345     llvm_cv_target_os_type="Cygwin" ;;
 346   *-*-darwin*)
 347     llvm_cv_target_os_type="Darwin" ;;
 348   *-*-minix*)
 349     llvm_cv_target_os_type="Minix" ;;
 350   *-*-freebsd*)
 351     llvm_cv_target_os_type="FreeBSD" ;;
 352   *-*-kfreebsd-gnu)
 353     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 354   *-*-openbsd*)
 355     llvm_cv_target_os_type="OpenBSD" ;;
 356   *-*-netbsd*)
 357     llvm_cv_target_os_type="NetBSD" ;;
 358   *-*-dragonfly*)
 359     llvm_cv_target_os_type="DragonFly" ;;
 360   *-*-bitrig*)
 361     llvm_cv_target_os_type="Bitrig" ;;
 362   *-*-hpux*)
 363     llvm_cv_target_os_type="HP-UX" ;;
 364   *-*-interix*)
 365     llvm_cv_target_os_type="Interix" ;;
 366   *-*-linux*)
 367     llvm_cv_target_os_type="Linux" ;;
 368   *-*-gnu*)
 369     llvm_cv_target_os_type="GNU" ;;
 370   *-*-solaris*)
 371     llvm_cv_target_os_type="SunOS" ;;
 372   *-*-win32*)
 373     llvm_cv_target_os_type="Win32" ;;
 374   *-*-mingw*)
 375     llvm_cv_target_os_type="MingW" ;;
 376   *-*-haiku*)
 377     llvm_cv_target_os_type="Haiku" ;;
 378   *-*-rtems*)
 379     llvm_cv_target_os_type="RTEMS" ;;
 380   *-*-nacl*)
 381     llvm_cv_target_os_type="NativeClient" ;;
 382   *-unknown-eabi*)
 383     llvm_cv_target_os_type="Freestanding" ;;
 384   *-*-ps4)
 385     llvm_cv_target_os_type="PS4" ;;
 386   *)
 387     llvm_cv_target_os_type="Unknown" ;;
 388 esac])
 389
 390 dnl Make sure we aren't attempting to configure for an unknown system
 391 if test "$llvm_cv_os_type" = "Unknown" ; then
 392   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 393 fi
 394
 395 dnl Set the "OS" Makefile variable based on the platform type so the
 396 dnl makefile can configure itself to specific build hosts
 397 AC_SUBST(OS,$llvm_cv_os_type)
 398 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 399 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 400
 401 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 402 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 403 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 404
 405 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 406 dnl This is used by lib/Support to determine the basic kind of implementation
 407 dnl to use.
 408 case $llvm_cv_platform_type in
 409   Unix)
 410     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 411     AC_SUBST(LLVM_ON_UNIX,[1])
 412     AC_SUBST(LLVM_ON_WIN32,[0])
 413     ;;
 414   Win32)
 415     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 416     AC_SUBST(LLVM_ON_UNIX,[0])
 417     AC_SUBST(LLVM_ON_WIN32,[1])
 418     ;;
 419 esac
 420
 421 dnl Determine what our target architecture is and configure accordingly.
 422 dnl This will allow Makefiles to make a distinction between the hardware and
 423 dnl the OS.
 424 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 425 [case $target in
 426   i?86-*)                 llvm_cv_target_arch="x86" ;;
 427   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 428   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 429   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 430   arm64*-*)               llvm_cv_target_arch="AArch64" ;;
 431   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 432   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 433   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 434   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 435   xcore-*)                llvm_cv_target_arch="XCore" ;;
 436   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 437   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 438   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 439   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 440   wasm*-*)                llvm_cv_target_arch="WebAssembly" ;;
 441   *)                      llvm_cv_target_arch="Unknown" ;;
 442 esac])
 443
 444 if test "$llvm_cv_target_arch" = "Unknown" ; then
 445   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 446 fi
 447
 448 dnl Determine the LLVM native architecture for the target
 449 case "$llvm_cv_target_arch" in
 450     x86)     LLVM_NATIVE_ARCH="X86" ;;
 451     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 452     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 453 esac
 454
 455 dnl Define a substitution, ARCH, for the target architecture
 456 AC_SUBST(ARCH,$llvm_cv_target_arch)
 457 AC_SUBST(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH)
 458
 459 dnl Determine what our host architecture.
 460 dnl This will allow MCJIT regress tests runs only for supported
 461 dnl platforms.
 462 case $host in
 463   i?86-*)                 host_arch="x86" ;;
 464   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 465   sparc*-*)               host_arch="Sparc" ;;
 466   powerpc*-*)             host_arch="PowerPC" ;;
 467   arm64*-*)               host_arch="AArch64" ;;
 468   arm*-*)                 host_arch="ARM" ;;
 469   aarch64*-*)             host_arch="AArch64" ;;
 470   mips-* | mips64-*)      host_arch="Mips" ;;
 471   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 472   xcore-*)                host_arch="XCore" ;;
 473   msp430-*)               host_arch="MSP430" ;;
 474   hexagon-*)              host_arch="Hexagon" ;;
 475   s390x-*)                host_arch="SystemZ" ;;
 476   wasm*-*)                host_arch="WebAssembly" ;;
 477   *)                      host_arch="Unknown" ;;
 478 esac
 479
 480 if test "$host_arch" = "Unknown" ; then
 481   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 482 fi
 483
 484 AC_SUBST(HOST_ARCH,$host_arch)
 485
 486 dnl Check for build platform executable suffix if we're cross-compiling
 487 if test "$cross_compiling" = yes; then
 488   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 489   AC_BUILD_EXEEXT
 490   ac_build_prefix=${build_alias}-
 491   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 492   if test -z "$BUILD_CXX"; then
 493      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 494      if test -z "$BUILD_CXX"; then
 495        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 496      fi
 497   fi
 498 else
 499   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 500 fi
 501
 502 dnl Check to see if there's a .svn or .git directory indicating that this
 503 dnl build is being done from a checkout. This sets up several defaults for
 504 dnl the command line switches. When we build with a checkout directory,
 505 dnl we get a debug with assertions turned on. Without, we assume a source
 506 dnl release and we get an optimized build without assertions.
 507 dnl See --enable-optimized and --enable-assertions below
 508 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 509   cvsbuild="yes"
 510   optimize="no"
 511   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 512 else
 513   cvsbuild="no"
 514   optimize="yes"
 515 fi
 516
 517 dnl===-----------------------------------------------------------------------===
 518 dnl===
 519 dnl=== SECTION 3: Command line arguments for the configure script.
 520 dnl===
 521 dnl===-----------------------------------------------------------------------===
 522
 523 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 524 AC_ARG_ENABLE(libcpp,
 525               AS_HELP_STRING([--enable-libcpp],
 526                              [Use libc++ if available (default is NO)]),,
 527                              enableval=default)
 528 case "$enableval" in
 529   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 530   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 531   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 532   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 533 esac
 534
 535 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 536 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 537 dnl these checks here so that we have the configuration of the standard C++
 538 dnl library finished.
 539 AC_ARG_ENABLE(compiler-version-checks,
 540               AS_HELP_STRING([--enable-compiler-version-checks],
 541                              [Check the version of the host compiler (default is YES)]),,
 542                              enableval=default)
 543 case "$enableval" in
 544   no)
 545     ;;
 546   yes|default)
 547     AC_LANG_PUSH([C++])
 548     case "$llvm_cv_cxx_compiler" in
 549     clang)
 550       AC_MSG_CHECKING([whether Clang is new enough])
 551       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 552 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 553 #error This version of Clang is too old to build LLVM
 554 #endif
 555 ]])],
 556           [AC_MSG_RESULT([yes])],
 557           [AC_MSG_RESULT([no])
 558            AC_MSG_ERROR([
 559 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 560 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 561 bypass these sanity checks.])])
 562
 563       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 564       dnl are sometimes deeply confusing though. Here we test for an obvious
 565       dnl incomplete feature in 4.6's standard library that was completed in
 566       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 567       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 568       dnl that happening in the Makefile.
 569       if test "$ENABLE_LIBCPP" -eq 0 ; then
 570         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 571         llvm_cv_old_cxxflags="$CXXFLAGS"
 572         CXXFLAGS="$CXXFLAGS -std=c++0x"
 573         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 574 #include <atomic>
 575 std::atomic<float> x(0.0f);
 576 int main() { return (float)x; }
 577 ]])],
 578             [AC_MSG_RESULT([yes])],
 579             [AC_MSG_RESULT([no])
 580              AC_MSG_ERROR([
 581 We detected a missing feature in the standard C++ library that was known to be
 582 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 583 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 584 than 4.7. You will need to update your system and ensure Clang uses the newer
 585 standard library.
 586
 587 If this error is incorrect or you need to force things to work, you may pass
 588 '--disable-compiler-version-checks' to configure to bypass this test.])])
 589         CXXFLAGS="$llvm_cv_old_cxxflags"
 590       fi
 591       ;;
 592     gcc)
 593       AC_MSG_CHECKING([whether GCC is new enough])
 594       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 595 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 596 #error This version of GCC is too old to build LLVM
 597 #endif
 598 ]])],
 599           [AC_MSG_RESULT([yes])],
 600           [AC_MSG_RESULT([no])
 601            AC_MSG_ERROR([
 602 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 603 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 604 bypass these sanity checks.])])
 605       ;;
 606     unknown)
 607       ;;
 608     esac
 609     AC_LANG_POP([C++])
 610     ;;
 611   *)
 612     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 613     ;;
 614 esac
 615
 616 dnl --enable-cxx1y : check whether or not to use -std=c++1y on the command line
 617 AC_ARG_ENABLE(cxx1y,
 618               AS_HELP_STRING([--enable-cxx1y],
 619                              [Use c++1y if available (default is NO)]),,
 620                              enableval=default)
 621 case "$enableval" in
 622   yes) AC_SUBST(ENABLE_CXX1Y,[1]) ;;
 623   no)  AC_SUBST(ENABLE_CXX1Y,[0]) ;;
 624   default) AC_SUBST(ENABLE_CXX1Y,[0]);;
 625   *) AC_MSG_ERROR([Invalid setting for --enable-cxx1y. Use "yes" or "no"]) ;;
 626 esac
 627
 628 dnl --enable-split-dwarf : check whether or not to use -gsplit-dwarf on the command
 629 dnl line
 630 AC_ARG_ENABLE(split-dwarf,
 631               AS_HELP_STRING([--enable-split-dwarf],
 632                              [Use split-dwarf if available (default is NO)]),,
 633                              enableval=default)
 634 case "$enableval" in
 635   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 636   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 637   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 638   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 639 esac
 640
 641 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 642 clang_arcmt="yes"
 643 AC_ARG_ENABLE(clang-arcmt,
 644               AS_HELP_STRING([--enable-clang-arcmt],
 645                              [Enable building of clang ARCMT (default is YES)]),
 646                              clang_arcmt="$enableval",
 647                              enableval="yes")
 648 case "$enableval" in
 649   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 650   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 651   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 652   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 653 esac
 654
 655 dnl --enable-clang-plugin-support: check whether to enable plugins in clang
 656 clang_plugin_support="yes"
 657 AC_ARG_ENABLE(clang-plugin-support,
 658               AS_HELP_STRING([--enable-clang-plugin-support],
 659                              [Enable plugin support in clang (default is YES)]),
 660                              clang_plugin_support="$enableval",
 661                              enableval="yes")
 662 case "$enableval" in
 663   yes) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]) ;;
 664   no)  AC_SUBST(CLANG_PLUGIN_SUPPORT,[0]) ;;
 665   default) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]);;
 666   *) AC_MSG_ERROR([Invalid setting for --enable-clang-plugin-support. Use "yes" or "no"]) ;;
 667 esac
 668
 669 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 670 clang_static_analyzer="yes"
 671 AC_ARG_ENABLE(clang-static-analyzer,
 672               AS_HELP_STRING([--enable-clang-static-analyzer],
 673                              [Enable building of clang Static Analyzer (default is YES)]),
 674                              clang_static_analyzer="$enableval",
 675                              enableval="yes")
 676 case "$enableval" in
 677   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 678   no)
 679     if test ${clang_arcmt} != "no" ; then
 680       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 681     fi
 682     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 683     ;;
 684   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 685   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 686 esac
 687
 688 dnl --enable-optimized : check whether they want to do an optimized build:
 689 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 690  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 691 if test ${enableval} = "no" ; then
 692   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 693 else
 694   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 695 fi
 696
 697 dnl --enable-profiling : check whether they want to do a profile build:
 698 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 699  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 700 if test ${enableval} = "no" ; then
 701   AC_SUBST(ENABLE_PROFILING,[[]])
 702 else
 703   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 704 fi
 705
 706 dnl --enable-assertions : check whether they want to turn on assertions or not:
 707 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 708   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 709 if test ${enableval} = "yes" ; then
 710   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 711   assertions_enabled="yes"
 712 else
 713   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 714   assertions_enabled="no"
 715 fi
 716
 717 dnl --enable-werror : check whether we want Werror on by default
 718 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 719   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 720 case "$enableval" in
 721   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 722   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 723   default) AC_SUBST(ENABLE_WERROR,[0]);;
 724   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 725 esac
 726
 727 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 728 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 729   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 730 if test ${enableval} = "yes" ; then
 731   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 732   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 733 else
 734   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 735   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 736 fi
 737
 738 dnl --enable-abi-breaking-checks : decide whether we should compile in asserts and
 739 dnl checks that make the build ABI incompatible with an llvm built without these
 740 dnl checks enabled.
 741 AC_ARG_ENABLE(abi-breaking-checks,AS_HELP_STRING(
 742   --enable-abi-breaking-checks,[Compile with abi-breaking asserts support (default is with-asserts)]),, enableval="with-asserts")
 743 case "$enableval" in
 744   with-asserts)  if test ${assertions_enabled} = "yes" ; then
 745                    AC_DEFINE([LLVM_ENABLE_ABI_BREAKING_CHECKS],[1],[Define to enable checks that alter the LLVM C++ ABI])
 746                    AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[1])
 747                  else
 748                    AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[0])
 749                  fi ;;
 750   yes)
 751                  AC_DEFINE([LLVM_ENABLE_ABI_BREAKING_CHECKS],[1],[Define to enable checks that alter the LLVM C++ ABI])
 752                  AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[1])
 753                  ;;
 754   no)
 755                  AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[0])
 756                  ;;
 757   *) AC_MSG_ERROR([Invalid setting for --enable-abi-breaking-checks.  Use "with-asserts", "yes" or "no"])
 758 esac
 759
 760 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 761 AC_ARG_ENABLE(debug-runtime,
 762    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 763 if test ${enableval} = "no" ; then
 764   AC_SUBST(DEBUG_RUNTIME,[[]])
 765 else
 766   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 767 fi
 768
 769 dnl --enable-debug-symbols : should even optimized compiler libraries
 770 dnl have debug symbols?
 771 AC_ARG_ENABLE(debug-symbols,
 772    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 773 if test ${enableval} = "no" ; then
 774   AC_SUBST(DEBUG_SYMBOLS,[[]])
 775 else
 776   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 777 fi
 778
 779 dnl --enable-keep-symbols : do not strip installed executables
 780 AC_ARG_ENABLE(keep-symbols,
 781    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 782 if test ${enableval} = "no" ; then
 783   AC_SUBST(KEEP_SYMBOLS,[[]])
 784 else
 785   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 786 fi
 787
 788 dnl --enable-jit: check whether they want to enable the jit
 789 AC_ARG_ENABLE(jit,
 790   AS_HELP_STRING(--enable-jit,
 791                  [Enable Just In Time Compiling (default is YES)]),,
 792   enableval=default)
 793 if test ${enableval} = "no"
 794 then
 795   AC_SUBST(JIT,[[]])
 796 else
 797   case "$llvm_cv_target_arch" in
 798     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 799     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 800     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 801     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 802     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 803     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 804     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 805     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 806     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 807     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 808     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 809     WebAssembly) AC_SUBST(TARGET_HAS_JIT,0) ;;
 810     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 811   esac
 812 fi
 813
 814 TARGETS_WITH_JIT="ARM AArch64 Mips PowerPC SystemZ X86"
 815 AC_SUBST(TARGETS_WITH_JIT,$TARGETS_WITH_JIT)
 816
 817 dnl Allow enablement of building and installing docs
 818 AC_ARG_ENABLE(docs,
 819               AS_HELP_STRING([--enable-docs],
 820                              [Build documents (default is YES)]),,
 821                              enableval=default)
 822 case "$enableval" in
 823   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 824   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 825   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 826   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 827 esac
 828
 829 dnl Allow enablement of doxygen generated documentation
 830 AC_ARG_ENABLE(doxygen,
 831               AS_HELP_STRING([--enable-doxygen],
 832                              [Build doxygen documentation (default is NO)]),,
 833                              enableval=default)
 834 case "$enableval" in
 835   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 836   no|default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 837   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 838 esac
 839
 840 dnl Allow enablement of doxygen search engine
 841 AC_ARG_ENABLE(doxygen-search,
 842               AS_HELP_STRING([--enable-doxygen-search],
 843                              [Enable doxygen search support (default is NO)]),,
 844                              enableval=default)
 845 ENABLE_DOXYGEN_SEARCH="$enableval"
 846
 847 case "$enableval" in
 848   yes|no|default) ;;
 849   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen-search. Use "yes" or "no"]) ;;
 850 esac
 851
 852 AC_ARG_ENABLE(doxygen-external-search,
 853               AS_HELP_STRING([--enable-doxygen-external-search],
 854                              [Enable doxygen exteranl search (default is NO)]),,
 855                              enableval=default)
 856 ENABLE_DOXYGEN_EXTERNAL_SEARCH="$enableval"
 857
 858 case "$enableval" in
 859   yes)
 860     dnl To match with the CMake behavior, enable doxygen when
 861     dnl --enable-doxygen-external-search is enabled.
 862     case "$ENABLE_DOXYGEN_SEARCH" in
 863       yes|default) ENABLE_DOXYGEN_SEARCH="yes" ;;
 864       no) AC_MSG_ERROR([The option --enable-doxygen-external-search requires --enable-doxygen-search]) ;;
 865     esac
 866     ;;
 867   no|default) ;;
 868   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen-external-search. Use "yes" or "no"]) ;;
 869 esac
 870
 871 AC_ARG_WITH(doxygen-search-engine-url,
 872             AS_HELP_STRING([--with-doxygen-search-engine-url],
 873                            [Specify the external search engine for doxygen]),,)
 874 WITH_DOXYGEN_SEARCH_ENGINE_URL="$withval"
 875
 876 AC_ARG_WITH(doxygen-search-mappings,
 877             AS_HELP_STRING([--with-doxygen-search-mappings],
 878                            [Specify the extra search mapping for doxygen]),,)
 879 WITH_DOXYGEN_SEARCH_MAPPINGS="$withval"
 880
 881 case "$ENABLE_DOXYGEN_SEARCH" in
 882   yes)
 883     if test "$ENABLE_DOXYGEN" = "0" ; then
 884       AC_MSG_ERROR([The option --enable-doxygen-search requires --enable-doxygen.])
 885     fi
 886
 887     AC_SUBST(enable_searchengine,[YES])
 888
 889     case "$ENABLE_DOXYGEN_EXTERNAL_SEARCH" in
 890       yes)
 891         AC_SUBST(enable_external_search,[YES])
 892         AC_SUBST(enable_server_based_search,[YES])
 893         AC_SUBST(searchengine_url,["$WITH_DOXYGEN_SEARCH_ENGINE_URL"])
 894         AC_SUBST(extra_search_mappings,["$WITH_DOXYGEN_SEARCH_MAPPINGS"])
 895         ;;
 896
 897       no|default)
 898         AC_SUBST(enable_external_search,[NO])
 899         AC_SUBST(enable_server_based_search,[NO])
 900         AC_SUBST(searchengine_url,[])
 901         AC_SUBST(extra_search_mappings,[])
 902         ;;
 903     esac
 904     ;;
 905
 906   no|default)
 907     AC_SUBST(enable_searchengine,[NO])
 908     AC_SUBST(searchengine_url,[])
 909     AC_SUBST(enable_server_based_search,[NO])
 910     AC_SUBST(enable_external_search,[NO])
 911     AC_SUBST(extra_search_mappings,[])
 912     ;;
 913
 914   *)
 915     AC_MSG_ERROR([Invalid setting for --enable-doxygen-search. Use "yes" or "no"])
 916     ;;
 917 esac
 918
 919 dnl Allow enablement of doxygen generated Qt help files
 920 AC_ARG_ENABLE(doxygen-qt-help,
 921               AS_HELP_STRING([--enable-doxygen-qt-help],
 922                              [Build Qt help files (default is NO)]),,
 923                              enableval=default)
 924 case "$enableval" in
 925   yes)
 926     if test "$ENABLE_DOXYGEN" = "0" ; then
 927       AC_MSG_ERROR([The option --enable-doxygen-qt-help requires --enable-doxygen.])
 928     fi
 929
 930     AC_PATH_PROG(QHELPGENERATOR, [qhelpgenerator], [qhelpgenerator])
 931
 932     dnl Qt help file for llvm doxygen documentation
 933     AC_SUBST(llvm_doxygen_generate_qhp,[YES])
 934     AC_SUBST(llvm_doxygen_qch_filename,[org.llvm.qch])
 935     AC_SUBST(llvm_doxygen_qhp_namespace,[org.llvm])
 936     AC_SUBST(llvm_doxygen_qhelpgenerator_path,["$QHELPGENERATOR"])
 937     AC_SUBST(llvm_doxygen_qhp_cust_filter_name,["$PACKAGE_STRING"])
 938     AC_SUBST(llvm_doxygen_qhp_cust_filter_attrs,["$PACKAGE_NAME,$PACKAGE_VERSION"])
 939
 940     dnl Qt help file for clang doxygen documentation
 941     AC_SUBST(clang_doxygen_generate_qhp,[YES])
 942     AC_SUBST(clang_doxygen_qch_filename,[org.llvm.clang.qch])
 943     AC_SUBST(clang_doxygen_qhp_namespace,[org.llvm.clang])
 944     AC_SUBST(clang_doxygen_qhelpgenerator_path,["$QHELPGENERATOR"])
 945     AC_SUBST(clang_doxygen_qhp_cust_filter_name,["Clang $PACKAGE_VERSION"])
 946     AC_SUBST(clang_doxygen_qhp_cust_filter_attrs,["Clang,$PACKAGE_VERSION"])
 947     ;;
 948
 949   no|default)
 950     AC_SUBST(llvm_doxygen_generate_qhp,[NO])
 951     AC_SUBST(llvm_doxygen_qch_filename,[])
 952     AC_SUBST(llvm_doxygen_qhp_namespace,[])
 953     AC_SUBST(llvm_doxygen_qhelpgenerator_path,[])
 954     AC_SUBST(llvm_doxygen_qhp_cust_filter_name,[])
 955     AC_SUBST(llvm_doxygen_qhp_cust_filter_attrs,[])
 956
 957     AC_SUBST(clang_doxygen_generate_qhp,[NO])
 958     AC_SUBST(clang_doxygen_qch_filename,[])
 959     AC_SUBST(clang_doxygen_qhp_namespace,[])
 960     AC_SUBST(clang_doxygen_qhelpgenerator_path,[])
 961     AC_SUBST(clang_doxygen_qhp_cust_filter_name,["Clang $PACKAGE_VERSION"])
 962     AC_SUBST(clang_doxygen_qhp_cust_filter_attrs,["Clang,$PACKAGE_VERSION"])
 963     ;;
 964
 965   *)
 966     AC_MSG_ERROR([Invalid setting for --enable-doxygen-qt-help. Use "yes" or "no"]) ;;
 967 esac
 968
 969 dnl Allow disablement of threads
 970 AC_ARG_ENABLE(threads,
 971               AS_HELP_STRING([--enable-threads],
 972                              [Use threads if available (default is YES)]),,
 973                              enableval=default)
 974 case "$enableval" in
 975   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 976   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 977   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 978   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 979 esac
 980 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 981                    [Define if threads enabled])
 982
 983 dnl Allow disablement of pthread.h
 984 AC_ARG_ENABLE(pthreads,
 985               AS_HELP_STRING([--enable-pthreads],
 986                              [Use pthreads if available (default is YES)]),,
 987                              enableval=default)
 988 case "$enableval" in
 989   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 990   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 991   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 992   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 993 esac
 994
 995 dnl Allow disablement of zlib
 996 AC_ARG_ENABLE(zlib,
 997               AS_HELP_STRING([--enable-zlib],
 998                              [Use zlib for compression/decompression if
 999                               available (default is YES)]),,
1000                               enableval=default)
1001 case "$enableval" in
1002   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
1003   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
1004   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
1005   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
1006 esac
1007 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
1008                    [Define if zlib is enabled])
1009
1010 dnl Allow building without position independent code
1011 AC_ARG_ENABLE(pic,
1012   AS_HELP_STRING([--enable-pic],
1013                  [Build LLVM with Position Independent Code (default is YES)]),,
1014                  enableval=default)
1015 case "$enableval" in
1016   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
1017   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
1018   default) AC_SUBST(ENABLE_PIC,[1]) ;;
1019   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
1020 esac
1021 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
1022                    [Define if position independent code is enabled])
1023
1024 dnl Allow building a shared library and linking tools against it.
1025 AC_ARG_ENABLE(shared,
1026   AS_HELP_STRING([--enable-shared],
1027                  [Build a shared library and link tools against it (default is NO)]),,
1028                  enableval=default)
1029 case "$enableval" in
1030   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
1031   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
1032   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
1033   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
1034 esac
1035
1036 dnl Allow libstdc++ is embedded in LLVM.dll.
1037 AC_ARG_ENABLE(embed-stdcxx,
1038   AS_HELP_STRING([--enable-embed-stdcxx],
1039                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
1040                  enableval=default)
1041 case "$enableval" in
1042   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
1043   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
1044   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
1045   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
1046 esac
1047
1048 dnl Enable embedding timestamp information into build.
1049 AC_ARG_ENABLE(timestamps,
1050   AS_HELP_STRING([--enable-timestamps],
1051                  [Enable embedding timestamp information in build (default is YES)]),,
1052                  enableval=default)
1053 case "$enableval" in
1054   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
1055   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
1056   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
1057   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
1058 esac
1059 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
1060                    [Define if timestamp information (e.g., __DATE__) is allowed])
1061
1062 dnl Enable support for showing backtraces.
1063 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
1064   [--enable-backtraces],
1065   [Enable embedding backtraces on crash (default is YES)]),
1066   [case "$enableval" in
1067     yes) llvm_cv_enable_backtraces="yes" ;;
1068     no)  llvm_cv_enable_backtraces="no"  ;;
1069     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
1070   esac],
1071   llvm_cv_enable_backtraces="yes")
1072 if test "$llvm_cv_enable_backtraces" = "yes" ; then
1073   AC_DEFINE([ENABLE_BACKTRACES],[1],
1074             [Define if you want backtraces on crash])
1075 fi
1076
1077 dnl Enable installing platform specific signal handling overrides, for improved
1078 dnl CrashRecovery support or interaction with crash reporting software. This
1079 dnl support may be inappropriate for some clients embedding LLVM as a library.
1080 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
1081   [--enable-crash-overrides],
1082   [Enable crash handling overrides (default is YES)]),
1083   [case "$enableval" in
1084     yes) llvm_cv_enable_crash_overrides="yes" ;;
1085     no)  llvm_cv_enable_crash_overrides="no"  ;;
1086     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
1087   esac],
1088   llvm_cv_enable_crash_overrides="yes")
1089 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
1090   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
1091             [Define to enable crash handling overrides])
1092 fi
1093
1094 dnl List all possible targets
1095 ALL_TARGETS="X86 Sparc PowerPC ARM AArch64 Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ AMDGPU BPF"
1096 AC_SUBST(ALL_TARGETS,$ALL_TARGETS)
1097
1098 dnl Allow specific targets to be specified for building (or not)
1099 TARGETS_TO_BUILD=""
1100 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
1101     [Build specific host targets: all or target1,target2,... Valid targets are:
1102      host, x86, x86_64, sparc, powerpc, arm64, arm, aarch64, mips, hexagon,
1103      xcore, msp430, nvptx, systemz, r600, bpf, wasm, and cpp (default=all)]),,
1104     enableval=all)
1105 if test "$enableval" = host-only ; then
1106   enableval=host
1107 fi
1108 case "$enableval" in
1109   all) TARGETS_TO_BUILD="$ALL_TARGETS" ;;
1110   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
1111       case "$a_target" in
1112         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1113         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1114         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
1115         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
1116         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1117         arm64)    TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1118         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
1119         bpf)      TARGETS_TO_BUILD="BPF $TARGETS_TO_BUILD" ;;
1120         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1121         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1122         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1123         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1124         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
1125         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
1126         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
1127         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
1128         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1129         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1130         amdgpu)   TARGETS_TO_BUILD="AMDGPU $TARGETS_TO_BUILD" ;;
1131         r600)     TARGETS_TO_BUILD="AMDGPU $TARGETS_TO_BUILD" ;;
1132         wasm)     TARGETS_TO_BUILD="WebAssembly $TARGETS_TO_BUILD" ;;
1133         host) case "$llvm_cv_target_arch" in
1134             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1135             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1136             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
1137             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
1138             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1139             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
1140             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1141             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
1142             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
1143             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
1144             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1145             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1146             WebAssembly) TARGETS_TO_BUILD="WebAssembly $TARGETS_TO_BUILD" ;;
1147             *)       AC_MSG_ERROR([Can not set target to build]) ;;
1148           esac ;;
1149         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
1150       esac
1151   done
1152   ;;
1153 esac
1154
1155 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
1156     [Build experimental host targets: disable or target1,target2,...
1157      (default=disable)]),,
1158     enableval=disable)
1159
1160 if test ${enableval} != "disable"
1161 then
1162   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
1163 fi
1164
1165 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
1166
1167 dnl Determine whether we are building LLVM support for the native architecture.
1168 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
1169 for a_target in $TARGETS_TO_BUILD; do
1170   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
1171     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
1172       [LLVM architecture name for the native architecture, if available])
1173     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
1174     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
1175     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
1176     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
1177     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1178       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
1179     fi
1180     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1181       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
1182     fi
1183     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1184       [LLVM name for the native Target init function, if available])
1185     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1186       [LLVM name for the native TargetInfo init function, if available])
1187     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1188       [LLVM name for the native target MC init function, if available])
1189     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1190       [LLVM name for the native AsmPrinter init function, if available])
1191     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1192       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1193        [LLVM name for the native AsmParser init function, if available])
1194     fi
1195     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1196       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1197        [LLVM name for the native Disassembler init function, if available])
1198     fi
1199   fi
1200 done
1201
1202 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1203 dnl target feature def files.
1204 LLVM_ENUM_TARGETS=""
1205 LLVM_ENUM_ASM_PRINTERS=""
1206 LLVM_ENUM_ASM_PARSERS=""
1207 LLVM_ENUM_DISASSEMBLERS=""
1208 for target_to_build in $TARGETS_TO_BUILD; do
1209   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1210   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1211     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1212   fi
1213   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1214     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1215   fi
1216   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1217     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1218   fi
1219 done
1220 AC_SUBST(LLVM_ENUM_TARGETS)
1221 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1222 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1223 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1224
1225 dnl Override the option to use for optimized builds.
1226 AC_ARG_WITH(optimize-option,
1227   AS_HELP_STRING([--with-optimize-option],
1228                  [Select the compiler options to use for optimized builds]),,
1229                  withval=default)
1230 AC_MSG_CHECKING([optimization flags])
1231 case "$withval" in
1232   default)
1233     case "$llvm_cv_os_type" in
1234     FreeBSD) optimize_option=-O2 ;;
1235     MingW) optimize_option=-O2 ;;
1236     *)     optimize_option=-O3 ;;
1237     esac ;;
1238   *) optimize_option="$withval" ;;
1239 esac
1240 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1241 AC_MSG_RESULT([$optimize_option])
1242
1243 dnl Specify extra build options
1244 AC_ARG_WITH(extra-options,
1245   AS_HELP_STRING([--with-extra-options],
1246                  [Specify additional options to compile LLVM with]),,
1247                  withval=default)
1248 case "$withval" in
1249   default) EXTRA_OPTIONS= ;;
1250   *) EXTRA_OPTIONS=$withval ;;
1251 esac
1252 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1253
1254 dnl Specify extra linker build options
1255 AC_ARG_WITH(extra-ld-options,
1256   AS_HELP_STRING([--with-extra-ld-options],
1257                  [Specify additional options to link LLVM with]),,
1258                  withval=default)
1259 case "$withval" in
1260   default) EXTRA_LD_OPTIONS= ;;
1261   *) EXTRA_LD_OPTIONS=$withval ;;
1262 esac
1263 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1264
1265 dnl Allow specific bindings to be specified for building (or not)
1266 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1267     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1268     enableval=default)
1269 BINDINGS_TO_BUILD=""
1270 case "$enableval" in
1271   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1272   all ) BINDINGS_TO_BUILD="ocaml" ;;
1273   none | no) BINDINGS_TO_BUILD="" ;;
1274   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1275       case "$a_binding" in
1276         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1277         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1278       esac
1279   done
1280   ;;
1281 esac
1282
1283 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1284 dnl script for bindings/ocaml/configure, except that its auto value depends on
1285 dnl OCAMLC, which is found here to support tests.
1286 AC_ARG_WITH([ocaml-libdir],
1287   [AS_HELP_STRING([--with-ocaml-libdir],
1288     [Specify install location for ocaml bindings (default is stdlib)])],
1289   [],
1290   [withval=auto])
1291 case "$withval" in
1292   auto) with_ocaml_libdir="$withval" ;;
1293   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1294   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1295 esac
1296
1297 AC_ARG_WITH(clang-srcdir,
1298   AS_HELP_STRING([--with-clang-srcdir],
1299     [Directory to the out-of-tree Clang source]),,
1300     withval="-")
1301 case "$withval" in
1302   -) clang_src_root="" ;;
1303   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1304   *) clang_src_root="$ac_pwd/$withval" ;;
1305 esac
1306 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1307
1308 AC_ARG_WITH(clang-resource-dir,
1309   AS_HELP_STRING([--with-clang-resource-dir],
1310     [Relative directory from the Clang binary for resource files]),,
1311     withval="")
1312 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1313                    [Relative directory for resource files])
1314
1315 AC_ARG_WITH(c-include-dirs,
1316   AS_HELP_STRING([--with-c-include-dirs],
1317     [Colon separated list of directories clang will search for headers]),,
1318     withval="")
1319 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1320                    [Directories clang will search for headers])
1321
1322 # Clang normally uses the system c++ headers and libraries. With this option,
1323 # clang will use the ones provided by a gcc installation instead. This option should
1324 # be passed the same value that was used with --prefix when configuring gcc.
1325 AC_ARG_WITH(gcc-toolchain,
1326   AS_HELP_STRING([--with-gcc-toolchain],
1327     [Directory where gcc is installed.]),,
1328     withval="")
1329 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1330                    [Directory where gcc is installed.])
1331
1332 AC_ARG_WITH(default-sysroot,
1333   AS_HELP_STRING([--with-default-sysroot],
1334     [Add --sysroot=<path> to all compiler invocations.]),,
1335     withval="")
1336 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1337                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1338
1339 AC_ARG_WITH(clang-default-openmp-runtime,
1340   AS_HELP_STRING([--with-clang-default-openmp-runtime],
1341     [The default OpenMP runtime for Clang.]),,
1342     withval="libgomp")
1343 AC_DEFINE_UNQUOTED(CLANG_DEFAULT_OPENMP_RUNTIME,"$withval",
1344                    [Default OpenMP runtime used by -fopenmp.])
1345
1346 dnl Allow linking of LLVM with GPLv3 binutils code.
1347 AC_ARG_WITH(binutils-include,
1348   AS_HELP_STRING([--with-binutils-include],
1349     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1350   withval=default)
1351 case "$withval" in
1352   default) WITH_BINUTILS_INCDIR=default ;;
1353   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1354   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1355 esac
1356 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1357   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1358   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1359      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1360      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1361   fi
1362 fi
1363
1364 dnl Specify the URL where bug reports should be submitted.
1365 AC_ARG_WITH(bug-report-url,
1366   AS_HELP_STRING([--with-bug-report-url],
1367     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1368     withval="http://llvm.org/bugs/")
1369 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1370                    [Bug report URL.])
1371
1372 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1373 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1374   [--enable-terminfo],
1375   [Query the terminfo database if available (default is YES)]),
1376   [case "$enableval" in
1377     yes) llvm_cv_enable_terminfo="yes" ;;
1378     no)  llvm_cv_enable_terminfo="no"  ;;
1379     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1380   esac],
1381   llvm_cv_enable_terminfo="yes")
1382 case "$llvm_cv_enable_terminfo" in
1383   yes) AC_SUBST(ENABLE_TERMINFO,[1]) ;;
1384   no)  AC_SUBST(ENABLE_TERMINFO,[0]) ;;
1385 esac
1386
1387 dnl --enable-libedit: check whether the user wants to turn off libedit.
1388 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1389   [--enable-libedit],
1390   [Use libedit if available (default is YES)]),
1391   [case "$enableval" in
1392     yes) llvm_cv_enable_libedit="yes" ;;
1393     no)  llvm_cv_enable_libedit="no"  ;;
1394     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1395   esac],
1396   llvm_cv_enable_libedit="yes")
1397
1398 dnl --enable-libffi : check whether the user wants to turn off libffi:
1399 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1400   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1401   [case "$enableval" in
1402     yes) llvm_cv_enable_libffi="yes" ;;
1403     no)  llvm_cv_enable_libffi="no"  ;;
1404     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1405   esac],
1406   llvm_cv_enable_libffi=no)
1407
1408 AC_ARG_WITH(internal-prefix,
1409   AS_HELP_STRING([--with-internal-prefix],
1410     [Installation directory for internal files]),,
1411     withval="")
1412 AC_SUBST(INTERNAL_PREFIX,[$withval])
1413
1414 dnl===-----------------------------------------------------------------------===
1415 dnl===
1416 dnl=== SECTION 4: Check for programs we need and that they are the right version
1417 dnl===
1418 dnl===-----------------------------------------------------------------------===
1419
1420 dnl Check for the tools that the makefiles require
1421 AC_CHECK_GNU_MAKE
1422 AC_PROG_LN_S
1423 AC_PATH_PROG(NM, [nm], [nm])
1424 AC_PATH_PROG(CMP, [cmp], [cmp])
1425 AC_PATH_PROG(CP, [cp], [cp])
1426 AC_PATH_PROG(DATE, [date], [date])
1427 AC_PATH_PROG(FIND, [find], [find])
1428 AC_PATH_PROG(GREP, [grep], [grep])
1429 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1430 AC_PATH_PROG(MV,   [mv],   [mv])
1431 AC_PROG_RANLIB
1432 AC_CHECK_TOOL(AR, ar, false)
1433 AC_PATH_PROG(RM,   [rm],   [rm])
1434 AC_PATH_PROG(SED,  [sed],  [sed])
1435 AC_PATH_PROG(TAR,  [tar],  [gtar])
1436 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1437
1438 dnl Looking for misc. graph plotting software
1439 AC_PATH_PROG(DOT, [dot], [echo dot])
1440 if test "$DOT" != "echo dot" ; then
1441   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1442   dnl If we're targeting for mingw we should emit windows paths, not msys
1443   if test "$llvm_cv_os_type" = "MingW" ; then
1444     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1445   fi
1446   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1447    [Define to path to dot program if found or 'echo dot' otherwise])
1448 fi
1449
1450 dnl Find the install program
1451 AC_PROG_INSTALL
1452 dnl Prepend src dir to install path dir if it's a relative path
1453 dnl This is a hack for installs that take place in something other
1454 dnl than the top level.
1455 case "$INSTALL" in
1456  [[\\/$]]* | ?:[[\\/]]* ) ;;
1457  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1458 esac
1459
1460 dnl Checks for documentation and testing tools that we can do without. If these
1461 dnl are not found then they are set to "true" which always succeeds but does
1462 dnl nothing. This just lets the build output show that we could have done
1463 dnl something if the tool was available.
1464 AC_PATH_PROG(BZIP2, [bzip2])
1465 AC_PATH_PROG(CAT, [cat])
1466 AC_PATH_PROG(DOXYGEN, [doxygen])
1467 AC_PATH_PROG(GROFF, [groff])
1468 AC_PATH_PROG(GZIPBIN, [gzip])
1469 AC_PATH_PROG(PDFROFF, [pdfroff])
1470 AC_PATH_PROG(ZIP, [zip])
1471 AC_PATH_PROG(GO, [go])
1472 AC_PATH_PROGS(OCAMLFIND, [ocamlfind])
1473 AC_PATH_PROGS(GAS, [gas as])
1474
1475 dnl Get the version of the linker in use.
1476 AC_LINK_GET_VERSION
1477
1478 dnl Determine whether the linker supports the -R option.
1479 AC_LINK_USE_R
1480
1481 dnl Determine whether the compiler supports the -rdynamic option.
1482 AC_LINK_EXPORT_DYNAMIC
1483
1484 dnl Determine whether the linker supports the --version-script option.
1485 AC_LINK_VERSION_SCRIPT
1486
1487 AC_CHECK_HEADERS([errno.h])
1488
1489 case "$llvm_cv_os_type" in
1490   Cygwin|MingW|Win32) llvm_shlib_ext=.dll ;;
1491   Darwin) llvm_shlib_ext=.dylib ;;
1492   *) llvm_shlib_ext=.so ;;
1493 esac
1494
1495 AC_DEFINE_UNQUOTED([LTDL_SHLIB_EXT], ["$llvm_shlib_ext"], [The shared library extension])
1496
1497 AC_MSG_CHECKING([tool compatibility])
1498
1499 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1500 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1501 dnl to support those options.
1502 dnl "icc" emits gcc signatures
1503 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1504 ICC=no
1505 IXX=no
1506 case $CC in
1507   icc*|icpc*)
1508     ICC=yes
1509     IXX=yes
1510     ;;
1511    *)
1512     ;;
1513 esac
1514
1515 if test "$GCC" != "yes" && test "$ICC" != "yes"
1516 then
1517   AC_MSG_ERROR([gcc|icc required but not found])
1518 fi
1519
1520 dnl Ensure that compilation tools are compatible with GCC extensions
1521 if test "$GXX" != "yes" && test "$IXX" != "yes"
1522 then
1523   AC_MSG_ERROR([g++|clang++|icc required but not found])
1524 fi
1525
1526 dnl Verify that GCC is version 3.0 or higher
1527 if test "$GCC" = "yes"
1528 then
1529   AC_COMPILE_IFELSE(
1530 [
1531   AC_LANG_SOURCE([[
1532     #if !defined(__GNUC__) || __GNUC__ < 3
1533     #error Unsupported GCC version
1534     #endif
1535   ]])
1536 ],
1537 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1538 fi
1539
1540 dnl Check for GNU Make.  We use its extensions, so don't build without it
1541 if test -z "$llvm_cv_gnu_make_command"
1542 then
1543   AC_MSG_ERROR([GNU Make required but not found])
1544 fi
1545
1546 dnl Tool compatibility is okay if we make it here.
1547 AC_MSG_RESULT([ok])
1548
1549 dnl Check optional compiler flags.
1550 AC_MSG_CHECKING([optional compiler flags])
1551 case "$llvm_cv_cxx_compiler" in
1552   clang)
1553     CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1554     CXX_FLAG_CHECK(MISSING_FIELD_INITIALIZERS, [-Wmissing-field-initializers])
1555     CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1556     ;;
1557   gcc)
1558     dnl If we're using gcc check for -Wno-missing-field-initializers as gcc will warn
1559     dnl on plain open brace initializations. clang won't so use -Wmissing-field-initializers
1560     dnl there.
1561     CXX_FLAG_CHECK(MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1562     CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1563     CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1564     CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1565     dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1566     dnl known to be uninitialized from cases which might be uninitialized.  We
1567     dnl still want to catch the first kind of errors.
1568     if test -z "$NO_MAYBE_UNINITIALIZED"
1569     then
1570       CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1571     fi
1572     ;;
1573   unknown)
1574     ;;
1575 esac
1576
1577 dnl Check for misbehaving -Wcomment (gcc-4.7 has this) and maybe add
1578 dnl -Wno-comment to the flags.
1579 no_comment=
1580 llvm_cv_old_cxxflags="$CXXFLAGS"
1581 CXXFLAGS="$CXXFLAGS -Wcomment -Werror"
1582 AC_COMPILE_IFELSE(
1583 [
1584   AC_LANG_SOURCE([[// Comment \o\
1585 // Another comment
1586 int main() { return 0; }
1587   ]])
1588 ],
1589 [
1590   no_comment=-Wno-comment
1591 ],
1592 [])
1593 AC_SUBST(NO_COMMENT, [$no_comment])
1594 CXXFLAGS="$llvm_cv_old_cxxflags"
1595
1596 AC_MSG_RESULT([$NO_VARIADIC_MACROS $MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED $NO_COMMENT])
1597
1598 AC_ARG_WITH([python],
1599             [AS_HELP_STRING([--with-python], [path to python])],
1600             [PYTHON="$withval"])
1601
1602 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1603   AC_MSG_CHECKING([for python])
1604   AC_MSG_RESULT([user defined: $with_python])
1605 else
1606   if test -n "$PYTHON" ; then
1607     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1608   fi
1609
1610   AC_PATH_PROG([PYTHON], [python python2 python27],
1611                [AC_MSG_RESULT([not found])
1612                 AC_MSG_ERROR([could not find python 2.7 or higher])])
1613 fi
1614
1615 AC_MSG_CHECKING([for python >= 2.7])
1616 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1617 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1618 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1619 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1620 if test "$ac_python_version_major" -gt "2" || \
1621    (test "$ac_python_version_major" -eq "2" && \
1622     test "$ac_python_version_minor" -ge "7") ; then
1623   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1624 else
1625   AC_MSG_RESULT([not found])
1626   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.7])
1627 fi
1628
1629 dnl===-----------------------------------------------------------------------===
1630 dnl===
1631 dnl=== SECTION 5: Check for libraries
1632 dnl===
1633 dnl===-----------------------------------------------------------------------===
1634
1635 AC_CHECK_LIB(m,sin)
1636 if test "$llvm_cv_os_type" = "MingW" ; then
1637   dnl mingw-gcc's driver doesn't imply -lole32 by default so we may need this
1638   dnl when being built with gcc for bootstrapping purposes.
1639   AC_CHECK_LIB(ole32, main)
1640   AC_CHECK_LIB(psapi, main)
1641   AC_CHECK_LIB(shell32, main)
1642 fi
1643
1644 dnl dlopen() is required for plugin support.
1645 AC_SEARCH_LIBS(dlopen,dl,LLVM_DEFINE_SUBST([HAVE_DLOPEN],[1],
1646                [Define if dlopen() is available on this platform.]),
1647                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1648
1649 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1650 dnl macros to detect whether clock_gettime is available, this just finds the
1651 dnl right libraries to link with.
1652 AC_SEARCH_LIBS(clock_gettime,rt)
1653
1654 dnl The curses library is optional; used for querying terminal info
1655 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1656   dnl We need the has_color functionality in curses for it to be useful.
1657   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1658                  LLVM_DEFINE_SUBST([HAVE_TERMINFO],[1],
1659                                    [Define if the setupterm() function is supported this platform.]))
1660 fi
1661
1662 dnl The libedit library is optional; used by lib/LineEditor
1663 if test "$llvm_cv_enable_libedit" = "yes" ; then
1664   AC_SEARCH_LIBS(el_init,edit,
1665                  AC_DEFINE([HAVE_LIBEDIT],[1],
1666                            [Define if libedit is available on this platform.]))
1667 fi
1668
1669 dnl libffi is optional; used to call external functions from the interpreter
1670 if test "$llvm_cv_enable_libffi" = "yes" ; then
1671   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1672                  [Define if libffi is available on this platform.]),
1673                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1674 fi
1675
1676 dnl mallinfo is optional; the code can compile (minus features) without it
1677 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1678                [Define if mallinfo() is available on this platform.]))
1679
1680 dnl pthread locking functions are optional - but llvm will not be thread-safe
1681 dnl without locks.
1682 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1683   AC_CHECK_LIB(pthread, pthread_mutex_init)
1684   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1685                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1686                            [Have pthread_mutex_lock]))
1687   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1688                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1689                  [Have pthread_rwlock_init]))
1690   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1691                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1692                  [Have pthread_getspecific]))
1693 fi
1694
1695 dnl zlib is optional; used for compression/uncompression
1696 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1697   AC_CHECK_LIB(z, compress2)
1698 fi
1699
1700 dnl Allow OProfile support for JIT output.
1701 AC_ARG_WITH(oprofile,
1702   AS_HELP_STRING([--with-oprofile=<prefix>],
1703     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1704     [
1705       AC_SUBST(USE_OPROFILE, [1])
1706       case "$withval" in
1707         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1708         no) llvm_cv_oppath=
1709             AC_SUBST(USE_OPROFILE, [0]) ;;
1710         *) llvm_cv_oppath="${withval}/lib/oprofile"
1711            CPPFLAGS="-I${withval}/include";;
1712       esac
1713       case $llvm_cv_os_type in
1714         Linux)
1715           if test -n "$llvm_cv_oppath" ; then
1716             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1717             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1718             dnl libbfd is not included properly in libopagent in some Debian
1719             dnl versions.  If libbfd isn't found at all, we assume opagent works
1720             dnl anyway.
1721             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1722             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1723               echo "Error! You need to have libopagent around."
1724               exit 1
1725             ])
1726             AC_CHECK_HEADER([opagent.h], [], [
1727               echo "Error! You need to have opagent.h around."
1728               exit 1
1729               ])
1730           fi ;;
1731         *)
1732           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1733       esac
1734     ],
1735     [
1736       AC_SUBST(USE_OPROFILE, [0])
1737     ])
1738 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1739                    [Define if we have the oprofile JIT-support library])
1740
1741 dnl Enable support for Intel JIT Events API.
1742 AC_ARG_WITH(intel-jitevents,
1743   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1744     [
1745        case "$withval" in
1746           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1747           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1748           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1749        esac
1750
1751       case $llvm_cv_os_type in
1752         Linux|Win32|Cygwin|MingW) ;;
1753         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1754       esac
1755
1756       case "$llvm_cv_target_arch" in
1757         x86|x86_64) ;;
1758         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1759       esac
1760     ],
1761     [
1762       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1763     ])
1764 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1765                    [Define if we have the Intel JIT API runtime support library])
1766
1767 dnl Check for libxml2
1768 dnl Right now we're just checking for the existence, we could also check for a
1769 dnl particular version via --version on xml2-config
1770 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1771
1772 AC_MSG_CHECKING(for libxml2 includes)
1773 if test "x$XML2CONFIG" = "x"; then
1774  AC_MSG_RESULT(xml2-config not found)
1775 else
1776  LIBXML2_INC=`$XML2CONFIG --cflags`
1777  AC_MSG_RESULT($LIBXML2_INC)
1778  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1779                                 LIBXML2_LIBS="-lxml2"])
1780 fi
1781 AC_SUBST(LIBXML2_LIBS)
1782 AC_SUBST(LIBXML2_INC)
1783
1784 dnl===-----------------------------------------------------------------------===
1785 dnl===
1786 dnl=== SECTION 6: Check for header files
1787 dnl===
1788 dnl===-----------------------------------------------------------------------===
1789
1790 dnl First, use autoconf provided macros for specific headers that we need
1791 dnl We don't check for ancient stuff or things that are guaranteed to be there
1792 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1793 dnl Generally we're looking for POSIX headers.
1794 AC_HEADER_DIRENT
1795 AC_HEADER_MMAP_ANONYMOUS
1796 AC_HEADER_STAT
1797 AC_HEADER_TIME
1798
1799 AC_LANG_PUSH([C++])
1800 dnl size_t must be defined before including cxxabi.h on FreeBSD 10.0.
1801 AC_CHECK_HEADERS([cxxabi.h], [], [],
1802 [#include <stddef.h>
1803 ])
1804 AC_LANG_POP([C++])
1805
1806 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1807 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1808 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1809 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1810 AC_CHECK_HEADERS([valgrind/valgrind.h])
1811 AC_CHECK_HEADERS([fenv.h])
1812 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1813 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1814   AC_CHECK_HEADERS(pthread.h,
1815                    AC_SUBST(HAVE_PTHREAD, 1),
1816                    AC_SUBST(HAVE_PTHREAD, 0))
1817 else
1818   AC_SUBST(HAVE_PTHREAD, 0)
1819 fi
1820 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1821   AC_CHECK_HEADERS(zlib.h,
1822                    AC_SUBST(HAVE_LIBZ, 1),
1823                    AC_SUBST(HAVE_LIBZ, 0))
1824 else
1825   AC_SUBST(HAVE_LIBZ, 0)
1826 fi
1827
1828 dnl Try to find ffi.h.
1829 if test "$llvm_cv_enable_libffi" = "yes" ; then
1830   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1831 fi
1832
1833 dnl Try to find Darwin specific crash reporting libraries.
1834 AC_CHECK_HEADERS([CrashReporterClient.h])
1835
1836 dnl Try to find Darwin specific crash reporting global.
1837 AC_MSG_CHECKING([__crashreporter_info__])
1838 AC_LINK_IFELSE(
1839 [
1840   AC_LANG_SOURCE([[
1841     extern const char *__crashreporter_info__;
1842     int main() {
1843       __crashreporter_info__ = "test";
1844       return 0;
1845     }
1846   ]])
1847 ],
1848 [
1849   AC_MSG_RESULT([yes])
1850   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1851 ],
1852 [
1853   AC_MSG_RESULT([no])
1854   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1855 ])
1856
1857 dnl===-----------------------------------------------------------------------===
1858 dnl===
1859 dnl=== SECTION 7: Check for types and structures
1860 dnl===
1861 dnl===-----------------------------------------------------------------------===
1862
1863 AC_HUGE_VAL_CHECK
1864 AC_TYPE_PID_T
1865 AC_TYPE_SIZE_T
1866 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1867 AC_STRUCT_TM
1868 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1869 AC_CHECK_TYPES([uint64_t],,
1870          AC_CHECK_TYPES([u_int64_t],,
1871          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1872
1873 dnl===-----------------------------------------------------------------------===
1874 dnl===
1875 dnl=== SECTION 8: Check for specific functions needed
1876 dnl===
1877 dnl===-----------------------------------------------------------------------===
1878
1879 AC_CHECK_FUNCS([backtrace getcwd ])
1880 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1881 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1882 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1883 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1884 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1885 AC_CHECK_FUNCS([setjmp longjmp writev])
1886 AC_CHECK_FUNCS([futimes futimens])
1887 AC_C_PRINTF_A
1888
1889 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1890 AC_CHECK_DECLS([arc4random])
1891
1892 dnl Check the declaration "Secure API" on Windows environments.
1893 AC_CHECK_DECLS([strerror_s])
1894
1895 dnl Check symbols in libgcc.a for JIT on Mingw.
1896 if test "$llvm_cv_os_type" = "MingW" ; then
1897   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1898   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1899   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1900   AC_CHECK_LIB(gcc,__chkstk_ms,AC_DEFINE([HAVE___CHKSTK_MS],[1],[Have host's __chkstk_ms]))
1901   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1902   AC_CHECK_LIB(gcc,___chkstk_ms,AC_DEFINE([HAVE____CHKSTK_MS],[1],[Have host's ___chkstk_ms]))
1903
1904   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1905   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1906   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1907   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1908   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1909   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1910   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1911   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1912   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1913   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1914
1915   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1916   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1917 fi
1918
1919 dnl Check Win32 API EnumerateLoadedModules.
1920 if test "$llvm_cv_os_type" = "MingW" ; then
1921   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1922   AC_COMPILE_IFELSE(
1923 [
1924   AC_LANG_SOURCE([[
1925     #include <windows.h>
1926     #include <imagehlp.h>
1927     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1928     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1929   ]])
1930 ],
1931 [
1932   AC_MSG_RESULT([yes])
1933   llvm_cv_win32_elmcb_pcstr="PCSTR"
1934 ],
1935 [
1936   AC_MSG_RESULT([no])
1937   llvm_cv_win32_elmcb_pcstr="PSTR"
1938 ])
1939   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1940 fi
1941
1942 dnl Check for mmap support.We also need to know if /dev/zero is required to
1943 dnl be opened for allocating RWX memory.
1944 dnl Make sure we aren't attempting to configure for an unknown system
1945 if test "$llvm_cv_platform_type" = "Unix" ; then
1946   AC_FUNC_MMAP
1947   AC_FUNC_MMAP_FILE
1948   AC_NEED_DEV_ZERO_FOR_MMAP
1949
1950   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1951   then
1952     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1953   fi
1954   if test "$ac_cv_func_mmap_file" = "no"
1955   then
1956     AC_MSG_WARN([mmap() of files required but not found])
1957   fi
1958 fi
1959
1960 dnl atomic builtins are required for threading support.
1961 AC_MSG_CHECKING(for GCC atomic builtins)
1962 dnl Since we'll be using these atomic builtins in C++ files we should test
1963 dnl the C++ compiler.
1964 AC_LANG_PUSH([C++])
1965 AC_LINK_IFELSE(
1966 [
1967   AC_LANG_SOURCE([[
1968     int main() {
1969       volatile unsigned long val = 1;
1970       __sync_synchronize();
1971       __sync_val_compare_and_swap(&val, 1, 0);
1972       __sync_add_and_fetch(&val, 1);
1973       __sync_sub_and_fetch(&val, 1);
1974       return 0;
1975     }
1976   ]])
1977 ],
1978 [
1979   AC_MSG_RESULT([yes])
1980   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1981 ],
1982 [
1983   AC_MSG_RESULT([no])
1984   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1985   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1986 ])
1987 AC_LANG_POP([C++])
1988
1989 dnl===-----------------------------------------------------------------------===
1990 dnl===
1991 dnl=== SECTION 9: Additional checks, variables, etc.
1992 dnl===
1993 dnl===-----------------------------------------------------------------------===
1994
1995 dnl Handle 32-bit linux systems running a 64-bit kernel.
1996 dnl This has to come after section 4 because it invokes the compiler.
1997 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1998   AC_IS_LINUX_MIXED
1999   if test "$llvm_cv_linux_mixed" = "yes"; then
2000     llvm_cv_target_arch="x86"
2001     ARCH="x86"
2002   fi
2003 fi
2004
2005 dnl Check whether __dso_handle is present
2006 AC_CHECK_FUNCS([__dso_handle])
2007
2008 dnl Propagate the shared library extension that the libltdl checks did to
2009 dnl the Makefiles so we can use it there too
2010 AC_SUBST(SHLIBEXT,$llvm_shlib_ext)
2011
2012 dnl Translate the various configuration directories and other basic
2013 dnl information into substitutions that will end up in Makefile.config.in
2014 dnl that these configured values can be used by the makefiles
2015 if test "${prefix}" = "NONE" ; then
2016   prefix="/usr/local"
2017 fi
2018 eval LLVM_PREFIX="${prefix}";
2019 eval LLVM_BINDIR="${prefix}/bin";
2020 eval LLVM_DATADIR="${prefix}/share/llvm";
2021 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
2022 eval LLVM_ETCDIR="${prefix}/etc/llvm";
2023 eval LLVM_INCLUDEDIR="${prefix}/include";
2024 eval LLVM_INFODIR="${prefix}/info";
2025 eval LLVM_MANDIR="${prefix}/man";
2026 LLVM_CONFIGTIME=`date`
2027 AC_SUBST(LLVM_PREFIX)
2028 AC_SUBST(LLVM_BINDIR)
2029 AC_SUBST(LLVM_DATADIR)
2030 AC_SUBST(LLVM_DOCSDIR)
2031 AC_SUBST(LLVM_ETCDIR)
2032 AC_SUBST(LLVM_INCLUDEDIR)
2033 AC_SUBST(LLVM_INFODIR)
2034 AC_SUBST(LLVM_MANDIR)
2035 AC_SUBST(LLVM_CONFIGTIME)
2036
2037 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
2038 if test "${ENABLE_TIMESTAMPS}" = "0"; then
2039   LLVM_CONFIGTIME="(timestamp not enabled)"
2040 fi
2041
2042 dnl Place the various directories into the config.h file as #defines so that we
2043 dnl can know about the installation paths within LLVM.
2044 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
2045                    [Installation prefix directory])
2046 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
2047                    [Installation directory for binary executables])
2048 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
2049                    [Installation directory for data files])
2050 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
2051                    [Installation directory for documentation])
2052 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
2053                    [Installation directory for config files])
2054 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
2055                    [Installation directory for include files])
2056 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
2057                    [Installation directory for .info files])
2058 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
2059                    [Installation directory for man pages])
2060 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
2061                    [Time at which LLVM was configured])
2062 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
2063                    [Host triple LLVM will be executed on])
2064 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
2065                    [Target triple LLVM will generate code for by default])
2066
2067 dnl Determine which bindings to build.
2068 if test "$BINDINGS_TO_BUILD" = auto ; then
2069   BINDINGS_TO_BUILD=""
2070   if test "x$OCAMLFIND" != x ; then
2071     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
2072   fi
2073   if test "x$GO" != x ; then
2074     if $GO run ${srcdir}/bindings/go/conftest.go ; then
2075       BINDINGS_TO_BUILD="go $BINDINGS_TO_BUILD"
2076     fi
2077   fi
2078 fi
2079 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
2080
2081 dnl Do any work necessary to ensure that bindings have what they need.
2082 binding_prereqs_failed=0
2083 for a_binding in $BINDINGS_TO_BUILD ; do
2084   case "$a_binding" in
2085   ocaml)
2086     if test "x$OCAMLFIND" = x ; then
2087       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlfind not found. Try configure OCAMLFIND=/path/to/ocamlfind])
2088       binding_prereqs_failed=1
2089     fi
2090
2091     if $OCAMLFIND opt -version >/dev/null 2>/dev/null ; then
2092       HAVE_OCAMLOPT=1
2093     else
2094       HAVE_OCAMLOPT=0
2095     fi
2096     AC_SUBST(HAVE_OCAMLOPT)
2097
2098     if ! $OCAMLFIND query ctypes >/dev/null 2>/dev/null; then
2099       AC_MSG_WARN([--enable-bindings=ocaml specified, but ctypes is not installed])
2100       binding_prereqs_failed=1
2101     fi
2102
2103     if $OCAMLFIND query oUnit >/dev/null 2>/dev/null; then
2104       HAVE_OCAML_OUNIT=1
2105     else
2106       HAVE_OCAML_OUNIT=0
2107       AC_MSG_WARN([--enable-bindings=ocaml specified, but OUnit 2 is not installed. Tests will not run])
2108       dnl oUnit is optional!
2109     fi
2110     AC_SUBST(HAVE_OCAML_OUNIT)
2111
2112     if test "x$with_ocaml_libdir" != xauto ; then
2113       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
2114     else
2115       ocaml_stdlib="`"$OCAMLFIND" ocamlc -where`"
2116       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
2117       then
2118         # ocaml stdlib is beneath our prefix; use stdlib
2119         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
2120       else
2121         # ocaml stdlib is outside our prefix; use libdir/ocaml
2122         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
2123       fi
2124     fi
2125     ;;
2126   go)
2127     if test "x$GO" = x ; then
2128       AC_MSG_WARN([--enable-bindings=go specified, but go not found. Try configure GO=/path/to/go])
2129       binding_prereqs_failed=1
2130     else
2131       if $GO run ${srcdir}/bindings/go/conftest.go ; then
2132         :
2133       else
2134         AC_MSG_WARN([--enable-bindings=go specified, but need at least Go 1.2. Try configure GO=/path/to/go])
2135         binding_prereqs_failed=1
2136       fi
2137     fi
2138     ;;
2139   esac
2140 done
2141 if test "$binding_prereqs_failed" = 1 ; then
2142   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
2143 fi
2144
2145 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
2146 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
2147
2148 dnl Determine linker rpath flag
2149 if test "$llvm_cv_link_use_r" = "yes" ; then
2150   RPATH="-Wl,-R"
2151 else
2152   RPATH="-Wl,-rpath"
2153 fi
2154 AC_SUBST(RPATH)
2155
2156 dnl Determine linker rdynamic flag
2157 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
2158   RDYNAMIC="-rdynamic"
2159 else
2160   RDYNAMIC=""
2161 fi
2162 AC_SUBST(RDYNAMIC)
2163
2164 dnl===-----------------------------------------------------------------------===
2165 dnl===
2166 dnl=== SECTION 10: Specify the output files and generate it
2167 dnl===
2168 dnl===-----------------------------------------------------------------------===
2169
2170 dnl Configure header files
2171 dnl WARNING: dnl If you add or remove any of the following config headers, then
2172 dnl you MUST also update Makefile so that the variable FilesToConfig
2173 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2174 dnl files can be updated automatically when their *.in sources change.
2175 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2176 AH_TOP([#ifndef CONFIG_H
2177 #define CONFIG_H
2178
2179 /* Exported configuration */
2180 #include "llvm/Config/llvm-config.h"])
2181 AH_BOTTOM([#endif])
2182
2183 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2184 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2185 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2186 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2187 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2188
2189 dnl Configure the makefile's configuration data
2190 AC_CONFIG_FILES([Makefile.config])
2191
2192 dnl Configure the RPM spec file for LLVM
2193 AC_CONFIG_FILES([llvm.spec])
2194
2195 dnl Configure doxygen's configuration file
2196 AC_CONFIG_FILES([docs/doxygen.cfg])
2197
2198 dnl Configure clang, if present
2199 if test "${clang_src_root}" = ""; then
2200   clang_src_root="$srcdir/tools/clang"
2201 fi
2202 if test -f ${clang_src_root}/README.txt; then
2203   dnl Clang supports build systems which use the multilib libdir suffix.
2204   dnl The autoconf system doesn't support this so stub out that variable.
2205   AC_DEFINE_UNQUOTED(CLANG_LIBDIR_SUFFIX,"",
2206                      [Multilib suffix for libdir.])
2207
2208   dnl Use variables to stay under 80 columns.
2209   configh="include/clang/Config/config.h"
2210   doxy="docs/doxygen.cfg"
2211   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2212   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2213 fi
2214
2215 dnl OCaml findlib META file
2216 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2217
2218 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2219 test "x$program_prefix" = "xNONE" && program_prefix=""
2220 AC_SUBST([program_prefix])
2221
2222
2223 dnl Do special configuration of Makefiles
2224 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2225 AC_CONFIG_MAKEFILE(Makefile)
2226 AC_CONFIG_MAKEFILE(Makefile.common)
2227 AC_CONFIG_MAKEFILE(examples/Makefile)
2228 AC_CONFIG_MAKEFILE(lib/Makefile)
2229 AC_CONFIG_MAKEFILE(test/Makefile)
2230 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2231 AC_CONFIG_MAKEFILE(unittests/Makefile)
2232 AC_CONFIG_MAKEFILE(tools/Makefile)
2233 AC_CONFIG_MAKEFILE(utils/Makefile)
2234 AC_CONFIG_MAKEFILE(projects/Makefile)
2235 AC_CONFIG_MAKEFILE(bindings/Makefile)
2236 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2237
2238 dnl Finally, crank out the output
2239 AC_OUTPUT