folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 AC_CONFIG_SRCDIR([Likely.h])
  16 AC_CONFIG_HEADERS([config.h])
  17 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  18 AC_CONFIG_AUX_DIR([build-aux])
  19
  20 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  21
  22 AC_CONFIG_MACRO_DIR([m4])
  23
  24 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  25 AX_CONFIG_FEATURE(
  26         [deprecated-assoc],
  27         [supports deprecated associative containers (hash_map/hash_set)],
  28         [HAVE_DEPRECATED_ASSOC],
  29         [Define if you want to support deprecated associative containers])
  30
  31 AC_PROG_INSTALL
  32 AM_PROG_LIBTOOL
  33
  34 AC_LANG([C++])
  35
  36 # Checks for programs.
  37 AC_PROG_CXX
  38 AC_PROG_CC
  39 AC_CXX_COMPILE_STDCXX_0X
  40
  41 # Be sure to add any -std option to CXXFLAGS before we invoke any
  42 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  43 # before we update CXXFLAGS will not be run with the same options that we use
  44 # during the real build.
  45 STD=""
  46 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  47    STD="-std=c++0x"
  48 fi
  49 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  50    STD="-std=gnu++0x"
  51 fi
  52
  53 CXXFLAGS="$STD $CXXFLAGS"
  54
  55 # Checks for libraries.
  56 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  57              [Please install google-glog library])])
  58 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  59              [Please install google-gflags library])])
  60
  61 AC_CHECK_LIB(ssl,
  62         SSL_ctrl,
  63         [],
  64         [AC_MSG_ERROR(["Error: libssl required"])])
  65
  66 # check for boost libs
  67 AX_BOOST_BASE([1.20.0], [], [AC_MSG_ERROR(
  68               [Please install boost >= 1.20.0 (thread, regex, and system)])])
  69 AX_BOOST_THREAD
  70 AX_BOOST_REGEX
  71 AX_BOOST_SYSTEM
  72 AX_BOOST_FILESYSTEM
  73
  74 # Checks for header files.
  75 AC_HEADER_STDC
  76 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h bits/functexcept.h bits/c++config.h])
  77
  78 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
  79                 [Couldn't find double-conversion.h, please download from \
  80                  https://github.com/floitsch/double-conversion/])], [])
  81 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
  82              [Please install double-conversion library])])
  83
  84 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
  85
  86 AC_CHECK_LIB([jemalloc], [xallocx])
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_HEADER_STDBOOL
  90 AC_C_CONST
  91 AC_C_INLINE
  92 AC_TYPE_SIZE_T
  93 AC_HEADER_TIME
  94 AC_C_VOLATILE
  95 AC_CHECK_TYPE([__int128], AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128]))
  96 AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
  97
  98 AC_CACHE_CHECK(
  99   [for ifunc support],
 100   [folly_cv_prog_cc_ifunc],
 101   [AC_COMPILE_IFELSE(
 102     [AC_LANG_SOURCE[
 103       #pragma GCC diagnostic error "-Wattributes"
 104       extern "C" void (*test_ifunc(void))() { return 0; }
 105       void func() __attribute__((ifunc("test_ifunc")));]
 106     ],
 107     [folly_cv_prog_cc_ifunc=yes],
 108     [folly_cv_prog_cc_ifunc=no])])
 109
 110 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 111   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 112 fi
 113
 114 AC_CACHE_CHECK(
 115   [for final and override support],
 116   [folly_cv_c_final_override],
 117   [AC_COMPILE_IFELSE(
 118     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 119                     class D : public C { virtual void g() override {} };]],
 120     [folly_cv_c_final_override=yes],
 121     [folly_cv_c_final_override=no])])
 122
 123 if test "$folly_cv_c_final_override" = "yes"; then
 124   final_val=final
 125   override_val=override
 126 else
 127   final_val=
 128   override_val=
 129 fi
 130
 131 AC_DEFINE_UNQUOTED(
 132   [FINAL], [$final_val],
 133   [Define to "final" if the compiler supports C++11 "final"])
 134 AC_DEFINE_UNQUOTED(
 135   [OVERRIDE], [$override_val],
 136   [Define to "override" if the compiler supports C++11 "override"])
 137
 138 AC_CACHE_CHECK(
 139   [for std::this_thread::sleep_for],
 140   [folly_cv_func_this_thread_sleep_for],
 141   [AC_COMPILE_IFELSE(
 142     [AC_LANG_SOURCE[
 143       #include <thread>
 144       #include <chrono>
 145       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 146     [folly_cv_func_this_thread_sleep_for=yes],
 147     [folly_cv_func_this_thread_sleep_for=no])])
 148
 149 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 150     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 151               [Define to 1 if std::this_thread::sleep_for() is defined.])
 152 fi
 153
 154 AC_CACHE_CHECK(
 155   [for constexpr strlen],
 156   [folly_cv_func_constexpr_strlen],
 157   [AC_COMPILE_IFELSE(
 158     [AC_LANG_SOURCE[
 159       #include <cstring>
 160       static constexpr int val = strlen("foo");]],
 161     [folly_cv_func_constexpr_strlen=yes],
 162     [folly_cv_func_constexpr_strlen=no])])
 163
 164 if test "$folly_cv_func_constexpr_strlen" = yes; then
 165     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 166               [Define to 1 if strlen(3) is constexpr.])
 167 fi
 168
 169 AC_CACHE_CHECK(
 170   [for libc++],
 171   [folly_cv_lib_libcpp],
 172   [AC_COMPILE_IFELSE(
 173     [AC_LANG_SOURCE[
 174       #include <type_traits>
 175       #if !_LIBCPP_VERSION
 176       #error No libc++
 177       #endif
 178       void func() {}]
 179     ],
 180     [folly_cv_lib_libcpp=yes],
 181     [folly_cv_lib_libcpp=no])])
 182
 183 if test "$folly_cv_lib_libcpp" = yes; then
 184   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we're using libc++.])
 185 fi
 186
 187 AC_CACHE_CHECK(
 188   [for usable std::is_trivially_copyable],
 189   [folly_cv_decl_std_is_trivially_copyable],
 190   [AC_COMPILE_IFELSE(
 191     [AC_LANG_SOURCE[
 192       #include <type_traits>
 193       const bool val = std::is_trivially_copyable<bool>::value;]
 194     ],
 195     [folly_cv_decl_std_is_trivially_copyable=yes],
 196     [folly_cv_decl_std_is_trivially_copyable=no])])
 197
 198 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 199   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 200             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 201              implementation.])
 202 fi
 203
 204 AC_CACHE_CHECK(
 205   [gflags namespace],
 206   [folly_cv_decl_gflags_namespace],
 207   [AC_COMPILE_IFELSE(
 208     [AC_LANG_SOURCE[
 209       #include <gflags/gflags.h>
 210       void foo() { gflags::GetArgv(); }]
 211     ],
 212     [folly_cv_decl_gflags_namespace=gflags],
 213     [AC_COMPILE_IFELSE(
 214       [AC_LANG_SOURCE[
 215         #include <gflags/gflags.h>
 216         void foo() { google::GetArgv(); }]
 217       ],
 218       [folly_cv_decl_gflags_namespace=google],
 219       [folly_cv_decl_gflags_namespace=error])])])
 220
 221 if test "$folly_cv_decl_gflags_namespace" = error; then
 222   AC_MSG_ERROR([Cannot determine gflags namespace])
 223 else
 224   AC_DEFINE_UNQUOTED(
 225     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 226     [Define to gflags namespace (usually "google" or "gflags")])
 227   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 228      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 229                [Define to 1 if the gflags namespace is not "gflags"])
 230   fi
 231 fi
 232
 233 # Figure out if we support weak symbols. If not, we will link in some null
 234 # stubs for functions that would otherwise be weak.
 235 AC_CACHE_CHECK(
 236   [for weak symbol support],
 237   [folly_cv_prog_cc_weak_symbols],
 238   [AC_LINK_IFELSE(
 239     [AC_LANG_SOURCE[
 240       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 241       int main(int argc, char** argv) {
 242           return configure_link_extern_weak_test == nullptr;
 243       }]],
 244     [folly_cv_prog_cc_weak_symbols="yes"],
 245     [folly_cv_prog_cc_weak_symbols="no"])])
 246
 247 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 248   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 249             [Define to 1 if the linker supports weak symbols.])
 250 fi
 251
 252 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 253 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 254   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 255             [Define to 1 if we have cplus_demangle_v3_callback.])
 256 fi
 257
 258 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 259 # want to link with librt if necessary.
 260 AC_SEARCH_LIBS([clock_gettime], [rt],
 261   AC_DEFINE(
 262     [HAVE_CLOCK_GETTIME],
 263     [1],
 264     [Define to 1 if we support clock_gettime(2).]),
 265   [])
 266
 267 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 268 # want to include pthread.h if necessary.
 269 AC_CACHE_CHECK(
 270   [for pthread_atfork support],
 271   [folly_cv_prog_cc_pthread_atfork],
 272   [AC_COMPILE_IFELSE(
 273     [AC_LANG_SOURCE[
 274       #include <pthread.h>
 275       void func() {pthread_atfork(NULL, NULL, NULL);}]
 276     ],
 277     [folly_cv_prog_cc_pthread_atfork=yes],
 278     [folly_cv_prog_cc_pthread_atfork=no])])
 279
 280 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 281   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 282 fi
 283
 284 # Checks for library functions.
 285 AC_CHECK_FUNCS([getdelim \
 286                 gettimeofday \
 287                 memmove \
 288                 memset \
 289                 pow \
 290                 strerror \
 291                 pthread_yield \
 292                 malloc_size \
 293                 malloc_usable_size \
 294                 memrchr \
 295                 pipe2])
 296
 297 if test "$ac_cv_func_pthread_yield" = "no"; then
 298    AC_CHECK_HEADERS([sched.h])
 299    AC_CHECK_FUNCS([sched_yield])
 300 fi
 301
 302 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 303 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 304 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 305 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 306
 307 # Include directory that contains "folly" so #include <folly/Foo.h> works
 308 AM_CPPFLAGS='-I$(top_srcdir)/..'
 309 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 310 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 311 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 312
 313 AC_SUBST([AM_CPPFLAGS])
 314 AC_SUBST([AM_LDFLAGS])
 315
 316 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 317 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 318 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 319 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 320                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 321 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 322
 323 # Output
 324 AC_CONFIG_FILES([Makefile
 325                  test/Makefile
 326                  test/function_benchmark/Makefile])
 327 AC_OUTPUT