autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.5svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [5], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  63 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  64 : ${CFLAGS=}
  65 : ${CXXFLAGS=}
  66
  67 dnl We need to check for the compiler up here to avoid anything else
  68 dnl starting with a different one.
  69 AC_PROG_CC(clang gcc)
  70 AC_PROG_CXX(clang++ g++)
  71 AC_PROG_CPP
  72
  73 dnl If CXX is Clang, check that it can find and parse C++ standard library
  74 dnl headers.
  75 if test "$CXX" = "clang++" ; then
  76   AC_MSG_CHECKING([whether clang works])
  77   AC_LANG_PUSH([C++])
  78   dnl Note that space between 'include' and '(' is required.  There's a broken
  79   dnl regex in aclocal that otherwise will think that we call m4's include
  80   dnl builtin.
  81   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  82 #if __has_include (<cxxabi.h>)
  83 #include <cxxabi.h>
  84 #endif
  85 #if __has_include (<unwind.h>)
  86 #include <unwind.h>
  87 #endif
  88 ]])],
  89 [
  90   AC_MSG_RESULT([yes])
  91 ],
  92 [
  93   AC_MSG_RESULT([no])
  94   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
  95 ])
  96   AC_LANG_POP([C++])
  97 fi
  98
  99 dnl Set up variables that track whether the host compiler is GCC or Clang where
 100 dnl we can effectively sanity check them. We don't try to sanity check all the
 101 dnl other possible compilers.
 102 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 103 AC_LANG_PUSH([C++])
 104 llvm_cv_cxx_compiler=unknown
 105 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 106                                     #error
 107                                     #endif
 108                                     ]])],
 109                   llvm_cv_cxx_compiler=clang,
 110                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 111                                                        #error
 112                                                        #endif
 113                                                        ]])],
 114                                      llvm_cv_cxx_compiler=gcc, [])])
 115 AC_LANG_POP([C++])
 116 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 117
 118 dnl Configure all of the projects present in our source tree. While we could
 119 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 120 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 121 dnl Instead we match on the known projects.
 122
 123 dnl
 124 dnl One tricky part of doing this is that some projects depend upon other
 125 dnl projects.  For example, several projects rely upon the LLVM test suite.
 126 dnl We want to configure those projects first so that their object trees are
 127 dnl created before running the configure scripts of projects that depend upon
 128 dnl them.
 129 dnl
 130
 131 dnl Several projects use the LLVM test suite, so configure it next.
 132 if test -d ${srcdir}/projects/test-suite ; then
 133   AC_CONFIG_SUBDIRS([projects/test-suite])
 134 fi
 135
 136 dnl llvm-test is the old name of the test-suite, kept here for backwards
 137 dnl compatibility
 138 if test -d ${srcdir}/projects/llvm-test ; then
 139   AC_CONFIG_SUBDIRS([projects/llvm-test])
 140 fi
 141
 142 dnl Some projects use poolalloc; configure that next
 143 if test -d ${srcdir}/projects/poolalloc ; then
 144   AC_CONFIG_SUBDIRS([projects/poolalloc])
 145 fi
 146
 147 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 148   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 149 fi
 150
 151 dnl Check for all other projects
 152 for i in `ls ${srcdir}/projects`
 153 do
 154   if test -d ${srcdir}/projects/${i} ; then
 155     case ${i} in
 156       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 157       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 158       compiler-rt)       ;;
 159       test-suite)     ;;
 160       llvm-test)      ;;
 161       poolalloc)      ;;
 162       llvm-poolalloc) ;;
 163       *)
 164         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 165         ;;
 166     esac
 167   fi
 168 done
 169
 170 dnl Disable the build of polly, even if it is checked out into tools/polly.
 171 AC_ARG_ENABLE(polly,
 172               AS_HELP_STRING([--enable-polly],
 173                              [Use polly if available (default is YES)]),,
 174                              enableval=default)
 175 case "$enableval" in
 176   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 177   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 178   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 179   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 180 esac
 181
 182
 183 dnl Check if polly is checked out into tools/polly and configure it if
 184 dnl available.
 185 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 186   AC_SUBST(LLVM_HAS_POLLY,1)
 187   AC_CONFIG_SUBDIRS([tools/polly])
 188 fi
 189
 190 dnl===-----------------------------------------------------------------------===
 191 dnl===
 192 dnl=== SECTION 2: Architecture, target, and host checks
 193 dnl===
 194 dnl===-----------------------------------------------------------------------===
 195
 196 dnl Check the target for which we're compiling and the host that will do the
 197 dnl compilations. This will tell us which LLVM compiler will be used for
 198 dnl compiling SSA into object code. This needs to be done early because
 199 dnl following tests depend on it.
 200 AC_CANONICAL_TARGET
 201
 202 dnl Determine the platform type and cache its value. This helps us configure
 203 dnl the System library to the correct build platform.
 204 AC_CACHE_CHECK([type of operating system we're going to host on],
 205                [llvm_cv_os_type],
 206 [case $host in
 207   *-*-aix*)
 208     llvm_cv_link_all_option="-Wl,--whole-archive"
 209     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 210     llvm_cv_os_type="AIX"
 211     llvm_cv_platform_type="Unix" ;;
 212   *-*-irix*)
 213     llvm_cv_link_all_option="-Wl,--whole-archive"
 214     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 215     llvm_cv_os_type="IRIX"
 216     llvm_cv_platform_type="Unix" ;;
 217   *-*-cygwin*)
 218     llvm_cv_link_all_option="-Wl,--whole-archive"
 219     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 220     llvm_cv_os_type="Cygwin"
 221     llvm_cv_platform_type="Unix" ;;
 222   *-*-darwin*)
 223     llvm_cv_link_all_option="-Wl,-all_load"
 224     llvm_cv_no_link_all_option="-Wl,-noall_load"
 225     llvm_cv_os_type="Darwin"
 226     llvm_cv_platform_type="Unix" ;;
 227   *-*-minix*)
 228     llvm_cv_link_all_option="-Wl,-all_load"
 229     llvm_cv_no_link_all_option="-Wl,-noall_load"
 230     llvm_cv_os_type="Minix"
 231     llvm_cv_platform_type="Unix" ;;
 232   *-*-freebsd*)
 233     llvm_cv_link_all_option="-Wl,--whole-archive"
 234     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 235     llvm_cv_os_type="FreeBSD"
 236     llvm_cv_platform_type="Unix" ;;
 237   *-*-kfreebsd-gnu)
 238     llvm_cv_link_all_option="-Wl,--whole-archive"
 239     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 240     llvm_cv_os_type="GNU/kFreeBSD"
 241     llvm_cv_platform_type="Unix" ;;
 242   *-*-openbsd*)
 243     llvm_cv_link_all_option="-Wl,--whole-archive"
 244     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 245     llvm_cv_os_type="OpenBSD"
 246     llvm_cv_platform_type="Unix" ;;
 247   *-*-netbsd*)
 248     llvm_cv_link_all_option="-Wl,--whole-archive"
 249     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 250     llvm_cv_os_type="NetBSD"
 251     llvm_cv_platform_type="Unix" ;;
 252   *-*-dragonfly*)
 253     llvm_cv_link_all_option="-Wl,--whole-archive"
 254     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 255     llvm_cv_os_type="DragonFly"
 256     llvm_cv_platform_type="Unix" ;;
 257   *-*-hpux*)
 258     llvm_cv_link_all_option="-Wl,--whole-archive"
 259     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 260     llvm_cv_os_type="HP-UX"
 261     llvm_cv_platform_type="Unix" ;;
 262   *-*-interix*)
 263     llvm_cv_link_all_option="-Wl,--whole-archive"
 264     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 265     llvm_cv_os_type="Interix"
 266     llvm_cv_platform_type="Unix" ;;
 267   *-*-linux*)
 268     llvm_cv_link_all_option="-Wl,--whole-archive"
 269     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 270     llvm_cv_os_type="Linux"
 271     llvm_cv_platform_type="Unix" ;;
 272   *-*-gnu*)
 273     llvm_cv_link_all_option="-Wl,--whole-archive"
 274     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 275     llvm_cv_os_type="GNU"
 276     llvm_cv_platform_type="Unix" ;;
 277   *-*-solaris*)
 278     llvm_cv_link_all_option="-Wl,-z,allextract"
 279     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 280     llvm_cv_os_type="SunOS"
 281     llvm_cv_platform_type="Unix" ;;
 282   *-*-auroraux*)
 283     llvm_cv_link_all_option="-Wl,-z,allextract"
 284     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 285     llvm_cv_os_type="AuroraUX"
 286     llvm_cv_platform_type="Unix" ;;
 287   *-*-win32*)
 288     llvm_cv_link_all_option="-Wl,--whole-archive"
 289     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 290     llvm_cv_os_type="Win32"
 291     llvm_cv_platform_type="Win32" ;;
 292   *-*-mingw*)
 293     llvm_cv_link_all_option="-Wl,--whole-archive"
 294     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 295     llvm_cv_os_type="MingW"
 296     llvm_cv_platform_type="Win32" ;;
 297   *-*-haiku*)
 298     llvm_cv_link_all_option="-Wl,--whole-archive"
 299     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 300     llvm_cv_os_type="Haiku"
 301     llvm_cv_platform_type="Unix" ;;
 302   *-unknown-eabi*)
 303     llvm_cv_link_all_option="-Wl,--whole-archive"
 304     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 305     llvm_cv_os_type="Freestanding"
 306     llvm_cv_platform_type="Unix" ;;
 307   *-unknown-elf*)
 308     llvm_cv_link_all_option="-Wl,--whole-archive"
 309     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 310     llvm_cv_os_type="Freestanding"
 311     llvm_cv_platform_type="Unix" ;;
 312   *)
 313     llvm_cv_link_all_option=""
 314     llvm_cv_no_link_all_option=""
 315     llvm_cv_os_type="Unknown"
 316     llvm_cv_platform_type="Unknown" ;;
 317 esac])
 318
 319 AC_CACHE_CHECK([type of operating system we're going to target],
 320                [llvm_cv_target_os_type],
 321 [case $target in
 322   *-*-aix*)
 323     llvm_cv_target_os_type="AIX" ;;
 324   *-*-irix*)
 325     llvm_cv_target_os_type="IRIX" ;;
 326   *-*-cygwin*)
 327     llvm_cv_target_os_type="Cygwin" ;;
 328   *-*-darwin*)
 329     llvm_cv_target_os_type="Darwin" ;;
 330   *-*-minix*)
 331     llvm_cv_target_os_type="Minix" ;;
 332   *-*-freebsd*)
 333     llvm_cv_target_os_type="FreeBSD" ;;
 334   *-*-kfreebsd-gnu)
 335     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 336   *-*-openbsd*)
 337     llvm_cv_target_os_type="OpenBSD" ;;
 338   *-*-netbsd*)
 339     llvm_cv_target_os_type="NetBSD" ;;
 340   *-*-dragonfly*)
 341     llvm_cv_target_os_type="DragonFly" ;;
 342   *-*-hpux*)
 343     llvm_cv_target_os_type="HP-UX" ;;
 344   *-*-interix*)
 345     llvm_cv_target_os_type="Interix" ;;
 346   *-*-linux*)
 347     llvm_cv_target_os_type="Linux" ;;
 348   *-*-gnu*)
 349     llvm_cv_target_os_type="GNU" ;;
 350   *-*-solaris*)
 351     llvm_cv_target_os_type="SunOS" ;;
 352   *-*-auroraux*)
 353     llvm_cv_target_os_type="AuroraUX" ;;
 354   *-*-win32*)
 355     llvm_cv_target_os_type="Win32" ;;
 356   *-*-mingw*)
 357     llvm_cv_target_os_type="MingW" ;;
 358   *-*-haiku*)
 359     llvm_cv_target_os_type="Haiku" ;;
 360   *-*-rtems*)
 361     llvm_cv_target_os_type="RTEMS" ;;
 362   *-*-nacl*)
 363     llvm_cv_target_os_type="NativeClient" ;;
 364   *-unknown-eabi*)
 365     llvm_cv_target_os_type="Freestanding" ;;
 366   *)
 367     llvm_cv_target_os_type="Unknown" ;;
 368 esac])
 369
 370 dnl Make sure we aren't attempting to configure for an unknown system
 371 if test "$llvm_cv_os_type" = "Unknown" ; then
 372   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 373 fi
 374
 375 dnl Set the "OS" Makefile variable based on the platform type so the
 376 dnl makefile can configure itself to specific build hosts
 377 AC_SUBST(OS,$llvm_cv_os_type)
 378 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 379 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 380
 381 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 382 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 383 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 384
 385 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 386 dnl This is used by lib/Support to determine the basic kind of implementation
 387 dnl to use.
 388 case $llvm_cv_platform_type in
 389   Unix)
 390     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 391     AC_SUBST(LLVM_ON_UNIX,[1])
 392     AC_SUBST(LLVM_ON_WIN32,[0])
 393     ;;
 394   Win32)
 395     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 396     AC_SUBST(LLVM_ON_UNIX,[0])
 397     AC_SUBST(LLVM_ON_WIN32,[1])
 398     ;;
 399 esac
 400
 401 dnl Determine what our target architecture is and configure accordingly.
 402 dnl This will allow Makefiles to make a distinction between the hardware and
 403 dnl the OS.
 404 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 405 [case $target in
 406   i?86-*)                 llvm_cv_target_arch="x86" ;;
 407   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 408   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 409   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 410   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 411   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 412   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 413   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 414   xcore-*)                llvm_cv_target_arch="XCore" ;;
 415   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 416   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 417   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 418   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 419   *)                      llvm_cv_target_arch="Unknown" ;;
 420 esac])
 421
 422 if test "$llvm_cv_target_arch" = "Unknown" ; then
 423   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 424 fi
 425
 426 dnl Determine the LLVM native architecture for the target
 427 case "$llvm_cv_target_arch" in
 428     x86)     LLVM_NATIVE_ARCH="X86" ;;
 429     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 430     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 431 esac
 432
 433 dnl Define a substitution, ARCH, for the target architecture
 434 AC_SUBST(ARCH,$llvm_cv_target_arch)
 435
 436 dnl Determine what our host architecture.
 437 dnl This will allow MCJIT regress tests runs only for supported
 438 dnl platforms.
 439 case $host in
 440   i?86-*)                 host_arch="x86" ;;
 441   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 442   sparc*-*)               host_arch="Sparc" ;;
 443   powerpc*-*)             host_arch="PowerPC" ;;
 444   arm*-*)                 host_arch="ARM" ;;
 445   aarch64*-*)             host_arch="AArch64" ;;
 446   mips-* | mips64-*)      host_arch="Mips" ;;
 447   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 448   xcore-*)                host_arch="XCore" ;;
 449   msp430-*)               host_arch="MSP430" ;;
 450   hexagon-*)              host_arch="Hexagon" ;;
 451   s390x-*)                host_arch="SystemZ" ;;
 452   *)                      host_arch="Unknown" ;;
 453 esac
 454
 455 if test "$host_arch" = "Unknown" ; then
 456   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 457 fi
 458
 459 AC_SUBST(HOST_ARCH,$host_arch)
 460
 461 dnl Check for build platform executable suffix if we're cross-compiling
 462 if test "$cross_compiling" = yes; then
 463   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 464   AC_BUILD_EXEEXT
 465   ac_build_prefix=${build_alias}-
 466   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 467   if test -z "$BUILD_CXX"; then
 468      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 469      if test -z "$BUILD_CXX"; then
 470        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 471      fi
 472   fi
 473 else
 474   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 475 fi
 476
 477 dnl Check to see if there's a .svn or .git directory indicating that this
 478 dnl build is being done from a checkout. This sets up several defaults for
 479 dnl the command line switches. When we build with a checkout directory,
 480 dnl we get a debug with assertions turned on. Without, we assume a source
 481 dnl release and we get an optimized build without assertions.
 482 dnl See --enable-optimized and --enable-assertions below
 483 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 484   cvsbuild="yes"
 485   optimize="no"
 486   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 487 else
 488   cvsbuild="no"
 489   optimize="yes"
 490 fi
 491
 492 dnl===-----------------------------------------------------------------------===
 493 dnl===
 494 dnl=== SECTION 3: Command line arguments for the configure script.
 495 dnl===
 496 dnl===-----------------------------------------------------------------------===
 497
 498 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 499 AC_ARG_ENABLE(libcpp,
 500               AS_HELP_STRING([--enable-libcpp],
 501                              [Use libc++ if available (default is NO)]),,
 502                              enableval=default)
 503 case "$enableval" in
 504   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 505   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 506   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 507   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 508 esac
 509
 510 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 511 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 512 dnl these checks here so that we have the configuration of the standard C++
 513 dnl library finished.
 514 AC_ARG_ENABLE(compiler-version-checks,
 515               AS_HELP_STRING([--enable-compiler-version-checks],
 516                              [Check the version of the host compiler (default is YES)]),,
 517                              enableval=default)
 518 case "$enableval" in
 519   no)
 520     ;;
 521   yes|default)
 522     AC_LANG_PUSH([C++])
 523     case "$llvm_cv_cxx_compiler" in
 524     clang)
 525       AC_MSG_CHECKING([whether Clang is new enough])
 526       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 527 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 528 #error This version of Clang is too old to build LLVM
 529 #endif
 530 ]])],
 531           [AC_MSG_RESULT([yes])],
 532           [AC_MSG_RESULT([no])
 533            AC_MSG_ERROR([
 534 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 535 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 536 bypass these sanity checks.])])
 537
 538       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 539       dnl are sometimes deeply confusing though. Here we test for an obvious
 540       dnl incomplete feature in 4.6's standard library that was completed in
 541       dnl 4.7's.
 542       AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 543       llvm_cv_old_cxxflags="$CXXFLAGS"
 544       CXXFLAGS="$CXXFLAGS -std=c++0x"
 545       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 546 #include <atomic>
 547 std::atomic<float> x(0.0f);
 548 int main() { return (float)x; }
 549 ]])],
 550           [AC_MSG_RESULT([yes])],
 551           [AC_MSG_RESULT([no])
 552            AC_MSG_ERROR([
 553 We detected a missing feature in the standard C++ library that was known to be
 554 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 555 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 556 than 4.7. You will need to update your system and ensure Clang uses the newer
 557 standard library.
 558
 559 If this error is incorrect or you need to force things to work, you may pass
 560 '--disable-compiler-version-checks' to configure to bypass this test.])])
 561       CXXFLAGS="$llvm_cv_old_cxxflags"
 562       ;;
 563     gcc)
 564       AC_MSG_CHECKING([whether GCC is new enough])
 565       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 566 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 567 #error This version of GCC is too old to build LLVM
 568 #endif
 569 ]])],
 570           [AC_MSG_RESULT([yes])],
 571           [AC_MSG_RESULT([no])
 572            AC_MSG_ERROR([
 573 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 574 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 575 bypass these sanity checks.])])
 576       ;;
 577     unknown)
 578       ;;
 579     esac
 580     AC_LANG_POP([C++])
 581     ;;
 582   *)
 583     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 584     ;;
 585 esac
 586
 587 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 588 AC_ARG_ENABLE(cxx11,
 589               AS_HELP_STRING([--enable-cxx11],
 590                              [Use c++11 if available (default is NO)]),,
 591                              enableval=default)
 592 case "$enableval" in
 593   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 594   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 595   default) AC_SUBST(ENABLE_CXX11,[0]);;
 596   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 597 esac
 598
 599 dnl --enable-fission : check whether or not to use -gsplit-dwarf on the command
 600 dnl line
 601 AC_ARG_ENABLE(split-dwarf,
 602               AS_HELP_STRING([--enable-split-dwarf],
 603                              [Use split-dwarf if available (default is NO)]),,
 604                              enableval=default)
 605 case "$enableval" in
 606   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 607   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 608   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 609   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 610 esac
 611
 612 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 613 clang_arcmt="yes"
 614 AC_ARG_ENABLE(clang-arcmt,
 615               AS_HELP_STRING([--enable-clang-arcmt],
 616                              [Enable building of clang ARCMT (default is YES)]),
 617                              clang_arcmt="$enableval",
 618                              enableval="yes")
 619 case "$enableval" in
 620   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 621   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 622   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 623   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 624 esac
 625
 626 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 627 clang_static_analyzer="yes"
 628 AC_ARG_ENABLE(clang-static-analyzer,
 629               AS_HELP_STRING([--enable-clang-static-analyzer],
 630                              [Enable building of clang Static Analyzer (default is YES)]),
 631                              clang_static_analyzer="$enableval",
 632                              enableval="yes")
 633 case "$enableval" in
 634   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 635   no)
 636     if test ${clang_arcmt} != "no" ; then
 637       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 638     fi
 639     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 640     ;;
 641   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 642   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 643 esac
 644
 645 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 646 AC_ARG_ENABLE(clang-rewriter,
 647               AS_HELP_STRING([--enable-clang-rewriter],
 648                              [Enable building of clang rewriter (default is YES)]),,
 649                              enableval="yes")
 650 case "$enableval" in
 651   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 652   no)
 653     if test ${clang_arcmt} != "no" ; then
 654       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 655     fi
 656     if test ${clang_static_analyzer} != "no" ; then
 657       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 658     fi
 659     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 660     ;;
 661   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 662   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 663 esac
 664
 665 dnl --enable-optimized : check whether they want to do an optimized build:
 666 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 667  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 668 if test ${enableval} = "no" ; then
 669   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 670 else
 671   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 672 fi
 673
 674 dnl --enable-profiling : check whether they want to do a profile build:
 675 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 676  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 677 if test ${enableval} = "no" ; then
 678   AC_SUBST(ENABLE_PROFILING,[[]])
 679 else
 680   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 681 fi
 682
 683 dnl --enable-assertions : check whether they want to turn on assertions or not:
 684 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 685   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 686 if test ${enableval} = "yes" ; then
 687   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 688 else
 689   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 690 fi
 691
 692 dnl --enable-werror : check whether we want Werror on by default
 693 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 694   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 695 case "$enableval" in
 696   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 697   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 698   default) AC_SUBST(ENABLE_WERROR,[0]);;
 699   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 700 esac
 701
 702 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 703 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 704   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 705 if test ${enableval} = "yes" ; then
 706   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 707   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 708 else
 709   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 710   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 711 fi
 712
 713 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 714 AC_ARG_ENABLE(debug-runtime,
 715    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 716 if test ${enableval} = "no" ; then
 717   AC_SUBST(DEBUG_RUNTIME,[[]])
 718 else
 719   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 720 fi
 721
 722 dnl --enable-debug-symbols : should even optimized compiler libraries
 723 dnl have debug symbols?
 724 AC_ARG_ENABLE(debug-symbols,
 725    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 726 if test ${enableval} = "no" ; then
 727   AC_SUBST(DEBUG_SYMBOLS,[[]])
 728 else
 729   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 730 fi
 731
 732 dnl --enable-keep-symbols : do not strip installed executables
 733 AC_ARG_ENABLE(keep-symbols,
 734    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 735 if test ${enableval} = "no" ; then
 736   AC_SUBST(KEEP_SYMBOLS,[[]])
 737 else
 738   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 739 fi
 740
 741 dnl --enable-jit: check whether they want to enable the jit
 742 AC_ARG_ENABLE(jit,
 743   AS_HELP_STRING(--enable-jit,
 744                  [Enable Just In Time Compiling (default is YES)]),,
 745   enableval=default)
 746 if test ${enableval} = "no"
 747 then
 748   AC_SUBST(JIT,[[]])
 749 else
 750   case "$llvm_cv_target_arch" in
 751     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 752     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 753     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 754     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 755     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 756     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 757     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 758     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 759     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 760     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 761     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 762     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 763     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 764   esac
 765 fi
 766
 767 dnl Allow enablement of building and installing docs
 768 AC_ARG_ENABLE(docs,
 769               AS_HELP_STRING([--enable-docs],
 770                              [Build documents (default is YES)]),,
 771                              enableval=default)
 772 case "$enableval" in
 773   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 774   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 775   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 776   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 777 esac
 778
 779 dnl Allow enablement of doxygen generated documentation
 780 AC_ARG_ENABLE(doxygen,
 781               AS_HELP_STRING([--enable-doxygen],
 782                              [Build doxygen documentation (default is NO)]),,
 783                              enableval=default)
 784 case "$enableval" in
 785   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 786   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 787   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 788   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 789 esac
 790
 791 dnl Allow disablement of threads
 792 AC_ARG_ENABLE(threads,
 793               AS_HELP_STRING([--enable-threads],
 794                              [Use threads if available (default is YES)]),,
 795                              enableval=default)
 796 case "$enableval" in
 797   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 798   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 799   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 800   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 801 esac
 802 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 803                    [Define if threads enabled])
 804
 805 dnl Allow disablement of pthread.h
 806 AC_ARG_ENABLE(pthreads,
 807               AS_HELP_STRING([--enable-pthreads],
 808                              [Use pthreads if available (default is YES)]),,
 809                              enableval=default)
 810 case "$enableval" in
 811   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 812   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 813   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 814   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 815 esac
 816
 817 dnl Allow disablement of zlib
 818 AC_ARG_ENABLE(zlib,
 819               AS_HELP_STRING([--enable-zlib],
 820                              [Use zlib for compression/decompression if
 821                               available (default is YES)]),,
 822                               enableval=default)
 823 case "$enableval" in
 824   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 825   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 826   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 827   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 828 esac
 829 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 830                    [Define if zlib is enabled])
 831
 832 dnl Allow building without position independent code
 833 AC_ARG_ENABLE(pic,
 834   AS_HELP_STRING([--enable-pic],
 835                  [Build LLVM with Position Independent Code (default is YES)]),,
 836                  enableval=default)
 837 case "$enableval" in
 838   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 839   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 840   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 841   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 842 esac
 843 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 844                    [Define if position independent code is enabled])
 845
 846 dnl Allow building a shared library and linking tools against it.
 847 AC_ARG_ENABLE(shared,
 848   AS_HELP_STRING([--enable-shared],
 849                  [Build a shared library and link tools against it (default is NO)]),,
 850                  enableval=default)
 851 case "$enableval" in
 852   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 853   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 854   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 855   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 856 esac
 857
 858 dnl Allow libstdc++ is embedded in LLVM.dll.
 859 AC_ARG_ENABLE(embed-stdcxx,
 860   AS_HELP_STRING([--enable-embed-stdcxx],
 861                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 862                  enableval=default)
 863 case "$enableval" in
 864   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 865   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 866   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 867   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 868 esac
 869
 870 dnl Enable embedding timestamp information into build.
 871 AC_ARG_ENABLE(timestamps,
 872   AS_HELP_STRING([--enable-timestamps],
 873                  [Enable embedding timestamp information in build (default is YES)]),,
 874                  enableval=default)
 875 case "$enableval" in
 876   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 877   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 878   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 879   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 880 esac
 881 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 882                    [Define if timestamp information (e.g., __DATE__) is allowed])
 883
 884 dnl Enable support for showing backtraces.
 885 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
 886   [--enable-backtraces],
 887   [Enable embedding backtraces on crash (default is YES)]),
 888   [case "$enableval" in
 889     yes) llvm_cv_enable_backtraces="yes" ;;
 890     no)  llvm_cv_enable_backtraces="no"  ;;
 891     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 892   esac],
 893   llvm_cv_enable_backtraces="yes")
 894 if test "$llvm_cv_enable_backtraces" = "yes" ; then
 895   AC_DEFINE([ENABLE_BACKTRACES],[1],
 896             [Define if you want backtraces on crash])
 897 fi
 898
 899 dnl Enable installing platform specific signal handling overrides, for improved
 900 dnl CrashRecovery support or interaction with crash reporting software. This
 901 dnl support may be inappropriate for some clients embedding LLVM as a library.
 902 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
 903   [--enable-crash-overrides],
 904   [Enable crash handling overrides (default is YES)]),
 905   [case "$enableval" in
 906     yes) llvm_cv_enable_crash_overrides="yes" ;;
 907     no)  llvm_cv_enable_crash_overrides="no"  ;;
 908     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
 909   esac],
 910   llvm_cv_enable_crash_overrides="yes")
 911 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
 912   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
 913             [Define to enable crash handling overrides])
 914 fi
 915
 916 dnl Allow specific targets to be specified for building (or not)
 917 TARGETS_TO_BUILD=""
 918 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 919     [Build specific host targets: all or target1,target2,... Valid targets are:
 920      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 921      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 922     enableval=all)
 923 if test "$enableval" = host-only ; then
 924   enableval=host
 925 fi
 926 case "$enableval" in
 927   all) TARGETS_TO_BUILD="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600" ;;
 928   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 929       case "$a_target" in
 930         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 931         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 932         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 933         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 934         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 935         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 936         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 937         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 938         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 939         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 940         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 941         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 942         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 943         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 944         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 945         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 946         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 947         host) case "$llvm_cv_target_arch" in
 948             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 949             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 950             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 951             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 952             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 953             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 954             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 955             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 956             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 957             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 958             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 959             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 960             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 961           esac ;;
 962         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 963       esac
 964   done
 965   ;;
 966 esac
 967
 968 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 969     [Build experimental host targets: disable or target1,target2,...
 970      (default=disable)]),,
 971     enableval=disable)
 972
 973 if test ${enableval} != "disable"
 974 then
 975   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 976 fi
 977
 978 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 979
 980 dnl Determine whether we are building LLVM support for the native architecture.
 981 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 982 for a_target in $TARGETS_TO_BUILD; do
 983   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 984     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 985       [LLVM architecture name for the native architecture, if available])
 986     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 987     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 988     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 989     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 990     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 991       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 992     fi
 993     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 994       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 995     fi
 996     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 997       [LLVM name for the native Target init function, if available])
 998     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 999       [LLVM name for the native TargetInfo init function, if available])
