autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34
  35 AC_INIT([LLVM],[3.7.0svn],[http://llvm.org/bugs/])
  36
  37 LLVM_VERSION_MAJOR=3
  38 LLVM_VERSION_MINOR=7
  39 LLVM_VERSION_PATCH=0
  40 LLVM_VERSION_SUFFIX=svn
  41
  42 AC_DEFINE_UNQUOTED([LLVM_VERSION_MAJOR], $LLVM_VERSION_MAJOR, [Major version of the LLVM API])
  43 AC_DEFINE_UNQUOTED([LLVM_VERSION_MINOR], $LLVM_VERSION_MINOR, [Minor version of the LLVM API])
  44 AC_DEFINE_UNQUOTED([LLVM_VERSION_PATCH], $LLVM_VERSION_PATCH, [Patch version of the LLVM API])
  45 AC_DEFINE_UNQUOTED([LLVM_VERSION_STRING], "$PACKAGE_VERSION", [LLVM version string])
  46
  47 AC_SUBST([LLVM_VERSION_MAJOR])
  48 AC_SUBST([LLVM_VERSION_MINOR])
  49 AC_SUBST([LLVM_VERSION_PATCH])
  50 AC_SUBST([LLVM_VERSION_SUFFIX])
  51
  52 dnl Provide a copyright substitution and ensure the copyright notice is included
  53 dnl in the output of --version option of the generated configure script.
  54 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2015 University of Illinois at Urbana-Champaign."])
  55 AC_COPYRIGHT([Copyright (c) 2003-2015 University of Illinois at Urbana-Champaign.])
  56
  57 dnl Indicate that we require autoconf 2.60 or later.
  58 AC_PREREQ(2.60)
  59
  60 dnl Verify that the source directory is valid. This makes sure that we are
  61 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  62 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  63
  64 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  65 dnl various tools where the m4 autoconf macros are.
  66 AC_CONFIG_AUX_DIR([autoconf])
  67
  68 dnl Quit if the source directory has already been configured.
  69 dnl NOTE: This relies upon undocumented autoconf behavior.
  70 if test ${srcdir} != "." ; then
  71   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  72     AC_MSG_ERROR([Already configured in ${srcdir}])
  73   fi
  74 fi
  75
  76 dnl Quit if it is an in-source build
  77 if test ${srcdir} == "." ; then
  78   AC_MSG_WARN([**************************************************************************************])
  79   AC_MSG_WARN([*                                                                                    *])
  80   AC_MSG_WARN([*                                   WARNING                                          *])
  81   AC_MSG_WARN([*                                                                                    *])
  82   AC_MSG_WARN([*                        In-source builds are deprecated.                            *])
  83   AC_MSG_WARN([*                                                                                    *])
  84   AC_MSG_WARN([*               Please configure from a separate build directory!                    *])
  85   AC_MSG_WARN([*                                                                                    *])
  86   AC_MSG_WARN([**************************************************************************************])
  87 fi
  88
  89 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  90 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  91 : ${CFLAGS=}
  92 : ${CXXFLAGS=}
  93
  94 dnl We need to check for the compiler up here to avoid anything else
  95 dnl starting with a different one.
  96 AC_PROG_CC(clang gcc)
  97 AC_PROG_CXX(clang++ g++)
  98 AC_PROG_CPP
  99
 100 dnl If CXX is Clang, check that it can find and parse C++ standard library
 101 dnl headers.
 102 if test "$CXX" = "clang++" ; then
 103   AC_MSG_CHECKING([whether clang works])
 104   AC_LANG_PUSH([C++])
 105   dnl Note that space between 'include' and '(' is required.  There's a broken
 106   dnl regex in aclocal that otherwise will think that we call m4's include
 107   dnl builtin.
 108   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
 109 #if __has_include (<cxxabi.h>)
 110 #include <cxxabi.h>
 111 #endif
 112 #if __has_include (<unwind.h>)
 113 #include <unwind.h>
 114 #endif
 115 ]])],
 116 [
 117   AC_MSG_RESULT([yes])
 118 ],
 119 [
 120   AC_MSG_RESULT([no])
 121   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler LLVM_SRC_DIR/configure ...])
 122 ])
 123   AC_LANG_POP([C++])
 124 fi
 125
 126 dnl Set up variables that track whether the host compiler is GCC or Clang where
 127 dnl we can effectively sanity check them. We don't try to sanity check all the
 128 dnl other possible compilers.
 129 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 130 AC_LANG_PUSH([C++])
 131 llvm_cv_cxx_compiler=unknown
 132 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 133                                     #error
 134                                     #endif
 135                                     ]])],
 136                   llvm_cv_cxx_compiler=clang,
 137                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 138                                                        #error
 139                                                        #endif
 140                                                        ]])],
 141                                      llvm_cv_cxx_compiler=gcc, [])])
 142 AC_LANG_POP([C++])
 143 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 144
 145 dnl Configure all of the projects present in our source tree. While we could
 146 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 147 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 148 dnl Instead we match on the known projects.
 149
 150 dnl
 151 dnl One tricky part of doing this is that some projects depend upon other
 152 dnl projects.  For example, several projects rely upon the LLVM test suite.
 153 dnl We want to configure those projects first so that their object trees are
 154 dnl created before running the configure scripts of projects that depend upon
 155 dnl them.
 156 dnl
 157
 158 dnl Several projects use the LLVM test suite, so configure it next.
 159 if test -d ${srcdir}/projects/test-suite ; then
 160   AC_CONFIG_SUBDIRS([projects/test-suite])
 161 fi
 162
 163 dnl llvm-test is the old name of the test-suite, kept here for backwards
 164 dnl compatibility
 165 if test -d ${srcdir}/projects/llvm-test ; then
 166   AC_CONFIG_SUBDIRS([projects/llvm-test])
 167 fi
 168
 169 dnl Some projects use poolalloc; configure that next
 170 if test -d ${srcdir}/projects/poolalloc ; then
 171   AC_CONFIG_SUBDIRS([projects/poolalloc])
 172 fi
 173
 174 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 175   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 176 fi
 177
 178 dnl Check for all other projects
 179 for i in `ls ${srcdir}/projects`
 180 do
 181   if test -d ${srcdir}/projects/${i} ; then
 182     case ${i} in
 183       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 184       compiler-rt)       ;;
 185       test-suite)     ;;
 186       llvm-test)      ;;
 187       poolalloc)      ;;
 188       llvm-poolalloc) ;;
 189       *)
 190         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 191         ;;
 192     esac
 193   fi
 194 done
 195
 196 dnl Disable the build of polly, even if it is checked out into tools/polly.
 197 AC_ARG_ENABLE(polly,
 198               AS_HELP_STRING([--enable-polly],
 199                              [Use polly if available (default is YES)]),,
 200                              enableval=default)
 201 case "$enableval" in
 202   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 203   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 204   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 205   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 206 esac
 207
 208
 209 dnl Check if polly is checked out into tools/polly and configure it if
 210 dnl available.
 211 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 212   AC_SUBST(LLVM_HAS_POLLY,1)
 213   AC_CONFIG_SUBDIRS([tools/polly])
 214 fi
 215
 216 dnl===-----------------------------------------------------------------------===
 217 dnl===
 218 dnl=== SECTION 2: Architecture, target, and host checks
 219 dnl===
 220 dnl===-----------------------------------------------------------------------===
 221
 222 dnl Check the target for which we're compiling and the host that will do the
 223 dnl compilations. This will tell us which LLVM compiler will be used for
 224 dnl compiling SSA into object code. This needs to be done early because
 225 dnl following tests depend on it.
 226 AC_CANONICAL_TARGET
 227
 228 dnl Determine the platform type and cache its value. This helps us configure
 229 dnl the System library to the correct build platform.
 230 AC_CACHE_CHECK([type of operating system we're going to host on],
 231                [llvm_cv_os_type],
 232 [case $host in
 233   *-*-aix*)
 234     llvm_cv_link_all_option="-Wl,--whole-archive"
 235     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 236     llvm_cv_os_type="AIX"
 237     llvm_cv_platform_type="Unix" ;;
 238   *-*-irix*)
 239     llvm_cv_link_all_option="-Wl,--whole-archive"
 240     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 241     llvm_cv_os_type="IRIX"
 242     llvm_cv_platform_type="Unix" ;;
 243   *-*-cygwin*)
 244     llvm_cv_link_all_option="-Wl,--whole-archive"
 245     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 246     llvm_cv_os_type="Cygwin"
 247     llvm_cv_platform_type="Unix" ;;
 248   *-*-darwin*)
 249     llvm_cv_link_all_option="-Wl,-all_load"
 250     llvm_cv_no_link_all_option="-Wl,-noall_load"
 251     llvm_cv_os_type="Darwin"
 252     llvm_cv_platform_type="Unix" ;;
 253   *-*-minix*)
 254     llvm_cv_link_all_option="-Wl,-all_load"
 255     llvm_cv_no_link_all_option="-Wl,-noall_load"
 256     llvm_cv_os_type="Minix"
 257     llvm_cv_platform_type="Unix" ;;
 258   *-*-freebsd*)
 259     llvm_cv_link_all_option="-Wl,--whole-archive"
 260     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 261     llvm_cv_os_type="FreeBSD"
 262     llvm_cv_platform_type="Unix" ;;
 263   *-*-kfreebsd-gnu)
 264     llvm_cv_link_all_option="-Wl,--whole-archive"
 265     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 266     llvm_cv_os_type="GNU/kFreeBSD"
 267     llvm_cv_platform_type="Unix" ;;
 268   *-*-openbsd*)
 269     llvm_cv_link_all_option="-Wl,--whole-archive"
 270     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 271     llvm_cv_os_type="OpenBSD"
 272     llvm_cv_platform_type="Unix" ;;
 273   *-*-netbsd*)
 274     llvm_cv_link_all_option="-Wl,--whole-archive"
 275     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 276     llvm_cv_os_type="NetBSD"
 277     llvm_cv_platform_type="Unix" ;;
 278   *-*-dragonfly*)
 279     llvm_cv_link_all_option="-Wl,--whole-archive"
 280     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 281     llvm_cv_os_type="DragonFly"
 282     llvm_cv_platform_type="Unix" ;;
 283   *-*-bitrig*)
 284     llvm_cv_link_all_option="-Wl,--whole-archive"
 285     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 286     llvm_cv_os_type="Bitrig"
 287     llvm_cv_platform_type="Unix" ;;
 288   *-*-hpux*)
 289     llvm_cv_link_all_option="-Wl,--whole-archive"
 290     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 291     llvm_cv_os_type="HP-UX"
 292     llvm_cv_platform_type="Unix" ;;
 293   *-*-interix*)
 294     llvm_cv_link_all_option="-Wl,--whole-archive"
 295     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 296     llvm_cv_os_type="Interix"
 297     llvm_cv_platform_type="Unix" ;;
 298   *-*-linux*)
 299     llvm_cv_link_all_option="-Wl,--whole-archive"
 300     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 301     llvm_cv_os_type="Linux"
 302     llvm_cv_platform_type="Unix" ;;
 303   *-*-gnu*)
 304     llvm_cv_link_all_option="-Wl,--whole-archive"
 305     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 306     llvm_cv_os_type="GNU"
 307     llvm_cv_platform_type="Unix" ;;
 308   *-*-solaris*)
 309     llvm_cv_link_all_option="-Wl,-z,allextract"
 310     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 311     llvm_cv_os_type="SunOS"
 312     llvm_cv_platform_type="Unix" ;;
 313   *-*-win32*)
 314     llvm_cv_link_all_option="-Wl,--whole-archive"
 315     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 316     llvm_cv_os_type="Win32"
 317     llvm_cv_platform_type="Win32" ;;
 318   *-*-mingw*)
 319     llvm_cv_link_all_option="-Wl,--whole-archive"
 320     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 321     llvm_cv_os_type="MingW"
 322     llvm_cv_platform_type="Win32" ;;
 323   *-*-haiku*)
 324     llvm_cv_link_all_option="-Wl,--whole-archive"
 325     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 326     llvm_cv_os_type="Haiku"
 327     llvm_cv_platform_type="Unix" ;;
 328   *-unknown-eabi*)
 329     llvm_cv_link_all_option="-Wl,--whole-archive"
 330     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 331     llvm_cv_os_type="Freestanding"
 332     llvm_cv_platform_type="Unix" ;;
 333   *-unknown-elf*)
 334     llvm_cv_link_all_option="-Wl,--whole-archive"
 335     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 336     llvm_cv_os_type="Freestanding"
 337     llvm_cv_platform_type="Unix" ;;
 338   *)
 339     llvm_cv_link_all_option=""
 340     llvm_cv_no_link_all_option=""
 341     llvm_cv_os_type="Unknown"
 342     llvm_cv_platform_type="Unknown" ;;
 343 esac])
 344
 345 AC_CACHE_CHECK([type of operating system we're going to target],
 346                [llvm_cv_target_os_type],
 347 [case $target in
 348   *-*-aix*)
 349     llvm_cv_target_os_type="AIX" ;;
 350   *-*-irix*)
 351     llvm_cv_target_os_type="IRIX" ;;
 352   *-*-cygwin*)
 353     llvm_cv_target_os_type="Cygwin" ;;
 354   *-*-darwin*)
 355     llvm_cv_target_os_type="Darwin" ;;
 356   *-*-minix*)
 357     llvm_cv_target_os_type="Minix" ;;
 358   *-*-freebsd*)
 359     llvm_cv_target_os_type="FreeBSD" ;;
 360   *-*-kfreebsd-gnu)
 361     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 362   *-*-openbsd*)
 363     llvm_cv_target_os_type="OpenBSD" ;;
 364   *-*-netbsd*)
 365     llvm_cv_target_os_type="NetBSD" ;;
 366   *-*-dragonfly*)
 367     llvm_cv_target_os_type="DragonFly" ;;
 368   *-*-bitrig*)
 369     llvm_cv_target_os_type="Bitrig" ;;
 370   *-*-hpux*)
 371     llvm_cv_target_os_type="HP-UX" ;;
 372   *-*-interix*)
 373     llvm_cv_target_os_type="Interix" ;;
 374   *-*-linux*)
 375     llvm_cv_target_os_type="Linux" ;;
 376   *-*-gnu*)
 377     llvm_cv_target_os_type="GNU" ;;
 378   *-*-solaris*)
 379     llvm_cv_target_os_type="SunOS" ;;
 380   *-*-win32*)
 381     llvm_cv_target_os_type="Win32" ;;
 382   *-*-mingw*)
 383     llvm_cv_target_os_type="MingW" ;;
 384   *-*-haiku*)
 385     llvm_cv_target_os_type="Haiku" ;;
 386   *-*-rtems*)
 387     llvm_cv_target_os_type="RTEMS" ;;
 388   *-*-nacl*)
 389     llvm_cv_target_os_type="NativeClient" ;;
 390   *-unknown-eabi*)
 391     llvm_cv_target_os_type="Freestanding" ;;
 392   *-*-ps4)
 393     llvm_cv_target_os_type="PS4" ;;
 394   *)
 395     llvm_cv_target_os_type="Unknown" ;;
 396 esac])
 397
 398 dnl Make sure we aren't attempting to configure for an unknown system
 399 if test "$llvm_cv_os_type" = "Unknown" ; then
 400   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 401 fi
 402
 403 dnl Set the "OS" Makefile variable based on the platform type so the
 404 dnl makefile can configure itself to specific build hosts
 405 AC_SUBST(OS,$llvm_cv_os_type)
 406 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 407 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 408
 409 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 410 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 411 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 412
 413 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 414 dnl This is used by lib/Support to determine the basic kind of implementation
 415 dnl to use.
 416 case $llvm_cv_platform_type in
 417   Unix)
 418     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 419     AC_SUBST(LLVM_ON_UNIX,[1])
 420     AC_SUBST(LLVM_ON_WIN32,[0])
 421     ;;
 422   Win32)
 423     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 424     AC_SUBST(LLVM_ON_UNIX,[0])
 425     AC_SUBST(LLVM_ON_WIN32,[1])
 426     ;;
 427 esac
 428
 429 dnl Determine what our target architecture is and configure accordingly.
 430 dnl This will allow Makefiles to make a distinction between the hardware and
 431 dnl the OS.
 432 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 433 [case $target in
 434   i?86-*)                 llvm_cv_target_arch="x86" ;;
 435   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 436   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 437   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 438   arm64*-*)               llvm_cv_target_arch="AArch64" ;;
 439   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 440   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 441   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 442   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 443   xcore-*)                llvm_cv_target_arch="XCore" ;;
 444   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 445   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 446   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 447   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 448   *)                      llvm_cv_target_arch="Unknown" ;;
 449 esac])
 450
 451 if test "$llvm_cv_target_arch" = "Unknown" ; then
 452   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 453 fi
 454
 455 dnl Determine the LLVM native architecture for the target
 456 case "$llvm_cv_target_arch" in
 457     x86)     LLVM_NATIVE_ARCH="X86" ;;
 458     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 459     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 460 esac
 461
 462 dnl Define a substitution, ARCH, for the target architecture
 463 AC_SUBST(ARCH,$llvm_cv_target_arch)
 464 AC_SUBST(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH)
 465
 466 dnl Determine what our host architecture.
 467 dnl This will allow MCJIT regress tests runs only for supported
 468 dnl platforms.
 469 case $host in
 470   i?86-*)                 host_arch="x86" ;;
 471   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 472   sparc*-*)               host_arch="Sparc" ;;
 473   powerpc*-*)             host_arch="PowerPC" ;;
 474   arm64*-*)               host_arch="AArch64" ;;
 475   arm*-*)                 host_arch="ARM" ;;
 476   aarch64*-*)             host_arch="AArch64" ;;
 477   mips-* | mips64-*)      host_arch="Mips" ;;
 478   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 479   xcore-*)                host_arch="XCore" ;;
 480   msp430-*)               host_arch="MSP430" ;;
 481   hexagon-*)              host_arch="Hexagon" ;;
 482   s390x-*)                host_arch="SystemZ" ;;
 483   *)                      host_arch="Unknown" ;;
 484 esac
 485
 486 if test "$host_arch" = "Unknown" ; then
 487   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 488 fi
 489
 490 AC_SUBST(HOST_ARCH,$host_arch)
 491
 492 dnl Check for build platform executable suffix if we're cross-compiling
 493 if test "$cross_compiling" = yes; then
 494   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 495   AC_BUILD_EXEEXT
 496   ac_build_prefix=${build_alias}-
 497   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 498   if test -z "$BUILD_CXX"; then
 499      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 500      if test -z "$BUILD_CXX"; then
 501        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 502      fi
 503   fi
 504 else
 505   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 506 fi
 507
 508 dnl Check to see if there's a .svn or .git directory indicating that this
 509 dnl build is being done from a checkout. This sets up several defaults for
 510 dnl the command line switches. When we build with a checkout directory,
 511 dnl we get a debug with assertions turned on. Without, we assume a source
 512 dnl release and we get an optimized build without assertions.
 513 dnl See --enable-optimized and --enable-assertions below
 514 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 515   cvsbuild="yes"
 516   optimize="no"
 517   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 518 else
 519   cvsbuild="no"
 520   optimize="yes"
 521 fi
 522
 523 dnl===-----------------------------------------------------------------------===
 524 dnl===
 525 dnl=== SECTION 3: Command line arguments for the configure script.
 526 dnl===
 527 dnl===-----------------------------------------------------------------------===
 528
 529 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 530 AC_ARG_ENABLE(libcpp,
 531               AS_HELP_STRING([--enable-libcpp],
 532                              [Use libc++ if available (default is NO)]),,
 533                              enableval=default)
 534 case "$enableval" in
 535   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 536   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 537   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 538   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 539 esac
 540
 541 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 542 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 543 dnl these checks here so that we have the configuration of the standard C++
 544 dnl library finished.
 545 AC_ARG_ENABLE(compiler-version-checks,
 546               AS_HELP_STRING([--enable-compiler-version-checks],
 547                              [Check the version of the host compiler (default is YES)]),,
 548                              enableval=default)
 549 case "$enableval" in
 550   no)
 551     ;;
 552   yes|default)
 553     AC_LANG_PUSH([C++])
 554     case "$llvm_cv_cxx_compiler" in
 555     clang)
 556       AC_MSG_CHECKING([whether Clang is new enough])
 557       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 558 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 559 #error This version of Clang is too old to build LLVM
 560 #endif
 561 ]])],
 562           [AC_MSG_RESULT([yes])],
 563           [AC_MSG_RESULT([no])
 564            AC_MSG_ERROR([
 565 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 566 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 567 bypass these sanity checks.])])
 568
 569       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 570       dnl are sometimes deeply confusing though. Here we test for an obvious
 571       dnl incomplete feature in 4.6's standard library that was completed in
 572       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 573       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 574       dnl that happening in the Makefile.
 575       if test "$ENABLE_LIBCPP" -eq 0 ; then
 576         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 577         llvm_cv_old_cxxflags="$CXXFLAGS"
 578         CXXFLAGS="$CXXFLAGS -std=c++0x"
 579         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 580 #include <atomic>
 581 std::atomic<float> x(0.0f);
 582 int main() { return (float)x; }
 583 ]])],
 584             [AC_MSG_RESULT([yes])],
 585             [AC_MSG_RESULT([no])
 586              AC_MSG_ERROR([
 587 We detected a missing feature in the standard C++ library that was known to be
 588 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 589 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 590 than 4.7. You will need to update your system and ensure Clang uses the newer
 591 standard library.
 592
 593 If this error is incorrect or you need to force things to work, you may pass
 594 '--disable-compiler-version-checks' to configure to bypass this test.])])
 595         CXXFLAGS="$llvm_cv_old_cxxflags"
 596       fi
 597       ;;
 598     gcc)
 599       AC_MSG_CHECKING([whether GCC is new enough])
 600       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 601 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 602 #error This version of GCC is too old to build LLVM
 603 #endif
 604 ]])],
 605           [AC_MSG_RESULT([yes])],
 606           [AC_MSG_RESULT([no])
 607            AC_MSG_ERROR([
 608 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 609 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 610 bypass these sanity checks.])])
 611       ;;
 612     unknown)
 613       ;;
 614     esac
 615     AC_LANG_POP([C++])
 616     ;;
 617   *)
 618     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 619     ;;
 620 esac
 621
 622 dnl --enable-cxx1y : check whether or not to use -std=c++1y on the command line
 623 AC_ARG_ENABLE(cxx1y,
 624               AS_HELP_STRING([--enable-cxx1y],
 625                              [Use c++1y if available (default is NO)]),,
 626                              enableval=default)
 627 case "$enableval" in
 628   yes) AC_SUBST(ENABLE_CXX1Y,[1]) ;;
 629   no)  AC_SUBST(ENABLE_CXX1Y,[0]) ;;
 630   default) AC_SUBST(ENABLE_CXX1Y,[0]);;
 631   *) AC_MSG_ERROR([Invalid setting for --enable-cxx1y. Use "yes" or "no"]) ;;
 632 esac
 633
 634 dnl --enable-split-dwarf : check whether or not to use -gsplit-dwarf on the command
 635 dnl line
 636 AC_ARG_ENABLE(split-dwarf,
 637               AS_HELP_STRING([--enable-split-dwarf],
 638                              [Use split-dwarf if available (default is NO)]),,
 639                              enableval=default)
 640 case "$enableval" in
 641   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 642   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 643   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 644   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 645 esac
 646
 647 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 648 clang_arcmt="yes"
 649 AC_ARG_ENABLE(clang-arcmt,
 650               AS_HELP_STRING([--enable-clang-arcmt],
 651                              [Enable building of clang ARCMT (default is YES)]),
 652                              clang_arcmt="$enableval",
 653                              enableval="yes")
 654 case "$enableval" in
 655   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 656   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 657   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 658   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 659 esac
 660
 661 dnl --enable-clang-plugin-support: check whether to enable plugins in clang
 662 clang_plugin_support="yes"
 663 AC_ARG_ENABLE(clang-plugin-support,
 664               AS_HELP_STRING([--enable-clang-plugin-support],
 665                              [Enable plugin support in clang (default is YES)]),
 666                              clang_plugin_support="$enableval",
 667                              enableval="yes")
 668 case "$enableval" in
 669   yes) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]) ;;
 670   no)  AC_SUBST(CLANG_PLUGIN_SUPPORT,[0]) ;;
 671   default) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]);;
 672   *) AC_MSG_ERROR([Invalid setting for --enable-clang-plugin-support. Use "yes" or "no"]) ;;
 673 esac
 674
 675 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 676 clang_static_analyzer="yes"
 677 AC_ARG_ENABLE(clang-static-analyzer,
 678               AS_HELP_STRING([--enable-clang-static-analyzer],
 679                              [Enable building of clang Static Analyzer (default is YES)]),
 680                              clang_static_analyzer="$enableval",
 681                              enableval="yes")
 682 case "$enableval" in
 683   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 684   no)
 685     if test ${clang_arcmt} != "no" ; then
 686       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 687     fi
 688     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 689     ;;
 690   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 691   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 692 esac
 693
 694 dnl --enable-optimized : check whether they want to do an optimized build:
 695 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 696  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 697 if test ${enableval} = "no" ; then
 698   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 699 else
 700   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 701 fi
 702
 703 dnl --enable-profiling : check whether they want to do a profile build:
 704 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 705  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 706 if test ${enableval} = "no" ; then
 707   AC_SUBST(ENABLE_PROFILING,[[]])
 708 else
 709   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 710 fi
 711
 712 dnl --enable-assertions : check whether they want to turn on assertions or not:
 713 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 714   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 715 if test ${enableval} = "yes" ; then
 716   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 717   assertions_enabled="yes"
 718 else
 719   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 720   assertions_enabled="no"
 721 fi
 722
 723 dnl --enable-werror : check whether we want Werror on by default
 724 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 725   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 726 case "$enableval" in
 727   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 728   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 729   default) AC_SUBST(ENABLE_WERROR,[0]);;
 730   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 731 esac
 732
 733 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 734 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 735   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 736 if test ${enableval} = "yes" ; then
 737   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 738   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 739 else
 740   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 741   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 742 fi
 743
 744 dnl --enable-abi-breaking-checks : decide whether we should compile in asserts and
 745 dnl checks that make the build ABI incompatible with an llvm built without these
 746 dnl checks enabled.
 747 AC_ARG_ENABLE(abi-breaking-checks,AS_HELP_STRING(
 748   --enable-abi-breaking-checks,[Compile with abi-breaking asserts support (default is with-asserts)]),, enableval="with-asserts")
 749 case "$enableval" in
 750   with-asserts)  if test ${assertions_enabled} = "yes" ; then
 751                    AC_DEFINE([LLVM_ENABLE_ABI_BREAKING_CHECKS],[1],[Define to enable checks that alter the LLVM C++ ABI])
 752                    AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[1])
 753                  else
 754                    AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[0])
 755                  fi ;;
 756   yes)
 757                  AC_DEFINE([LLVM_ENABLE_ABI_BREAKING_CHECKS],[1],[Define to enable checks that alter the LLVM C++ ABI])
 758                  AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[1])
 759                  ;;
 760   no)
 761                  AC_SUBST(ENABLE_ABI_BREAKING_CHECKS,[0])
 762                  ;;
 763   *) AC_MSG_ERROR([Invalid setting for --enable-abi-breaking-checks.  Use "with-asserts", "yes" or "no"])
 764 esac
 765
 766 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 767 AC_ARG_ENABLE(debug-runtime,
 768    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 769 if test ${enableval} = "no" ; then
 770   AC_SUBST(DEBUG_RUNTIME,[[]])
 771 else
 772   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 773 fi
 774
 775 dnl --enable-debug-symbols : should even optimized compiler libraries
 776 dnl have debug symbols?
 777 AC_ARG_ENABLE(debug-symbols,
 778    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 779 if test ${enableval} = "no" ; then
 780   AC_SUBST(DEBUG_SYMBOLS,[[]])
 781 else
 782   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 783 fi
 784
 785 dnl --enable-keep-symbols : do not strip installed executables
 786 AC_ARG_ENABLE(keep-symbols,
 787    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 788 if test ${enableval} = "no" ; then
 789   AC_SUBST(KEEP_SYMBOLS,[[]])
 790 else
 791   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 792 fi
 793
 794 dnl --enable-jit: check whether they want to enable the jit
 795 AC_ARG_ENABLE(jit,
 796   AS_HELP_STRING(--enable-jit,
 797                  [Enable Just In Time Compiling (default is YES)]),,
 798   enableval=default)
 799 if test ${enableval} = "no"
 800 then
 801   AC_SUBST(JIT,[[]])
 802 else
 803   case "$llvm_cv_target_arch" in
 804     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 805     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 806     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 807     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 808     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 809     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 810     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 811     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 812     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 813     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 814     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 815     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 816   esac
 817 fi
 818
 819 TARGETS_WITH_JIT="ARM AArch64 Mips PowerPC SystemZ X86"
 820 AC_SUBST(TARGETS_WITH_JIT,$TARGETS_WITH_JIT)
 821
 822 dnl Allow enablement of building and installing docs
 823 AC_ARG_ENABLE(docs,
 824               AS_HELP_STRING([--enable-docs],
 825                              [Build documents (default is YES)]),,
 826                              enableval=default)
 827 case "$enableval" in
 828   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 829   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 830   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 831   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 832 esac
 833
 834 dnl Allow enablement of doxygen generated documentation
 835 AC_ARG_ENABLE(doxygen,
 836               AS_HELP_STRING([--enable-doxygen],
 837                              [Build doxygen documentation (default is NO)]),,
 838                              enableval=default)
 839 case "$enableval" in
 840   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 841   no|default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 842   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 843 esac
 844
 845 dnl Allow enablement of doxygen search engine
 846 AC_ARG_ENABLE(doxygen-search,
 847               AS_HELP_STRING([--enable-doxygen-search],
 848                              [Enable doxygen search support (default is NO)]),,
 849                              enableval=default)
 850 ENABLE_DOXYGEN_SEARCH="$enableval"
 851
 852 case "$enableval" in
 853   yes|no|default) ;;
 854   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen-search. Use "yes" or "no"]) ;;
 855 esac
 856
 857 AC_ARG_ENABLE(doxygen-external-search,
 858               AS_HELP_STRING([--enable-doxygen-external-search],
 859                              [Enable doxygen exteranl search (default is NO)]),,
 860                              enableval=default)
 861 ENABLE_DOXYGEN_EXTERNAL_SEARCH="$enableval"
 862
 863 case "$enableval" in
 864   yes)
 865     dnl To match with the CMake behavior, enable doxygen when
 866     dnl --enable-doxygen-external-search is enabled.
 867     case "$ENABLE_DOXYGEN_SEARCH" in
 868       yes|default) ENABLE_DOXYGEN_SEARCH="yes" ;;
 869       no) AC_MSG_ERROR([The option --enable-doxygen-external-search requires --enable-doxygen-search]) ;;
 870     esac
 871     ;;
 872   no|default) ;;
 873   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen-external-search. Use "yes" or "no"]) ;;
 874 esac
 875
 876 AC_ARG_WITH(doxygen-search-engine-url,
 877             AS_HELP_STRING([--with-doxygen-search-engine-url],
 878                            [Specify the external search engine for doxygen]),,)
 879 WITH_DOXYGEN_SEARCH_ENGINE_URL="$withval"
 880
 881 AC_ARG_WITH(doxygen-search-mappings,
 882             AS_HELP_STRING([--with-doxygen-search-mappings],
 883                            [Specify the extra search mapping for doxygen]),,)
 884 WITH_DOXYGEN_SEARCH_MAPPINGS="$withval"
 885
 886 case "$ENABLE_DOXYGEN_SEARCH" in
 887   yes)
 888     if test "$ENABLE_DOXYGEN" = "0" ; then
 889       AC_MSG_ERROR([The option --enable-doxygen-search requires --enable-doxygen.])
 890     fi
 891
 892     AC_SUBST(enable_searchengine,[YES])
 893
 894     case "$ENABLE_DOXYGEN_EXTERNAL_SEARCH" in
 895       yes)
 896         AC_SUBST(enable_external_search,[YES])
 897         AC_SUBST(enable_server_based_search,[YES])
 898         AC_SUBST(searchengine_url,["$WITH_DOXYGEN_SEARCH_ENGINE_URL"])
 899         AC_SUBST(extra_search_mappings,["$WITH_DOXYGEN_SEARCH_MAPPINGS"])
 900         ;;
 901
 902       no|default)
 903         AC_SUBST(enable_external_search,[NO])
 904         AC_SUBST(enable_server_based_search,[NO])
 905         AC_SUBST(searchengine_url,[])
 906         AC_SUBST(extra_search_mappings,[])
 907         ;;
 908     esac
 909     ;;
 910
 911   no|default)
 912     AC_SUBST(enable_searchengine,[NO])
 913     AC_SUBST(searchengine_url,[])
 914     AC_SUBST(enable_server_based_search,[NO])
 915     AC_SUBST(enable_external_search,[NO])
 916     AC_SUBST(extra_search_mappings,[])
 917     ;;
 918
 919   *)
 920     AC_MSG_ERROR([Invalid setting for --enable-doxygen-search. Use "yes" or "no"])
 921     ;;
 922 esac
 923
 924 dnl Allow enablement of doxygen generated Qt help files
 925 AC_ARG_ENABLE(doxygen-qt-help,
 926               AS_HELP_STRING([--enable-doxygen-qt-help],
 927                              [Build Qt help files (default is NO)]),,
 928                              enableval=default)
 929 case "$enableval" in
 930   yes)
 931     if test "$ENABLE_DOXYGEN" = "0" ; then
 932       AC_MSG_ERROR([The option --enable-doxygen-qt-help requires --enable-doxygen.])
 933     fi
 934
 935     AC_PATH_PROG(QHELPGENERATOR, [qhelpgenerator], [qhelpgenerator])
 936
 937     dnl Qt help file for llvm doxygen documentation
 938     AC_SUBST(llvm_doxygen_generate_qhp,[YES])
 939     AC_SUBST(llvm_doxygen_qch_filename,[org.llvm.qch])
 940     AC_SUBST(llvm_doxygen_qhp_namespace,[org.llvm])
 941     AC_SUBST(llvm_doxygen_qhelpgenerator_path,["$QHELPGENERATOR"])
 942     AC_SUBST(llvm_doxygen_qhp_cust_filter_name,["$PACKAGE_STRING"])
 943     AC_SUBST(llvm_doxygen_qhp_cust_filter_attrs,["$PACKAGE_NAME,$PACKAGE_VERSION"])
 944
 945     dnl Qt help file for clang doxygen documentation
 946     AC_SUBST(clang_doxygen_generate_qhp,[YES])
 947     AC_SUBST(clang_doxygen_qch_filename,[org.llvm.clang.qch])
 948     AC_SUBST(clang_doxygen_qhp_namespace,[org.llvm.clang])
 949     AC_SUBST(clang_doxygen_qhelpgenerator_path,["$QHELPGENERATOR"])
 950     AC_SUBST(clang_doxygen_qhp_cust_filter_name,["Clang $PACKAGE_VERSION"])
 951     AC_SUBST(clang_doxygen_qhp_cust_filter_attrs,["Clang,$PACKAGE_VERSION"])
 952     ;;
 953
 954   no|default)
 955     AC_SUBST(llvm_doxygen_generate_qhp,[NO])
 956     AC_SUBST(llvm_doxygen_qch_filename,[])
 957     AC_SUBST(llvm_doxygen_qhp_namespace,[])
 958     AC_SUBST(llvm_doxygen_qhelpgenerator_path,[])
 959     AC_SUBST(llvm_doxygen_qhp_cust_filter_name,[])
 960     AC_SUBST(llvm_doxygen_qhp_cust_filter_attrs,[])
 961
 962     AC_SUBST(clang_doxygen_generate_qhp,[NO])
 963     AC_SUBST(clang_doxygen_qch_filename,[])
 964     AC_SUBST(clang_doxygen_qhp_namespace,[])
 965     AC_SUBST(clang_doxygen_qhelpgenerator_path,[])
 966     AC_SUBST(clang_doxygen_qhp_cust_filter_name,["Clang $PACKAGE_VERSION"])
 967     AC_SUBST(clang_doxygen_qhp_cust_filter_attrs,["Clang,$PACKAGE_VERSION"])
 968     ;;
 969
 970   *)
 971     AC_MSG_ERROR([Invalid setting for --enable-doxygen-qt-help. Use "yes" or "no"]) ;;
 972 esac
 973
 974 dnl Allow disablement of threads
 975 AC_ARG_ENABLE(threads,
 976               AS_HELP_STRING([--enable-threads],
 977                              [Use threads if available (default is YES)]),,
 978                              enableval=default)
 979 case "$enableval" in
 980   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 981   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 982   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 983   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 984 esac
 985 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 986                    [Define if threads enabled])
 987
 988 dnl Allow disablement of pthread.h
 989 AC_ARG_ENABLE(pthreads,
 990               AS_HELP_STRING([--enable-pthreads],
 991                              [Use pthreads if available (default is YES)]),,
 992                              enableval=default)
 993 case "$enableval" in
 994   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 995   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 996   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 997   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 998 esac
 999
