CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 # FIXME: It may be removed when we use 2.8.12.
   6 if(CMAKE_VERSION VERSION_LESS 2.8.12)
   7   # Invalidate a couple of keywords.
   8   set(cmake_2_8_12_INTERFACE)
   9   set(cmake_2_8_12_PRIVATE)
  10 else()
  11   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  12   set(cmake_2_8_12_INTERFACE INTERFACE)
  13   set(cmake_2_8_12_PRIVATE PRIVATE)
  14   if(POLICY CMP0022)
  15     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  16   endif()
  17 endif()
  18
  19 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  20   set(cmake_3_2_USES_TERMINAL)
  21 else()
  22   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  23 endif()
  24
  25 project(LLVM)
  26
  27 # The following only works with the Ninja generator in CMake >= 3.0.
  28 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  29   "Define the maximum number of concurrent compilation jobs.")
  30 if(LLVM_PARALLEL_COMPILE_JOBS)
  31   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  32   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  33 endif()
  34
  35 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  36   "Define the maximum number of concurrent link jobs.")
  37 if(LLVM_PARALLEL_LINK_JOBS)
  38   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  39   set(CMAKE_JOB_POOL_LINK link_job_pool)
  40 endif()
  41
  42 # Add path for custom modules
  43 set(CMAKE_MODULE_PATH
  44   ${CMAKE_MODULE_PATH}
  45   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  46   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  47   )
  48
  49 set(LLVM_VERSION_MAJOR 3)
  50 set(LLVM_VERSION_MINOR 6)
  51 set(LLVM_VERSION_PATCH 0)
  52
  53 if (NOT PACKAGE_VERSION)
  54   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  55 endif()
  56
  57 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  58
  59 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  60 if ( LLVM_USE_FOLDERS )
  61   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  62 endif()
  63
  64 include(VersionFromVCS)
  65
  66 option(LLVM_APPEND_VC_REV
  67   "Append the version control system revision id to LLVM version" OFF)
  68
  69 if( LLVM_APPEND_VC_REV )
  70   add_version_info_from_vcs(PACKAGE_VERSION)
  71 endif()
  72
  73 set(PACKAGE_NAME LLVM)
  74 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  75 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  76
  77 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  78   "Default URL where bug reports are to be submitted.")
  79
  80 # Configure CPack.
  81 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  82 set(CPACK_PACKAGE_VENDOR "LLVM")
  83 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  84 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  85 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  86 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  87 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  88 if(WIN32 AND NOT UNIX)
  89   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  90   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  91   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  92   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  93   set(CPACK_NSIS_MODIFY_PATH "ON")
  94   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  95   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  96     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  97   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  98     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  99 endif()
 100 include(CPack)
 101
 102 # Sanity check our source directory to make sure that we are not trying to
 103 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 104 # sure that we don't have any stray generated files lying around in the tree
 105 # (which would end up getting picked up by header search, instead of the correct
 106 # versions).
 107 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 108   message(FATAL_ERROR "In-source builds are not allowed.
 109 CMake would overwrite the makefiles distributed with LLVM.
 110 Please create a directory and run cmake from there, passing the path
 111 to this source directory as the last argument.
 112 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 113 Please delete them.")
 114 endif()
 115 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 116   file(GLOB_RECURSE
 117     tablegenned_files_on_include_dir
 118     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 119   file(GLOB_RECURSE
 120     tablegenned_files_on_lib_dir
 121     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 122   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 123     message(FATAL_ERROR "Apparently there is a previous in-source build,
 124 probably as the result of running `configure' and `make' on
 125 ${CMAKE_CURRENT_SOURCE_DIR}.
 126 This may cause problems. The suspicious files are:
 127 ${tablegenned_files_on_lib_dir}
 128 ${tablegenned_files_on_include_dir}
 129 Please clean the source directory.")
 130   endif()
 131 endif()
 132
 133 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 134
 135 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 136
 137 # They are used as destination of target generators.
 138 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 139 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 140 if(WIN32 OR CYGWIN)
 141   # DLL platform -- put DLLs into bin.
 142   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 143 else()
 144   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 145 endif()
 146
 147 # Each of them corresponds to llvm-config's.
 148 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 149 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 150 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 151 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 152 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 153
 154 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 155 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 156
 157 set(LLVM_ALL_TARGETS
 158   AArch64
 159   ARM
 160   CppBackend
 161   Hexagon
 162   Mips
 163   MSP430
 164   NVPTX
 165   PowerPC
 166   R600
 167   Sparc
 168   SystemZ
 169   X86
 170   XCore
 171   )
 172
 173 # List of targets with JIT support:
 174 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 175
 176 set(LLVM_TARGETS_TO_BUILD "all"
 177     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 178
 179 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 180   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 181
 182 option(BUILD_SHARED_LIBS
 183   "Build all libraries as shared libraries instead of static" OFF)
 184
 185 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 186 if(LLVM_ENABLE_TIMESTAMPS)
 187   set(ENABLE_TIMESTAMPS 1)
 188 endif()
 189
 190 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 191 if(LLVM_ENABLE_BACKTRACES)
 192   set(ENABLE_BACKTRACES 1)
 193 endif()
 194
 195 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 196 if(LLVM_ENABLE_CRASH_OVERRIDES)
 197   set(ENABLE_CRASH_OVERRIDES 1)
 198 endif()
 199
 200 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 201 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 202 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 203
 204 set(LLVM_TARGET_ARCH "host"
 205   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 206
 207 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 208
 209 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 210
 211 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 212
 213 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 214   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 215 endif()
 216
 217 set(LLVM_TARGETS_TO_BUILD
 218    ${LLVM_TARGETS_TO_BUILD}
 219    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 220 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 221
 222 include(AddLLVMDefinitions)
 223
 224 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 225
 226 # MSVC has a gazillion warnings with this.
 227 if( MSVC )
 228   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 229 else()
 230   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 231 endif()
 232
 233 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 234 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 235 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 236 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 237 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 238
 239 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 240   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 241 else()
 242   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 243 endif()
 244
 245 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 246        "Set to ON to force using an old, unsupported host toolchain." OFF)
 247
 248 option(LLVM_USE_INTEL_JITEVENTS
 249   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 250   OFF)
 251
 252 if( LLVM_USE_INTEL_JITEVENTS )
 253   # Verify we are on a supported platform
 254   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 255     message(FATAL_ERROR
 256       "Intel JIT API support is available on Linux and Windows only.")
 257   endif()
 258 endif( LLVM_USE_INTEL_JITEVENTS )
 259
 260 option(LLVM_USE_OPROFILE
 261   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 262
 263 # If enabled, verify we are on a platform that supports oprofile.
 264 if( LLVM_USE_OPROFILE )
 265   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 266     message(FATAL_ERROR "OProfile support is available on Linux only.")
 267   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 268 endif( LLVM_USE_OPROFILE )
 269
 270 set(LLVM_USE_SANITIZER "" CACHE STRING
 271   "Define the sanitizer used to build binaries and tests.")
 272
 273 option(LLVM_USE_SPLIT_DWARF
 274   "Use -gsplit-dwarf when compiling llvm." OFF)
 275
 276 option(WITH_POLLY "Build LLVM with Polly" ON)
 277 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 278
 279 # Define an option controlling whether we should build for 32-bit on 64-bit
 280 # platforms, where supported.
 281 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 282   # TODO: support other platforms and toolchains.
 283   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 284 endif()
 285
 286 # Define the default arguments to use with 'lit', and an option for the user to
 287 # override.
 288 set(LIT_ARGS_DEFAULT "-sv")
 289 if (MSVC OR XCODE)
 290   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 291 endif()
 292 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 293
 294 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 295 if( WIN32 AND NOT CYGWIN )
 296   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 297 endif()
 298
 299 # Define options to control the inclusion and default build behavior for
 300 # components which may not strictly be necessary (tools, examples, and tests).
 301 #
 302 # This is primarily to support building smaller or faster project files.
 303 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 304 option(LLVM_BUILD_TOOLS
 305   "Build the LLVM tools. If OFF, just generate build targets." ON)
 306
 307 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 308
 309 option(LLVM_BUILD_RUNTIME
 310   "Build the LLVM runtime libraries." ON)
 311 option(LLVM_BUILD_EXAMPLES
 312   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 313 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 314
 315 option(LLVM_BUILD_TESTS
 316   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 317 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 318
 319 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 320 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 321 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 322 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 323
 324 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 325   "Build compiler-rt as an external project." OFF)
 326
 327 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 328 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 329 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 330   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 331 endif()
 332
 333 # All options referred to from HandleLLVMOptions have to be specified
 334 # BEFORE this include, otherwise options will not be correctly set on
 335 # first cmake run
 336 include(config-ix)
 337
 338 # By default, we target the host, but this can be overridden at CMake
 339 # invocation time.
 340 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 341   "Default target for which LLVM will generate code." )
 342 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 343
 344 include(HandleLLVMOptions)
 345
 346 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 347 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 348 include(FindPythonInterp)
 349 if( NOT PYTHONINTERP_FOUND )
 350   message(FATAL_ERROR
 351 "Unable to find Python interpreter, required for builds and testing.
 352
 353 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 354 endif()
 355
 356 ######
 357 # LLVMBuild Integration
 358 #
 359 # We use llvm-build to generate all the data required by the CMake based
 360 # build system in one swoop:
 361 #
 362 #  - We generate a file (a CMake fragment) in the object root which contains
 363 #    all the definitions that are required by CMake.
 364 #
 365 #  - We generate the library table used by llvm-config.
 366 #
 367 #  - We generate the dependencies for the CMake fragment, so that we will
 368 #    automatically reconfigure outselves.
 369
 370 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 371 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 372   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 373 set(LLVMBUILDCMAKEFRAG
 374   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 375
 376 # Create the list of optional components that are enabled
 377 if (LLVM_USE_INTEL_JITEVENTS)
 378   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 379 endif (LLVM_USE_INTEL_JITEVENTS)
 380 if (LLVM_USE_OPROFILE)
 381   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 382 endif (LLVM_USE_OPROFILE)
 383
 384 message(STATUS "Constructing LLVMBuild project information")
 385 execute_process(
 386   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 387             --native-target "${LLVM_NATIVE_ARCH}"
 388             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 389             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 390             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 391             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 392             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 393             ERROR_VARIABLE LLVMBUILDERRORS
 394             OUTPUT_STRIP_TRAILING_WHITESPACE
 395             ERROR_STRIP_TRAILING_WHITESPACE
 396   RESULT_VARIABLE LLVMBUILDRESULT)
 397
 398 # On Win32, CMake doesn't properly handle piping the default output/error
 399 # streams into the GUI console. So, we explicitly catch and report them.
 400 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 401   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 402 endif()
 403 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 404   message(FATAL_ERROR
 405     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 406 endif()
 407
 408 # Include the generated CMake fragment. This will define properties from the
 409 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 410 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 411 # files change.
 412 include(${LLVMBUILDCMAKEFRAG})
 413
 414 ######
 415
 416 # Configure all of the various header file fragments LLVM uses which depend on
 417 # configuration variables.
 418 set(LLVM_ENUM_TARGETS "")
 419 set(LLVM_ENUM_ASM_PRINTERS "")
 420 set(LLVM_ENUM_ASM_PARSERS "")
 421 set(LLVM_ENUM_DISASSEMBLERS "")
 422 foreach(t ${LLVM_TARGETS_TO_BUILD})
 423   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 424
 425   list(FIND LLVM_ALL_TARGETS ${t} idx)
 426   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 427   if( idx LESS 0 AND idy LESS 0 )
 428     message(FATAL_ERROR "The target `${t}' does not exist.
 429     It should be one of\n${LLVM_ALL_TARGETS}")
 430   else()
 431     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 432   endif()
 433
 434   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 435   if( asmp_file )
 436     set(LLVM_ENUM_ASM_PRINTERS
 437       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 438   endif()
 439   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 440     set(LLVM_ENUM_ASM_PARSERS
 441       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 442   endif()
 443   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 444     set(LLVM_ENUM_DISASSEMBLERS
 445       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 446   endif()
 447 endforeach(t)
 448
 449 # Produce the target definition files, which provide a way for clients to easily
 450 # include various classes of targets.
 451 configure_file(
 452   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 453   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 454   )
 455 configure_file(
 456   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 457   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 458   )
 459 configure_file(
 460   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 461   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 462   )
 463 configure_file(
 464   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 465   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 466   )
 467
 468 # Configure the three LLVM configuration header files.
 469 configure_file(
 470   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 471   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 472 configure_file(
 473   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 474   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 475 configure_file(
 476   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 477   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 478
 479 # They are not referenced. See set_output_directory().
 480 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 481 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 482 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 483
 484 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 485 if (APPLE)
 486   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 487   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 488 else(UNIX)
 489   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 490     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 491     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 492       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 493       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 494     endif()
 495   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 496 endif()
 497
 498 # Work around a broken bfd ld behavior. When linking a binary with a
 499 # foo.so library, it will try to find any library that foo.so uses and
 500 # check its symbols. This is wasteful (the check was done when foo.so
 501 # was created) and can fail since it is not the dynamic linker and
 502 # doesn't know how to handle search paths correctly.
 503 if (UNIX AND NOT APPLE)
 504   set(CMAKE_EXE_LINKER_FLAGS
 505       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 506 endif()
 507
 508 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 509
 510 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 511
 512 # when crosscompiling import the executable targets from a file
 513 if(CMAKE_CROSSCOMPILING)
 514   include(CrossCompile)
 515 endif(CMAKE_CROSSCOMPILING)
 516
 517 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 518   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 519   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 520   include_directories("/usr/local/include")
 521   link_directories("/usr/local/lib")
 522 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 523
 524 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 525    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 526 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 527
 528 # Make sure we don't get -rdynamic in every binary. For those that need it,
 529 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 530 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 531
 532 include(AddLLVM)
 533 include(TableGen)
 534
 535 if( MINGW )
 536   # People report that -O3 is unreliable on MinGW. The traditional
 537   # build also uses -O2 for that reason:
 538   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 539 endif()
 540
 541 # Put this before tblgen. Else we have a circular dependence.
 542 add_subdirectory(lib/Support)
 543 add_subdirectory(lib/TableGen)
 544
 545 add_subdirectory(utils/TableGen)
 546
 547 add_subdirectory(include/llvm)
 548
 549 add_subdirectory(lib)
 550
 551 if( LLVM_INCLUDE_UTILS )
 552   add_subdirectory(utils/FileCheck)
 553   add_subdirectory(utils/PerfectShuffle)
 554   add_subdirectory(utils/count)
 555   add_subdirectory(utils/not)
 556   add_subdirectory(utils/llvm-lit)
 557   add_subdirectory(utils/yaml-bench)
 558 else()
 559   if ( LLVM_INCLUDE_TESTS )
 560     message(FATAL_ERROR "Including tests when not building utils will not work.
 561     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 562   endif()
 563 endif()
 564
 565 if(LLVM_INCLUDE_TESTS)
 566   add_subdirectory(utils/unittest)
 567 endif()
 568
 569 foreach( binding ${LLVM_BINDINGS_LIST} )
 570   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 571     add_subdirectory(bindings/${binding})
 572   endif()
 573 endforeach()
 574
 575 add_subdirectory(projects)
 576
 577 if(WITH_POLLY)
 578   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 579     set(WITH_POLLY OFF)
 580   endif()
 581 endif(WITH_POLLY)
 582
 583 if( LLVM_INCLUDE_TOOLS )
 584   add_subdirectory(tools)
 585 endif()
 586
 587 if( LLVM_INCLUDE_EXAMPLES )
 588   add_subdirectory(examples)
 589 endif()
 590
 591 if( LLVM_INCLUDE_TESTS )
 592   add_subdirectory(test)
 593   add_subdirectory(unittests)
 594   if (MSVC)
 595     # This utility is used to prevent crashing tests from calling Dr. Watson on
 596     # Windows.
 597     add_subdirectory(utils/KillTheDoctor)
 598   endif()
 599
 600   # Add a global check rule now that all subdirectories have been traversed
 601   # and we know the total set of lit testsuites.
 602   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 603   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 604   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 605   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 606   add_lit_target(check-all
 607     "Running all regression tests"
 608     ${LLVM_LIT_TESTSUITES}
 609     PARAMS ${LLVM_LIT_PARAMS}
 610     DEPENDS ${LLVM_LIT_DEPENDS}
 611     ARGS ${LLVM_LIT_EXTRA_ARGS}
 612     )
 613 endif()
 614
 615 if (LLVM_INCLUDE_DOCS)
 616   add_subdirectory(docs)
 617 endif()
 618
 619 add_subdirectory(cmake/modules)
 620
 621 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 622   install(DIRECTORY include/llvm include/llvm-c
 623     DESTINATION include
 624     FILES_MATCHING
 625     PATTERN "*.def"
 626     PATTERN "*.h"
 627     PATTERN "*.td"
 628     PATTERN "*.inc"
 629     PATTERN "LICENSE.TXT"
 630     PATTERN ".svn" EXCLUDE
 631     )
 632
 633   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 634     DESTINATION include
 635     FILES_MATCHING
 636     PATTERN "*.def"
 637     PATTERN "*.h"
 638     PATTERN "*.gen"
 639     PATTERN "*.inc"
 640     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 641     PATTERN "CMakeFiles" EXCLUDE
 642     PATTERN "config.h" EXCLUDE
 643     PATTERN ".svn" EXCLUDE
 644     )
 645 endif()