1000     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1001       [LLVM name for the native target MC init function, if available])
1002     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1003       [LLVM name for the native AsmPrinter init function, if available])
1004     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1005       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1006        [LLVM name for the native AsmParser init function, if available])
1007     fi
1008     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1009       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1010        [LLVM name for the native Disassembler init function, if available])
1011     fi
1012   fi
1013 done
1014
1015 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1016 dnl target feature def files.
1017 LLVM_ENUM_TARGETS=""
1018 LLVM_ENUM_ASM_PRINTERS=""
1019 LLVM_ENUM_ASM_PARSERS=""
1020 LLVM_ENUM_DISASSEMBLERS=""
1021 for target_to_build in $TARGETS_TO_BUILD; do
1022   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1023   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1024     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1025   fi
1026   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1027     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1028   fi
1029   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1030     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1031   fi
1032 done
1033 AC_SUBST(LLVM_ENUM_TARGETS)
1034 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1035 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1036 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1037
1038 dnl Override the option to use for optimized builds.
1039 AC_ARG_WITH(optimize-option,
1040   AS_HELP_STRING([--with-optimize-option],
1041                  [Select the compiler options to use for optimized builds]),,
1042                  withval=default)
1043 AC_MSG_CHECKING([optimization flags])
1044 case "$withval" in
1045   default)
1046     case "$llvm_cv_os_type" in
1047     FreeBSD) optimize_option=-O2 ;;
1048     MingW) optimize_option=-O2 ;;
1049     *)     optimize_option=-O3 ;;
1050     esac ;;
1051   *) optimize_option="$withval" ;;
1052 esac
1053 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1054 AC_MSG_RESULT([$optimize_option])
1055
1056 dnl Specify extra build options
1057 AC_ARG_WITH(extra-options,
1058   AS_HELP_STRING([--with-extra-options],
1059                  [Specify additional options to compile LLVM with]),,
1060                  withval=default)
1061 case "$withval" in
1062   default) EXTRA_OPTIONS= ;;
1063   *) EXTRA_OPTIONS=$withval ;;
1064 esac
1065 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1066
1067 dnl Specify extra linker build options
1068 AC_ARG_WITH(extra-ld-options,
1069   AS_HELP_STRING([--with-extra-ld-options],
1070                  [Specify additional options to link LLVM with]),,
1071                  withval=default)
1072 case "$withval" in
1073   default) EXTRA_LD_OPTIONS= ;;
1074   *) EXTRA_LD_OPTIONS=$withval ;;
1075 esac
1076 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1077
1078 dnl Allow specific bindings to be specified for building (or not)
1079 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1080     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1081     enableval=default)
1082 BINDINGS_TO_BUILD=""
1083 case "$enableval" in
1084   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1085   all ) BINDINGS_TO_BUILD="ocaml" ;;
1086   none | no) BINDINGS_TO_BUILD="" ;;
1087   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1088       case "$a_binding" in
1089         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1090         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1091       esac
1092   done
1093   ;;
1094 esac
1095
1096 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1097 dnl script for bindings/ocaml/configure, except that its auto value depends on
1098 dnl OCAMLC, which is found here to support tests.
1099 AC_ARG_WITH([ocaml-libdir],
1100   [AS_HELP_STRING([--with-ocaml-libdir],
1101     [Specify install location for ocaml bindings (default is stdlib)])],
1102   [],
1103   [withval=auto])
1104 case "$withval" in
1105   auto) with_ocaml_libdir="$withval" ;;
1106   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1107   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1108 esac
1109
1110 AC_ARG_WITH(clang-srcdir,
1111   AS_HELP_STRING([--with-clang-srcdir],
1112     [Directory to the out-of-tree Clang source]),,
1113     withval="-")
1114 case "$withval" in
1115   -) clang_src_root="" ;;
1116   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1117   *) clang_src_root="$ac_pwd/$withval" ;;
1118 esac
1119 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1120
1121 AC_ARG_WITH(clang-resource-dir,
1122   AS_HELP_STRING([--with-clang-resource-dir],
1123     [Relative directory from the Clang binary for resource files]),,
1124     withval="")
1125 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1126                    [Relative directory for resource files])
1127
1128 AC_ARG_WITH(c-include-dirs,
1129   AS_HELP_STRING([--with-c-include-dirs],
1130     [Colon separated list of directories clang will search for headers]),,
1131     withval="")
1132 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1133                    [Directories clang will search for headers])
1134
1135 # Clang normally uses the system c++ headers and libraries. With this option,
1136 # clang will use the ones provided by a gcc installation instead. This option should
1137 # be passed the same value that was used with --prefix when configuring gcc.
1138 AC_ARG_WITH(gcc-toolchain,
1139   AS_HELP_STRING([--with-gcc-toolchain],
1140     [Directory where gcc is installed.]),,
1141     withval="")
1142 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1143                    [Directory where gcc is installed.])
1144
1145 AC_ARG_WITH(default-sysroot,
1146   AS_HELP_STRING([--with-default-sysroot],
1147     [Add --sysroot=<path> to all compiler invocations.]),,
1148     withval="")
1149 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1150                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1151
1152 dnl Allow linking of LLVM with GPLv3 binutils code.
1153 AC_ARG_WITH(binutils-include,
1154   AS_HELP_STRING([--with-binutils-include],
1155     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1156   withval=default)
1157 case "$withval" in
1158   default) WITH_BINUTILS_INCDIR=default ;;
1159   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1160   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1161 esac
1162 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1163   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1164   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1165      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1166      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1167   fi
1168 fi
1169
1170 dnl Specify the URL where bug reports should be submitted.
1171 AC_ARG_WITH(bug-report-url,
1172   AS_HELP_STRING([--with-bug-report-url],
1173     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1174     withval="http://llvm.org/bugs/")
1175 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1176                    [Bug report URL.])
1177
1178 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1179 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1180   [--enable-terminfo],
1181   [Query the terminfo database if available (default is YES)]),
1182   [case "$enableval" in
1183     yes) llvm_cv_enable_terminfo="yes" ;;
1184     no)  llvm_cv_enable_terminfo="no"  ;;
1185     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1186   esac],
1187   llvm_cv_enable_terminfo="yes")
1188
1189 dnl --enable-libffi : check whether the user wants to turn off libffi:
1190 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1191   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1192   [case "$enableval" in
1193     yes) llvm_cv_enable_libffi="yes" ;;
1194     no)  llvm_cv_enable_libffi="no"  ;;
1195     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1196   esac],
1197   llvm_cv_enable_libffi=no)
1198
1199 AC_ARG_WITH(internal-prefix,
1200   AS_HELP_STRING([--with-internal-prefix],
1201     [Installation directory for internal files]),,
1202     withval="")
1203 AC_SUBST(INTERNAL_PREFIX,[$withval])
1204
1205 dnl===-----------------------------------------------------------------------===
1206 dnl===
1207 dnl=== SECTION 4: Check for programs we need and that they are the right version
1208 dnl===
1209 dnl===-----------------------------------------------------------------------===
1210
1211 AC_PROG_NM
1212 AC_SUBST(NM)
1213
1214 dnl Check for the tools that the makefiles require
1215 AC_CHECK_GNU_MAKE
1216 AC_PROG_LN_S
1217 AC_PATH_PROG(CMP, [cmp], [cmp])
1218 AC_PATH_PROG(CP, [cp], [cp])
1219 AC_PATH_PROG(DATE, [date], [date])
1220 AC_PATH_PROG(FIND, [find], [find])
1221 AC_PATH_PROG(GREP, [grep], [grep])
1222 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1223 AC_PATH_PROG(MV,   [mv],   [mv])
1224 AC_PROG_RANLIB
1225 AC_CHECK_TOOL(AR, ar, false)
1226 AC_PATH_PROG(RM,   [rm],   [rm])
1227 AC_PATH_PROG(SED,  [sed],  [sed])
1228 AC_PATH_PROG(TAR,  [tar],  [gtar])
1229 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1230
1231 dnl Looking for misc. graph plotting software
1232 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1233 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1234   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1235   dnl If we're targeting for mingw we should emit windows paths, not msys
1236   if test "$llvm_cv_os_type" = "MingW" ; then
1237     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1238   fi
1239   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1240    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1241 fi
1242 AC_PATH_PROG(DOT, [dot], [echo dot])
1243 if test "$DOT" != "echo dot" ; then
1244   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1245   dnl If we're targeting for mingw we should emit windows paths, not msys
1246   if test "$llvm_cv_os_type" = "MingW" ; then
1247     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1248   fi
1249   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1250    [Define to path to dot program if found or 'echo dot' otherwise])
1251 fi
1252 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1253 if test "$FDP" != "echo fdp" ; then
1254   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1255   dnl If we're targeting for mingw we should emit windows paths, not msys
1256   if test "$llvm_cv_os_type" = "MingW" ; then
1257     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1258   fi
1259   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1260    [Define to path to fdp program if found or 'echo fdp' otherwise])
1261 fi
1262 AC_PATH_PROG(NEATO, [neato], [echo neato])
1263 if test "$NEATO" != "echo neato" ; then
1264   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1265   dnl If we're targeting for mingw we should emit windows paths, not msys
1266   if test "$llvm_cv_os_type" = "MingW" ; then
1267     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1268   fi
1269   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1270    [Define to path to neato program if found or 'echo neato' otherwise])
1271 fi
1272 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1273 if test "$TWOPI" != "echo twopi" ; then
1274   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1275   dnl If we're targeting for mingw we should emit windows paths, not msys
1276   if test "$llvm_cv_os_type" = "MingW" ; then
1277     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1278   fi
1279   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1280    [Define to path to twopi program if found or 'echo twopi' otherwise])
1281 fi
1282 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1283 if test "$CIRCO" != "echo circo" ; then
1284   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1285   dnl If we're targeting for mingw we should emit windows paths, not msys
1286   if test "$llvm_cv_os_type" = "MingW" ; then
1287     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1288   fi
1289   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1290    [Define to path to circo program if found or 'echo circo' otherwise])
1291 fi
1292 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1293 if test "$GV" != "echo gv" ; then
1294   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1295   dnl If we're targeting for mingw we should emit windows paths, not msys
1296   if test "$llvm_cv_os_type" = "MingW" ; then
1297     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1298   fi
1299   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1300    [Define to path to gv program if found or 'echo gv' otherwise])
1301 fi
1302 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1303 if test "$DOTTY" != "echo dotty" ; then
1304   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1305   dnl If we're targeting for mingw we should emit windows paths, not msys
1306   if test "$llvm_cv_os_type" = "MingW" ; then
1307     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1308   fi
1309   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1310    [Define to path to dotty program if found or 'echo dotty' otherwise])
1311 fi
1312 AC_PATH_PROGS(XDOT, [xdot xdot.py], [echo xdot])
1313 if test "$XDOT" != "echo xdot" ; then
1314   AC_DEFINE([HAVE_XDOT],[1],[Define if the xdot program is available])
1315   dnl If we're targeting for mingw we should emit windows paths, not msys
1316   if test "$llvm_cv_os_type" = "MingW" ; then
1317     XDOT=`echo $XDOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1318   fi
1319   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT],"$XDOT${EXEEXT}",
1320    [Define to path to xdot program if found or 'echo xdot' otherwise])
1321 fi
1322
1323 dnl Find the install program
1324 AC_PROG_INSTALL
1325 dnl Prepend src dir to install path dir if it's a relative path
1326 dnl This is a hack for installs that take place in something other
1327 dnl than the top level.
1328 case "$INSTALL" in
1329  [[\\/$]]* | ?:[[\\/]]* ) ;;
1330  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1331 esac
1332
1333 dnl Checks for documentation and testing tools that we can do without. If these
1334 dnl are not found then they are set to "true" which always succeeds but does
1335 dnl nothing. This just lets the build output show that we could have done
1336 dnl something if the tool was available.
1337 AC_PATH_PROG(BZIP2, [bzip2])
1338 AC_PATH_PROG(CAT, [cat])
1339 AC_PATH_PROG(DOXYGEN, [doxygen])
1340 AC_PATH_PROG(GROFF, [groff])
1341 AC_PATH_PROG(GZIPBIN, [gzip])
1342 AC_PATH_PROG(PDFROFF, [pdfroff])
1343 AC_PATH_PROG(ZIP, [zip])
1344 AC_PATH_PROGS(OCAMLC, [ocamlc])
1345 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1346 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1347 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1348 AC_PATH_PROGS(GAS, [gas as])
1349
1350 dnl Get the version of the linker in use.
1351 AC_LINK_GET_VERSION
1352
1353 dnl Determine whether the linker supports the -R option.
1354 AC_LINK_USE_R
1355
1356 dnl Determine whether the compiler supports the -rdynamic option.
1357 AC_LINK_EXPORT_DYNAMIC
1358
1359 dnl Determine whether the linker supports the --version-script option.
1360 AC_LINK_VERSION_SCRIPT
1361
1362 dnl Check for libtool and the library that has dlopen function (which must come
1363 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1364 dnl libtool).
1365 AC_LIBTOOL_DLOPEN
1366 AC_LIB_LTDL
1367
1368 AC_MSG_CHECKING([tool compatibility])
1369
1370 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1371 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1372 dnl to support those options.
1373 dnl "icc" emits gcc signatures
1374 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1375 ICC=no
1376 IXX=no
1377 case $CC in
1378   icc*|icpc*)
1379     ICC=yes
1380     IXX=yes
1381     ;;
1382    *)
1383     ;;
1384 esac
1385
1386 if test "$GCC" != "yes" && test "$ICC" != "yes"
1387 then
1388   AC_MSG_ERROR([gcc|icc required but not found])
1389 fi
1390
1391 dnl Ensure that compilation tools are compatible with GCC extensions
1392 if test "$GXX" != "yes" && test "$IXX" != "yes"
1393 then
1394   AC_MSG_ERROR([g++|clang++|icc required but not found])
1395 fi
1396
1397 dnl Verify that GCC is version 3.0 or higher
1398 if test "$GCC" = "yes"
1399 then
1400   AC_COMPILE_IFELSE(
1401 [
1402   AC_LANG_SOURCE([[
1403     #if !defined(__GNUC__) || __GNUC__ < 3
1404     #error Unsupported GCC version
1405     #endif
1406   ]])
1407 ],
1408 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1409 fi
1410
1411 dnl Check for GNU Make.  We use its extensions, so don't build without it
1412 if test -z "$llvm_cv_gnu_make_command"
1413 then
1414   AC_MSG_ERROR([GNU Make required but not found])
1415 fi
1416
1417 dnl Tool compatibility is okay if we make it here.
1418 AC_MSG_RESULT([ok])
1419
1420 dnl Check optional compiler flags.
1421 AC_MSG_CHECKING([optional compiler flags])
1422 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1423 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1424 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1425
1426 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1427 dnl false positives, so disable it.
1428 NO_UNINITIALIZED=
1429 NO_MAYBE_UNINITIALIZED=
1430 if test "$GXX" = "yes"
1431 then
1432   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1433   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1434   dnl known to be uninitialized from cases which might be uninitialized.  We
1435   dnl still want to catch the first kind of errors.
1436   if test -z "$NO_MAYBE_UNINITIALIZED"
1437   then
1438     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1439   fi
1440 fi
1441 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1442
1443 AC_ARG_WITH([python],
1444             [AS_HELP_STRING([--with-python], [path to python])],
1445             [PYTHON="$withval"])
1446
1447 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1448   AC_MSG_CHECKING([for python])
1449   AC_MSG_RESULT([user defined: $with_python])
1450 else
1451   if test -n "$PYTHON" ; then
1452     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1453   fi
1454
1455   AC_PATH_PROG([PYTHON], [python python2 python26],
1456                [AC_MSG_RESULT([not found])
1457                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1458 fi
1459
1460 AC_MSG_CHECKING([for python >= 2.5])
1461 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1462 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1463 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1464 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1465 if test "$ac_python_version_major" -gt "2" || \
1466    (test "$ac_python_version_major" -eq "2" && \
1467     test "$ac_python_version_minor" -ge "5") ; then
1468   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1469 else
1470   AC_MSG_RESULT([not found])
1471   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1472 fi
1473
1474 dnl===-----------------------------------------------------------------------===
1475 dnl===
1476 dnl=== SECTION 5: Check for libraries
1477 dnl===
1478 dnl===-----------------------------------------------------------------------===
1479
1480 AC_CHECK_LIB(m,sin)
1481 if test "$llvm_cv_os_type" = "MingW" ; then
1482   AC_CHECK_LIB(imagehlp, main)
1483   AC_CHECK_LIB(psapi, main)
1484   AC_CHECK_LIB(shell32, main)
1485 fi
1486
1487 dnl dlopen() is required for plugin support.
1488 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1489                [Define if dlopen() is available on this platform.]),
1490                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1491
1492 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1493 dnl macros to detect whether clock_gettime is available, this just finds the
1494 dnl right libraries to link with.
1495 AC_SEARCH_LIBS(clock_gettime,rt)
1496
1497 dnl The curses library is optional; used for querying terminal info
1498 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1499   dnl We need the has_color functionality in curses for it to be useful.
1500   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1501                  AC_DEFINE([HAVE_TERMINFO],[1],
1502                            [Define if the setupterm() function is supported this platform.]))
1503 fi
1504
1505 dnl libffi is optional; used to call external functions from the interpreter
1506 if test "$llvm_cv_enable_libffi" = "yes" ; then
1507   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1508                  [Define if libffi is available on this platform.]),
1509                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1510 fi
1511
1512 dnl mallinfo is optional; the code can compile (minus features) without it
1513 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1514                [Define if mallinfo() is available on this platform.]))
1515
1516 dnl pthread locking functions are optional - but llvm will not be thread-safe
1517 dnl without locks.
1518 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1519   AC_CHECK_LIB(pthread, pthread_mutex_init)
1520   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1521                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1522                            [Have pthread_mutex_lock]))
1523   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1524                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1525                  [Have pthread_rwlock_init]))
1526   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1527                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1528                  [Have pthread_getspecific]))
1529 fi
1530
1531 dnl zlib is optional; used for compression/uncompression
1532 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1533   AC_CHECK_LIB(z, compress2)
1534 fi
1535
1536 dnl Allow extra x86-disassembler library
1537 AC_ARG_WITH(udis86,
1538   AS_HELP_STRING([--with-udis86=<path>],
1539     [Use udis86 external x86 disassembler library]),
1540     [
1541       AC_SUBST(USE_UDIS86, [1])
1542       case "$withval" in
1543         /usr/lib|yes) ;;
1544         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1545       esac
1546       AC_CHECK_LIB(udis86, ud_init, [], [
1547         echo "Error! You need to have libudis86 around."
1548         exit -1
1549       ])
1550     ],
1551     AC_SUBST(USE_UDIS86, [0]))
1552 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1553                    [Define if use udis86 library])
1554
1555 dnl Allow OProfile support for JIT output.
1556 AC_ARG_WITH(oprofile,
1557   AS_HELP_STRING([--with-oprofile=<prefix>],
1558     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1559     [
1560       AC_SUBST(USE_OPROFILE, [1])
1561       case "$withval" in
1562         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1563         no) llvm_cv_oppath=
1564             AC_SUBST(USE_OPROFILE, [0]) ;;
1565         *) llvm_cv_oppath="${withval}/lib/oprofile"
1566            CPPFLAGS="-I${withval}/include";;
1567       esac
1568       case $llvm_cv_os_type in
1569         Linux)
1570           if test -n "$llvm_cv_oppath" ; then
1571             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1572             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1573             dnl libbfd is not included properly in libopagent in some Debian
1574             dnl versions.  If libbfd isn't found at all, we assume opagent works
1575             dnl anyway.
1576             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1577             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1578               echo "Error! You need to have libopagent around."
1579               exit -1
1580             ])
1581             AC_CHECK_HEADER([opagent.h], [], [
1582               echo "Error! You need to have opagent.h around."
1583               exit -1
1584               ])
1585           fi ;;
1586         *)
1587           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1588       esac
1589     ],
1590     [
1591       AC_SUBST(USE_OPROFILE, [0])
1592     ])
1593 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1594                    [Define if we have the oprofile JIT-support library])
1595
1596 dnl Enable support for Intel JIT Events API.
1597 AC_ARG_WITH(intel-jitevents,
1598   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1599     [
1600        case "$withval" in
1601           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1602           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1603           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1604        esac
1605
1606       case $llvm_cv_os_type in
1607         Linux|Win32|Cygwin|MingW) ;;
1608         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1609       esac
1610
1611       case "$llvm_cv_target_arch" in
1612         x86|x86_64) ;;
1613         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1614       esac
1615     ],
1616     [
1617       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1618     ])
1619 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1620                    [Define if we have the Intel JIT API runtime support library])
1621
1622 dnl Check for libxml2
1623 dnl Right now we're just checking for the existence, we could also check for a
1624 dnl particular version via --version on xml2-config
1625 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1626
1627 AC_MSG_CHECKING(for libxml2 includes)
1628 if test "x$XML2CONFIG" = "x"; then
1629  AC_MSG_RESULT(xml2-config not found)
1630 else
1631  LIBXML2_INC=`$XML2CONFIG --cflags`
1632  AC_MSG_RESULT($LIBXML2_INC)
1633  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1634                                 LIBXML2_LIBS="-lxml2"])
1635 fi
1636 AC_SUBST(LIBXML2_LIBS)
1637 AC_SUBST(LIBXML2_INC)
1638
1639 dnl===-----------------------------------------------------------------------===
1640 dnl===
1641 dnl=== SECTION 6: Check for header files
1642 dnl===
1643 dnl===-----------------------------------------------------------------------===
1644
1645 dnl First, use autoconf provided macros for specific headers that we need
1646 dnl We don't check for ancient stuff or things that are guaranteed to be there
1647 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1648 dnl Generally we're looking for POSIX headers.
1649 AC_HEADER_DIRENT
1650 AC_HEADER_MMAP_ANONYMOUS
1651 AC_HEADER_STAT
1652 AC_HEADER_SYS_WAIT
1653 AC_HEADER_TIME
1654
1655 AC_LANG_PUSH([C++])
1656 AC_CHECK_HEADERS([cxxabi.h])
1657 AC_LANG_POP([C++])
1658 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1659 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1660 AC_CHECK_HEADERS([utime.h])
1661 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1662 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1663 AC_CHECK_HEADERS([valgrind/valgrind.h])
1664 AC_CHECK_HEADERS([fenv.h])
1665 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1666 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1667   AC_CHECK_HEADERS(pthread.h,
1668                    AC_SUBST(HAVE_PTHREAD, 1),
1669                    AC_SUBST(HAVE_PTHREAD, 0))
1670 else
1671   AC_SUBST(HAVE_PTHREAD, 0)
1672 fi
1673 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1674   AC_CHECK_HEADERS(zlib.h,
1675                    AC_SUBST(HAVE_LIBZ, 1),
1676                    AC_SUBST(HAVE_LIBZ, 0))
1677 else
1678   AC_SUBST(HAVE_LIBZ, 0)
1679 fi
1680
1681 dnl Try to find ffi.h.
1682 if test "$llvm_cv_enable_libffi" = "yes" ; then
1683   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1684 fi
1685
1686 dnl Try to find Darwin specific crash reporting libraries.
1687 AC_CHECK_HEADERS([CrashReporterClient.h])
1688
1689 dnl Try to find Darwin specific crash reporting global.
1690 AC_MSG_CHECKING([__crashreporter_info__])
1691 AC_LINK_IFELSE(
1692 [
1693   AC_LANG_SOURCE([[
1694     extern const char *__crashreporter_info__;
1695     int main() {
1696       __crashreporter_info__ = "test";
1697       return 0;
1698     }
1699   ]])
1700 ],
1701 [
1702   AC_MSG_RESULT([yes])
1703   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1704 ],
1705 [
1706   AC_MSG_RESULT([no])
1707   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1708 ])
1709
1710 dnl===-----------------------------------------------------------------------===
1711 dnl===
1712 dnl=== SECTION 7: Check for types and structures
1713 dnl===
1714 dnl===-----------------------------------------------------------------------===
1715
1716 AC_HUGE_VAL_CHECK
1717 AC_TYPE_PID_T
1718 AC_TYPE_SIZE_T
1719 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1720 AC_STRUCT_TM
1721 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1722 AC_CHECK_TYPES([uint64_t],,
1723          AC_CHECK_TYPES([u_int64_t],,
1724          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1725
1726 dnl===-----------------------------------------------------------------------===
1727 dnl===
1728 dnl=== SECTION 8: Check for specific functions needed
1729 dnl===
1730 dnl===-----------------------------------------------------------------------===
1731
1732 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1733 AC_CHECK_FUNCS([powf fmodf strtof round ])
1734 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1735 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1736 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1737 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1738 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1739 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1740 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1741 AC_CHECK_FUNCS([futimes futimens])
1742 AC_C_PRINTF_A
1743 AC_FUNC_RAND48
1744
1745 dnl Check the declaration "Secure API" on Windows environments.
1746 AC_CHECK_DECLS([strerror_s])
1747
1748 dnl Check symbols in libgcc.a for JIT on Mingw.
1749 if test "$llvm_cv_os_type" = "MingW" ; then
1750   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1751   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1752   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1753   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1754
1755   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1756   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1757   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1758   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1759   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1760   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1761   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1762   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1763   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1764   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1765
1766   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1767   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1768 fi
1769
1770 dnl Check Win32 API EnumerateLoadedModules.
1771 if test "$llvm_cv_os_type" = "MingW" ; then
1772   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1773   AC_COMPILE_IFELSE(
1774 [
1775   AC_LANG_SOURCE([[
1776     #include <windows.h>
1777     #include <imagehlp.h>
1778     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1779     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1780   ]])
1781 ],
1782 [
1783   AC_MSG_RESULT([yes])
1784   llvm_cv_win32_elmcb_pcstr="PCSTR"
1785 ],
1786 [
1787   AC_MSG_RESULT([no])
1788   llvm_cv_win32_elmcb_pcstr="PSTR"
1789 ])
1790   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1791 fi
1792
1793 dnl Check for variations in the Standard C++ library and STL. These macros are
1794 dnl provided by LLVM in the autoconf/m4 directory.
1795 AC_FUNC_ISNAN
1796 AC_FUNC_ISINF
1797
1798 dnl Check for mmap support.We also need to know if /dev/zero is required to
1799 dnl be opened for allocating RWX memory.
1800 dnl Make sure we aren't attempting to configure for an unknown system
1801 if test "$llvm_cv_platform_type" = "Unix" ; then
1802   AC_FUNC_MMAP
1803   AC_FUNC_MMAP_FILE
1804   AC_NEED_DEV_ZERO_FOR_MMAP
1805
1806   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1807   then
1808     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1809   fi
1810   if test "$ac_cv_func_mmap_file" = "no"
1811   then
1812     AC_MSG_WARN([mmap() of files required but not found])
1813   fi
1814 fi
1815
1816 dnl atomic builtins are required for threading support.
1817 AC_MSG_CHECKING(for GCC atomic builtins)
1818 dnl Since we'll be using these atomic builtins in C++ files we should test
1819 dnl the C++ compiler.
1820 AC_LANG_PUSH([C++])
1821 AC_LINK_IFELSE(
1822 [
1823   AC_LANG_SOURCE([[
1824     int main() {
1825       volatile unsigned long val = 1;
1826       __sync_synchronize();
1827       __sync_val_compare_and_swap(&val, 1, 0);
1828       __sync_add_and_fetch(&val, 1);
1829       __sync_sub_and_fetch(&val, 1);
1830       return 0;
1831     }
1832   ]])
1833 ],
1834 [
1835   AC_MSG_RESULT([yes])
1836   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1837 ],
1838 [
1839   AC_MSG_RESULT([no])
1840   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1841   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1842 ])
1843 AC_LANG_POP([C++])
1844
1845 dnl===-----------------------------------------------------------------------===
1846 dnl===
1847 dnl=== SECTION 9: Additional checks, variables, etc.
1848 dnl===
1849 dnl===-----------------------------------------------------------------------===
1850
1851 dnl Handle 32-bit linux systems running a 64-bit kernel.
1852 dnl This has to come after section 4 because it invokes the compiler.
1853 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1854   AC_IS_LINUX_MIXED
1855   if test "$llvm_cv_linux_mixed" = "yes"; then
1856     llvm_cv_target_arch="x86"
1857     ARCH="x86"
1858   fi
1859 fi
1860
1861 dnl Check whether __dso_handle is present
1862 AC_CHECK_FUNCS([__dso_handle])
1863
1864 dnl Propagate the shared library extension that the libltdl checks did to
1865 dnl the Makefiles so we can use it there too
1866 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1867
1868 dnl Propagate the run-time library path variable that the libltdl
1869 dnl checks found to the Makefiles so we can use it there too
1870 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1871
1872 dnl Translate the various configuration directories and other basic
1873 dnl information into substitutions that will end up in Makefile.config.in
1874 dnl that these configured values can be used by the makefiles
1875 if test "${prefix}" = "NONE" ; then
1876   prefix="/usr/local"
1877 fi
1878 eval LLVM_PREFIX="${prefix}";
1879 eval LLVM_BINDIR="${prefix}/bin";
1880 eval LLVM_DATADIR="${prefix}/share/llvm";
1881 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1882 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1883 eval LLVM_INCLUDEDIR="${prefix}/include";
1884 eval LLVM_INFODIR="${prefix}/info";
1885 eval LLVM_MANDIR="${prefix}/man";
1886 LLVM_CONFIGTIME=`date`
1887 AC_SUBST(LLVM_PREFIX)
1888 AC_SUBST(LLVM_BINDIR)
1889 AC_SUBST(LLVM_DATADIR)
1890 AC_SUBST(LLVM_DOCSDIR)
1891 AC_SUBST(LLVM_ETCDIR)
1892 AC_SUBST(LLVM_INCLUDEDIR)
1893 AC_SUBST(LLVM_INFODIR)
1894 AC_SUBST(LLVM_MANDIR)
1895 AC_SUBST(LLVM_CONFIGTIME)
1896
1897 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1898 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1899   LLVM_CONFIGTIME="(timestamp not enabled)"
1900 fi
1901
1902 dnl Place the various directories into the config.h file as #defines so that we
1903 dnl can know about the installation paths within LLVM.
1904 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1905                    [Installation prefix directory])
1906 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1907                    [Installation directory for binary executables])
1908 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1909                    [Installation directory for data files])
1910 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1911                    [Installation directory for documentation])
1912 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1913                    [Installation directory for config files])
1914 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1915                    [Installation directory for include files])
1916 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1917                    [Installation directory for .info files])
1918 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1919                    [Installation directory for man pages])
1920 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1921                    [Time at which LLVM was configured])
1922 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1923                    [Host triple LLVM will be executed on])
1924 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1925                    [Target triple LLVM will generate code for by default])
1926
1927 dnl Determine which bindings to build.
1928 if test "$BINDINGS_TO_BUILD" = auto ; then
1929   BINDINGS_TO_BUILD=""
1930   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1931     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1932   fi
1933 fi
1934 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1935
1936 dnl This isn't really configurey, but it avoids having to repeat the list in
1937 dnl other files.
1938 AC_SUBST(ALL_BINDINGS,ocaml)
1939
1940 dnl Do any work necessary to ensure that bindings have what they need.
1941 binding_prereqs_failed=0
1942 for a_binding in $BINDINGS_TO_BUILD ; do
1943   case "$a_binding" in
1944   ocaml)
1945     if test "x$OCAMLC" = x ; then
1946       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1947       binding_prereqs_failed=1
1948     fi
1949     if test "x$OCAMLDEP" = x ; then
1950       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1951       binding_prereqs_failed=1
1952     fi
1953     if test "x$OCAMLOPT" = x ; then
1954       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1955       dnl ocamlopt is optional!
1956     fi
1957     if test "x$with_ocaml_libdir" != xauto ; then
1958       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1959     else
1960       ocaml_stdlib="`"$OCAMLC" -where`"
1961       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1962       then
1963         # ocaml stdlib is beneath our prefix; use stdlib
1964         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1965       else
1966         # ocaml stdlib is outside our prefix; use libdir/ocaml
1967         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
1968       fi
1969     fi
1970     ;;
1971   esac
1972 done
1973 if test "$binding_prereqs_failed" = 1 ; then
1974   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1975 fi
1976
1977 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1978 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1979
1980 dnl Determine linker rpath flag
1981 if test "$llvm_cv_link_use_r" = "yes" ; then
1982   RPATH="-Wl,-R"
1983 else
1984   RPATH="-Wl,-rpath"
1985 fi
1986 AC_SUBST(RPATH)
1987
1988 dnl Determine linker rdynamic flag
1989 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1990   RDYNAMIC="-rdynamic"
1991 else
1992   RDYNAMIC=""
1993 fi
1994 AC_SUBST(RDYNAMIC)
1995
1996 dnl===-----------------------------------------------------------------------===
1997 dnl===
1998 dnl=== SECTION 10: Specify the output files and generate it
1999 dnl===
2000 dnl===-----------------------------------------------------------------------===
2001
2002 dnl Configure header files
2003 dnl WARNING: dnl If you add or remove any of the following config headers, then
2004 dnl you MUST also update Makefile so that the variable FilesToConfig
2005 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2006 dnl files can be updated automatically when their *.in sources change.
2007 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2008 AH_TOP([#ifndef CONFIG_H
2009 #define CONFIG_H])
2010 AH_BOTTOM([#endif])
2011
2012 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2013 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2014 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2015 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2016 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2017
2018 dnl Configure the makefile's configuration data
2019 AC_CONFIG_FILES([Makefile.config])
2020
2021 dnl Configure the RPM spec file for LLVM
2022 AC_CONFIG_FILES([llvm.spec])
2023
2024 dnl Configure doxygen's configuration file
2025 AC_CONFIG_FILES([docs/doxygen.cfg])
2026
2027 dnl Configure clang, if present
2028 if test "${clang_src_root}" = ""; then
2029   clang_src_root="$srcdir/tools/clang"
2030 fi
2031 if test -f ${clang_src_root}/README.txt; then
2032   dnl Use variables to stay under 80 columns.
2033   configh="include/clang/Config/config.h"
2034   doxy="docs/doxygen.cfg"
2035   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2036   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2037 fi
2038
2039 dnl OCaml findlib META file
2040 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2041
2042 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2043 test "x$program_prefix" = "xNONE" && program_prefix=""
2044 AC_SUBST([program_prefix])
2045
2046
2047 dnl Do special configuration of Makefiles
2048 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2049 AC_CONFIG_MAKEFILE(Makefile)
2050 AC_CONFIG_MAKEFILE(Makefile.common)
2051 AC_CONFIG_MAKEFILE(examples/Makefile)
2052 AC_CONFIG_MAKEFILE(lib/Makefile)
2053 AC_CONFIG_MAKEFILE(test/Makefile)
2054 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2055 AC_CONFIG_MAKEFILE(unittests/Makefile)
2056 AC_CONFIG_MAKEFILE(tools/Makefile)
2057 AC_CONFIG_MAKEFILE(utils/Makefile)
2058 AC_CONFIG_MAKEFILE(projects/Makefile)
2059 AC_CONFIG_MAKEFILE(bindings/Makefile)
2060 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2061
2062 dnl Finally, crank out the output
2063 AC_OUTPUT