1000 dnl Allow disablement of zlib
1001 AC_ARG_ENABLE(zlib,
1002               AS_HELP_STRING([--enable-zlib],
1003                              [Use zlib for compression/decompression if
1004                               available (default is YES)]),,
1005                               enableval=default)
1006 case "$enableval" in
1007   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
1008   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
1009   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
1010   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
1011 esac
1012 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
1013                    [Define if zlib is enabled])
1014
1015 dnl Allow building without position independent code
1016 AC_ARG_ENABLE(pic,
1017   AS_HELP_STRING([--enable-pic],
1018                  [Build LLVM with Position Independent Code (default is YES)]),,
1019                  enableval=default)
1020 case "$enableval" in
1021   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
1022   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
1023   default) AC_SUBST(ENABLE_PIC,[1]) ;;
1024   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
1025 esac
1026 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
1027                    [Define if position independent code is enabled])
1028
1029 dnl Allow building a shared library and linking tools against it.
1030 AC_ARG_ENABLE(shared,
1031   AS_HELP_STRING([--enable-shared],
1032                  [Build a shared library and link tools against it (default is NO)]),,
1033                  enableval=default)
1034 case "$enableval" in
1035   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
1036   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
1037   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
1038   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
1039 esac
1040
1041 dnl Allow libstdc++ is embedded in LLVM.dll.
1042 AC_ARG_ENABLE(embed-stdcxx,
1043   AS_HELP_STRING([--enable-embed-stdcxx],
1044                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
1045                  enableval=default)
1046 case "$enableval" in
1047   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
1048   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
1049   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
1050   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
1051 esac
1052
1053 dnl Enable embedding timestamp information into build.
1054 AC_ARG_ENABLE(timestamps,
1055   AS_HELP_STRING([--enable-timestamps],
1056                  [Enable embedding timestamp information in build (default is YES)]),,
1057                  enableval=default)
1058 case "$enableval" in
1059   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
1060   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
1061   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
1062   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
1063 esac
1064 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
1065                    [Define if timestamp information (e.g., __DATE__) is allowed])
1066
1067 dnl Enable support for showing backtraces.
1068 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
1069   [--enable-backtraces],
1070   [Enable embedding backtraces on crash (default is YES)]),
1071   [case "$enableval" in
1072     yes) llvm_cv_enable_backtraces="yes" ;;
1073     no)  llvm_cv_enable_backtraces="no"  ;;
1074     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
1075   esac],
1076   llvm_cv_enable_backtraces="yes")
1077 if test "$llvm_cv_enable_backtraces" = "yes" ; then
1078   AC_DEFINE([ENABLE_BACKTRACES],[1],
1079             [Define if you want backtraces on crash])
1080 fi
1081
1082 dnl Enable installing platform specific signal handling overrides, for improved
1083 dnl CrashRecovery support or interaction with crash reporting software. This
1084 dnl support may be inappropriate for some clients embedding LLVM as a library.
1085 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
1086   [--enable-crash-overrides],
1087   [Enable crash handling overrides (default is YES)]),
1088   [case "$enableval" in
1089     yes) llvm_cv_enable_crash_overrides="yes" ;;
1090     no)  llvm_cv_enable_crash_overrides="no"  ;;
1091     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
1092   esac],
1093   llvm_cv_enable_crash_overrides="yes")
1094 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
1095   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
1096             [Define to enable crash handling overrides])
1097 fi
1098
1099 dnl List all possible targets
1100 ALL_TARGETS="X86 Sparc PowerPC ARM AArch64 Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600 BPF"
1101 AC_SUBST(ALL_TARGETS,$ALL_TARGETS)
1102
1103 dnl Allow specific targets to be specified for building (or not)
1104 TARGETS_TO_BUILD=""
1105 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
1106     [Build specific host targets: all or target1,target2,... Valid targets are:
1107      host, x86, x86_64, sparc, powerpc, arm64, arm, aarch64, mips, hexagon,
1108      xcore, msp430, nvptx, systemz, r600, bpf, and cpp (default=all)]),,
1109     enableval=all)
1110 if test "$enableval" = host-only ; then
1111   enableval=host
1112 fi
1113 case "$enableval" in
1114   all) TARGETS_TO_BUILD="$ALL_TARGETS" ;;
1115   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
1116       case "$a_target" in
1117         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1118         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1119         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
1120         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
1121         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1122         arm64)    TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1123         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
1124         bpf)      TARGETS_TO_BUILD="BPF $TARGETS_TO_BUILD" ;;
1125         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1126         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1127         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1128         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1129         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
1130         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
1131         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
1132         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
1133         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1134         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1135         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
1136         host) case "$llvm_cv_target_arch" in
1137             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1138             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1139             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
1140             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
1141             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1142             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
1143             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1144             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
1145             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
1146             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
1147             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1148             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1149             *)       AC_MSG_ERROR([Can not set target to build]) ;;
1150           esac ;;
1151         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
1152       esac
1153   done
1154   ;;
1155 esac
1156
1157 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
1158     [Build experimental host targets: disable or target1,target2,...
1159      (default=disable)]),,
1160     enableval=disable)
1161
1162 if test ${enableval} != "disable"
1163 then
1164   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
1165 fi
1166
1167 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
1168
1169 dnl Determine whether we are building LLVM support for the native architecture.
1170 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
1171 for a_target in $TARGETS_TO_BUILD; do
1172   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
1173     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
1174       [LLVM architecture name for the native architecture, if available])
1175     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
1176     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
1177     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
1178     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
1179     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1180       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
1181     fi
1182     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1183       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
1184     fi
1185     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1186       [LLVM name for the native Target init function, if available])
1187     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1188       [LLVM name for the native TargetInfo init function, if available])
1189     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1190       [LLVM name for the native target MC init function, if available])
1191     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1192       [LLVM name for the native AsmPrinter init function, if available])
1193     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1194       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1195        [LLVM name for the native AsmParser init function, if available])
1196     fi
1197     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1198       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1199        [LLVM name for the native Disassembler init function, if available])
1200     fi
1201   fi
1202 done
1203
1204 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1205 dnl target feature def files.
1206 LLVM_ENUM_TARGETS=""
1207 LLVM_ENUM_ASM_PRINTERS=""
1208 LLVM_ENUM_ASM_PARSERS=""
1209 LLVM_ENUM_DISASSEMBLERS=""
1210 for target_to_build in $TARGETS_TO_BUILD; do
1211   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1212   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1213     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1214   fi
1215   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1216     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1217   fi
1218   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1219     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1220   fi
1221 done
1222 AC_SUBST(LLVM_ENUM_TARGETS)
1223 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1224 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1225 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1226
1227 dnl Override the option to use for optimized builds.
1228 AC_ARG_WITH(optimize-option,
1229   AS_HELP_STRING([--with-optimize-option],
1230                  [Select the compiler options to use for optimized builds]),,
1231                  withval=default)
1232 AC_MSG_CHECKING([optimization flags])
1233 case "$withval" in
1234   default)
1235     case "$llvm_cv_os_type" in
1236     FreeBSD) optimize_option=-O2 ;;
1237     MingW) optimize_option=-O2 ;;
1238     *)     optimize_option=-O3 ;;
1239     esac ;;
1240   *) optimize_option="$withval" ;;
1241 esac
1242 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1243 AC_MSG_RESULT([$optimize_option])
1244
1245 dnl Specify extra build options
1246 AC_ARG_WITH(extra-options,
1247   AS_HELP_STRING([--with-extra-options],
1248                  [Specify additional options to compile LLVM with]),,
1249                  withval=default)
1250 case "$withval" in
1251   default) EXTRA_OPTIONS= ;;
1252   *) EXTRA_OPTIONS=$withval ;;
1253 esac
1254 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1255
1256 dnl Specify extra linker build options
1257 AC_ARG_WITH(extra-ld-options,
1258   AS_HELP_STRING([--with-extra-ld-options],
1259                  [Specify additional options to link LLVM with]),,
1260                  withval=default)
1261 case "$withval" in
1262   default) EXTRA_LD_OPTIONS= ;;
1263   *) EXTRA_LD_OPTIONS=$withval ;;
1264 esac
1265 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1266
1267 dnl Allow specific bindings to be specified for building (or not)
1268 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1269     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1270     enableval=default)
1271 BINDINGS_TO_BUILD=""
1272 case "$enableval" in
1273   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1274   all ) BINDINGS_TO_BUILD="ocaml" ;;
1275   none | no) BINDINGS_TO_BUILD="" ;;
1276   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1277       case "$a_binding" in
1278         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1279         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1280       esac
1281   done
1282   ;;
1283 esac
1284
1285 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1286 dnl script for bindings/ocaml/configure, except that its auto value depends on
1287 dnl OCAMLC, which is found here to support tests.
1288 AC_ARG_WITH([ocaml-libdir],
1289   [AS_HELP_STRING([--with-ocaml-libdir],
1290     [Specify install location for ocaml bindings (default is stdlib)])],
1291   [],
1292   [withval=auto])
1293 case "$withval" in
1294   auto) with_ocaml_libdir="$withval" ;;
1295   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1296   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1297 esac
1298
1299 AC_ARG_WITH(clang-srcdir,
1300   AS_HELP_STRING([--with-clang-srcdir],
1301     [Directory to the out-of-tree Clang source]),,
1302     withval="-")
1303 case "$withval" in
1304   -) clang_src_root="" ;;
1305   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1306   *) clang_src_root="$ac_pwd/$withval" ;;
1307 esac
1308 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1309
1310 AC_ARG_WITH(clang-resource-dir,
1311   AS_HELP_STRING([--with-clang-resource-dir],
1312     [Relative directory from the Clang binary for resource files]),,
1313     withval="")
1314 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1315                    [Relative directory for resource files])
1316
1317 AC_ARG_WITH(c-include-dirs,
1318   AS_HELP_STRING([--with-c-include-dirs],
1319     [Colon separated list of directories clang will search for headers]),,
1320     withval="")
1321 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1322                    [Directories clang will search for headers])
1323
1324 # Clang normally uses the system c++ headers and libraries. With this option,
1325 # clang will use the ones provided by a gcc installation instead. This option should
1326 # be passed the same value that was used with --prefix when configuring gcc.
1327 AC_ARG_WITH(gcc-toolchain,
1328   AS_HELP_STRING([--with-gcc-toolchain],
1329     [Directory where gcc is installed.]),,
1330     withval="")
1331 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1332                    [Directory where gcc is installed.])
1333
1334 AC_ARG_WITH(default-sysroot,
1335   AS_HELP_STRING([--with-default-sysroot],
1336     [Add --sysroot=<path> to all compiler invocations.]),,
1337     withval="")
1338 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1339                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1340
1341 AC_ARG_WITH(clang-default-openmp-runtime,
1342   AS_HELP_STRING([--with-clang-default-openmp-runtime],
1343     [The default OpenMP runtime for Clang.]),,
1344     withval="libgomp")
1345 AC_DEFINE_UNQUOTED(CLANG_DEFAULT_OPENMP_RUNTIME,"$withval",
1346                    [Default OpenMP runtime used by -fopenmp.])
1347
1348 dnl Allow linking of LLVM with GPLv3 binutils code.
1349 AC_ARG_WITH(binutils-include,
1350   AS_HELP_STRING([--with-binutils-include],
1351     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1352   withval=default)
1353 case "$withval" in
1354   default) WITH_BINUTILS_INCDIR=default ;;
1355   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1356   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1357 esac
1358 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1359   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1360   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1361      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1362      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1363   fi
1364 fi
1365
1366 dnl Specify the URL where bug reports should be submitted.
1367 AC_ARG_WITH(bug-report-url,
1368   AS_HELP_STRING([--with-bug-report-url],
1369     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1370     withval="http://llvm.org/bugs/")
1371 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1372                    [Bug report URL.])
1373
1374 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1375 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1376   [--enable-terminfo],
1377   [Query the terminfo database if available (default is YES)]),
1378   [case "$enableval" in
1379     yes) llvm_cv_enable_terminfo="yes" ;;
1380     no)  llvm_cv_enable_terminfo="no"  ;;
1381     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1382   esac],
1383   llvm_cv_enable_terminfo="yes")
1384 case "$llvm_cv_enable_terminfo" in
1385   yes) AC_SUBST(ENABLE_TERMINFO,[1]) ;;
1386   no)  AC_SUBST(ENABLE_TERMINFO,[0]) ;;
1387 esac
1388
1389 dnl --enable-libedit: check whether the user wants to turn off libedit.
1390 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1391   [--enable-libedit],
1392   [Use libedit if available (default is YES)]),
1393   [case "$enableval" in
1394     yes) llvm_cv_enable_libedit="yes" ;;
1395     no)  llvm_cv_enable_libedit="no"  ;;
1396     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1397   esac],
1398   llvm_cv_enable_libedit="yes")
1399
1400 dnl --enable-libffi : check whether the user wants to turn off libffi:
1401 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1402   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1403   [case "$enableval" in
1404     yes) llvm_cv_enable_libffi="yes" ;;
1405     no)  llvm_cv_enable_libffi="no"  ;;
1406     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1407   esac],
1408   llvm_cv_enable_libffi=no)
1409
1410 AC_ARG_WITH(internal-prefix,
1411   AS_HELP_STRING([--with-internal-prefix],
1412     [Installation directory for internal files]),,
1413     withval="")
1414 AC_SUBST(INTERNAL_PREFIX,[$withval])
1415
1416 dnl===-----------------------------------------------------------------------===
1417 dnl===
1418 dnl=== SECTION 4: Check for programs we need and that they are the right version
1419 dnl===
1420 dnl===-----------------------------------------------------------------------===
1421
1422 dnl Check for the tools that the makefiles require
1423 AC_CHECK_GNU_MAKE
1424 AC_PROG_LN_S
1425 AC_PATH_PROG(NM, [nm], [nm])
1426 AC_PATH_PROG(CMP, [cmp], [cmp])
1427 AC_PATH_PROG(CP, [cp], [cp])
1428 AC_PATH_PROG(DATE, [date], [date])
1429 AC_PATH_PROG(FIND, [find], [find])
1430 AC_PATH_PROG(GREP, [grep], [grep])
1431 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1432 AC_PATH_PROG(MV,   [mv],   [mv])
1433 AC_PROG_RANLIB
1434 AC_CHECK_TOOL(AR, ar, false)
1435 AC_PATH_PROG(RM,   [rm],   [rm])
1436 AC_PATH_PROG(SED,  [sed],  [sed])
1437 AC_PATH_PROG(TAR,  [tar],  [gtar])
1438 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1439
1440 dnl Looking for misc. graph plotting software
1441 AC_PATH_PROG(DOT, [dot], [echo dot])
1442 if test "$DOT" != "echo dot" ; then
1443   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1444   dnl If we're targeting for mingw we should emit windows paths, not msys
1445   if test "$llvm_cv_os_type" = "MingW" ; then
1446     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1447   fi
1448   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1449    [Define to path to dot program if found or 'echo dot' otherwise])
1450 fi
1451
1452 dnl Find the install program
1453 AC_PROG_INSTALL
1454 dnl Prepend src dir to install path dir if it's a relative path
1455 dnl This is a hack for installs that take place in something other
1456 dnl than the top level.
1457 case "$INSTALL" in
1458  [[\\/$]]* | ?:[[\\/]]* ) ;;
1459  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1460 esac
1461
1462 dnl Checks for documentation and testing tools that we can do without. If these
1463 dnl are not found then they are set to "true" which always succeeds but does
1464 dnl nothing. This just lets the build output show that we could have done
1465 dnl something if the tool was available.
1466 AC_PATH_PROG(BZIP2, [bzip2])
1467 AC_PATH_PROG(CAT, [cat])
1468 AC_PATH_PROG(DOXYGEN, [doxygen])
1469 AC_PATH_PROG(GROFF, [groff])
1470 AC_PATH_PROG(GZIPBIN, [gzip])
1471 AC_PATH_PROG(PDFROFF, [pdfroff])
1472 AC_PATH_PROG(ZIP, [zip])
1473 AC_PATH_PROG(GO, [go])
1474 AC_PATH_PROGS(OCAMLFIND, [ocamlfind])
1475 AC_PATH_PROGS(GAS, [gas as])
1476
1477 dnl Get the version of the linker in use.
1478 AC_LINK_GET_VERSION
1479
1480 dnl Determine whether the linker supports the -R option.
1481 AC_LINK_USE_R
1482
1483 dnl Determine whether the compiler supports the -rdynamic option.
1484 AC_LINK_EXPORT_DYNAMIC
1485
1486 dnl Determine whether the linker supports the --version-script option.
1487 AC_LINK_VERSION_SCRIPT
1488
1489 AC_CHECK_HEADERS([errno.h])
1490
1491 case "$llvm_cv_os_type" in
1492   Cygwin|MingW|Win32) llvm_shlib_ext=.dll ;;
1493   Darwin) llvm_shlib_ext=.dylib ;;
1494   *) llvm_shlib_ext=.so ;;
1495 esac
1496
1497 AC_DEFINE_UNQUOTED([LTDL_SHLIB_EXT], ["$llvm_shlib_ext"], [The shared library extension])
1498
1499 AC_MSG_CHECKING([tool compatibility])
1500
1501 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1502 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1503 dnl to support those options.
1504 dnl "icc" emits gcc signatures
1505 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1506 ICC=no
1507 IXX=no
1508 case $CC in
1509   icc*|icpc*)
1510     ICC=yes
1511     IXX=yes
1512     ;;
1513    *)
1514     ;;
1515 esac
1516
1517 if test "$GCC" != "yes" && test "$ICC" != "yes"
1518 then
1519   AC_MSG_ERROR([gcc|icc required but not found])
1520 fi
1521
1522 dnl Ensure that compilation tools are compatible with GCC extensions
1523 if test "$GXX" != "yes" && test "$IXX" != "yes"
1524 then
1525   AC_MSG_ERROR([g++|clang++|icc required but not found])
1526 fi
1527
1528 dnl Verify that GCC is version 3.0 or higher
1529 if test "$GCC" = "yes"
1530 then
1531   AC_COMPILE_IFELSE(
1532 [
1533   AC_LANG_SOURCE([[
1534     #if !defined(__GNUC__) || __GNUC__ < 3
1535     #error Unsupported GCC version
1536     #endif
1537   ]])
1538 ],
1539 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1540 fi
1541
1542 dnl Check for GNU Make.  We use its extensions, so don't build without it
1543 if test -z "$llvm_cv_gnu_make_command"
1544 then
1545   AC_MSG_ERROR([GNU Make required but not found])
1546 fi
1547
1548 dnl Tool compatibility is okay if we make it here.
1549 AC_MSG_RESULT([ok])
1550
1551 dnl Check optional compiler flags.
1552 AC_MSG_CHECKING([optional compiler flags])
1553 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1554 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1555 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1556
1557 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1558 dnl false positives, so disable it.
1559 NO_UNINITIALIZED=
1560 NO_MAYBE_UNINITIALIZED=
1561 if test "$GXX" = "yes"
1562 then
1563   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1564   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1565   dnl known to be uninitialized from cases which might be uninitialized.  We
1566   dnl still want to catch the first kind of errors.
1567   if test -z "$NO_MAYBE_UNINITIALIZED"
1568   then
1569     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1570   fi
1571 fi
1572
1573 dnl Check for misbehaving -Wcomment (gcc-4.7 has this) and maybe add
1574 dnl -Wno-comment to the flags.
1575 no_comment=
1576 llvm_cv_old_cxxflags="$CXXFLAGS"
1577 CXXFLAGS="$CXXFLAGS -Wcomment -Werror"
1578 AC_COMPILE_IFELSE(
1579 [
1580   AC_LANG_SOURCE([[// Comment \o\
1581 // Another comment
1582 int main() { return 0; }
1583   ]])
1584 ],
1585 [
1586   no_comment=-Wno-comment
1587 ],
1588 [])
1589 AC_SUBST(NO_COMMENT, [$no_comment])
1590 CXXFLAGS="$llvm_cv_old_cxxflags"
1591
1592 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED $NO_COMMENT])
1593
1594 AC_ARG_WITH([python],
1595             [AS_HELP_STRING([--with-python], [path to python])],
1596             [PYTHON="$withval"])
1597
1598 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1599   AC_MSG_CHECKING([for python])
1600   AC_MSG_RESULT([user defined: $with_python])
1601 else
1602   if test -n "$PYTHON" ; then
1603     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1604   fi
1605
1606   AC_PATH_PROG([PYTHON], [python python2 python27],
1607                [AC_MSG_RESULT([not found])
1608                 AC_MSG_ERROR([could not find python 2.7 or higher])])
1609 fi
1610
1611 AC_MSG_CHECKING([for python >= 2.7])
1612 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1613 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1614 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1615 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1616 if test "$ac_python_version_major" -gt "2" || \
1617    (test "$ac_python_version_major" -eq "2" && \
1618     test "$ac_python_version_minor" -ge "7") ; then
1619   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1620 else
1621   AC_MSG_RESULT([not found])
1622   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.7])
1623 fi
1624
1625 dnl===-----------------------------------------------------------------------===
1626 dnl===
1627 dnl=== SECTION 5: Check for libraries
1628 dnl===
1629 dnl===-----------------------------------------------------------------------===
1630
1631 AC_CHECK_LIB(m,sin)
1632 if test "$llvm_cv_os_type" = "MingW" ; then
1633   AC_CHECK_LIB(imagehlp, main)
1634   AC_CHECK_LIB(psapi, main)
1635   AC_CHECK_LIB(shell32, main)
1636 fi
1637
1638 dnl dlopen() is required for plugin support.
1639 AC_SEARCH_LIBS(dlopen,dl,LLVM_DEFINE_SUBST([HAVE_DLOPEN],[1],
1640                [Define if dlopen() is available on this platform.]),
1641                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1642
1643 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1644 dnl macros to detect whether clock_gettime is available, this just finds the
1645 dnl right libraries to link with.
1646 AC_SEARCH_LIBS(clock_gettime,rt)
1647
1648 dnl The curses library is optional; used for querying terminal info
1649 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1650   dnl We need the has_color functionality in curses for it to be useful.
1651   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1652                  LLVM_DEFINE_SUBST([HAVE_TERMINFO],[1],
1653                                    [Define if the setupterm() function is supported this platform.]))
1654 fi
1655
1656 dnl The libedit library is optional; used by lib/LineEditor
1657 if test "$llvm_cv_enable_libedit" = "yes" ; then
1658   AC_SEARCH_LIBS(el_init,edit,
1659                  AC_DEFINE([HAVE_LIBEDIT],[1],
1660                            [Define if libedit is available on this platform.]))
1661 fi
1662
1663 dnl libffi is optional; used to call external functions from the interpreter
1664 if test "$llvm_cv_enable_libffi" = "yes" ; then
1665   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1666                  [Define if libffi is available on this platform.]),
1667                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1668 fi
1669
1670 dnl mallinfo is optional; the code can compile (minus features) without it
1671 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1672                [Define if mallinfo() is available on this platform.]))
1673
1674 dnl pthread locking functions are optional - but llvm will not be thread-safe
1675 dnl without locks.
1676 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1677   AC_CHECK_LIB(pthread, pthread_mutex_init)
1678   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1679                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1680                            [Have pthread_mutex_lock]))
1681   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1682                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1683                  [Have pthread_rwlock_init]))
1684   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1685                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1686                  [Have pthread_getspecific]))
1687 fi
1688
1689 dnl zlib is optional; used for compression/uncompression
1690 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1691   AC_CHECK_LIB(z, compress2)
1692 fi
1693
1694 dnl Allow OProfile support for JIT output.
1695 AC_ARG_WITH(oprofile,
1696   AS_HELP_STRING([--with-oprofile=<prefix>],
1697     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1698     [
1699       AC_SUBST(USE_OPROFILE, [1])
1700       case "$withval" in
1701         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1702         no) llvm_cv_oppath=
1703             AC_SUBST(USE_OPROFILE, [0]) ;;
1704         *) llvm_cv_oppath="${withval}/lib/oprofile"
1705            CPPFLAGS="-I${withval}/include";;
1706       esac
1707       case $llvm_cv_os_type in
1708         Linux)
1709           if test -n "$llvm_cv_oppath" ; then
1710             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1711             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1712             dnl libbfd is not included properly in libopagent in some Debian
1713             dnl versions.  If libbfd isn't found at all, we assume opagent works
1714             dnl anyway.
1715             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1716             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1717               echo "Error! You need to have libopagent around."
1718               exit 1
1719             ])
1720             AC_CHECK_HEADER([opagent.h], [], [
1721               echo "Error! You need to have opagent.h around."
1722               exit 1
1723               ])
1724           fi ;;
1725         *)
1726           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1727       esac
1728     ],
1729     [
1730       AC_SUBST(USE_OPROFILE, [0])
1731     ])
1732 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1733                    [Define if we have the oprofile JIT-support library])
1734
1735 dnl Enable support for Intel JIT Events API.
1736 AC_ARG_WITH(intel-jitevents,
1737   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1738     [
1739        case "$withval" in
1740           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1741           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1742           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1743        esac
1744
1745       case $llvm_cv_os_type in
1746         Linux|Win32|Cygwin|MingW) ;;
1747         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1748       esac
1749
1750       case "$llvm_cv_target_arch" in
1751         x86|x86_64) ;;
1752         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1753       esac
1754     ],
1755     [
1756       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1757     ])
1758 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1759                    [Define if we have the Intel JIT API runtime support library])
1760
1761 dnl Check for libxml2
1762 dnl Right now we're just checking for the existence, we could also check for a
1763 dnl particular version via --version on xml2-config
1764 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1765
1766 AC_MSG_CHECKING(for libxml2 includes)
1767 if test "x$XML2CONFIG" = "x"; then
1768  AC_MSG_RESULT(xml2-config not found)
1769 else
1770  LIBXML2_INC=`$XML2CONFIG --cflags`
1771  AC_MSG_RESULT($LIBXML2_INC)
1772  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1773                                 LIBXML2_LIBS="-lxml2"])
1774 fi
1775 AC_SUBST(LIBXML2_LIBS)
1776 AC_SUBST(LIBXML2_INC)
1777
1778 dnl===-----------------------------------------------------------------------===
1779 dnl===
1780 dnl=== SECTION 6: Check for header files
1781 dnl===
1782 dnl===-----------------------------------------------------------------------===
1783
1784 dnl First, use autoconf provided macros for specific headers that we need
1785 dnl We don't check for ancient stuff or things that are guaranteed to be there
1786 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1787 dnl Generally we're looking for POSIX headers.
1788 AC_HEADER_DIRENT
1789 AC_HEADER_MMAP_ANONYMOUS
1790 AC_HEADER_STAT
1791 AC_HEADER_SYS_WAIT
1792 AC_HEADER_TIME
1793
1794 AC_LANG_PUSH([C++])
1795 dnl size_t must be defined before including cxxabi.h on FreeBSD 10.0.
1796 AC_CHECK_HEADERS([cxxabi.h], [], [],
1797 [#include <stddef.h>
1798 ])
1799 AC_LANG_POP([C++])
1800
1801 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1802 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1803 AC_CHECK_HEADERS([utime.h])
1804 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1805 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1806 AC_CHECK_HEADERS([valgrind/valgrind.h])
1807 AC_CHECK_HEADERS([fenv.h])
1808 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1809 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1810   AC_CHECK_HEADERS(pthread.h,
1811                    AC_SUBST(HAVE_PTHREAD, 1),
1812                    AC_SUBST(HAVE_PTHREAD, 0))
1813 else
1814   AC_SUBST(HAVE_PTHREAD, 0)
1815 fi
1816 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1817   AC_CHECK_HEADERS(zlib.h,
1818                    AC_SUBST(HAVE_LIBZ, 1),
1819                    AC_SUBST(HAVE_LIBZ, 0))
1820 else
1821   AC_SUBST(HAVE_LIBZ, 0)
1822 fi
1823
1824 dnl Try to find ffi.h.
1825 if test "$llvm_cv_enable_libffi" = "yes" ; then
1826   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1827 fi
1828
1829 dnl Try to find Darwin specific crash reporting libraries.
1830 AC_CHECK_HEADERS([CrashReporterClient.h])
1831
1832 dnl Try to find Darwin specific crash reporting global.
1833 AC_MSG_CHECKING([__crashreporter_info__])
1834 AC_LINK_IFELSE(
1835 [
1836   AC_LANG_SOURCE([[
1837     extern const char *__crashreporter_info__;
1838     int main() {
1839       __crashreporter_info__ = "test";
1840       return 0;
1841     }
1842   ]])
1843 ],
1844 [
1845   AC_MSG_RESULT([yes])
1846   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1847 ],
1848 [
1849   AC_MSG_RESULT([no])
1850   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1851 ])
1852
1853 dnl===-----------------------------------------------------------------------===
1854 dnl===
1855 dnl=== SECTION 7: Check for types and structures
1856 dnl===
1857 dnl===-----------------------------------------------------------------------===
1858
1859 AC_HUGE_VAL_CHECK
1860 AC_TYPE_PID_T
1861 AC_TYPE_SIZE_T
1862 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1863 AC_STRUCT_TM
1864 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1865 AC_CHECK_TYPES([uint64_t],,
1866          AC_CHECK_TYPES([u_int64_t],,
1867          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1868
1869 dnl===-----------------------------------------------------------------------===
1870 dnl===
1871 dnl=== SECTION 8: Check for specific functions needed
1872 dnl===
1873 dnl===-----------------------------------------------------------------------===
1874
1875 AC_CHECK_FUNCS([backtrace getcwd ])
1876 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1877 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1878 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1879 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1880 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1881 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1882 AC_CHECK_FUNCS([futimes futimens])
1883 AC_C_PRINTF_A
1884 AC_FUNC_RAND48
1885
1886 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1887 AC_CHECK_DECLS([arc4random])
1888
1889 dnl Check the declaration "Secure API" on Windows environments.
1890 AC_CHECK_DECLS([strerror_s])
1891
1892 dnl Check symbols in libgcc.a for JIT on Mingw.
1893 if test "$llvm_cv_os_type" = "MingW" ; then
1894   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1895   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1896   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1897   AC_CHECK_LIB(gcc,__chkstk_ms,AC_DEFINE([HAVE___CHKSTK_MS],[1],[Have host's __chkstk_ms]))
1898   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1899   AC_CHECK_LIB(gcc,___chkstk_ms,AC_DEFINE([HAVE____CHKSTK_MS],[1],[Have host's ___chkstk_ms]))
1900
1901   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1902   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1903   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1904   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1905   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1906   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1907   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1908   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1909   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1910   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1911
1912   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1913   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1914 fi
1915
1916 dnl Check Win32 API EnumerateLoadedModules.
1917 if test "$llvm_cv_os_type" = "MingW" ; then
1918   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1919   AC_COMPILE_IFELSE(
1920 [
1921   AC_LANG_SOURCE([[
1922     #include <windows.h>
1923     #include <imagehlp.h>
1924     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1925     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1926   ]])
1927 ],
1928 [
1929   AC_MSG_RESULT([yes])
1930   llvm_cv_win32_elmcb_pcstr="PCSTR"
1931 ],
1932 [
1933   AC_MSG_RESULT([no])
1934   llvm_cv_win32_elmcb_pcstr="PSTR"
1935 ])
1936   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1937 fi
1938
1939 dnl Check for mmap support.We also need to know if /dev/zero is required to
1940 dnl be opened for allocating RWX memory.
1941 dnl Make sure we aren't attempting to configure for an unknown system
1942 if test "$llvm_cv_platform_type" = "Unix" ; then
1943   AC_FUNC_MMAP
1944   AC_FUNC_MMAP_FILE
1945   AC_NEED_DEV_ZERO_FOR_MMAP
1946
1947   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1948   then
1949     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1950   fi
1951   if test "$ac_cv_func_mmap_file" = "no"
1952   then
1953     AC_MSG_WARN([mmap() of files required but not found])
1954   fi
1955 fi
1956
1957 dnl atomic builtins are required for threading support.
1958 AC_MSG_CHECKING(for GCC atomic builtins)
1959 dnl Since we'll be using these atomic builtins in C++ files we should test
1960 dnl the C++ compiler.
1961 AC_LANG_PUSH([C++])
1962 AC_LINK_IFELSE(
1963 [
1964   AC_LANG_SOURCE([[
1965     int main() {
1966       volatile unsigned long val = 1;
1967       __sync_synchronize();
1968       __sync_val_compare_and_swap(&val, 1, 0);
1969       __sync_add_and_fetch(&val, 1);
1970       __sync_sub_and_fetch(&val, 1);
1971       return 0;
1972     }
1973   ]])
1974 ],
1975 [
1976   AC_MSG_RESULT([yes])
1977   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1978 ],
1979 [
1980   AC_MSG_RESULT([no])
1981   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1982   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1983 ])
1984 AC_LANG_POP([C++])
1985
1986 dnl===-----------------------------------------------------------------------===
1987 dnl===
1988 dnl=== SECTION 9: Additional checks, variables, etc.
1989 dnl===
1990 dnl===-----------------------------------------------------------------------===
1991
1992 dnl Handle 32-bit linux systems running a 64-bit kernel.
1993 dnl This has to come after section 4 because it invokes the compiler.
1994 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1995   AC_IS_LINUX_MIXED
1996   if test "$llvm_cv_linux_mixed" = "yes"; then
1997     llvm_cv_target_arch="x86"
1998     ARCH="x86"
1999   fi
2000 fi
2001
2002 dnl Check whether __dso_handle is present
2003 AC_CHECK_FUNCS([__dso_handle])
2004
2005 dnl Propagate the shared library extension that the libltdl checks did to
2006 dnl the Makefiles so we can use it there too
2007 AC_SUBST(SHLIBEXT,$llvm_shlib_ext)
2008
2009 dnl Translate the various configuration directories and other basic
2010 dnl information into substitutions that will end up in Makefile.config.in
2011 dnl that these configured values can be used by the makefiles
2012 if test "${prefix}" = "NONE" ; then
2013   prefix="/usr/local"
2014 fi
2015 eval LLVM_PREFIX="${prefix}";
2016 eval LLVM_BINDIR="${prefix}/bin";
2017 eval LLVM_DATADIR="${prefix}/share/llvm";
2018 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
2019 eval LLVM_ETCDIR="${prefix}/etc/llvm";
2020 eval LLVM_INCLUDEDIR="${prefix}/include";
2021 eval LLVM_INFODIR="${prefix}/info";
2022 eval LLVM_MANDIR="${prefix}/man";
2023 LLVM_CONFIGTIME=`date`
2024 AC_SUBST(LLVM_PREFIX)
2025 AC_SUBST(LLVM_BINDIR)
2026 AC_SUBST(LLVM_DATADIR)
2027 AC_SUBST(LLVM_DOCSDIR)
2028 AC_SUBST(LLVM_ETCDIR)
2029 AC_SUBST(LLVM_INCLUDEDIR)
2030 AC_SUBST(LLVM_INFODIR)
2031 AC_SUBST(LLVM_MANDIR)
2032 AC_SUBST(LLVM_CONFIGTIME)
2033
2034 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
2035 if test "${ENABLE_TIMESTAMPS}" = "0"; then
2036   LLVM_CONFIGTIME="(timestamp not enabled)"
2037 fi
2038
2039 dnl Place the various directories into the config.h file as #defines so that we
2040 dnl can know about the installation paths within LLVM.
2041 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
2042                    [Installation prefix directory])
2043 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
2044                    [Installation directory for binary executables])
2045 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
2046                    [Installation directory for data files])
2047 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
2048                    [Installation directory for documentation])
2049 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
2050                    [Installation directory for config files])
2051 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
2052                    [Installation directory for include files])
2053 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
2054                    [Installation directory for .info files])
2055 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
2056                    [Installation directory for man pages])
2057 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
2058                    [Time at which LLVM was configured])
2059 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
2060                    [Host triple LLVM will be executed on])
2061 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
2062                    [Target triple LLVM will generate code for by default])
2063
2064 dnl Determine which bindings to build.
2065 if test "$BINDINGS_TO_BUILD" = auto ; then
2066   BINDINGS_TO_BUILD=""
2067   if test "x$OCAMLFIND" != x ; then
2068     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
2069   fi
2070   if test "x$GO" != x ; then
2071     if $GO run ${srcdir}/bindings/go/conftest.go ; then
2072       BINDINGS_TO_BUILD="go $BINDINGS_TO_BUILD"
2073     fi
2074   fi
2075 fi
2076 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
2077
2078 dnl Do any work necessary to ensure that bindings have what they need.
2079 binding_prereqs_failed=0
2080 for a_binding in $BINDINGS_TO_BUILD ; do
2081   case "$a_binding" in
2082   ocaml)
2083     if test "x$OCAMLFIND" = x ; then
2084       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlfind not found. Try configure OCAMLFIND=/path/to/ocamlfind])
2085       binding_prereqs_failed=1
2086     fi
2087
2088     if $OCAMLFIND opt -version >/dev/null 2>/dev/null ; then
2089       HAVE_OCAMLOPT=1
2090     else
2091       HAVE_OCAMLOPT=0
2092     fi
2093     AC_SUBST(HAVE_OCAMLOPT)
2094
2095     if ! $OCAMLFIND query ctypes >/dev/null 2>/dev/null; then
2096       AC_MSG_WARN([--enable-bindings=ocaml specified, but ctypes is not installed])
2097       binding_prereqs_failed=1
2098     fi
2099
2100     if $OCAMLFIND query oUnit >/dev/null 2>/dev/null; then
2101       HAVE_OCAML_OUNIT=1
2102     else
2103       HAVE_OCAML_OUNIT=0
2104       AC_MSG_WARN([--enable-bindings=ocaml specified, but OUnit 2 is not installed. Tests will not run])
2105       dnl oUnit is optional!
2106     fi
2107     AC_SUBST(HAVE_OCAML_OUNIT)
2108
2109     if test "x$with_ocaml_libdir" != xauto ; then
2110       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
2111     else
2112       ocaml_stdlib="`"$OCAMLFIND" ocamlc -where`"
2113       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
2114       then
2115         # ocaml stdlib is beneath our prefix; use stdlib
2116         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
2117       else
2118         # ocaml stdlib is outside our prefix; use libdir/ocaml
2119         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
2120       fi
2121     fi
2122     ;;
2123   go)
2124     if test "x$GO" = x ; then
2125       AC_MSG_WARN([--enable-bindings=go specified, but go not found. Try configure GO=/path/to/go])
2126       binding_prereqs_failed=1
2127     else
2128       if $GO run ${srcdir}/bindings/go/conftest.go ; then
2129         :
2130       else
2131         AC_MSG_WARN([--enable-bindings=go specified, but need at least Go 1.2. Try configure GO=/path/to/go])
2132         binding_prereqs_failed=1
2133       fi
2134     fi
2135     ;;
2136   esac
2137 done
2138 if test "$binding_prereqs_failed" = 1 ; then
2139   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
2140 fi
2141
2142 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
2143 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
2144
2145 dnl Determine linker rpath flag
2146 if test "$llvm_cv_link_use_r" = "yes" ; then
2147   RPATH="-Wl,-R"
2148 else
2149   RPATH="-Wl,-rpath"
2150 fi
2151 AC_SUBST(RPATH)
2152
2153 dnl Determine linker rdynamic flag
2154 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
2155   RDYNAMIC="-rdynamic"
2156 else
2157   RDYNAMIC=""
2158 fi
2159 AC_SUBST(RDYNAMIC)
2160
2161 dnl===-----------------------------------------------------------------------===
2162 dnl===
2163 dnl=== SECTION 10: Specify the output files and generate it
2164 dnl===
2165 dnl===-----------------------------------------------------------------------===
2166
2167 dnl Configure header files
2168 dnl WARNING: dnl If you add or remove any of the following config headers, then
2169 dnl you MUST also update Makefile so that the variable FilesToConfig
2170 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2171 dnl files can be updated automatically when their *.in sources change.
2172 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2173 AH_TOP([#ifndef CONFIG_H
2174 #define CONFIG_H])
2175 AH_BOTTOM([#endif])
2176
2177 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2178 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2179 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2180 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2181 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2182
2183 dnl Configure the makefile's configuration data
2184 AC_CONFIG_FILES([Makefile.config])
2185
2186 dnl Configure the RPM spec file for LLVM
2187 AC_CONFIG_FILES([llvm.spec])
2188
2189 dnl Configure doxygen's configuration file
2190 AC_CONFIG_FILES([docs/doxygen.cfg])
2191
2192 dnl Configure clang, if present
2193 if test "${clang_src_root}" = ""; then
2194   clang_src_root="$srcdir/tools/clang"
2195 fi
2196 if test -f ${clang_src_root}/README.txt; then
2197   dnl Clang supports build systems which use the multilib libdir suffix.
2198   dnl The autoconf system doesn't support this so stub out that variable.
2199   AC_DEFINE_UNQUOTED(CLANG_LIBDIR_SUFFIX,"",
2200                      [Multilib suffix for libdir.])
2201
2202   dnl Use variables to stay under 80 columns.
2203   configh="include/clang/Config/config.h"
2204   doxy="docs/doxygen.cfg"
2205   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2206   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2207 fi
2208
2209 dnl OCaml findlib META file
2210 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2211
2212 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2213 test "x$program_prefix" = "xNONE" && program_prefix=""
2214 AC_SUBST([program_prefix])
2215
2216
2217 dnl Do special configuration of Makefiles
2218 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2219 AC_CONFIG_MAKEFILE(Makefile)
2220 AC_CONFIG_MAKEFILE(Makefile.common)
2221 AC_CONFIG_MAKEFILE(examples/Makefile)
2222 AC_CONFIG_MAKEFILE(lib/Makefile)
2223 AC_CONFIG_MAKEFILE(test/Makefile)
2224 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2225 AC_CONFIG_MAKEFILE(unittests/Makefile)
2226 AC_CONFIG_MAKEFILE(tools/Makefile)
2227 AC_CONFIG_MAKEFILE(utils/Makefile)
2228 AC_CONFIG_MAKEFILE(projects/Makefile)
2229 AC_CONFIG_MAKEFILE(bindings/Makefile)
2230 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2231
2232 dnl Finally, crank out the output
2233 AC_OUTPUT