folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 #declare pkg-config variables
  16 PKG_VERSION=m4_join([.], m4_reverse(m4_translit(folly_version_str, [:], [,])))
  17 AC_SUBST([PKG_VERSION])
  18 AC_SUBST([PKG_CXXFLAGS])
  19 AC_SUBST([PKG_DEPS])
  20 AC_SUBST([PKG_LIBS])
  21
  22 AC_CONFIG_SRCDIR([Likely.h])
  23 AC_CONFIG_HEADERS([config.h])
  24 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  32 AX_CONFIG_FEATURE(
  33         [deprecated-assoc],
  34         [supports deprecated associative containers (hash_map/hash_set)],
  35         [HAVE_DEPRECATED_ASSOC],
  36         [Define if you want to support deprecated associative containers])
  37
  38 AC_PROG_INSTALL
  39 AM_PROG_LIBTOOL
  40
  41 AC_LANG([C++])
  42
  43 # Checks for programs.
  44 AC_PROG_CXX
  45 AC_PROG_CC
  46
  47 AC_CXX_COMPILE_STDCXX_1Y
  48
  49 # Be sure to add any -std option to CXXFLAGS before we invoke any
  50 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  51 # before we update CXXFLAGS will not be run with the same options that we use
  52 # during the real build.
  53 STD=""
  54 if test "x$ac_cv_cxx_compile_cxx1y_cxx" = xyes; then
  55    STD="-std=c++1y"
  56 fi
  57 if test "x$ac_cv_cxx_compile_cxx1y_gxx" = xyes; then
  58    STD="-std=gnu++1y"
  59 fi
  60
  61 CXXFLAGS="$STD $CXXFLAGS"
  62
  63 # expose required -std option via pkg-config
  64 PKG_CXXFLAGS=$STD
  65
  66 # Checks for glog and gflags
  67 # There are no symbols with C linkage, so we do a try-run
  68 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  69                 [Please install google-gflags library])])
  70 AC_CACHE_CHECK(
  71   [for gflags viability],
  72   [folly_cv_prog_cc_gflags],
  73   [AC_RUN_IFELSE(
  74     [AC_LANG_SOURCE[
  75       #include <gflags/gflags.h>
  76       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  77       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  78       int main(int argc, char** argv) {
  79         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  80       }
  81     ]],
  82     [folly_cv_prog_cc_gflags=yes],
  83     [folly_cv_prog_cc_gflags=no]
  84   )]
  85 )
  86
  87 if test "$folly_cv_prog_cc_gflags" != "yes"; then
  88   AC_MSG_ERROR(["libgflags invalid, see config.log for details"])
  89 fi
  90 FB_CHECK_PKG_CONFIG([GFLAGS], [libgflags])
  91
  92 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
  93                 [Please install google-glog library])])
  94 AC_CACHE_CHECK(
  95   [for glog viability],
  96   [folly_cv_prog_cc_glog],
  97   [AC_RUN_IFELSE(
  98     [AC_LANG_SOURCE[
  99       #include <glog/logging.h>
 100       int main(int argc, char** argv) {
 101         google::InitGoogleLogging(argv[0]);
 102         google::ShutdownGoogleLogging();
 103         return 0;
 104       }
 105     ]],
 106     [folly_cv_prog_cc_glog=yes],
 107     [folly_cv_prog_cc_glog=no]
 108   )]
 109 )
 110
 111 if test "$folly_cv_prog_cc_glog" != "yes"; then
 112   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
 113 fi
 114 FB_CHECK_PKG_CONFIG([GLOG], [libglog])
 115
 116 AX_CHECK_OPENSSL([],
 117         [AC_MSG_ERROR(["Error: libssl required"])])
 118 FB_CHECK_PKG_CONFIG([OPENSSL], [openssl])
 119
 120 # check for boost libs
 121 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 122               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 123 AX_BOOST_CONTEXT
 124 AX_BOOST_PROGRAM_OPTIONS
 125 AX_BOOST_THREAD
 126 AX_BOOST_REGEX
 127 AX_BOOST_SYSTEM
 128 AX_BOOST_FILESYSTEM
 129 AX_BOOST_CHRONO
 130
 131 # Check for python interpreter
 132 AM_PATH_PYTHON
 133
 134 # Checks for header files.
 135 AC_HEADER_STDC
 136 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h sched.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h byteswap.h bits/functexcept.h bits/c++config.h])
 137
 138 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 139                 [Couldn't find double-conversion.h, please download from \
 140                  https://github.com/google/double-conversion/])], [])
 141 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 142              [Please install double-conversion library])])
 143
 144 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 145 FB_CHECK_PKG_CONFIG([EVENT], [libevent])
 146
 147 AC_CHECK_LIB([jemalloc], [xallocx])
 148
 149 # Checks for typedefs, structures, and compiler characteristics.
 150 AC_HEADER_STDBOOL
 151 AC_C_CONST
 152 AC_C_INLINE
 153 AC_TYPE_SIZE_T
 154 AC_HEADER_TIME
 155 AC_C_VOLATILE
 156 AC_CHECK_TYPE([__int128], [folly_cv_prog_cc_int128=yes],
 157     [folly_cv_prog_cc_int128=no])
 158 if test "$folly_cv_prog_cc_int128" = "yes"; then
 159   AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128])
 160   AC_CACHE_CHECK(
 161     [for __int128 type traits],
 162     [folly_cv_prog_cc_int128traits],
 163     [AC_COMPILE_IFELSE(
 164       [AC_LANG_SOURCE([[
 165 #include <type_traits>
 166 static_assert(
 167   ::std::is_same<::std::make_signed<unsigned __int128>::type, __int128>::value,
 168   "signed form of `unsigned __uint128` must be `__int128`.");
 169       ]])],
 170       [folly_cv_prog_cc_int128traits=yes],
 171       [folly_cv_prog_cc_int128traits=no])
 172     ])
 173   if test "$folly_cv_prog_cc_int128traits" = "no"; then
 174     AC_DEFINE([SUPPLY_MISSING_INT128_TRAITS], [1], [Define if we need the standard integer traits defined for the type `__int128'.])
 175   fi
 176 fi
 177
 178 AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
 179
 180 AC_CACHE_CHECK(
 181   [for ifunc support],
 182   [folly_cv_prog_cc_ifunc],
 183   [AC_COMPILE_IFELSE(
 184     [AC_LANG_SOURCE[
 185       #pragma GCC diagnostic error "-Wattributes"
 186       extern "C" void (*test_ifunc(void))() { return 0; }
 187       void func() __attribute__((ifunc("test_ifunc")));]
 188     ],
 189     [folly_cv_prog_cc_ifunc=yes],
 190     [folly_cv_prog_cc_ifunc=no])])
 191
 192 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 193   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 194 fi
 195
 196 AC_CACHE_CHECK(
 197   [for final and override support],
 198   [folly_cv_c_final_override],
 199   [AC_COMPILE_IFELSE(
 200     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 201                     class D : public C { virtual void g() override {} };]],
 202     [folly_cv_c_final_override=yes],
 203     [folly_cv_c_final_override=no])])
 204
 205 if test "$folly_cv_c_final_override" = "yes"; then
 206   final_val=final
 207   override_val=override
 208 else
 209   final_val=
 210   override_val=
 211 fi
 212
 213 AC_DEFINE_UNQUOTED(
 214   [FINAL], [$final_val],
 215   [Define to "final" if the compiler supports C++11 "final"])
 216 AC_DEFINE_UNQUOTED(
 217   [OVERRIDE], [$override_val],
 218   [Define to "override" if the compiler supports C++11 "override"])
 219
 220 AC_CACHE_CHECK(
 221   [for std::this_thread::sleep_for],
 222   [folly_cv_func_this_thread_sleep_for],
 223   [AC_COMPILE_IFELSE(
 224     [AC_LANG_SOURCE[
 225       #include <thread>
 226       #include <chrono>
 227       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 228     [folly_cv_func_this_thread_sleep_for=yes],
 229     [folly_cv_func_this_thread_sleep_for=no])])
 230
 231 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 232     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 233               [Define to 1 if std::this_thread::sleep_for() is defined.])
 234 fi
 235
 236 AC_CACHE_CHECK(
 237   [for constexpr strlen],
 238   [folly_cv_func_constexpr_strlen],
 239   [AC_COMPILE_IFELSE(
 240     [AC_LANG_SOURCE[
 241       #include <cstring>
 242       static constexpr int val = strlen("foo");]],
 243     [folly_cv_func_constexpr_strlen=yes],
 244     [folly_cv_func_constexpr_strlen=no])])
 245
 246 if test "$folly_cv_func_constexpr_strlen" = yes; then
 247     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 248               [Define to 1 if strlen(3) is constexpr.])
 249 fi
 250
 251 AC_CACHE_CHECK(
 252   [for libc++],
 253   [folly_cv_lib_libcpp],
 254   [AC_COMPILE_IFELSE(
 255     [AC_LANG_SOURCE[
 256       #include <type_traits>
 257       #if !_LIBCPP_VERSION
 258       #error No libc++
 259       #endif
 260       void func() {}]
 261     ],
 262     [folly_cv_lib_libcpp=yes],
 263     [folly_cv_lib_libcpp=no])])
 264
 265 if test "$folly_cv_lib_libcpp" = yes; then
 266   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 267 fi
 268
 269 AC_CACHE_CHECK(
 270   [for c++11 atomic support without GNU Atomic library],
 271   [folly_cv_lib_libatomic],
 272   [AC_LINK_IFELSE(
 273     [AC_LANG_SOURCE[
 274       #include <atomic>
 275       int main() {
 276         struct Test { int val; };
 277         std::atomic<Test> s;
 278         s.is_lock_free();
 279       }
 280     ]],
 281     [folly_cv_lib_libatomic=yes],
 282     [folly_cv_lib_libatomic=no])])
 283
 284 if test "$folly_cv_lib_libatomic" = no; then
 285   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 286                   [Please install the GNU Atomic library])])
 287 fi
 288
 289 AC_CACHE_CHECK(
 290   [for liblinux-vdso support],
 291   [folly_cv_lib_liblinux_vdso],
 292   [AC_RUN_IFELSE(
 293     [AC_LANG_PROGRAM[
 294       #include <dlfcn.h>
 295       int main() {
 296         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 297         if (h == nullptr) {
 298           return -1;
 299         }
 300         dlclose(h);
 301         return 0;
 302       }
 303     ]],
 304     [folly_cv_lib_liblinux_vdso=yes],
 305     [folly_cv_lib_liblinux_vdso=no])])
 306
 307 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 308   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 309 fi
 310
 311 AC_CACHE_CHECK(
 312   [for usable std::is_trivially_copyable],
 313   [folly_cv_decl_std_is_trivially_copyable],
 314   [AC_COMPILE_IFELSE(
 315     [AC_LANG_SOURCE[
 316       #include <type_traits>
 317       const bool val = std::is_trivially_copyable<bool>::value;]
 318     ],
 319     [folly_cv_decl_std_is_trivially_copyable=yes],
 320     [folly_cv_decl_std_is_trivially_copyable=no])])
 321
 322 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 323   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 324             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 325              implementation.])
 326 fi
 327
 328 AC_CACHE_CHECK(
 329   [gflags namespace],
 330   [folly_cv_decl_gflags_namespace],
 331   [AC_COMPILE_IFELSE(
 332     [AC_LANG_SOURCE[
 333       #include <gflags/gflags.h>
 334       void foo() { gflags::GetArgv(); }]
 335     ],
 336     [folly_cv_decl_gflags_namespace=gflags],
 337     [AC_COMPILE_IFELSE(
 338       [AC_LANG_SOURCE[
 339         #include <gflags/gflags.h>
 340         void foo() { google::GetArgv(); }]
 341       ],
 342       [folly_cv_decl_gflags_namespace=google],
 343       [folly_cv_decl_gflags_namespace=error])])])
 344
 345 if test "$folly_cv_decl_gflags_namespace" = error; then
 346   AC_MSG_ERROR([Cannot determine gflags namespace])
 347 else
 348   AC_DEFINE_UNQUOTED(
 349     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 350     [Define to gflags namespace (usually "google" or "gflags")])
 351   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 352      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 353                [Define to 1 if the gflags namespace is not "gflags"])
 354   fi
 355 fi
 356
 357 # Figure out if we support weak symbols. If not, we will link in some null
 358 # stubs for functions that would otherwise be weak.
 359 AC_CACHE_CHECK(
 360   [for weak symbol support],
 361   [folly_cv_prog_cc_weak_symbols],
 362   [AC_LINK_IFELSE(
 363     [AC_LANG_SOURCE[
 364       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 365       int main(int argc, char** argv) {
 366           return configure_link_extern_weak_test == nullptr;
 367       }]],
 368     [folly_cv_prog_cc_weak_symbols="yes"],
 369     [folly_cv_prog_cc_weak_symbols="no"])])
 370
 371 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 372   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 373             [Define to 1 if the linker supports weak symbols.])
 374 fi
 375
 376
 377 # Figure out if we support wchar well
 378 AC_CACHE_CHECK(
 379   [for wchar support],
 380   [folly_cv_prog_cc_wchar_support],
 381   [AC_RUN_IFELSE(
 382     [AC_LANG_SOURCE[
 383       #include <cstddef>
 384       #include <cwchar>
 385
 386       int main(int argc, char** argv) {
 387         return wcstol(L"01", nullptr, 10) == 1 ? 0 : 1;
 388       }
 389     ]],
 390     [folly_cv_prog_cc_wchar_support=yes],
 391     [folly_cv_prog_cc_wchar_support=no])])
 392
 393 if test "$folly_cv_prog_cc_wchar_support" = "yes"; then
 394   AC_DEFINE([HAVE_WCHAR_SUPPORT], [1], [Define to 1 if the libc supports wchar well])
 395 fi
 396
 397 # Figure out whether the architecture supports unaligned accesses
 398 AC_CACHE_CHECK(
 399   [for unaligned access support],
 400   [folly_cv_prog_cc_unaligned_access],
 401   [AC_RUN_IFELSE(
 402     [AC_LANG_SOURCE[
 403       int main(int argc, char** argv) {
 404         char buf[64] = {0};
 405         unsigned long *ptr = (unsigned long *)(buf + 1);
 406         *ptr = 0xdeadbeef;
 407         return (*ptr & 0xff) == 0xef ? 0 : 1;
 408       }
 409     ]],
 410     [folly_cv_prog_cc_unaligned_access=yes],
 411     [folly_cv_prog_cc_unaligned_access=no])])
 412
 413 if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
 414   AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
 415 fi
 416
 417 AC_CACHE_CHECK(
 418   [for vsnprintf reporting bad format strings],
 419   [folly_cv_prog_vsnprintf_bad_format],
 420   [AC_RUN_IFELSE(
 421     [AC_LANG_SOURCE[
 422       #include <stdio.h>
 423
 424       int main(int argc, char** argv) {
 425           char buf[256];
 426           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 427       }]],
 428     [folly_cv_prog_vsnprintf_bad_format="yes"],
 429     [folly_cv_prog_vsnprintf_bad_format="no"])])
 430
 431 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 432   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 433             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 434 fi
 435
 436 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 437 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 438   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 439             [Define to 1 if we have cplus_demangle_v3_callback.])
 440 fi
 441
 442 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 443 # want to link with librt if necessary.
 444 AC_SEARCH_LIBS([clock_gettime], [rt],
 445   AC_DEFINE(
 446     [HAVE_CLOCK_GETTIME],
 447     [1],
 448     [Define to 1 if we support clock_gettime(2).]),
 449   [])
 450
 451 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 452 # want to include pthread.h if necessary.
 453 AC_CACHE_CHECK(
 454   [for pthread_atfork support],
 455   [folly_cv_prog_cc_pthread_atfork],
 456   [AC_COMPILE_IFELSE(
 457     [AC_LANG_SOURCE[
 458       #include <pthread.h>
 459       void func() {pthread_atfork(NULL, NULL, NULL);}]
 460     ],
 461     [folly_cv_prog_cc_pthread_atfork=yes],
 462     [folly_cv_prog_cc_pthread_atfork=no])])
 463
 464 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 465   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 466 fi
 467
 468 # Check for XSI-compatible strerror_r as default implementation
 469 AC_CACHE_CHECK(
 470   [for XSI style strerror_r support],
 471   [folly_cv_prog_cc_xsi_strerror_r],
 472   [AC_RUN_IFELSE(
 473     [AC_LANG_SOURCE[
 474       #include <string.h>
 475       #include <errno.h>
 476       int main(int argc, char** argv) {
 477         char buf[1024];
 478         buf[0] = 0;
 479         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 480         return ret;
 481       }
 482     ]],
 483     [folly_cv_prog_cc_xsi_strerror_r=yes],
 484     [folly_cv_prog_cc_xsi_strerror_r=no])])
 485
 486 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 487   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 488 fi
 489
 490 AC_CACHE_CHECK(
 491   [for ext/random and __gnu_cxx::sfmt19937],
 492   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 493   [AC_COMPILE_IFELSE(
 494     [AC_LANG_SOURCE[
 495       #include <ext/random>
 496       int main(int argc, char** argv) {
 497         __gnu_cxx::sfmt19937 rng;
 498         return 0;
 499       }
 500     ]],
 501     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 502     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 503
 504 AC_CACHE_CHECK(
 505   [for VLA (variable-length array) support],
 506   [folly_cv_prog_cc_have_vla],
 507   [AC_COMPILE_IFELSE(
 508     [AC_LANG_SOURCE[
 509       int main(int argc, char** argv) {
 510         unsigned size = argc;
 511         char data[size];
 512         return 0;
 513       }
 514     ]],
 515     [folly_cv_prog_cc_have_vla=yes],
 516     [folly_cv_prog_cc_have_vla=no])])
 517
 518 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 519 AC_DEFINE_UNQUOTED(
 520   [HAVE_VLA],
 521   [$have_vla],
 522   [Define to 1 if the compiler has VLA (variable-length array) support,
 523    otherwise define to 0])
 524
 525 # Checks for library functions.
 526 AC_CHECK_FUNCS([getdelim \
 527                 gettimeofday \
 528                 memmove \
 529                 memset \
 530                 pow \
 531                 strerror \
 532                 sched_yield \
 533                 malloc_size \
 534                 malloc_usable_size \
 535                 memrchr \
 536                 pipe2 \
 537                 preadv \
 538                 pwritev \
 539               ])
 540
 541 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 542 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 543 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 544 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 545 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [main]))
 546 AC_CHECK_HEADER([linux/membarrier.h], AC_DEFINE([HAVE_LINUX_MEMBARRIER_H], [1], [Define to 1 if membarrier.h is available]))
 547
 548 AC_ARG_ENABLE([follytestmain],
 549    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 550    [follytestmain=${enableval}], [follytestmain=no])
 551
 552 use_follytestmain=yes
 553 if test "x${follytestmain}" = "xyes"; then
 554    AC_CHECK_HEADERS([libdwarf.h dwarf.h],, AC_MSG_ERROR([Please install libdwarf development package]))
 555    AC_CHECK_HEADERS([libelf.h elf.h],, AC_MSG_ERROR([Please install libelf development package]))
 556    AC_CHECK_HEADERS([libunwind.h],, AC_MSG_ERROR([Please install libinwind development package]))
 557 else
 558    AC_CHECK_HEADERS([libdwarf.h dwarf.h],, [use_follytestmain=no])
 559    AC_CHECK_HEADERS([libelf.h elf.h],, [use_follytestmain=no])
 560    AC_CHECK_HEADERS([libunwind.h],, [use_follytestmain=no])
 561 fi
 562
 563 AC_ARG_ENABLE([mobile],
 564    AS_HELP_STRING([--enable-mobile],
 565                   [enables using main function from folly for tests]),
 566                   [mobile=${enableval}], [mobile=no])
 567 AS_IF([test "x${mobile}" = "xyes"], [
 568     AC_DEFINE([MOBILE], [1],
 569               [Define to 1 for compiler guards for mobile targets.])
 570 ])
 571
 572 # Include directory that contains "folly" so #include <folly/Foo.h> works
 573 AM_CPPFLAGS='-I$(top_srcdir)/..'
 574 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 575 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 576 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 577 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 578 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 579
 580 AM_LDFLAGS="$AM_LDFLAGS $OPENSSL_LDFLAGS $OPENSSL_LIBS"
 581
 582 AC_SUBST([AM_CPPFLAGS])
 583 AC_SUBST([AM_LDFLAGS])
 584
 585 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 586 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 587 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 588 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 589 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 590 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 591                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 592 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT_H], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 593 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 594                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 595 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 596 AM_CONDITIONAL([HAVE_BOOST_CONTEXT], [test "x${ax_cv_boost_context}" = "xyes"])
 597
 598 # remove pkg-config deps from dependent libraries
 599 # (at least for pkg-config file purposes)
 600 FB_FILTER_PKG_LIBS([$AM_LDFLAGS $LIBS])
 601
 602 # Output
 603 AC_CONFIG_FILES([Makefile
 604                  libfolly.pc
 605                  test/Makefile
 606                  test/function_benchmark/Makefile
 607                  experimental/Makefile
 608                  experimental/symbolizer/Makefile
 609                  init/Makefile])
 610 AC_OUTPUT