folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 #declare pkg-config variables
  16 PKG_VERSION=m4_join([.], m4_reverse(m4_translit(folly_version_str, [:], [,])))
  17 AC_SUBST([PKG_VERSION])
  18 AC_SUBST([PKG_CXXFLAGS])
  19 AC_SUBST([PKG_DEPS])
  20 AC_SUBST([PKG_LIBS])
  21
  22 AC_CONFIG_SRCDIR([Likely.h])
  23 AC_CONFIG_HEADERS([config.h])
  24 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  32 AX_CONFIG_FEATURE(
  33         [deprecated-assoc],
  34         [supports deprecated associative containers (hash_map/hash_set)],
  35         [HAVE_DEPRECATED_ASSOC],
  36         [Define if you want to support deprecated associative containers])
  37
  38 AC_PROG_INSTALL
  39 AM_PROG_LIBTOOL
  40
  41 AC_LANG([C++])
  42
  43 # Checks for programs.
  44 AC_PROG_CXX
  45 AC_PROG_CC
  46
  47 AC_CXX_COMPILE_STDCXX_1Y
  48
  49 # Be sure to add any -std option to CXXFLAGS before we invoke any
  50 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  51 # before we update CXXFLAGS will not be run with the same options that we use
  52 # during the real build.
  53 STD=""
  54 if test "x$ac_cv_cxx_compile_cxx1y_cxx" = xyes; then
  55    STD="-std=c++1y"
  56 fi
  57 if test "x$ac_cv_cxx_compile_cxx1y_gxx" = xyes; then
  58    STD="-std=gnu++1y"
  59 fi
  60
  61 CXXFLAGS="$STD $CXXFLAGS"
  62
  63 # expose required -std option via pkg-config
  64 PKG_CXXFLAGS=$STD
  65
  66 # See if -Wshadow-local and -Wshadow-compatible-local are supported
  67 AC_MSG_CHECKING(
  68   [whether -Wshadow-local and -Wshadow-compatible-local are supported])
  69 AC_CACHE_VAL([folly_cv_cxx_shadow_local_support], [
  70   folly_save_CXXFLAGS="$CXXFLAGS"
  71   CXXFLAGS="$CXXFLAGS -Wshadow-local -Wshadow-compatible-local"
  72   AC_COMPILE_IFELSE(
  73     [AC_LANG_PROGRAM([[]], [[]])],
  74     [folly_cv_cxx_shadow_local_support=yes],
  75     [folly_cv_cxx_shadow_local_support=no])
  76   CXXFLAGS="$folly_save_CXXFLAGS"])
  77 AC_MSG_RESULT([$folly_cv_cxx_shadow_local_support])
  78 if test "$folly_cv_cxx_shadow_local_support" = yes; then
  79   AC_DEFINE([HAVE_SHADOW_LOCAL_WARNINGS], [1],
  80   [Define if both -Wshadow-local and -Wshadow-compatible-local are supported.])
  81 fi
  82
  83 # Checks for glog and gflags
  84 # There are no symbols with C linkage, so we do a try-run
  85 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  86                 [Please install google-gflags library])])
  87 AC_CACHE_CHECK(
  88   [for gflags viability],
  89   [folly_cv_prog_cc_gflags],
  90   [AC_RUN_IFELSE(
  91     [AC_LANG_SOURCE[
  92       #include <gflags/gflags.h>
  93       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  94       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  95       int main(int argc, char** argv) {
  96         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  97       }
  98     ]],
  99     [folly_cv_prog_cc_gflags=yes],
 100     [folly_cv_prog_cc_gflags=no]
 101   )]
 102 )
 103
 104 if test "$folly_cv_prog_cc_gflags" != "yes"; then
 105   AC_MSG_ERROR(["libgflags invalid, see config.log for details"])
 106 fi
 107 FB_CHECK_PKG_CONFIG([GFLAGS], [libgflags])
 108
 109 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
 110                 [Please install google-glog library])])
 111 AC_CACHE_CHECK(
 112   [for glog viability],
 113   [folly_cv_prog_cc_glog],
 114   [AC_RUN_IFELSE(
 115     [AC_LANG_SOURCE[
 116       #include <glog/logging.h>
 117       int main(int argc, char** argv) {
 118         google::InitGoogleLogging(argv[0]);
 119         google::ShutdownGoogleLogging();
 120         return 0;
 121       }
 122     ]],
 123     [folly_cv_prog_cc_glog=yes],
 124     [folly_cv_prog_cc_glog=no]
 125   )]
 126 )
 127
 128 if test "$folly_cv_prog_cc_glog" != "yes"; then
 129   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
 130 fi
 131 FB_CHECK_PKG_CONFIG([GLOG], [libglog])
 132
 133 AX_CHECK_OPENSSL([],
 134         [AC_MSG_ERROR(["Error: libssl required"])])
 135 FB_CHECK_PKG_CONFIG([OPENSSL], [openssl])
 136
 137 # check for boost libs
 138 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 139               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 140 AX_BOOST_CONTEXT
 141 AX_BOOST_PROGRAM_OPTIONS
 142 AX_BOOST_THREAD
 143 AX_BOOST_REGEX
 144 AX_BOOST_SYSTEM
 145 AX_BOOST_FILESYSTEM
 146 AX_BOOST_CHRONO
 147
 148 # Check for python interpreter
 149 AM_PATH_PYTHON
 150
 151 # Checks for header files.
 152 AC_HEADER_STDC
 153 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h sched.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h byteswap.h bits/functexcept.h bits/c++config.h])
 154
 155 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 156                 [Couldn't find double-conversion.h, please download from \
 157                  https://github.com/google/double-conversion/])], [])
 158 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 159              [Please install double-conversion library])])
 160
 161 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 162 FB_CHECK_PKG_CONFIG([EVENT], [libevent])
 163
 164 AC_ARG_WITH([jemalloc], [
 165   --with-jemalloc     Whether to make folly jemalloc aware
 166 ],[
 167   AC_CHECK_LIB([jemalloc], [xallocx],[
 168     AC_DEFINE([USE_JEMALLOC], [1], [Enable jemalloc])
 169   ],[
 170     AC_MSG_ERROR([--with-jemalloc requested, but jemalloc not found])
 171   ])
 172 ])
 173
 174 # Checks for typedefs, structures, and compiler characteristics.
 175 AC_HEADER_STDBOOL
 176 AC_C_CONST
 177 AC_C_INLINE
 178 AC_TYPE_SIZE_T
 179 AC_HEADER_TIME
 180 AC_C_VOLATILE
 181 AC_CHECK_TYPE([__int128], [folly_cv_prog_cc_int128=yes],
 182     [folly_cv_prog_cc_int128=no])
 183 if test "$folly_cv_prog_cc_int128" = "yes"; then
 184   AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128])
 185   AC_CACHE_CHECK(
 186     [for __int128 type traits],
 187     [folly_cv_prog_cc_int128traits],
 188     [AC_COMPILE_IFELSE(
 189       [AC_LANG_SOURCE([[
 190 #include <type_traits>
 191 static_assert(
 192   ::std::is_same<::std::make_signed<unsigned __int128>::type, __int128>::value,
 193   "signed form of \`unsigned __uint128\` must be \`__int128\`.");
 194       ]])],
 195       [folly_cv_prog_cc_int128traits=yes],
 196       [folly_cv_prog_cc_int128traits=no])
 197     ])
 198   if test "$folly_cv_prog_cc_int128traits" = "no"; then
 199     AC_DEFINE([SUPPLY_MISSING_INT128_TRAITS], [1], [Define if we need the standard integer traits defined for the type `__int128'.])
 200   fi
 201 fi
 202
 203 AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
 204
 205 AC_CACHE_CHECK(
 206   [for ifunc support],
 207   [folly_cv_prog_cc_ifunc],
 208   [AC_COMPILE_IFELSE(
 209     [AC_LANG_SOURCE[
 210       #pragma GCC diagnostic error "-Wattributes"
 211       extern "C" void (*test_ifunc(void))() { return 0; }
 212       void func() __attribute__((ifunc("test_ifunc")));]
 213     ],
 214     [folly_cv_prog_cc_ifunc=yes],
 215     [folly_cv_prog_cc_ifunc=no])])
 216
 217 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 218   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 219 fi
 220
 221 AC_CACHE_CHECK(
 222   [for final and override support],
 223   [folly_cv_c_final_override],
 224   [AC_COMPILE_IFELSE(
 225     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 226                     class D : public C { virtual void g() override {} };]],
 227     [folly_cv_c_final_override=yes],
 228     [folly_cv_c_final_override=no])])
 229
 230 if test "$folly_cv_c_final_override" = "yes"; then
 231   final_val=final
 232   override_val=override
 233 else
 234   final_val=
 235   override_val=
 236 fi
 237
 238 AC_DEFINE_UNQUOTED(
 239   [FINAL], [$final_val],
 240   [Define to "final" if the compiler supports C++11 "final"])
 241 AC_DEFINE_UNQUOTED(
 242   [OVERRIDE], [$override_val],
 243   [Define to "override" if the compiler supports C++11 "override"])
 244
 245 AC_CACHE_CHECK(
 246   [for std::this_thread::sleep_for],
 247   [folly_cv_func_this_thread_sleep_for],
 248   [AC_COMPILE_IFELSE(
 249     [AC_LANG_SOURCE[
 250       #include <thread>
 251       #include <chrono>
 252       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 253     [folly_cv_func_this_thread_sleep_for=yes],
 254     [folly_cv_func_this_thread_sleep_for=no])])
 255
 256 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 257     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 258               [Define to 1 if std::this_thread::sleep_for() is defined.])
 259 fi
 260
 261 AC_CACHE_CHECK(
 262   [for constexpr strlen],
 263   [folly_cv_func_constexpr_strlen],
 264   [AC_COMPILE_IFELSE(
 265     [AC_LANG_SOURCE[
 266       #include <cstring>
 267       static constexpr int val = strlen("foo");]],
 268     [folly_cv_func_constexpr_strlen=yes],
 269     [folly_cv_func_constexpr_strlen=no])])
 270
 271 if test "$folly_cv_func_constexpr_strlen" = yes; then
 272     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 273               [Define to 1 if strlen(3) is constexpr.])
 274 fi
 275
 276 AC_CACHE_CHECK(
 277   [for libc++],
 278   [folly_cv_lib_libcpp],
 279   [AC_COMPILE_IFELSE(
 280     [AC_LANG_SOURCE[
 281       #include <type_traits>
 282       #if !_LIBCPP_VERSION
 283       #error No libc++
 284       #endif
 285       void func() {}]
 286     ],
 287     [folly_cv_lib_libcpp=yes],
 288     [folly_cv_lib_libcpp=no])])
 289
 290 if test "$folly_cv_lib_libcpp" = yes; then
 291   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 292 fi
 293
 294 AC_CACHE_CHECK(
 295   [for c++11 atomic support without GNU Atomic library],
 296   [folly_cv_lib_libatomic],
 297   [AC_LINK_IFELSE(
 298     [AC_LANG_SOURCE[
 299       #include <atomic>
 300       int main() {
 301         struct Test { int val; };
 302         std::atomic<Test> s;
 303         s.is_lock_free();
 304       }
 305     ]],
 306     [folly_cv_lib_libatomic=yes],
 307     [folly_cv_lib_libatomic=no])])
 308
 309 if test "$folly_cv_lib_libatomic" = no; then
 310   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 311                   [Please install the GNU Atomic library])])
 312 fi
 313
 314 AC_CACHE_CHECK(
 315   [for liblinux-vdso support],
 316   [folly_cv_lib_liblinux_vdso],
 317   [AC_RUN_IFELSE(
 318     [AC_LANG_PROGRAM[
 319       #include <dlfcn.h>
 320       int main() {
 321         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 322         if (h == nullptr) {
 323           return -1;
 324         }
 325         dlclose(h);
 326         return 0;
 327       }
 328     ]],
 329     [folly_cv_lib_liblinux_vdso=yes],
 330     [folly_cv_lib_liblinux_vdso=no])])
 331
 332 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 333   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 334 fi
 335
 336 AC_CACHE_CHECK(
 337   [for usable std::is_trivially_copyable],
 338   [folly_cv_decl_std_is_trivially_copyable],
 339   [AC_COMPILE_IFELSE(
 340     [AC_LANG_SOURCE[
 341       #include <type_traits>
 342       const bool val = std::is_trivially_copyable<bool>::value;]
 343     ],
 344     [folly_cv_decl_std_is_trivially_copyable=yes],
 345     [folly_cv_decl_std_is_trivially_copyable=no])])
 346
 347 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 348   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 349             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 350              implementation.])
 351 fi
 352
 353 AC_CACHE_CHECK(
 354   [gflags namespace],
 355   [folly_cv_decl_gflags_namespace],
 356   [AC_COMPILE_IFELSE(
 357     [AC_LANG_SOURCE[
 358       #include <gflags/gflags.h>
 359       void foo() { gflags::GetArgv(); }]
 360     ],
 361     [folly_cv_decl_gflags_namespace=gflags],
 362     [AC_COMPILE_IFELSE(
 363       [AC_LANG_SOURCE[
 364         #include <gflags/gflags.h>
 365         void foo() { google::GetArgv(); }]
 366       ],
 367       [folly_cv_decl_gflags_namespace=google],
 368       [folly_cv_decl_gflags_namespace=error])])])
 369
 370 if test "$folly_cv_decl_gflags_namespace" = error; then
 371   AC_MSG_ERROR([Cannot determine gflags namespace])
 372 else
 373   AC_DEFINE_UNQUOTED(
 374     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 375     [Define to gflags namespace (usually "google" or "gflags")])
 376   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 377      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 378                [Define to 1 if the gflags namespace is not "gflags"])
 379   fi
 380 fi
 381
 382 # Figure out if we support weak symbols. If not, we will link in some null
 383 # stubs for functions that would otherwise be weak.
 384 AC_CACHE_CHECK(
 385   [for weak symbol support],
 386   [folly_cv_prog_cc_weak_symbols],
 387   [AC_LINK_IFELSE(
 388     [AC_LANG_SOURCE[
 389       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 390       int main(int argc, char** argv) {
 391           return configure_link_extern_weak_test == nullptr;
 392       }]],
 393     [folly_cv_prog_cc_weak_symbols="yes"],
 394     [folly_cv_prog_cc_weak_symbols="no"])])
 395
 396 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 397   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 398             [Define to 1 if the linker supports weak symbols.])
 399 fi
 400
 401
 402 # Figure out if we support wchar well
 403 AC_CACHE_CHECK(
 404   [for wchar support],
 405   [folly_cv_prog_cc_wchar_support],
 406   [AC_RUN_IFELSE(
 407     [AC_LANG_SOURCE[
 408       #include <cstddef>
 409       #include <cwchar>
 410
 411       int main(int argc, char** argv) {
 412         return wcstol(L"01", nullptr, 10) == 1 ? 0 : 1;
 413       }
 414     ]],
 415     [folly_cv_prog_cc_wchar_support=yes],
 416     [folly_cv_prog_cc_wchar_support=no])])
 417
 418 if test "$folly_cv_prog_cc_wchar_support" = "yes"; then
 419   AC_DEFINE([HAVE_WCHAR_SUPPORT], [1], [Define to 1 if the libc supports wchar well])
 420 fi
 421
 422 # Figure out whether the architecture supports unaligned accesses
 423 AC_CACHE_CHECK(
 424   [for unaligned access support],
 425   [folly_cv_prog_cc_unaligned_access],
 426   [AC_RUN_IFELSE(
 427     [AC_LANG_SOURCE[
 428       int main(int argc, char** argv) {
 429         char buf[64] = {0};
 430         unsigned long *ptr = (unsigned long *)(buf + 1);
 431         *ptr = 0xdeadbeef;
 432         return (*ptr & 0xff) == 0xef ? 0 : 1;
 433       }
 434     ]],
 435     [folly_cv_prog_cc_unaligned_access=yes],
 436     [folly_cv_prog_cc_unaligned_access=no])])
 437
 438 if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
 439   AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
 440 fi
 441
 442 AC_CACHE_CHECK(
 443   [for vsnprintf reporting bad format strings],
 444   [folly_cv_prog_vsnprintf_bad_format],
 445   [AC_RUN_IFELSE(
 446     [AC_LANG_SOURCE[
 447       #include <stdio.h>
 448
 449       int main(int argc, char** argv) {
 450           char buf[256];
 451           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 452       }]],
 453     [folly_cv_prog_vsnprintf_bad_format="yes"],
 454     [folly_cv_prog_vsnprintf_bad_format="no"])])
 455
 456 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 457   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 458             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 459 fi
 460
 461 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 462 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 463   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 464             [Define to 1 if we have cplus_demangle_v3_callback.])
 465 fi
 466
 467 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 468 # want to link with librt if necessary.
 469 AC_SEARCH_LIBS([clock_gettime], [rt],
 470   AC_DEFINE(
 471     [HAVE_CLOCK_GETTIME],
 472     [1],
 473     [Define to 1 if we support clock_gettime(2).]),
 474   [])
 475
 476 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 477 # want to include pthread.h if necessary.
 478 AC_CACHE_CHECK(
 479   [for pthread_atfork support],
 480   [folly_cv_prog_cc_pthread_atfork],
 481   [AC_COMPILE_IFELSE(
 482     [AC_LANG_SOURCE[
 483       #include <pthread.h>
 484       void func() {pthread_atfork(NULL, NULL, NULL);}]
 485     ],
 486     [folly_cv_prog_cc_pthread_atfork=yes],
 487     [folly_cv_prog_cc_pthread_atfork=no])])
 488
 489 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 490   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 491 fi
 492
 493 # Check for XSI-compatible strerror_r as default implementation
 494 AC_CACHE_CHECK(
 495   [for XSI style strerror_r support],
 496   [folly_cv_prog_cc_xsi_strerror_r],
 497   [AC_RUN_IFELSE(
 498     [AC_LANG_SOURCE[
 499       #include <string.h>
 500       #include <errno.h>
 501       int main(int argc, char** argv) {
 502         char buf[1024];
 503         buf[0] = 0;
 504         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 505         return ret;
 506       }
 507     ]],
 508     [folly_cv_prog_cc_xsi_strerror_r=yes],
 509     [folly_cv_prog_cc_xsi_strerror_r=no])])
 510
 511 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 512   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 513 fi
 514
 515 AC_CACHE_CHECK(
 516   [for ext/random and __gnu_cxx::sfmt19937],
 517   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 518   [AC_COMPILE_IFELSE(
 519     [AC_LANG_SOURCE[
 520       #include <ext/random>
 521       int main(int argc, char** argv) {
 522         __gnu_cxx::sfmt19937 rng;
 523         return 0;
 524       }
 525     ]],
 526     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 527     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 528
 529 AC_CACHE_CHECK(
 530   [for VLA (variable-length array) support],
 531   [folly_cv_prog_cc_have_vla],
 532   [AC_COMPILE_IFELSE(
 533     [AC_LANG_SOURCE[
 534       int main(int argc, char** argv) {
 535         unsigned size = argc;
 536         char data[size];
 537         return 0;
 538       }
 539     ]],
 540     [folly_cv_prog_cc_have_vla=yes],
 541     [folly_cv_prog_cc_have_vla=no])])
 542
 543 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 544 AC_DEFINE_UNQUOTED(
 545   [HAVE_VLA],
 546   [$have_vla],
 547   [Define to 1 if the compiler has VLA (variable-length array) support,
 548    otherwise define to 0])
 549
 550 # Checks for library functions.
 551 AC_CHECK_FUNCS([getdelim \
 552                 gettimeofday \
 553                 memmove \
 554                 memset \
 555                 pow \
 556                 strerror \
 557                 sched_yield \
 558                 malloc_size \
 559                 malloc_usable_size \
 560                 memrchr \
 561                 pipe2 \
 562                 preadv \
 563                 pwritev \
 564               ])
 565
 566 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 567 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 568 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 569 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 570 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [ZSTD_compressStream]))
 571 AC_CHECK_HEADER([linux/membarrier.h], AC_DEFINE([HAVE_LINUX_MEMBARRIER_H], [1], [Define to 1 if membarrier.h is available]))
 572
 573 AC_ARG_ENABLE([follytestmain],
 574    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 575    [follytestmain=${enableval}], [follytestmain=no])
 576
 577 use_follytestmain=yes
 578 # libdwarf used to install in /usr/include, now installs in /usr/include/libdwarf.
 579 AC_CHECK_HEADERS([libdwarf/dwarf.h dwarf.h], [break])
 580 # Check whether we have both the library and the header
 581 have_libdwarf=no
 582 AS_IF([test "x${ac_cv_header_libdwarf_dwarf_h}" = xyes], [have_libdwarf=yes])
 583 AS_IF([test "x${ac_cv_header_dwarf_h}" = xyes], [have_libdwarf=yes])
 584 if test "x${follytestmain}" = "xyes"; then
 585    AS_IF([test "x${have_libdwarf}" = xno], [AC_MSG_ERROR([Please install libdwarf development library and headers])])
 586    AC_CHECK_HEADERS([elf.h],, AC_MSG_ERROR([Please install libelf development package]))
 587    AC_CHECK_HEADERS([libunwind.h],, AC_MSG_ERROR([Please install libunwind development package]))
 588 else
 589    AS_IF([test "x${have_libdwarf}" = xno],, [use_follytestmain=no])
 590    AC_CHECK_HEADERS([elf.h],, [use_follytestmain=no])
 591    AC_CHECK_HEADERS([libunwind.h],, [use_follytestmain=no])
 592 fi
 593
 594 AC_ARG_ENABLE([mobile],
 595    AS_HELP_STRING([--enable-mobile],
 596                   [enables using main function from folly for tests]),
 597                   [mobile=${enableval}], [mobile=no])
 598 AS_IF([test "x${mobile}" = "xyes"], [
 599     AC_DEFINE([MOBILE], [1],
 600               [Define to 1 for compiler guards for mobile targets.])
 601 ])
 602
 603 # Include directory that contains "folly" so #include <folly/Foo.h> works
 604 AM_CPPFLAGS='-I$(top_srcdir)/..'
 605 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 606 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 607 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 608 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 609 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 610
 611 AM_LDFLAGS="$AM_LDFLAGS $OPENSSL_LDFLAGS $OPENSSL_LIBS"
 612
 613 AC_SUBST([AM_CPPFLAGS])
 614 AC_SUBST([AM_LDFLAGS])
 615
 616 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 617 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 618 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 619 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 620 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 621 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 622                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 623 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT_H], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 624 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 625                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 626 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 627 AM_CONDITIONAL([HAVE_BOOST_CONTEXT], [test "x${ax_cv_boost_context}" = "xyes"])
 628
 629 # remove pkg-config deps from dependent libraries
 630 # (at least for pkg-config file purposes)
 631 FB_FILTER_PKG_LIBS([$AM_LDFLAGS $LIBS])
 632
 633 # Output
 634 AC_CONFIG_FILES([Makefile
 635                  libfolly.pc
 636                  test/Makefile
 637                  test/function_benchmark/Makefile
 638                  experimental/Makefile
 639                  experimental/symbolizer/Makefile
 640                  init/Makefile])
 641 AC_OUTPUT