folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6 AC_INIT(folly, 0.1, folly@fb.com)
   7 AC_CONFIG_SRCDIR([Likely.h])
   8 AC_CONFIG_HEADERS([config.h])
   9 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11
  12 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  13
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AC_PROG_INSTALL
  17 AM_PROG_LIBTOOL
  18
  19 AC_LANG([C++])
  20
  21 # Checks for programs.
  22 AC_PROG_CXX
  23 AC_PROG_CC
  24 AC_CXX_COMPILE_STDCXX_0X
  25
  26 # Checks for libraries.
  27 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  28              [Please install google-glog library])])
  29 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  30              [Please install google-gflags library])])
  31
  32 # check for boost libs
  33 AX_BOOST_BASE
  34 AX_BOOST_THREAD
  35 AX_BOOST_REGEX
  36 AX_BOOST_SYSTEM
  37
  38 # Checks for header files.
  39 AC_HEADER_STDC
  40 AC_CHECK_HEADERS([fcntl.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h features.h malloc.h emmintrin.h])
  41
  42 AC_CHECK_HEADER(double-conversion.h, [], [AC_MSG_ERROR(
  43                 [Couldn't find double-conversion.h, please download from \
  44                 http://code.google.com/p/double-conversion/])], [])
  45 AC_CHECK_LIB([double_conversion_pic],[ceil],[],[AC_MSG_ERROR(
  46              [Please install double-conversion library])])
  47
  48 # Checks for typedefs, structures, and compiler characteristics.
  49 AC_HEADER_STDBOOL
  50 AC_C_CONST
  51 AC_C_INLINE
  52 AC_TYPE_SIZE_T
  53 AC_HEADER_TIME
  54 AC_C_VOLATILE
  55 AC_CHECK_TYPE([__int128],
  56   [AC_DEFINE([HAVE_INT128_T], [1], [Define if __int128 exists])],
  57   [AC_DEFINE([HAVE_INT128_T], [0], [Define if __int128 does not exist])])
  58 AC_CHECK_TYPES([ptrdiff_t])
  59 AC_COMPILE_IFELSE(
  60   [AC_LANG_SOURCE[extern "C" void (*test_ifunc(void))() { return 0; }
  61                   void func() __attribute__((ifunc("test_ifunc")));]],
  62   [AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])],
  63   [AC_DEFINE([HAVE_IFUNC], [0], [Define to 0 if the compiler doesn't support ifunc])]
  64 )
  65
  66 # Checks for library functions.
  67 AC_CHECK_FUNCS([getdelim \
  68                 gettimeofday \
  69                 memmove \
  70                 memset \
  71                 pow \
  72                 strerror \
  73                 pthread_yield \
  74                 rallocm \
  75                 malloc_size \
  76                 malloc_usable_size])
  77
  78 if test "$ac_cv_func_pthread_yield" = "no"; then
  79    AC_CHECK_HEADERS([sched.h])
  80    AC_CHECK_FUNCS([sched_yield])
  81 fi
  82
  83 CXX_FLAGS=""
  84 if test "$ac_cv_cxx_compile_cxx0x_cxx" = yes; then
  85    CXX_FLAGS="-std=c++0x"
  86 fi
  87 if test "$ac_cv_cxx_compile_cxx0x_gxx" = yes; then
  88    CXX_FLAGS="-std=gnu++0x"
  89 fi
  90
  91 AC_SUBST(AM_CPPFLAGS, '-I../$(top_srcdir)'" "'-I$(top_srcdir)/io'" "'-I$(top_srcdir)/test'" -lstdc++ $CXX_FLAGS $BOOST_CPPFLAGS")
  92 AC_SUBST(AM_CXXFLAGS, "$BOOST_THREAD_LIB $BOOST_SYSTEM_LIB")
  93
  94 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
  95 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
  96
  97 # Output
  98 AC_CONFIG_FILES([Makefile
  99                  test/Makefile
 100                  test/function_benchmark/Makefile])
 101 AC_OUTPUT