folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6 AC_INIT(folly, 0.1, folly@fb.com)
   7
   8 m4_define([folly_libtool_current], [1])
   9
  10 # We assume all revisions are backwards incompatible.
  11 LT_VERSION=folly_libtool_current:0:0
  12 AC_SUBST(LT_VERSION)
  13
  14 AC_CONFIG_SRCDIR([Likely.h])
  15 AC_CONFIG_HEADERS([config.h])
  16 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  17 AC_CONFIG_AUX_DIR([build-aux])
  18
  19 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  24 AX_CONFIG_FEATURE(
  25         [deprecated-assoc],
  26         [supports deprecated associative containers (hash_map/hash_set)],
  27         [HAVE_DEPRECATED_ASSOC],
  28         [Define if you want to support deprecated associative containers])
  29
  30 AC_PROG_INSTALL
  31 AM_PROG_LIBTOOL
  32
  33 AC_LANG([C++])
  34
  35 # Checks for programs.
  36 AC_PROG_CXX
  37 AC_PROG_CC
  38 AC_CXX_COMPILE_STDCXX_0X
  39
  40 # Be sure to add any -std option to CXXFLAGS before we invoke any
  41 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  42 # before we update CXXFLAGS will not be run with the same options that we use
  43 # during the real build.
  44 STD=""
  45 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  46    STD="-std=c++0x"
  47 fi
  48 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  49    STD="-std=gnu++0x"
  50 fi
  51
  52 CXXFLAGS="$STD $CXXFLAGS"
  53
  54 # Checks for libraries.
  55 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  56              [Please install google-glog library])])
  57 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  58              [Please install google-gflags library])])
  59
  60 # check for boost libs
  61 AX_BOOST_BASE([1.20.0], [], [AC_MSG_ERROR(
  62               [Please install boost >= 1.20.0 (thread, regex, and system)])])
  63 AX_BOOST_THREAD
  64 AX_BOOST_REGEX
  65 AX_BOOST_SYSTEM
  66 AX_BOOST_FILESYSTEM
  67
  68 # Checks for header files.
  69 AC_HEADER_STDC
  70 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h bits/functexcept.h bits/c++config.h])
  71
  72 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
  73                 [Couldn't find double-conversion.h, please download from \
  74                 http://code.google.com/p/double-conversion/])], [])
  75 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
  76              [Please install double-conversion library])])
  77
  78 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
  79
  80 AC_CHECK_LIB([jemalloc], [rallocm])
  81
  82 # Checks for typedefs, structures, and compiler characteristics.
  83 AC_HEADER_STDBOOL
  84 AC_C_CONST
  85 AC_C_INLINE
  86 AC_TYPE_SIZE_T
  87 AC_HEADER_TIME
  88 AC_C_VOLATILE
  89 AC_CHECK_TYPE([__int128],
  90   [AC_DEFINE([HAVE_INT128_T], [1], [Define if __int128 exists])],
  91   [AC_DEFINE([HAVE_INT128_T], [0], [Define if __int128 does not exist])])
  92 AC_CHECK_TYPES([ptrdiff_t])
  93 AC_COMPILE_IFELSE(
  94   [AC_LANG_SOURCE[
  95     #pragma GCC diagnostic error "-Wattributes"
  96     extern "C" void (*test_ifunc(void))() { return 0; }
  97     void func() __attribute__((ifunc("test_ifunc")));]
  98   ],
  99   [AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])],
 100   [AC_DEFINE([HAVE_IFUNC], [0], [Define to 0 if the compiler doesn't support ifunc])]
 101 )
 102 AC_COMPILE_IFELSE(
 103   [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 104                   class D : public C { virtual void g() override {} };]],
 105   [AC_DEFINE([FINAL], [final],
 106              [Define to "final" if the compiler supports C++11 "final"])
 107    AC_DEFINE([OVERRIDE], [override],
 108              [Define to "override" if the compiler supports C++11 "override"])],
 109   [AC_DEFINE([FINAL], [],
 110              [Define to "final" if the compiler supports C++11 "final"])
 111    AC_DEFINE([OVERRIDE], [],
 112              [Define to "override" if the compiler supports C++11 "override"])]
 113 )
 114
 115 AC_COMPILE_IFELSE(
 116   [AC_LANG_SOURCE[
 117     #include <thread>
 118     #include <chrono>
 119     void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 120   [AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 121              [Define to 1 if std::this_thread::sleep_for() is defined.])])
 122
 123 AC_COMPILE_IFELSE(
 124   [AC_LANG_SOURCE[
 125     #include <cstring>
 126     static constexpr int val = strlen("foo");]],
 127   [AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 128              [Define to 1 if strlen(3) is constexpr.])])
 129
 130 AC_COMPILE_IFELSE(
 131   [AC_LANG_SOURCE[
 132     #include <type_traits>
 133     #if !_LIBCPP_VERSION
 134     #error No libc++
 135     #endif
 136     void func() {}]
 137   ],
 138   [AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we're using libc++.])])
 139
 140 AC_COMPILE_IFELSE(
 141   [AC_LANG_SOURCE[
 142     #include <type_traits>
 143     const bool val = std::is_trivially_copyable<bool>::value;]
 144   ],
 145   [AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 146              [Define to 1 if we have a usable std::is_trivially_copyable<T>
 147               implementation.])])
 148
 149 # Figure out if we support weak symbols. If not, we will link in some null
 150 # stubs for functions that would otherwise be weak.
 151 AC_LINK_IFELSE(
 152   [AC_LANG_SOURCE[
 153     extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 154     int main(int argc, char** argv) {
 155         return configure_link_extern_weak_test == nullptr;
 156     }]
 157   ],
 158   [
 159     ac_have_weak_symbols="yes"
 160     AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 161               [Define to 1 if the linker supports weak symbols.])])
 162
 163 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty])
 164 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 165   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 166             [Define to 1 if we have cplus_demangle_v3_callback.])
 167 fi
 168
 169 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 170 # want to link with librt if necessary.
 171 AC_SEARCH_LIBS([clock_gettime], [rt],
 172   AC_DEFINE(
 173     [HAVE_CLOCK_GETTIME],
 174     [1],
 175     [Define to 1 if we support clock_gettime(2).]),
 176   [])
 177
 178 # Checks for library functions.
 179 AC_CHECK_FUNCS([getdelim \
 180                 gettimeofday \
 181                 memmove \
 182                 memset \
 183                 pow \
 184                 strerror \
 185                 pthread_yield \
 186                 rallocm \
 187                 malloc_size \
 188                 malloc_usable_size \
 189                 memrchr])
 190
 191 if test "$ac_cv_func_pthread_yield" = "no"; then
 192    AC_CHECK_HEADERS([sched.h])
 193    AC_CHECK_FUNCS([sched_yield])
 194 fi
 195
 196 AC_SUBST(AM_CPPFLAGS, '-I../$(top_srcdir)'" "'-I$(top_srcdir)/io'" "'-I$(top_srcdir)/test'" $BOOST_CPPFLAGS")
 197 AC_SUBST(AM_LDFLAGS, "$BOOST_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread")
 198
 199 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 200 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 201 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 202 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS], [test "$ac_have_weak_symbols" = "yes"])
 203 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept" = "yes"])
 204
 205 # Output
 206 AC_CONFIG_FILES([Makefile
 207                  test/Makefile
 208                  test/function_benchmark/Makefile])
 209 AC_OUTPUT