CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(PACKAGE_VERSION "3.0")
  14
  15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  16
  17 include(VersionFromVCS)
  18
  19 option(LLVM_APPEND_VC_REV
  20   "Append the version control system revision id to LLVM version" OFF)
  21
  22 if( LLVM_APPEND_VC_REV )
  23   add_version_info_from_vcs(PACKAGE_VERSION)
  24 endif()
  25
  26 set(PACKAGE_NAME llvm)
  27 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  28 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  29
  30 # Sanity check our source directory to make sure that we are not trying to
  31 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  32 # sure that we don't have any stray generated files lying around in the tree
  33 # (which would end up getting picked up by header search, instead of the correct
  34 # versions).
  35 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  36   message(FATAL_ERROR "In-source builds are not allowed.
  37 CMake would overwrite the makefiles distributed with LLVM.
  38 Please create a directory and run cmake from there, passing the path
  39 to this source directory as the last argument.
  40 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  41 Please delete them.")
  42 endif()
  43 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  44   file(GLOB_RECURSE
  45     tablegenned_files_on_include_dir
  46     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  47   file(GLOB_RECURSE
  48     tablegenned_files_on_lib_dir
  49     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  50   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  51     message(FATAL_ERROR "Apparently there is a previous in-source build,
  52 probably as the result of running `configure' and `make' on
  53 ${CMAKE_CURRENT_SOURCE_DIR}.
  54 This may cause problems. The suspicious files are:
  55 ${tablegenned_files_on_lib_dir}
  56 ${tablegenned_files_on_include_dir}
  57 Please clean the source directory.")
  58   endif()
  59 endif()
  60
  61 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  62
  63 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  64 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  65 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  66 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  67 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  68 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  69
  70 set(LLVM_ALL_TARGETS
  71   ARM
  72   CBackend
  73   CellSPU
  74   CppBackend
  75   Mips
  76   MBlaze
  77   MSP430
  78   PowerPC
  79   PTX
  80   Sparc
  81   X86
  82   XCore
  83   )
  84
  85 # List of targets with JIT support:
  86 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  87
  88 if( MSVC )
  89   set(LLVM_TARGETS_TO_BUILD X86
  90     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  91 else( MSVC )
  92   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  93     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  94 endif( MSVC )
  95
  96 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
  97 if(LLVM_ENABLE_CBE_PRINTF_A)
  98   set(ENABLE_CBE_PRINTF_A 1)
  99 endif()
 100
 101 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 102 if(LLVM_ENABLE_TIMESTAMPS)
 103   set(ENABLE_TIMESTAMPS 1)
 104 endif()
 105
 106 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 107 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 108 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 109
 110 set(LLVM_TARGET_ARCH "host"
 111   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 112
 113 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 114
 115 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 116   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 117 endif()
 118
 119 set(LLVM_ENUM_TARGETS "")
 120 foreach(c ${LLVM_TARGETS_TO_BUILD})
 121   list(FIND LLVM_ALL_TARGETS ${c} idx)
 122   if( idx LESS 0 )
 123     message(FATAL_ERROR "The target `${c}' does not exist.
 124     It should be one of\n${LLVM_ALL_TARGETS}")
 125   else()
 126     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 127   endif()
 128 endforeach(c)
 129
 130 # Produce llvm/Config/Targets.def
 131 configure_file(
 132   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 133   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 134   )
 135
 136 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 137
 138 include(AddLLVMDefinitions)
 139
 140 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 141
 142 # MSVC has a gazillion warnings with this.
 143 if( MSVC )
 144   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 145 else( MSVC )
 146   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 147 endif()
 148
 149 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 150 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 151
 152 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 153   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 154 else()
 155   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 156 endif()
 157
 158 # Define an option controlling whether we should build for 32-bit on 64-bit
 159 # platforms, where supported.
 160 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 161   # TODO: support other platforms and toolchains.
 162   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 163 endif()
 164
 165 # Define the default arguments to use with 'lit', and an option for the user to
 166 # override.
 167 set(LIT_ARGS_DEFAULT "-sv")
 168 if (MSVC OR XCODE)
 169   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 170 endif()
 171 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 172
 173 # On Win32/Cygwin, provide an option to specify the path to the GnuWin32 tools.
 174 if( WIN32 AND CYGWIN )
 175   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 176 endif()
 177
 178 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 179 # to use.
 180 if( MSVC_IDE AND ( MSVC90 OR MSVC10 ) )
 181   # Only Visual Studio 2008 and 2010 officially supports /MP.  Visual Studio
 182   # 2005 supports it but it is experimental.
 183   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 184     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 185 endif()
 186
 187 # Define options to control the inclusion and default build behavior for
 188 # components which may not strictly be necessary (tools, runtime, examples, and
 189 # tests).
 190 #
 191 # This is primarily to support building smaller or faster project files.
 192 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 193 option(LLVM_BUILD_TOOLS
 194   "Build the LLVM tools. If OFF, just generate build targets." ON)
 195
 196 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 197 option(LLVM_BUILD_RUNTIME
 198   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 199
 200 option(LLVM_BUILD_EXAMPLES
 201   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 202 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 203
 204 option(LLVM_BUILD_TESTS
 205   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 206 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 207
 208 # All options referred to from HandleLLVMOptions have to be specified
 209 # BEFORE this include, otherwise options will not be correctly set on
 210 # first cmake run
 211 include(config-ix)
 212 include(HandleLLVMOptions)
 213
 214 configure_file(
 215   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 216   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 217
 218 configure_file(
 219   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 220   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 221
 222 configure_file(
 223   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 224   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 225
 226 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 227 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 228 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 229
 230 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 231
 232 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 233
 234 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 235    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 236 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 237
 238 include(AddLLVM)
 239 include(TableGen)
 240
 241 if( MINGW )
 242   # People report that -O3 is unreliable on MinGW. The traditional
 243   # build also uses -O2 for that reason:
 244   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 245 endif()
 246
 247 # Put this before tblgen. Else we have a circular dependence.
 248 add_subdirectory(lib/Support)
 249 add_subdirectory(lib/TableGen)
 250
 251 add_subdirectory(utils/TableGen)
 252
 253 add_subdirectory(include/llvm)
 254
 255 add_subdirectory(lib)
 256
 257 add_subdirectory(utils/FileCheck)
 258 add_subdirectory(utils/FileUpdate)
 259 add_subdirectory(utils/count)
 260 add_subdirectory(utils/not)
 261 add_subdirectory(utils/llvm-lit)
 262
 263 add_subdirectory(projects)
 264
 265 if( LLVM_INCLUDE_TOOLS )
 266   add_subdirectory(tools)
 267 endif()
 268
 269 if( LLVM_INCLUDE_RUNTIME )
 270   add_subdirectory(runtime)
 271 endif()
 272
 273 if( LLVM_INCLUDE_EXAMPLES )
 274   add_subdirectory(examples)
 275 endif()
 276
 277 if( LLVM_INCLUDE_TESTS )
 278   add_subdirectory(test)
 279   add_subdirectory(utils/unittest)
 280   add_subdirectory(unittests)
 281   if (MSVC)
 282     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 283     # Windows.
 284     add_subdirectory(utils/KillTheDoctor)
 285   endif()
 286 endif()
 287
 288 add_subdirectory(cmake/modules)
 289
 290 install(DIRECTORY include/
 291   DESTINATION include
 292   FILES_MATCHING
 293   PATTERN "*.def"
 294   PATTERN "*.h"
 295   PATTERN "*.td"
 296   PATTERN "*.inc"
 297   PATTERN "LICENSE.TXT"
 298   PATTERN ".svn" EXCLUDE
 299   )
 300
 301 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 302   DESTINATION include
 303   FILES_MATCHING
 304   PATTERN "*.def"
 305   PATTERN "*.h"
 306   PATTERN "*.gen"
 307   PATTERN "*.inc"
 308   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 309   PATTERN "CMakeFiles" EXCLUDE
 310   PATTERN ".svn" EXCLUDE
 311   )
 312
 313 # TODO: make and install documentation.
 314
 315 set(CPACK_PACKAGE_VENDOR "LLVM")
 316 set(CPACK_PACKAGE_VERSION_MAJOR 2)
 317 set(CPACK_PACKAGE_VERSION_MINOR 9)
 318 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 319 include(CPack)
 320
 321 # Workaround for MSVS10 to avoid the Dialog Hell
 322 # FIXME: This could be removed with future version of CMake.
 323 if(MSVC_VERSION EQUAL 1600)
 324   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 325   if( EXISTS "${LLVM_SLN_FILENAME}" )
 326     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 327   endif()
 328 endif()