CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 if(POLICY CMP0022)
  11   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  12 endif()
  13
  14 if (POLICY CMP0051)
  15   # CMake 3.1 and higher include generator expressions of the form
  16   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  17   # stripped everywhere that access the SOURCES property, so we just
  18   # defer to the OLD behavior of not including generator expressions
  19   # in the output for now.
  20   cmake_policy(SET CMP0051 OLD)
  21 endif()
  22
  23 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  24   set(cmake_3_2_USES_TERMINAL)
  25 else()
  26   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  27 endif()
  28
  29 project(LLVM)
  30
  31 # The following only works with the Ninja generator in CMake >= 3.0.
  32 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  33   "Define the maximum number of concurrent compilation jobs.")
  34 if(LLVM_PARALLEL_COMPILE_JOBS)
  35   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  36   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  37 endif()
  38
  39 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  40   "Define the maximum number of concurrent link jobs.")
  41 if(LLVM_PARALLEL_LINK_JOBS)
  42   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  43   set(CMAKE_JOB_POOL_LINK link_job_pool)
  44 endif()
  45
  46 # Add path for custom modules
  47 set(CMAKE_MODULE_PATH
  48   ${CMAKE_MODULE_PATH}
  49   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  50   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  51   )
  52
  53 set(LLVM_VERSION_MAJOR 3)
  54 set(LLVM_VERSION_MINOR 7)
  55 set(LLVM_VERSION_PATCH 0)
  56 set(LLVM_VERSION_SUFFIX svn)
  57
  58 if (NOT PACKAGE_VERSION)
  59   set(PACKAGE_VERSION
  60     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  61 endif()
  62
  63 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
  64
  65 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  66
  67 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  68 if ( LLVM_USE_FOLDERS )
  69   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  70 endif()
  71
  72 include(VersionFromVCS)
  73
  74 option(LLVM_APPEND_VC_REV
  75   "Append the version control system revision id to LLVM version" OFF)
  76
  77 if( LLVM_APPEND_VC_REV )
  78   add_version_info_from_vcs(PACKAGE_VERSION)
  79 endif()
  80
  81 set(PACKAGE_NAME LLVM)
  82 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  83 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  84
  85 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  86   "Default URL where bug reports are to be submitted.")
  87
  88 # Configure CPack.
  89 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  90 set(CPACK_PACKAGE_VENDOR "LLVM")
  91 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  92 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  93 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  94 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  95 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  96 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
  97 if(WIN32 AND NOT UNIX)
  98   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  99   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 100   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 101   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 102   set(CPACK_NSIS_MODIFY_PATH "ON")
 103   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 104   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 105     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 106   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 107     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 108   if( CMAKE_CL_64 )
 109     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 110   endif()
 111 endif()
 112 include(CPack)
 113
 114 # Sanity check our source directory to make sure that we are not trying to
 115 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 116 # sure that we don't have any stray generated files lying around in the tree
 117 # (which would end up getting picked up by header search, instead of the correct
 118 # versions).
 119 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 120   message(FATAL_ERROR "In-source builds are not allowed.
 121 CMake would overwrite the makefiles distributed with LLVM.
 122 Please create a directory and run cmake from there, passing the path
 123 to this source directory as the last argument.
 124 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 125 Please delete them.")
 126 endif()
 127 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 128   file(GLOB_RECURSE
 129     tablegenned_files_on_include_dir
 130     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 131   file(GLOB_RECURSE
 132     tablegenned_files_on_lib_dir
 133     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 134   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 135     message(FATAL_ERROR "Apparently there is a previous in-source build,
 136 probably as the result of running `configure' and `make' on
 137 ${CMAKE_CURRENT_SOURCE_DIR}.
 138 This may cause problems. The suspicious files are:
 139 ${tablegenned_files_on_lib_dir}
 140 ${tablegenned_files_on_include_dir}
 141 Please clean the source directory.")
 142   endif()
 143 endif()
 144
 145 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 146
 147 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 148
 149 # They are used as destination of target generators.
 150 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 151 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 152 if(WIN32 OR CYGWIN)
 153   # DLL platform -- put DLLs into bin.
 154   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 155 else()
 156   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 157 endif()
 158
 159 # Each of them corresponds to llvm-config's.
 160 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 161 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 162 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 163 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 164 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 165
 166 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 167 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 168
 169 set(LLVM_ALL_TARGETS
 170   AArch64
 171   ARM
 172   BPF
 173   CppBackend
 174   Hexagon
 175   Mips
 176   MSP430
 177   NVPTX
 178   PowerPC
 179   R600
 180   Sparc
 181   SystemZ
 182   X86
 183   XCore
 184   )
 185
 186 # List of targets with JIT support:
 187 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 188
 189 set(LLVM_TARGETS_TO_BUILD "all"
 190     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 191
 192 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 193   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 194
 195 option(BUILD_SHARED_LIBS
 196   "Build all libraries as shared libraries instead of static" OFF)
 197
 198 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 199 if(LLVM_ENABLE_TIMESTAMPS)
 200   set(ENABLE_TIMESTAMPS 1)
 201 endif()
 202
 203 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 204 if(LLVM_ENABLE_BACKTRACES)
 205   set(ENABLE_BACKTRACES 1)
 206 endif()
 207
 208 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 209 if(LLVM_ENABLE_CRASH_OVERRIDES)
 210   set(ENABLE_CRASH_OVERRIDES 1)
 211 endif()
 212
 213 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 214 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 215 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 216
 217 set(LLVM_TARGET_ARCH "host"
 218   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 219
 220 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 221
 222 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 223
 224 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 225
 226 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 227   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 228 endif()
 229
 230 set(LLVM_TARGETS_TO_BUILD
 231    ${LLVM_TARGETS_TO_BUILD}
 232    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 233 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 234
 235 include(AddLLVMDefinitions)
 236
 237 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 238 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 239 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 240 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 241 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 242 option(LLVM_ENABLE_LIBCXXABI "Use libc++abi when using libc++." OFF)
 243 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 244 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 245
 246 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 247   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 248 else()
 249   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 250 endif()
 251
 252 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 253   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 254
 255 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 256        "Set to ON to force using an old, unsupported host toolchain." OFF)
 257
 258 option(LLVM_USE_INTEL_JITEVENTS
 259   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 260   OFF)
 261
 262 if( LLVM_USE_INTEL_JITEVENTS )
 263   # Verify we are on a supported platform
 264   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 265     message(FATAL_ERROR
 266       "Intel JIT API support is available on Linux and Windows only.")
 267   endif()
 268 endif( LLVM_USE_INTEL_JITEVENTS )
 269
 270 option(LLVM_USE_OPROFILE
 271   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 272
 273 # If enabled, verify we are on a platform that supports oprofile.
 274 if( LLVM_USE_OPROFILE )
 275   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 276     message(FATAL_ERROR "OProfile support is available on Linux only.")
 277   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 278 endif( LLVM_USE_OPROFILE )
 279
 280 set(LLVM_USE_SANITIZER "" CACHE STRING
 281   "Define the sanitizer used to build binaries and tests.")
 282
 283 option(LLVM_USE_SPLIT_DWARF
 284   "Use -gsplit-dwarf when compiling llvm." OFF)
 285
 286 option(WITH_POLLY "Build LLVM with Polly" ON)
 287 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 288
 289 # Define an option controlling whether we should build for 32-bit on 64-bit
 290 # platforms, where supported.
 291 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 292   # TODO: support other platforms and toolchains.
 293   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 294 endif()
 295
 296 # Define the default arguments to use with 'lit', and an option for the user to
 297 # override.
 298 set(LIT_ARGS_DEFAULT "-sv")
 299 if (MSVC OR XCODE)
 300   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 301 endif()
 302 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 303
 304 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 305 if( WIN32 AND NOT CYGWIN )
 306   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 307 endif()
 308
 309 # Define options to control the inclusion and default build behavior for
 310 # components which may not strictly be necessary (tools, examples, and tests).
 311 #
 312 # This is primarily to support building smaller or faster project files.
 313 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 314 option(LLVM_BUILD_TOOLS
 315   "Build the LLVM tools. If OFF, just generate build targets." ON)
 316
 317 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 318
 319 option(LLVM_BUILD_RUNTIME
 320   "Build the LLVM runtime libraries." ON)
 321 option(LLVM_BUILD_EXAMPLES
 322   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 323 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 324
 325 option(LLVM_BUILD_TESTS
 326   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 327 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 328
 329 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 330 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 331 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 332 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 333
 334 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 335   "Build compiler-rt as an external project." OFF)
 336
 337 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 338 option(LLVM_DYLIB_EXPORT_ALL "Export all symbols from libLLVM.dylib (default is C API only" OFF)
 339 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 340 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 341   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 342 endif()
 343
 344 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 345 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 346   set(LLVM_USE_HOST_TOOLS ON)
 347 endif()
 348
 349 # All options referred to from HandleLLVMOptions have to be specified
 350 # BEFORE this include, otherwise options will not be correctly set on
 351 # first cmake run
 352 include(config-ix)
 353
 354 # By default, we target the host, but this can be overridden at CMake
 355 # invocation time.
 356 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 357   "Default target for which LLVM will generate code." )
 358 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 359
 360 include(HandleLLVMOptions)
 361
 362 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 363 # FIXME: We should support systems with only Python 3, but that requires work
 364 # on LLDB.
 365 set(Python_ADDITIONAL_VERSIONS 2.7)
 366 include(FindPythonInterp)
 367 if( NOT PYTHONINTERP_FOUND )
 368   message(FATAL_ERROR
 369 "Unable to find Python interpreter, required for builds and testing.
 370
 371 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 372 endif()
 373
 374 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 375   message(FATAL_ERROR "Python 2.7 or newer is required")
 376 endif()
 377
 378 ######
 379 # LLVMBuild Integration
 380 #
 381 # We use llvm-build to generate all the data required by the CMake based
 382 # build system in one swoop:
 383 #
 384 #  - We generate a file (a CMake fragment) in the object root which contains
 385 #    all the definitions that are required by CMake.
 386 #
 387 #  - We generate the library table used by llvm-config.
 388 #
 389 #  - We generate the dependencies for the CMake fragment, so that we will
 390 #    automatically reconfigure outselves.
 391
 392 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 393 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 394   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 395 set(LLVMBUILDCMAKEFRAG
 396   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 397
 398 # Create the list of optional components that are enabled
 399 if (LLVM_USE_INTEL_JITEVENTS)
 400   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 401 endif (LLVM_USE_INTEL_JITEVENTS)
 402 if (LLVM_USE_OPROFILE)
 403   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 404 endif (LLVM_USE_OPROFILE)
 405
 406 message(STATUS "Constructing LLVMBuild project information")
 407 execute_process(
 408   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 409             --native-target "${LLVM_NATIVE_ARCH}"
 410             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 411             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 412             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 413             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 414             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 415             ERROR_VARIABLE LLVMBUILDERRORS
 416             OUTPUT_STRIP_TRAILING_WHITESPACE
 417             ERROR_STRIP_TRAILING_WHITESPACE
 418   RESULT_VARIABLE LLVMBUILDRESULT)
 419
 420 # On Win32, CMake doesn't properly handle piping the default output/error
 421 # streams into the GUI console. So, we explicitly catch and report them.
 422 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 423   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 424 endif()
 425 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 426   message(FATAL_ERROR
 427     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 428 endif()
 429
 430 # Include the generated CMake fragment. This will define properties from the
 431 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 432 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 433 # files change.
 434 include(${LLVMBUILDCMAKEFRAG})
 435
 436 ######
 437
 438 # Configure all of the various header file fragments LLVM uses which depend on
 439 # configuration variables.
 440 set(LLVM_ENUM_TARGETS "")
 441 set(LLVM_ENUM_ASM_PRINTERS "")
 442 set(LLVM_ENUM_ASM_PARSERS "")
 443 set(LLVM_ENUM_DISASSEMBLERS "")
 444 foreach(t ${LLVM_TARGETS_TO_BUILD})
 445   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 446
 447   list(FIND LLVM_ALL_TARGETS ${t} idx)
 448   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 449   if( idx LESS 0 AND idy LESS 0 )
 450     message(FATAL_ERROR "The target `${t}' does not exist.
 451     It should be one of\n${LLVM_ALL_TARGETS}")
 452   else()
 453     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 454   endif()
 455
 456   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 457   if( asmp_file )
 458     set(LLVM_ENUM_ASM_PRINTERS
 459       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 460   endif()
 461   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 462     set(LLVM_ENUM_ASM_PARSERS
 463       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 464   endif()
 465   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 466     set(LLVM_ENUM_DISASSEMBLERS
 467       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 468   endif()
 469 endforeach(t)
 470
 471 # Produce the target definition files, which provide a way for clients to easily
 472 # include various classes of targets.
 473 configure_file(
 474   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 475   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 476   )
 477 configure_file(
 478   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 479   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 480   )
 481 configure_file(
 482   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 483   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 484   )
 485 configure_file(
 486   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 487   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 488   )
 489
 490 # Configure the three LLVM configuration header files.
 491 configure_file(
 492   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 493   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 494 configure_file(
 495   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 496   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 497 configure_file(
 498   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 499   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 500
 501 # They are not referenced. See set_output_directory().
 502 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 503 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 504 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 505
 506 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 507 if (APPLE)
 508   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 509   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 510 else(UNIX)
 511   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 512     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 513     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 514       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 515       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 516     endif()
 517   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 518 endif()
 519
 520 # Work around a broken bfd ld behavior. When linking a binary with a
 521 # foo.so library, it will try to find any library that foo.so uses and
 522 # check its symbols. This is wasteful (the check was done when foo.so
 523 # was created) and can fail since it is not the dynamic linker and
 524 # doesn't know how to handle search paths correctly.
 525 if (UNIX AND NOT APPLE)
 526   set(CMAKE_EXE_LINKER_FLAGS
 527       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 528 endif()
 529
 530 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 531
 532 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 533
 534 # when crosscompiling import the executable targets from a file
 535 if(LLVM_USE_HOST_TOOLS)
 536   include(CrossCompile)
 537 endif(LLVM_USE_HOST_TOOLS)
 538
 539 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 540   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 541   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 542   include_directories("/usr/local/include")
 543   link_directories("/usr/local/lib")
 544 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 545
 546 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 547    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 548 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 549
 550 # Make sure we don't get -rdynamic in every binary. For those that need it,
 551 # use export_executable_symbols(target).
 552 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 553
 554 include(AddLLVM)
 555 include(TableGen)
 556
 557 if( MINGW )
 558   # People report that -O3 is unreliable on MinGW. The traditional
 559   # build also uses -O2 for that reason:
 560   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 561 endif()
 562
 563 # Put this before tblgen. Else we have a circular dependence.
 564 add_subdirectory(lib/Support)
 565 add_subdirectory(lib/TableGen)
 566
 567 add_subdirectory(utils/TableGen)
 568
 569 add_subdirectory(include/llvm)
 570
 571 add_subdirectory(lib)
 572
 573 if( LLVM_INCLUDE_UTILS )
 574   add_subdirectory(utils/FileCheck)
 575   add_subdirectory(utils/PerfectShuffle)
 576   add_subdirectory(utils/count)
 577   add_subdirectory(utils/not)
 578   add_subdirectory(utils/llvm-lit)
 579   add_subdirectory(utils/yaml-bench)
 580 else()
 581   if ( LLVM_INCLUDE_TESTS )
 582     message(FATAL_ERROR "Including tests when not building utils will not work.
 583     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 584   endif()
 585 endif()
 586
 587 if(LLVM_INCLUDE_TESTS)
 588   add_subdirectory(utils/unittest)
 589 endif()
 590
 591 foreach( binding ${LLVM_BINDINGS_LIST} )
 592   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 593     add_subdirectory(bindings/${binding})
 594   endif()
 595 endforeach()
 596
 597 add_subdirectory(projects)
 598
 599 if(WITH_POLLY)
 600   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 601     set(WITH_POLLY OFF)
 602   endif()
 603 endif(WITH_POLLY)
 604
 605 if( LLVM_INCLUDE_TOOLS )
 606   add_subdirectory(tools)
 607 endif()
 608
 609 if( LLVM_INCLUDE_EXAMPLES )
 610   add_subdirectory(examples)
 611 endif()
 612
 613 if( LLVM_INCLUDE_TESTS )
 614   add_subdirectory(test)
 615   add_subdirectory(unittests)
 616   if (MSVC)
 617     # This utility is used to prevent crashing tests from calling Dr. Watson on
 618     # Windows.
 619     add_subdirectory(utils/KillTheDoctor)
 620   endif()
 621
 622   # Add a global check rule now that all subdirectories have been traversed
 623   # and we know the total set of lit testsuites.
 624   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 625   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 626   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 627   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 628   add_lit_target(check-all
 629     "Running all regression tests"
 630     ${LLVM_LIT_TESTSUITES}
 631     PARAMS ${LLVM_LIT_PARAMS}
 632     DEPENDS ${LLVM_LIT_DEPENDS}
 633     ARGS ${LLVM_LIT_EXTRA_ARGS}
 634     )
 635 endif()
 636
 637 if (LLVM_INCLUDE_DOCS)
 638   add_subdirectory(docs)
 639 endif()
 640
 641 add_subdirectory(cmake/modules)
 642
 643 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 644   install(DIRECTORY include/llvm include/llvm-c
 645     DESTINATION include
 646     COMPONENT llvm-headers
 647     FILES_MATCHING
 648     PATTERN "*.def"
 649     PATTERN "*.h"
 650     PATTERN "*.td"
 651     PATTERN "*.inc"
 652     PATTERN "LICENSE.TXT"
 653     PATTERN ".svn" EXCLUDE
 654     )
 655
 656   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 657     DESTINATION include
 658     COMPONENT llvm-headers
 659     FILES_MATCHING
 660     PATTERN "*.def"
 661     PATTERN "*.h"
 662     PATTERN "*.gen"
 663     PATTERN "*.inc"
 664     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 665     PATTERN "CMakeFiles" EXCLUDE
 666     PATTERN "config.h" EXCLUDE
 667     PATTERN ".svn" EXCLUDE
 668     )
 669
 670   if (NOT CMAKE_CONFIGURATION_TYPES)
 671     add_custom_target(installhdrs
 672                       DEPENDS ${name}
 673                       COMMAND "${CMAKE_COMMAND}"
 674                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 675                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 676   endif()
 677 endif()