folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 #declare pkg-config variables
  16 PKG_VERSION=m4_join([.], m4_reverse(m4_translit(folly_version_str, [:], [,])))
  17 AC_SUBST([PKG_VERSION])
  18 AC_SUBST([PKG_CXXFLAGS])
  19 AC_SUBST([PKG_DEPS])
  20 AC_SUBST([PKG_LIBS])
  21
  22 AC_CONFIG_SRCDIR([Likely.h])
  23 AC_CONFIG_HEADERS([config.h])
  24 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  32 AX_CONFIG_FEATURE(
  33         [deprecated-assoc],
  34         [supports deprecated associative containers (hash_map/hash_set)],
  35         [HAVE_DEPRECATED_ASSOC],
  36         [Define if you want to support deprecated associative containers])
  37
  38 AC_PROG_INSTALL
  39 AM_PROG_LIBTOOL
  40
  41 AC_LANG([C++])
  42
  43 # Checks for programs.
  44 AC_PROG_CXX
  45 AC_PROG_CC
  46
  47 AC_CXX_COMPILE_STDCXX_1Y
  48
  49 # Be sure to add any -std option to CXXFLAGS before we invoke any
  50 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  51 # before we update CXXFLAGS will not be run with the same options that we use
  52 # during the real build.
  53 STD=""
  54 if test "x$ac_cv_cxx_compile_cxx1y_cxx" = xyes; then
  55    STD="-std=c++1y"
  56 fi
  57 if test "x$ac_cv_cxx_compile_cxx1y_gxx" = xyes; then
  58    STD="-std=gnu++1y"
  59 fi
  60
  61 CXXFLAGS="$STD $CXXFLAGS"
  62
  63 # expose required -std option via pkg-config
  64 PKG_CXXFLAGS=$STD
  65
  66 # See if -Wshadow-local and -Wshadow-compatible-local are supported
  67 AC_MSG_CHECKING(
  68   [whether -Wshadow-local and -Wshadow-compatible-local are supported])
  69 AC_CACHE_VAL([folly_cv_cxx_shadow_local_support], [
  70   folly_save_CXXFLAGS="$CXXFLAGS"
  71   CXXFLAGS="$CXXFLAGS -Wshadow-local -Wshadow-compatible-local"
  72   AC_COMPILE_IFELSE(
  73     [AC_LANG_PROGRAM([[]], [[]])],
  74     [folly_cv_cxx_shadow_local_support=yes],
  75     [folly_cv_cxx_shadow_local_support=no])
  76   CXXFLAGS="$folly_save_CXXFLAGS"])
  77 AC_MSG_RESULT([$folly_cv_cxx_shadow_local_support])
  78 if test "$folly_cv_cxx_shadow_local_support" = yes; then
  79   AC_DEFINE([HAVE_SHADOW_LOCAL_WARNINGS], [1],
  80   [Define if both -Wshadow-local and -Wshadow-compatible-local are supported.])
  81 fi
  82
  83 # Checks for glog and gflags
  84 # There are no symbols with C linkage, so we do a try-run
  85 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  86                 [Please install google-gflags library])])
  87 AC_CACHE_CHECK(
  88   [for gflags viability],
  89   [folly_cv_prog_cc_gflags],
  90   [AC_RUN_IFELSE(
  91     [AC_LANG_SOURCE[
  92       #include <gflags/gflags.h>
  93       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  94       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  95       int main(int argc, char** argv) {
  96         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  97       }
  98     ]],
  99     [folly_cv_prog_cc_gflags=yes],
 100     [folly_cv_prog_cc_gflags=no]
 101   )]
 102 )
 103
 104 if test "$folly_cv_prog_cc_gflags" != "yes"; then
 105   AC_MSG_ERROR(["gflags invalid, see config.log for details"])
 106 fi
 107 FB_CHECK_PKG_CONFIG([GFLAGS], [gflags])
 108
 109 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
 110                 [Please install google-glog library])])
 111 AC_CACHE_CHECK(
 112   [for glog viability],
 113   [folly_cv_prog_cc_glog],
 114   [AC_RUN_IFELSE(
 115     [AC_LANG_SOURCE[
 116       #include <glog/logging.h>
 117       int main(int argc, char** argv) {
 118         google::InitGoogleLogging(argv[0]);
 119         google::ShutdownGoogleLogging();
 120         return 0;
 121       }
 122     ]],
 123     [folly_cv_prog_cc_glog=yes],
 124     [folly_cv_prog_cc_glog=no]
 125   )]
 126 )
 127
 128 if test "$folly_cv_prog_cc_glog" != "yes"; then
 129   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
 130 fi
 131 FB_CHECK_PKG_CONFIG([GLOG], [libglog])
 132
 133 AS_IF(
 134   [test "x$OPENSSL_INCLUDES" = "x"],
 135   [
 136     AX_CHECK_OPENSSL([], [AC_MSG_ERROR(["Error: libssl required"])])
 137   ],
 138   [
 139     # AX_CHECK_OPENSSL doesn't seem to play nice with builds started
 140     # via build/bootstrap-osx-homebrew.sh
 141     AC_MSG_WARN(["Using existing OpenSSL flags from environment."])
 142     PKG_CXXFLAGS="$PKG_CXXFLAGS $OPENSSL_INCLUDES"
 143   ]
 144 )
 145 FB_CHECK_PKG_CONFIG([OPENSSL], [openssl])
 146
 147 # check for boost libs
 148 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 149               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 150 AX_BOOST_CONTEXT
 151 AX_BOOST_PROGRAM_OPTIONS
 152 AX_BOOST_THREAD
 153 AX_BOOST_REGEX
 154 AX_BOOST_SYSTEM
 155 AX_BOOST_FILESYSTEM
 156 AX_BOOST_CHRONO
 157
 158 # Check for python interpreter
 159 AM_PATH_PYTHON
 160
 161 # Checks for header files.
 162 AC_HEADER_STDC
 163 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h bits/functexcept.h bits/c++config.h])
 164
 165 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 166                 [Couldn't find double-conversion.h, please download from \
 167                  https://github.com/google/double-conversion/])], [])
 168 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 169              [Please install double-conversion library])])
 170
 171 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 172 FB_CHECK_PKG_CONFIG([EVENT], [libevent])
 173
 174 AC_ARG_WITH([jemalloc], [
 175   --with-jemalloc     Whether to make folly jemalloc aware
 176 ],[
 177   AC_CHECK_LIB([jemalloc], [xallocx],[
 178     AC_DEFINE([USE_JEMALLOC], [1], [Enable jemalloc])
 179   ],[
 180     AC_MSG_ERROR([--with-jemalloc requested, but jemalloc not found])
 181   ])
 182 ])
 183
 184 # Checks for typedefs, structures, and compiler characteristics.
 185 AC_HEADER_STDBOOL
 186 AC_C_CONST
 187 AC_C_INLINE
 188 AC_TYPE_SIZE_T
 189 AC_HEADER_TIME
 190 AC_C_VOLATILE
 191 AC_CHECK_TYPE([__int128], [folly_cv_prog_cc_int128=yes],
 192     [folly_cv_prog_cc_int128=no])
 193 if test "$folly_cv_prog_cc_int128" = "yes"; then
 194   AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128])
 195   AC_CACHE_CHECK(
 196     [for __int128 type traits],
 197     [folly_cv_prog_cc_int128traits],
 198     [AC_COMPILE_IFELSE(
 199       [AC_LANG_SOURCE([[
 200 #include <type_traits>
 201 static_assert(
 202   ::std::is_same<::std::make_signed<unsigned __int128>::type, __int128>::value,
 203   "signed form of \`unsigned __uint128\` must be \`__int128\`.");
 204       ]])],
 205       [folly_cv_prog_cc_int128traits=yes],
 206       [folly_cv_prog_cc_int128traits=no])
 207     ])
 208   if test "$folly_cv_prog_cc_int128traits" = "no"; then
 209     AC_DEFINE([SUPPLY_MISSING_INT128_TRAITS], [1], [Define if we need the standard integer traits defined for the type `__int128'.])
 210   fi
 211 fi
 212
 213 AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
 214
 215 AC_CACHE_CHECK(
 216   [for ifunc support],
 217   [folly_cv_prog_cc_ifunc],
 218   [AC_COMPILE_IFELSE(
 219     [AC_LANG_SOURCE[
 220       #pragma GCC diagnostic error "-Wattributes"
 221       extern "C" void (*test_ifunc(void))() { return 0; }
 222       void func() __attribute__((ifunc("test_ifunc")));]
 223     ],
 224     [folly_cv_prog_cc_ifunc=yes],
 225     [folly_cv_prog_cc_ifunc=no])])
 226
 227 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 228   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 229 fi
 230
 231 AC_CACHE_CHECK(
 232   [for final and override support],
 233   [folly_cv_c_final_override],
 234   [AC_COMPILE_IFELSE(
 235     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 236                     class D : public C { virtual void g() override {} };]],
 237     [folly_cv_c_final_override=yes],
 238     [folly_cv_c_final_override=no])])
 239
 240 if test "$folly_cv_c_final_override" = "yes"; then
 241   final_val=final
 242   override_val=override
 243 else
 244   final_val=
 245   override_val=
 246 fi
 247
 248 AC_DEFINE_UNQUOTED(
 249   [FINAL], [$final_val],
 250   [Define to "final" if the compiler supports C++11 "final"])
 251 AC_DEFINE_UNQUOTED(
 252   [OVERRIDE], [$override_val],
 253   [Define to "override" if the compiler supports C++11 "override"])
 254
 255 AC_CACHE_CHECK(
 256   [for constexpr strlen],
 257   [folly_cv_func_constexpr_strlen],
 258   [AC_COMPILE_IFELSE(
 259     [AC_LANG_SOURCE[
 260       #include <cstring>
 261       static constexpr int val = strlen("foo");]],
 262     [folly_cv_func_constexpr_strlen=yes],
 263     [folly_cv_func_constexpr_strlen=no])])
 264
 265 if test "$folly_cv_func_constexpr_strlen" = yes; then
 266     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 267               [Define to 1 if strlen(3) is constexpr.])
 268 fi
 269
 270 AC_CACHE_CHECK(
 271   [for libc++],
 272   [folly_cv_lib_libcpp],
 273   [AC_COMPILE_IFELSE(
 274     [AC_LANG_SOURCE[
 275       #include <type_traits>
 276       #if !_LIBCPP_VERSION
 277       #error No libc++
 278       #endif
 279       void func() {}]
 280     ],
 281     [folly_cv_lib_libcpp=yes],
 282     [folly_cv_lib_libcpp=no])])
 283
 284 if test "$folly_cv_lib_libcpp" = yes; then
 285   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 286 fi
 287
 288 AC_CACHE_CHECK(
 289   [for c++11 atomic support without GNU Atomic library],
 290   [folly_cv_lib_libatomic],
 291   [AC_LINK_IFELSE(
 292     [AC_LANG_SOURCE[
 293       #include <atomic>
 294       int main() {
 295         struct Test { int val; };
 296         std::atomic<Test> s;
 297         s.is_lock_free();
 298       }
 299     ]],
 300     [folly_cv_lib_libatomic=yes],
 301     [folly_cv_lib_libatomic=no])])
 302
 303 if test "$folly_cv_lib_libatomic" = no; then
 304   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 305                   [Please install the GNU Atomic library])])
 306 fi
 307
 308 AC_CACHE_CHECK(
 309   [for liblinux-vdso support],
 310   [folly_cv_lib_liblinux_vdso],
 311   [AC_RUN_IFELSE(
 312     [AC_LANG_PROGRAM[
 313       #include <dlfcn.h>
 314       int main() {
 315         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 316         if (h == nullptr) {
 317           return -1;
 318         }
 319         dlclose(h);
 320         return 0;
 321       }
 322     ]],
 323     [folly_cv_lib_liblinux_vdso=yes],
 324     [folly_cv_lib_liblinux_vdso=no])])
 325
 326 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 327   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 328 fi
 329
 330 AC_CACHE_CHECK(
 331   [for usable std::is_trivially_copyable],
 332   [folly_cv_decl_std_is_trivially_copyable],
 333   [AC_COMPILE_IFELSE(
 334     [AC_LANG_SOURCE[
 335       #include <type_traits>
 336       const bool val = std::is_trivially_copyable<bool>::value;]
 337     ],
 338     [folly_cv_decl_std_is_trivially_copyable=yes],
 339     [folly_cv_decl_std_is_trivially_copyable=no])])
 340
 341 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 342   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 343             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 344              implementation.])
 345 fi
 346
 347 AC_CACHE_CHECK(
 348   [gflags namespace],
 349   [folly_cv_decl_gflags_namespace],
 350   [AC_COMPILE_IFELSE(
 351     [AC_LANG_SOURCE[
 352       #include <gflags/gflags.h>
 353       void foo() { gflags::GetArgv(); }]
 354     ],
 355     [folly_cv_decl_gflags_namespace=gflags],
 356     [AC_COMPILE_IFELSE(
 357       [AC_LANG_SOURCE[
 358         #include <gflags/gflags.h>
 359         void foo() { google::GetArgv(); }]
 360       ],
 361       [folly_cv_decl_gflags_namespace=google],
 362       [folly_cv_decl_gflags_namespace=error])])])
 363
 364 if test "$folly_cv_decl_gflags_namespace" = error; then
 365   AC_MSG_ERROR([Cannot determine gflags namespace])
 366 else
 367   AC_DEFINE_UNQUOTED(
 368     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 369     [Define to gflags namespace (usually "google" or "gflags")])
 370   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 371      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 372                [Define to 1 if the gflags namespace is not "gflags"])
 373   fi
 374 fi
 375
 376 # Figure out if we support weak symbols. If not, we will link in some null
 377 # stubs for functions that would otherwise be weak.
 378 AC_CACHE_CHECK(
 379   [for weak symbol support],
 380   [folly_cv_prog_cc_weak_symbols],
 381   [AC_LINK_IFELSE(
 382     [AC_LANG_SOURCE[
 383       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 384       int main(int argc, char** argv) {
 385           return configure_link_extern_weak_test == nullptr;
 386       }]],
 387     [folly_cv_prog_cc_weak_symbols="yes"],
 388     [folly_cv_prog_cc_weak_symbols="no"])])
 389
 390 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 391   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 392             [Define to 1 if the linker supports weak symbols.])
 393 fi
 394
 395
 396 # Figure out if we support wchar well
 397 AC_CACHE_CHECK(
 398   [for wchar support],
 399   [folly_cv_prog_cc_wchar_support],
 400   [AC_RUN_IFELSE(
 401     [AC_LANG_SOURCE[
 402       #include <cstddef>
 403       #include <cwchar>
 404
 405       int main(int argc, char** argv) {
 406         return wcstol(L"01", nullptr, 10) == 1 ? 0 : 1;
 407       }
 408     ]],
 409     [folly_cv_prog_cc_wchar_support=yes],
 410     [folly_cv_prog_cc_wchar_support=no])])
 411
 412 if test "$folly_cv_prog_cc_wchar_support" = "yes"; then
 413   AC_DEFINE([HAVE_WCHAR_SUPPORT], [1], [Define to 1 if the libc supports wchar well])
 414 fi
 415
 416 # Figure out whether the architecture supports unaligned accesses
 417 AC_CACHE_CHECK(
 418   [for unaligned access support],
 419   [folly_cv_prog_cc_unaligned_access],
 420   [AC_RUN_IFELSE(
 421     [AC_LANG_SOURCE[
 422       int main(int argc, char** argv) {
 423         char buf[64] = {0};
 424         unsigned long *ptr = (unsigned long *)(buf + 1);
 425         *ptr = 0xdeadbeef;
 426         return (*ptr & 0xff) == 0xef ? 0 : 1;
 427       }
 428     ]],
 429     [folly_cv_prog_cc_unaligned_access=yes],
 430     [folly_cv_prog_cc_unaligned_access=no])])
 431
 432 if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
 433   AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
 434 fi
 435
 436 AC_CACHE_CHECK(
 437   [for vsnprintf reporting bad format strings],
 438   [folly_cv_prog_vsnprintf_bad_format],
 439   [AC_RUN_IFELSE(
 440     [AC_LANG_SOURCE[
 441       #include <stdio.h>
 442
 443       int main(int argc, char** argv) {
 444           char buf[256];
 445           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 446       }]],
 447     [folly_cv_prog_vsnprintf_bad_format="yes"],
 448     [folly_cv_prog_vsnprintf_bad_format="no"])])
 449
 450 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 451   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 452             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 453 fi
 454
 455 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 456 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 457   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 458             [Define to 1 if we have cplus_demangle_v3_callback.])
 459 fi
 460
 461 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 462 # want to link with librt if necessary.
 463 AC_SEARCH_LIBS([clock_gettime], [rt],
 464   AC_DEFINE(
 465     [HAVE_CLOCK_GETTIME],
 466     [1],
 467     [Define to 1 if we support clock_gettime(2).]),
 468   [])
 469
 470 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 471 # want to include pthread.h if necessary.
 472 AC_CACHE_CHECK(
 473   [for pthread_atfork support],
 474   [folly_cv_prog_cc_pthread_atfork],
 475   [AC_COMPILE_IFELSE(
 476     [AC_LANG_SOURCE[
 477       #include <pthread.h>
 478       void func() {pthread_atfork(NULL, NULL, NULL);}]
 479     ],
 480     [folly_cv_prog_cc_pthread_atfork=yes],
 481     [folly_cv_prog_cc_pthread_atfork=no])])
 482
 483 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 484   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 485 fi
 486
 487 # Check for XSI-compatible strerror_r as default implementation
 488 AC_CACHE_CHECK(
 489   [for XSI style strerror_r support],
 490   [folly_cv_prog_cc_xsi_strerror_r],
 491   [AC_RUN_IFELSE(
 492     [AC_LANG_SOURCE[
 493       #include <string.h>
 494       #include <errno.h>
 495       int main(int argc, char** argv) {
 496         char buf[1024];
 497         buf[0] = 0;
 498         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 499         return ret;
 500       }
 501     ]],
 502     [folly_cv_prog_cc_xsi_strerror_r=yes],
 503     [folly_cv_prog_cc_xsi_strerror_r=no])])
 504
 505 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 506   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 507 fi
 508
 509 AC_CACHE_CHECK(
 510   [for ext/random and __gnu_cxx::sfmt19937],
 511   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 512   [AC_COMPILE_IFELSE(
 513     [AC_LANG_SOURCE[
 514       #include <ext/random>
 515       int main(int argc, char** argv) {
 516         __gnu_cxx::sfmt19937 rng;
 517         return 0;
 518       }
 519     ]],
 520     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 521     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 522
 523 AC_CACHE_CHECK(
 524   [for VLA (variable-length array) support],
 525   [folly_cv_prog_cc_have_vla],
 526   [AC_COMPILE_IFELSE(
 527     [AC_LANG_SOURCE[
 528       int main(int argc, char** argv) {
 529         unsigned size = argc;
 530         char data[size];
 531         return 0;
 532       }
 533     ]],
 534     [folly_cv_prog_cc_have_vla=yes],
 535     [folly_cv_prog_cc_have_vla=no])])
 536
 537 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 538 AC_DEFINE_UNQUOTED(
 539   [HAVE_VLA],
 540   [$have_vla],
 541   [Define to 1 if the compiler has VLA (variable-length array) support,
 542    otherwise define to 0])
 543
 544 # Checks for library functions.
 545 AC_CHECK_FUNCS([getdelim \
 546                 gettimeofday \
 547                 memmove \
 548                 memset \
 549                 pow \
 550                 strerror \
 551                 malloc_size \
 552                 malloc_usable_size \
 553                 memrchr \
 554                 pipe2 \
 555                 preadv \
 556                 pwritev \
 557               ])
 558
 559 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 560 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 561 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 562 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 563 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [ZSTD_compressStream]))
 564 AC_CHECK_HEADER([linux/membarrier.h], AC_DEFINE([HAVE_LINUX_MEMBARRIER_H], [1], [Define to 1 if membarrier.h is available]))
 565
 566 AC_ARG_ENABLE([follytestmain],
 567    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 568    [follytestmain=${enableval}], [follytestmain=no])
 569
 570 use_follytestmain=yes
 571 # libdwarf used to install in /usr/include, now installs in /usr/include/libdwarf.
 572 AC_CHECK_HEADERS([libdwarf/dwarf.h dwarf.h], [break])
 573 # Check whether we have both the library and the header
 574 have_libdwarf=no
 575 AS_IF([test "x${ac_cv_header_libdwarf_dwarf_h}" = xyes], [have_libdwarf=yes])
 576 AS_IF([test "x${ac_cv_header_dwarf_h}" = xyes], [have_libdwarf=yes])
 577
 578
 579 AC_ARG_ENABLE([mobile],
 580    AS_HELP_STRING([--enable-mobile],
 581                   [enables using main function from folly for tests]),
 582                   [mobile=${enableval}], [mobile=no])
 583 AS_IF([test "x${mobile}" = "xyes"], [
 584     AC_DEFINE([MOBILE], [1],
 585               [Define to 1 for compiler guards for mobile targets.])
 586 ])
 587
 588 # Include directory that contains "folly" so #include <folly/Foo.h> works
 589 AM_CPPFLAGS='-I$(top_srcdir)/..'
 590 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS $OPENSSL_INCLUDES"
 591 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 592 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 593 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 594 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 595
 596 AM_LDFLAGS="$AM_LDFLAGS $OPENSSL_LDFLAGS $OPENSSL_LIBS"
 597
 598 AC_SUBST([AM_CPPFLAGS])
 599 AC_SUBST([AM_LDFLAGS])
 600
 601 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 602 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 603 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 604 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 605 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 606 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 607                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 608 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT_H], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 609 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 610                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 611 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 612 AM_CONDITIONAL([HAVE_LIBDWARF], [test "x${have_libdwarf}" = "xyes"])
 613 AM_CONDITIONAL([HAVE_BOOST_CONTEXT], [test "x${ax_cv_boost_context}" = "xyes"])
 614
 615 # remove pkg-config deps from dependent libraries
 616 # (at least for pkg-config file purposes)
 617 FB_FILTER_PKG_LIBS([$AM_LDFLAGS $LIBS])
 618
 619 # Output
 620 AC_CONFIG_FILES([Makefile
 621                  libfolly.pc
 622                  test/Makefile
 623                  test/function_benchmark/Makefile
 624                  experimental/Makefile
 625                  experimental/symbolizer/Makefile
 626                  init/Makefile])
 627 AC_OUTPUT