CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 2)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  19
  20 include(VersionFromVCS)
  21
  22 option(LLVM_APPEND_VC_REV
  23   "Append the version control system revision id to LLVM version" OFF)
  24
  25 if( LLVM_APPEND_VC_REV )
  26   add_version_info_from_vcs(PACKAGE_VERSION)
  27 endif()
  28
  29 set(PACKAGE_NAME LLVM)
  30 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  31 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  32
  33 # Sanity check our source directory to make sure that we are not trying to
  34 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  35 # sure that we don't have any stray generated files lying around in the tree
  36 # (which would end up getting picked up by header search, instead of the correct
  37 # versions).
  38 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  39   message(FATAL_ERROR "In-source builds are not allowed.
  40 CMake would overwrite the makefiles distributed with LLVM.
  41 Please create a directory and run cmake from there, passing the path
  42 to this source directory as the last argument.
  43 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  44 Please delete them.")
  45 endif()
  46 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  47   file(GLOB_RECURSE
  48     tablegenned_files_on_include_dir
  49     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  50   file(GLOB_RECURSE
  51     tablegenned_files_on_lib_dir
  52     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  53   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  54     message(FATAL_ERROR "Apparently there is a previous in-source build,
  55 probably as the result of running `configure' and `make' on
  56 ${CMAKE_CURRENT_SOURCE_DIR}.
  57 This may cause problems. The suspicious files are:
  58 ${tablegenned_files_on_lib_dir}
  59 ${tablegenned_files_on_include_dir}
  60 Please clean the source directory.")
  61   endif()
  62 endif()
  63
  64 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  65
  66 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  67 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  68 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  69 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  70 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  71 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  72
  73 set(LLVM_ALL_TARGETS
  74   ARM
  75   CellSPU
  76   CppBackend
  77   Hexagon
  78   Mips
  79   MBlaze
  80   MSP430
  81   PowerPC
  82   PTX
  83   Sparc
  84   X86
  85   XCore
  86   )
  87
  88 # List of targets with JIT support:
  89 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  90
  91 if( MSVC )
  92   set(LLVM_TARGETS_TO_BUILD X86
  93     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  94 else( MSVC )
  95   set(LLVM_TARGETS_TO_BUILD "all"
  96     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  97 endif( MSVC )
  98
  99 option(BUILD_SHARED_LIBS
 100   "Build all libraries as shared libraries instead of static" OFF)
 101
 102 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 103 if(LLVM_ENABLE_CBE_PRINTF_A)
 104   set(ENABLE_CBE_PRINTF_A 1)
 105 endif()
 106
 107 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 108 if(LLVM_ENABLE_TIMESTAMPS)
 109   set(ENABLE_TIMESTAMPS 1)
 110 endif()
 111
 112 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 113 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 114 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 115
 116 set(LLVM_TARGET_ARCH "host"
 117   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 118
 119 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 120
 121 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 122   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 123 endif()
 124
 125 set(LLVM_ENUM_TARGETS "")
 126 foreach(c ${LLVM_TARGETS_TO_BUILD})
 127   list(FIND LLVM_ALL_TARGETS ${c} idx)
 128   if( idx LESS 0 )
 129     message(FATAL_ERROR "The target `${c}' does not exist.
 130     It should be one of\n${LLVM_ALL_TARGETS}")
 131   else()
 132     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 133   endif()
 134 endforeach(c)
 135
 136 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 137
 138 include(AddLLVMDefinitions)
 139
 140 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 141
 142 # MSVC has a gazillion warnings with this.
 143 if( MSVC )
 144   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 145 else( MSVC )
 146   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 147 endif()
 148
 149 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 150 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 151
 152 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 153   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 154 else()
 155   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 156 endif()
 157
 158 option(LLVM_USE_INTEL_JITEVENTS
 159   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 160   OFF)
 161
 162 if( LLVM_USE_INTEL_JITEVENTS )
 163   # Verify we are on a supported platform
 164   if( CMAKE_SYSTEM_NAME MATCHES "Windows" OR CMAKE_SYSTEM_NAME MATCHES "Linux" )
 165     # Directory where Intel Parallel Amplifier XE 2011 is installed.
 166     if ( WIN32 )
 167       set(LLVM_INTEL_JITEVENTS_DIR $ENV{VTUNE_AMPLIFIER_XE_2011_DIR})
 168     else ( WIN32 )
 169       set(LLVM_INTEL_JITEVENTS_DIR "/opt/intel/vtune_amplifier_xe_2011")
 170     endif ( WIN32 )
 171
 172     # Set include and library search paths for Intel JIT Events API
 173     set(LLVM_INTEL_JITEVENTS_INCDIR "${LLVM_INTEL_JITEVENTS_DIR}/include")
 174
 175     if ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 176       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib64")
 177     else ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 178       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib32")
 179     endif ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 180   else()
 181     message(FATAL_ERROR
 182       "Intel JIT API support is available on Linux and Windows only.")
 183   endif()
 184 endif( LLVM_USE_INTEL_JITEVENTS )
 185
 186 option(LLVM_USE_OPROFILE
 187   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 188
 189 # If enabled, ierify we are on a platform that supports oprofile.
 190 if( LLVM_USE_OPROFILE )
 191   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 192     message(FATAL_ERROR "OProfile support is available on Linux only.")
 193   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 194 endif( LLVM_USE_OPROFILE )
 195
 196 # Define an option controlling whether we should build for 32-bit on 64-bit
 197 # platforms, where supported.
 198 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 199   # TODO: support other platforms and toolchains.
 200   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 201 endif()
 202
 203 # Define the default arguments to use with 'lit', and an option for the user to
 204 # override.
 205 set(LIT_ARGS_DEFAULT "-sv")
 206 if (MSVC OR XCODE)
 207   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 208 endif()
 209 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 210
 211 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 212 if( WIN32 AND NOT CYGWIN )
 213   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 214 endif()
 215
 216 # Define options to control the inclusion and default build behavior for
 217 # components which may not strictly be necessary (tools, runtime, examples, and
 218 # tests).
 219 #
 220 # This is primarily to support building smaller or faster project files.
 221 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 222 option(LLVM_BUILD_TOOLS
 223   "Build the LLVM tools. If OFF, just generate build targets." ON)
 224
 225 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 226 option(LLVM_BUILD_RUNTIME
 227   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 228
 229 option(LLVM_BUILD_EXAMPLES
 230   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 231 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 232
 233 option(LLVM_BUILD_TESTS
 234   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 235 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 236
 237 # All options referred to from HandleLLVMOptions have to be specified
 238 # BEFORE this include, otherwise options will not be correctly set on
 239 # first cmake run
 240 include(config-ix)
 241 include(HandleLLVMOptions)
 242
 243 # Verify that we can find a Python interpreter,
 244 include(FindPythonInterp)
 245 if( NOT PYTHONINTERP_FOUND )
 246   message(FATAL_ERROR
 247 "Unable to find Python interpreter, required for builds and testing.
 248
 249 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 250 endif()
 251
 252 ######
 253 # LLVMBuild Integration
 254 #
 255 # We use llvm-build to generate all the data required by the CMake based
 256 # build system in one swoop:
 257 #
 258 #  - We generate a file (a CMake fragment) in the object root which contains
 259 #    all the definitions that are required by CMake.
 260 #
 261 #  - We generate the library table used by llvm-config.
 262 #
 263 #  - We generate the dependencies for the CMake fragment, so that we will
 264 #    automatically reconfigure outselves.
 265
 266 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 267 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 268   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 269 set(LLVMBUILDCMAKEFRAG
 270   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 271 message(STATUS "Constructing LLVMBuild project information")
 272 execute_process(
 273   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 274             --native-target "${LLVM_NATIVE_ARCH}"
 275             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 276             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 277             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 278             ERROR_VARIABLE LLVMBUILDOUTPUT
 279             ERROR_VARIABLE LLVMBUILDERRORS
 280             OUTPUT_STRIP_TRAILING_WHITESPACE
 281             ERROR_STRIP_TRAILING_WHITESPACE
 282   RESULT_VARIABLE LLVMBUILDRESULT)
 283
 284 # On Win32, CMake doesn't properly handle piping the default output/error
 285 # streams into the GUI console. So, we explicitly catch and report them.
 286 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 287   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 288 endif()
 289 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 290   message(FATAL_ERROR
 291     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 292 endif()
 293
 294 # Include the generated CMake fragment. This will define properties from the
 295 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 296 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 297 # files change.
 298 include(${LLVMBUILDCMAKEFRAG})
 299
 300 ######
 301
 302 # Configure all of the various header file fragments LLVM uses which depend on
 303 # configuration variables.
 304 set(LLVM_ENUM_ASM_PRINTERS "")
 305 set(LLVM_ENUM_ASM_PARSERS "")
 306 set(LLVM_ENUM_DISASSEMBLERS "")
 307 foreach(t ${LLVM_TARGETS_TO_BUILD})
 308   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 309   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 310   if( asmp_file )
 311     set(LLVM_ENUM_ASM_PRINTERS
 312       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 313   endif()
 314   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 315     set(LLVM_ENUM_ASM_PARSERS
 316       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 317   endif()
 318   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 319     set(LLVM_ENUM_DISASSEMBLERS
 320       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 321   endif()
 322 endforeach(t)
 323
 324 # Produce the target definition files, which provide a way for clients to easily
 325 # include various classes of targets.
 326 configure_file(
 327   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 328   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 329   )
 330 configure_file(
 331   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 332   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 333   )
 334 configure_file(
 335   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 336   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 337   )
 338 configure_file(
 339   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 340   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 341   )
 342
 343 # Configure the three LLVM configuration header files.
 344 configure_file(
 345   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 346   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 347 configure_file(
 348   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 349   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 350 configure_file(
 351   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 352   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 353
 354 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 355 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 356 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 357
 358 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 359
 360 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 361
 362 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 363    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 364 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 365
 366 include(AddLLVM)
 367 include(TableGen)
 368
 369 if( MINGW )
 370   # People report that -O3 is unreliable on MinGW. The traditional
 371   # build also uses -O2 for that reason:
 372   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 373 endif()
 374
 375 # Put this before tblgen. Else we have a circular dependence.
 376 add_subdirectory(lib/Support)
 377 add_subdirectory(lib/TableGen)
 378
 379 add_subdirectory(utils/TableGen)
 380
 381 add_subdirectory(include/llvm)
 382
 383 add_subdirectory(lib)
 384
 385 add_subdirectory(utils/FileCheck)
 386 add_subdirectory(utils/FileUpdate)
 387 add_subdirectory(utils/count)
 388 add_subdirectory(utils/not)
 389 add_subdirectory(utils/llvm-lit)
 390 add_subdirectory(utils/yaml-bench)
 391
 392 add_subdirectory(projects)
 393
 394 if( LLVM_INCLUDE_TOOLS )
 395   add_subdirectory(tools)
 396 endif()
 397
 398 if( LLVM_INCLUDE_RUNTIME )
 399   add_subdirectory(runtime)
 400 endif()
 401
 402 if( LLVM_INCLUDE_EXAMPLES )
 403   add_subdirectory(examples)
 404 endif()
 405
 406 if( LLVM_INCLUDE_TESTS )
 407   add_subdirectory(test)
 408   add_subdirectory(utils/unittest)
 409   add_subdirectory(unittests)
 410   if (MSVC)
 411     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 412     # Windows.
 413     add_subdirectory(utils/KillTheDoctor)
 414   endif()
 415 endif()
 416
 417 add_subdirectory(cmake/modules)
 418
 419 install(DIRECTORY include/
 420   DESTINATION include
 421   FILES_MATCHING
 422   PATTERN "*.def"
 423   PATTERN "*.h"
 424   PATTERN "*.td"
 425   PATTERN "*.inc"
 426   PATTERN "LICENSE.TXT"
 427   PATTERN ".svn" EXCLUDE
 428   )
 429
 430 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 431   DESTINATION include
 432   FILES_MATCHING
 433   PATTERN "*.def"
 434   PATTERN "*.h"
 435   PATTERN "*.gen"
 436   PATTERN "*.inc"
 437   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 438   PATTERN "CMakeFiles" EXCLUDE
 439   PATTERN ".svn" EXCLUDE
 440   )
 441
 442 # TODO: make and install documentation.
 443
 444 set(CPACK_PACKAGE_VENDOR "LLVM")
 445 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 446 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 447 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 448 include(CPack)
 449
 450 # Workaround for MSVS10 to avoid the Dialog Hell
 451 # FIXME: This could be removed with future version of CMake.
 452 if(MSVC_VERSION EQUAL 1600)
 453   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 454   if( EXISTS "${LLVM_SLN_FILENAME}" )
 455     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 456   endif()
 457 endif()