CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
   6   set(cmake_3_2_USES_TERMINAL)
   7 else()
   8   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
   9 endif()
  10
  11 project(LLVM)
  12
  13 # The following only works with the Ninja generator in CMake >= 3.0.
  14 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  15   "Define the maximum number of concurrent compilation jobs.")
  16 if(LLVM_PARALLEL_COMPILE_JOBS)
  17   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  18   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  19 endif()
  20
  21 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  22   "Define the maximum number of concurrent link jobs.")
  23 if(LLVM_PARALLEL_LINK_JOBS)
  24   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  25   set(CMAKE_JOB_POOL_LINK link_job_pool)
  26 endif()
  27
  28 # Add path for custom modules
  29 set(CMAKE_MODULE_PATH
  30   ${CMAKE_MODULE_PATH}
  31   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  32   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  33   )
  34
  35 set(LLVM_VERSION_MAJOR 3)
  36 set(LLVM_VERSION_MINOR 7)
  37 set(LLVM_VERSION_PATCH 0)
  38
  39 if (NOT PACKAGE_VERSION)
  40   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  41 endif()
  42
  43 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  44
  45 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  46 if ( LLVM_USE_FOLDERS )
  47   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  48 endif()
  49
  50 include(VersionFromVCS)
  51
  52 option(LLVM_APPEND_VC_REV
  53   "Append the version control system revision id to LLVM version" OFF)
  54
  55 if( LLVM_APPEND_VC_REV )
  56   add_version_info_from_vcs(PACKAGE_VERSION)
  57 endif()
  58
  59 set(PACKAGE_NAME LLVM)
  60 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  61 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  62
  63 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  64   "Default URL where bug reports are to be submitted.")
  65
  66 # Configure CPack.
  67 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  68 set(CPACK_PACKAGE_VENDOR "LLVM")
  69 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  70 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  71 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  72 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  73 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  74 if(WIN32 AND NOT UNIX)
  75   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  76   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  77   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  78   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  79   set(CPACK_NSIS_MODIFY_PATH "ON")
  80   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  81   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  82     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  83   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  84     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  85   if( CMAKE_CL_64 )
  86     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
  87   endif()
  88 endif()
  89 include(CPack)
  90
  91 # Sanity check our source directory to make sure that we are not trying to
  92 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  93 # sure that we don't have any stray generated files lying around in the tree
  94 # (which would end up getting picked up by header search, instead of the correct
  95 # versions).
  96 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  97   message(FATAL_ERROR "In-source builds are not allowed.
  98 CMake would overwrite the makefiles distributed with LLVM.
  99 Please create a directory and run cmake from there, passing the path
 100 to this source directory as the last argument.
 101 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 102 Please delete them.")
 103 endif()
 104 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 105   file(GLOB_RECURSE
 106     tablegenned_files_on_include_dir
 107     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 108   file(GLOB_RECURSE
 109     tablegenned_files_on_lib_dir
 110     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 111   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 112     message(FATAL_ERROR "Apparently there is a previous in-source build,
 113 probably as the result of running `configure' and `make' on
 114 ${CMAKE_CURRENT_SOURCE_DIR}.
 115 This may cause problems. The suspicious files are:
 116 ${tablegenned_files_on_lib_dir}
 117 ${tablegenned_files_on_include_dir}
 118 Please clean the source directory.")
 119   endif()
 120 endif()
 121
 122 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 123
 124 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 125
 126 # They are used as destination of target generators.
 127 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 128 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 129 if(WIN32 OR CYGWIN)
 130   # DLL platform -- put DLLs into bin.
 131   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 132 else()
 133   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 134 endif()
 135
 136 # Each of them corresponds to llvm-config's.
 137 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 138 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 139 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 140 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 141 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 142
 143 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 144 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 145
 146 set(LLVM_ALL_TARGETS
 147   AArch64
 148   ARM
 149   CppBackend
 150   Hexagon
 151   Mips
 152   MSP430
 153   NVPTX
 154   PowerPC
 155   R600
 156   Sparc
 157   SystemZ
 158   X86
 159   XCore
 160   )
 161
 162 # List of targets with JIT support:
 163 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 164
 165 set(LLVM_TARGETS_TO_BUILD "all"
 166     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 167
 168 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 169   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 170
 171 option(BUILD_SHARED_LIBS
 172   "Build all libraries as shared libraries instead of static" OFF)
 173
 174 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 175 if(LLVM_ENABLE_TIMESTAMPS)
 176   set(ENABLE_TIMESTAMPS 1)
 177 endif()
 178
 179 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 180 if(LLVM_ENABLE_BACKTRACES)
 181   set(ENABLE_BACKTRACES 1)
 182 endif()
 183
 184 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 185 if(LLVM_ENABLE_CRASH_OVERRIDES)
 186   set(ENABLE_CRASH_OVERRIDES 1)
 187 endif()
 188
 189 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 190 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 191 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 192
 193 set(LLVM_TARGET_ARCH "host"
 194   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 195
 196 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 197
 198 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 199
 200 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 201
 202 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 203   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 204 endif()
 205
 206 set(LLVM_TARGETS_TO_BUILD
 207    ${LLVM_TARGETS_TO_BUILD}
 208    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 209 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 210
 211 include(AddLLVMDefinitions)
 212
 213 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 214
 215 # MSVC has a gazillion warnings with this.
 216 if( MSVC )
 217   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 218 else()
 219   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 220 endif()
 221
 222 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 223 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 224 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 225 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 226 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 227
 228 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 229   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 230 else()
 231   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 232 endif()
 233
 234 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 235        "Set to ON to force using an old, unsupported host toolchain." OFF)
 236
 237 option(LLVM_USE_INTEL_JITEVENTS
 238   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 239   OFF)
 240
 241 if( LLVM_USE_INTEL_JITEVENTS )
 242   # Verify we are on a supported platform
 243   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 244     message(FATAL_ERROR
 245       "Intel JIT API support is available on Linux and Windows only.")
 246   endif()
 247 endif( LLVM_USE_INTEL_JITEVENTS )
 248
 249 option(LLVM_USE_OPROFILE
 250   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 251
 252 # If enabled, verify we are on a platform that supports oprofile.
 253 if( LLVM_USE_OPROFILE )
 254   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 255     message(FATAL_ERROR "OProfile support is available on Linux only.")
 256   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 257 endif( LLVM_USE_OPROFILE )
 258
 259 set(LLVM_USE_SANITIZER "" CACHE STRING
 260   "Define the sanitizer used to build binaries and tests.")
 261
 262 option(LLVM_USE_SPLIT_DWARF
 263   "Use -gsplit-dwarf when compiling llvm." OFF)
 264
 265 option(WITH_POLLY "Build LLVM with Polly" ON)
 266 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 267
 268 # Define an option controlling whether we should build for 32-bit on 64-bit
 269 # platforms, where supported.
 270 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 271   # TODO: support other platforms and toolchains.
 272   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 273 endif()
 274
 275 # Define the default arguments to use with 'lit', and an option for the user to
 276 # override.
 277 set(LIT_ARGS_DEFAULT "-sv")
 278 if (MSVC OR XCODE)
 279   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 280 endif()
 281 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 282
 283 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 284 if( WIN32 AND NOT CYGWIN )
 285   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 286 endif()
 287
 288 # Define options to control the inclusion and default build behavior for
 289 # components which may not strictly be necessary (tools, examples, and tests).
 290 #
 291 # This is primarily to support building smaller or faster project files.
 292 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 293 option(LLVM_BUILD_TOOLS
 294   "Build the LLVM tools. If OFF, just generate build targets." ON)
 295
 296 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 297
 298 option(LLVM_BUILD_RUNTIME
 299   "Build the LLVM runtime libraries." ON)
 300 option(LLVM_BUILD_EXAMPLES
 301   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 302 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 303
 304 option(LLVM_BUILD_TESTS
 305   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 306 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 307
 308 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 309 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 310 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 311 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 312
 313 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 314   "Build compiler-rt as an external project." OFF)
 315
 316 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 317 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 318 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 319   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 320 endif()
 321
 322 # All options referred to from HandleLLVMOptions have to be specified
 323 # BEFORE this include, otherwise options will not be correctly set on
 324 # first cmake run
 325 include(config-ix)
 326
 327 # By default, we target the host, but this can be overridden at CMake
 328 # invocation time.
 329 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 330   "Default target for which LLVM will generate code." )
 331 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 332
 333 include(HandleLLVMOptions)
 334
 335 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 336 # FIXME: We should support systems with only Python 3, but that requires work
 337 # on LLDB.
 338 set(Python_ADDITIONAL_VERSIONS 2.7)
 339 include(FindPythonInterp)
 340 if( NOT PYTHONINTERP_FOUND )
 341   message(FATAL_ERROR
 342 "Unable to find Python interpreter, required for builds and testing.
 343
 344 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 345 endif()
 346
 347 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 348   message(FATAL_ERROR "Python 2.7 or newer is required")
 349 endif()
 350
 351 ######
 352 # LLVMBuild Integration
 353 #
 354 # We use llvm-build to generate all the data required by the CMake based
 355 # build system in one swoop:
 356 #
 357 #  - We generate a file (a CMake fragment) in the object root which contains
 358 #    all the definitions that are required by CMake.
 359 #
 360 #  - We generate the library table used by llvm-config.
 361 #
 362 #  - We generate the dependencies for the CMake fragment, so that we will
 363 #    automatically reconfigure outselves.
 364
 365 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 366 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 367   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 368 set(LLVMBUILDCMAKEFRAG
 369   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 370
 371 # Create the list of optional components that are enabled
 372 if (LLVM_USE_INTEL_JITEVENTS)
 373   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 374 endif (LLVM_USE_INTEL_JITEVENTS)
 375 if (LLVM_USE_OPROFILE)
 376   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 377 endif (LLVM_USE_OPROFILE)
 378
 379 message(STATUS "Constructing LLVMBuild project information")
 380 execute_process(
 381   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 382             --native-target "${LLVM_NATIVE_ARCH}"
 383             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 384             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 385             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 386             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 387             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 388             ERROR_VARIABLE LLVMBUILDERRORS
 389             OUTPUT_STRIP_TRAILING_WHITESPACE
 390             ERROR_STRIP_TRAILING_WHITESPACE
 391   RESULT_VARIABLE LLVMBUILDRESULT)
 392
 393 # On Win32, CMake doesn't properly handle piping the default output/error
 394 # streams into the GUI console. So, we explicitly catch and report them.
 395 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 396   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 397 endif()
 398 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 399   message(FATAL_ERROR
 400     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 401 endif()
 402
 403 # Include the generated CMake fragment. This will define properties from the
 404 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 405 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 406 # files change.
 407 include(${LLVMBUILDCMAKEFRAG})
 408
 409 ######
 410
 411 # Configure all of the various header file fragments LLVM uses which depend on
 412 # configuration variables.
 413 set(LLVM_ENUM_TARGETS "")
 414 set(LLVM_ENUM_ASM_PRINTERS "")
 415 set(LLVM_ENUM_ASM_PARSERS "")
 416 set(LLVM_ENUM_DISASSEMBLERS "")
 417 foreach(t ${LLVM_TARGETS_TO_BUILD})
 418   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 419
 420   list(FIND LLVM_ALL_TARGETS ${t} idx)
 421   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 422   if( idx LESS 0 AND idy LESS 0 )
 423     message(FATAL_ERROR "The target `${t}' does not exist.
 424     It should be one of\n${LLVM_ALL_TARGETS}")
 425   else()
 426     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 427   endif()
 428
 429   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 430   if( asmp_file )
 431     set(LLVM_ENUM_ASM_PRINTERS
 432       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 433   endif()
 434   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 435     set(LLVM_ENUM_ASM_PARSERS
 436       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 437   endif()
 438   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 439     set(LLVM_ENUM_DISASSEMBLERS
 440       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 441   endif()
 442 endforeach(t)
 443
 444 # Produce the target definition files, which provide a way for clients to easily
 445 # include various classes of targets.
 446 configure_file(
 447   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 448   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 449   )
 450 configure_file(
 451   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 452   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 453   )
 454 configure_file(
 455   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 456   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 457   )
 458 configure_file(
 459   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 460   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 461   )
 462
 463 # Configure the three LLVM configuration header files.
 464 configure_file(
 465   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 466   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 467 configure_file(
 468   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 469   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 470 configure_file(
 471   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 472   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 473
 474 # They are not referenced. See set_output_directory().
 475 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 476 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 477 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 478
 479 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 480 if (APPLE)
 481   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 482   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 483 else(UNIX)
 484   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 485     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 486     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 487       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 488       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 489     endif()
 490   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 491 endif()
 492
 493 # Work around a broken bfd ld behavior. When linking a binary with a
 494 # foo.so library, it will try to find any library that foo.so uses and
 495 # check its symbols. This is wasteful (the check was done when foo.so
 496 # was created) and can fail since it is not the dynamic linker and
 497 # doesn't know how to handle search paths correctly.
 498 if (UNIX AND NOT APPLE)
 499   set(CMAKE_EXE_LINKER_FLAGS
 500       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 501 endif()
 502
 503 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 504
 505 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 506
 507 # when crosscompiling import the executable targets from a file
 508 if(CMAKE_CROSSCOMPILING)
 509   include(CrossCompile)
 510 endif(CMAKE_CROSSCOMPILING)
 511
 512 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 513   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 514   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 515   include_directories("/usr/local/include")
 516   link_directories("/usr/local/lib")
 517 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 518
 519 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 520    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 521 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 522
 523 # Make sure we don't get -rdynamic in every binary. For those that need it,
 524 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 525 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 526
 527 include(AddLLVM)
 528 include(TableGen)
 529
 530 if( MINGW )
 531   # People report that -O3 is unreliable on MinGW. The traditional
 532   # build also uses -O2 for that reason:
 533   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 534 endif()
 535
 536 # Put this before tblgen. Else we have a circular dependence.
 537 add_subdirectory(lib/Support)
 538 add_subdirectory(lib/TableGen)
 539
 540 add_subdirectory(utils/TableGen)
 541
 542 add_subdirectory(include/llvm)
 543
 544 add_subdirectory(lib)
 545
 546 if( LLVM_INCLUDE_UTILS )
 547   add_subdirectory(utils/FileCheck)
 548   add_subdirectory(utils/PerfectShuffle)
 549   add_subdirectory(utils/count)
 550   add_subdirectory(utils/not)
 551   add_subdirectory(utils/llvm-lit)
 552   add_subdirectory(utils/yaml-bench)
 553 else()
 554   if ( LLVM_INCLUDE_TESTS )
 555     message(FATAL_ERROR "Including tests when not building utils will not work.
 556     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 557   endif()
 558 endif()
 559
 560 if(LLVM_INCLUDE_TESTS)
 561   add_subdirectory(utils/unittest)
 562 endif()
 563
 564 foreach( binding ${LLVM_BINDINGS_LIST} )
 565   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 566     add_subdirectory(bindings/${binding})
 567   endif()
 568 endforeach()
 569
 570 add_subdirectory(projects)
 571
 572 if(WITH_POLLY)
 573   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 574     set(WITH_POLLY OFF)
 575   endif()
 576 endif(WITH_POLLY)
 577
 578 if( LLVM_INCLUDE_TOOLS )
 579   add_subdirectory(tools)
 580 endif()
 581
 582 if( LLVM_INCLUDE_EXAMPLES )
 583   add_subdirectory(examples)
 584 endif()
 585
 586 if( LLVM_INCLUDE_TESTS )
 587   add_subdirectory(test)
 588   add_subdirectory(unittests)
 589   if (MSVC)
 590     # This utility is used to prevent crashing tests from calling Dr. Watson on
 591     # Windows.
 592     add_subdirectory(utils/KillTheDoctor)
 593   endif()
 594
 595   # Add a global check rule now that all subdirectories have been traversed
 596   # and we know the total set of lit testsuites.
 597   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 598   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 599   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 600   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 601   add_lit_target(check-all
 602     "Running all regression tests"
 603     ${LLVM_LIT_TESTSUITES}
 604     PARAMS ${LLVM_LIT_PARAMS}
 605     DEPENDS ${LLVM_LIT_DEPENDS}
 606     ARGS ${LLVM_LIT_EXTRA_ARGS}
 607     )
 608 endif()
 609
 610 if (LLVM_INCLUDE_DOCS)
 611   add_subdirectory(docs)
 612 endif()
 613
 614 add_subdirectory(cmake/modules)
 615
 616 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 617   install(DIRECTORY include/llvm include/llvm-c
 618     DESTINATION include
 619     FILES_MATCHING
 620     PATTERN "*.def"
 621     PATTERN "*.h"
 622     PATTERN "*.td"
 623     PATTERN "*.inc"
 624     PATTERN "LICENSE.TXT"
 625     PATTERN ".svn" EXCLUDE
 626     )
 627
 628   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 629     DESTINATION include
 630     FILES_MATCHING
 631     PATTERN "*.def"
 632     PATTERN "*.h"
 633     PATTERN "*.gen"
 634     PATTERN "*.inc"
 635     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 636     PATTERN "CMakeFiles" EXCLUDE
 637     PATTERN "config.h" EXCLUDE
 638     PATTERN ".svn" EXCLUDE
 639     )
 640 endif()