folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 AC_CONFIG_SRCDIR([Likely.h])
  16 AC_CONFIG_HEADERS([config.h])
  17 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  18 AC_CONFIG_AUX_DIR([build-aux])
  19
  20 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  21
  22 AC_CONFIG_MACRO_DIR([m4])
  23
  24 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  25 AX_CONFIG_FEATURE(
  26         [deprecated-assoc],
  27         [supports deprecated associative containers (hash_map/hash_set)],
  28         [HAVE_DEPRECATED_ASSOC],
  29         [Define if you want to support deprecated associative containers])
  30
  31 AC_PROG_INSTALL
  32 AM_PROG_LIBTOOL
  33
  34 AC_LANG([C++])
  35
  36 # Checks for programs.
  37 AC_PROG_CXX
  38 AC_PROG_CC
  39 AC_CXX_COMPILE_STDCXX_0X
  40
  41 # Be sure to add any -std option to CXXFLAGS before we invoke any
  42 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  43 # before we update CXXFLAGS will not be run with the same options that we use
  44 # during the real build.
  45 STD=""
  46 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  47    STD="-std=c++0x"
  48 fi
  49 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  50    STD="-std=gnu++0x"
  51 fi
  52
  53 CXXFLAGS="$STD $CXXFLAGS"
  54
  55 # Checks for libraries.
  56 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  57              [Please install google-glog library])])
  58 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  59              [Please install google-gflags library])])
  60
  61 AC_CHECK_LIB(ssl,
  62         SSL_ctrl,
  63         [],
  64         [AC_MSG_ERROR(["Error: libssl required"])])
  65
  66 # check for boost libs
  67 AX_BOOST_BASE([1.20.0], [], [AC_MSG_ERROR(
  68               [Please install boost >= 1.20.0 (thread, regex, and system)])])
  69 AX_BOOST_THREAD
  70 AX_BOOST_REGEX
  71 AX_BOOST_SYSTEM
  72 AX_BOOST_FILESYSTEM
  73
  74 # Checks for header files.
  75 AC_HEADER_STDC
  76 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h bits/functexcept.h bits/c++config.h])
  77
  78 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
  79                 [Couldn't find double-conversion.h, please download from \
  80                 http://code.google.com/p/double-conversion/])], [])
  81 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
  82              [Please install double-conversion library])])
  83
  84 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
  85
  86 AC_CHECK_LIB([jemalloc], [xallocx])
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_HEADER_STDBOOL
  90 AC_C_CONST
  91 AC_C_INLINE
  92 AC_TYPE_SIZE_T
  93 AC_HEADER_TIME
  94 AC_C_VOLATILE
  95 AC_CHECK_TYPE([__int128],
  96   [AC_DEFINE([HAVE_INT128_T], [1], [Define if __int128 exists])],
  97   [AC_DEFINE([HAVE_INT128_T], [0], [Define if __int128 does not exist])])
  98 AC_CHECK_TYPES([ptrdiff_t])
  99
 100 AC_CACHE_CHECK(
 101   [for ifunc support],
 102   [folly_cv_prog_cc_ifunc],
 103   [AC_COMPILE_IFELSE(
 104     [AC_LANG_SOURCE[
 105       #pragma GCC diagnostic error "-Wattributes"
 106       extern "C" void (*test_ifunc(void))() { return 0; }
 107       void func() __attribute__((ifunc("test_ifunc")));]
 108     ],
 109     [folly_cv_prog_cc_ifunc=yes],
 110     [folly_cv_prog_cc_ifunc=no])])
 111
 112 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 113   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 114 fi
 115
 116 AC_CACHE_CHECK(
 117   [for final and override support],
 118   [folly_cv_c_final_override],
 119   [AC_COMPILE_IFELSE(
 120     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 121                     class D : public C { virtual void g() override {} };]],
 122     [folly_cv_c_final_override=yes],
 123     [folly_cv_c_final_override=no])])
 124
 125 if test "$folly_cv_c_final_override" = "yes"; then
 126   final_val=final
 127   override_val=override
 128 else
 129   final_val=
 130   override_val=
 131 fi
 132
 133 AC_DEFINE_UNQUOTED(
 134   [FINAL], [$final_val],
 135   [Define to "final" if the compiler supports C++11 "final"])
 136 AC_DEFINE_UNQUOTED(
 137   [OVERRIDE], [$override_val],
 138   [Define to "override" if the compiler supports C++11 "override"])
 139
 140 AC_CACHE_CHECK(
 141   [for std::this_thread::sleep_for],
 142   [folly_cv_func_this_thread_sleep_for],
 143   [AC_COMPILE_IFELSE(
 144     [AC_LANG_SOURCE[
 145       #include <thread>
 146       #include <chrono>
 147       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 148     [folly_cv_func_this_thread_sleep_for=yes],
 149     [folly_cv_func_this_thread_sleep_for=no])])
 150
 151 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 152     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 153               [Define to 1 if std::this_thread::sleep_for() is defined.])
 154 fi
 155
 156 AC_CACHE_CHECK(
 157   [for constexpr strlen],
 158   [folly_cv_func_constexpr_strlen],
 159   [AC_COMPILE_IFELSE(
 160     [AC_LANG_SOURCE[
 161       #include <cstring>
 162       static constexpr int val = strlen("foo");]],
 163     [folly_cv_func_constexpr_strlen=yes],
 164     [folly_cv_func_constexpr_strlen=no])])
 165
 166 if test "$folly_cv_func_constexpr_strlen" = yes; then
 167     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 168               [Define to 1 if strlen(3) is constexpr.])
 169 fi
 170
 171 AC_CACHE_CHECK(
 172   [for libc++],
 173   [folly_cv_lib_libcpp],
 174   [AC_COMPILE_IFELSE(
 175     [AC_LANG_SOURCE[
 176       #include <type_traits>
 177       #if !_LIBCPP_VERSION
 178       #error No libc++
 179       #endif
 180       void func() {}]
 181     ],
 182     [folly_cv_lib_libcpp=yes],
 183     [folly_cv_lib_libcpp=no])])
 184
 185 if test "$folly_cv_lib_libcpp" = yes; then
 186   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we're using libc++.])
 187 fi
 188
 189 AC_CACHE_CHECK(
 190   [for usable std::is_trivially_copyable],
 191   [folly_cv_decl_std_is_trivially_copyable],
 192   [AC_COMPILE_IFELSE(
 193     [AC_LANG_SOURCE[
 194       #include <type_traits>
 195       const bool val = std::is_trivially_copyable<bool>::value;]
 196     ],
 197     [folly_cv_decl_std_is_trivially_copyable=yes],
 198     [folly_cv_decl_std_is_trivially_copyable=no])])
 199
 200 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 201   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 202             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 203              implementation.])
 204 fi
 205
 206 AC_CACHE_CHECK(
 207   [gflags namespace],
 208   [folly_cv_decl_gflags_namespace],
 209   [AC_COMPILE_IFELSE(
 210     [AC_LANG_SOURCE[
 211       #include <gflags/gflags.h>
 212       void foo() { gflags::GetArgv(); }]
 213     ],
 214     [folly_cv_decl_gflags_namespace=gflags],
 215     [AC_COMPILE_IFELSE(
 216       [AC_LANG_SOURCE[
 217         #include <gflags/gflags.h>
 218         void foo() { google::GetArgv(); }]
 219       ],
 220       [folly_cv_decl_gflags_namespace=google],
 221       [folly_cv_decl_gflags_namespace=error])])])
 222
 223 if test "$folly_cv_decl_gflags_namespace" = error; then
 224   AC_MSG_ERROR([Cannot determine gflags namespace])
 225 else
 226   AC_DEFINE_UNQUOTED(
 227     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 228     [Define to gflags namespace (usually "google" or "gflags")])
 229   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 230      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 231                [Define to 1 if the gflags namespace is not "gflags"])
 232   fi
 233 fi
 234
 235 # Figure out if we support weak symbols. If not, we will link in some null
 236 # stubs for functions that would otherwise be weak.
 237 AC_CACHE_CHECK(
 238   [for weak symbol support],
 239   [folly_cv_prog_cc_weak_symbols],
 240   [AC_LINK_IFELSE(
 241     [AC_LANG_SOURCE[
 242       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 243       int main(int argc, char** argv) {
 244           return configure_link_extern_weak_test == nullptr;
 245       }]],
 246     [folly_cv_prog_cc_weak_symbols="yes"],
 247     [folly_cv_prog_cc_weak_symbols="no"])])
 248
 249 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 250   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 251             [Define to 1 if the linker supports weak symbols.])
 252 fi
 253
 254 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 255 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 256   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 257             [Define to 1 if we have cplus_demangle_v3_callback.])
 258 fi
 259
 260 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 261 # want to link with librt if necessary.
 262 AC_SEARCH_LIBS([clock_gettime], [rt],
 263   AC_DEFINE(
 264     [HAVE_CLOCK_GETTIME],
 265     [1],
 266     [Define to 1 if we support clock_gettime(2).]),
 267   [])
 268
 269 # Checks for library functions.
 270 AC_CHECK_FUNCS([getdelim \
 271                 gettimeofday \
 272                 memmove \
 273                 memset \
 274                 pow \
 275                 strerror \
 276                 pthread_yield \
 277                 malloc_size \
 278                 malloc_usable_size \
 279                 memrchr \
 280                 pipe2])
 281
 282 if test "$ac_cv_func_pthread_yield" = "no"; then
 283    AC_CHECK_HEADERS([sched.h])
 284    AC_CHECK_FUNCS([sched_yield])
 285 fi
 286
 287 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 288 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 289 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 290 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 291
 292 # Include directory that contains "folly" so #include <folly/Foo.h> works
 293 AM_CPPFLAGS='-I$(top_srcdir)/..'
 294 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 295 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 296 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 297
 298 AC_SUBST([AM_CPPFLAGS])
 299 AC_SUBST([AM_LDFLAGS])
 300
 301 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 302 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 303 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 304 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 305                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 306 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept" = "yes"])
 307
 308 # Output
 309 AC_CONFIG_FILES([Makefile
 310                  test/Makefile
 311                  test/function_benchmark/Makefile])
 312 AC_OUTPUT