folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6 AC_INIT(folly, 0.1, folly@fb.com)
   7 AC_CONFIG_SRCDIR([Likely.h])
   8 AC_CONFIG_HEADERS([config.h])
   9 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11
  12 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc])
  13
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AC_PROG_INSTALL
  17 AM_PROG_LIBTOOL
  18
  19 AC_LANG([C++])
  20
  21 # Checks for programs.
  22 AC_PROG_CXX
  23 AC_PROG_CC
  24 AC_CXX_COMPILE_STDCXX_0X
  25
  26 # Checks for libraries.
  27 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  28              [Please install google-glog library])])
  29 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  30              [Please install google-gflags library])])
  31
  32 # check for boost libs
  33 AX_BOOST_BASE([1.20.0], [], [AC_MSG_ERROR(
  34               [Please install boost >= 1.20.0 (thread, regex, and system)])])
  35 AX_BOOST_THREAD
  36 AX_BOOST_REGEX
  37 AX_BOOST_SYSTEM
  38
  39 # Checks for header files.
  40 AC_HEADER_STDC
  41 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h])
  42
  43 AC_CHECK_HEADER(double-conversion.h, [], [AC_MSG_ERROR(
  44                 [Couldn't find double-conversion.h, please download from \
  45                 http://code.google.com/p/double-conversion/])], [])
  46 AC_CHECK_LIB([double_conversion_pic],[ceil],[],[AC_MSG_ERROR(
  47              [Please install double-conversion library])])
  48
  49 # Checks for typedefs, structures, and compiler characteristics.
  50 AC_HEADER_STDBOOL
  51 AC_C_CONST
  52 AC_C_INLINE
  53 AC_TYPE_SIZE_T
  54 AC_HEADER_TIME
  55 AC_C_VOLATILE
  56 AC_CHECK_TYPE([__int128],
  57   [AC_DEFINE([HAVE_INT128_T], [1], [Define if __int128 exists])],
  58   [AC_DEFINE([HAVE_INT128_T], [0], [Define if __int128 does not exist])])
  59 AC_CHECK_TYPES([ptrdiff_t])
  60 AC_COMPILE_IFELSE(
  61   [AC_LANG_SOURCE[
  62     #pragma GCC diagnostic error "-Wattributes"
  63     extern "C" void (*test_ifunc(void))() { return 0; }
  64     void func() __attribute__((ifunc("test_ifunc")));]
  65   ],
  66   [AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])],
  67   [AC_DEFINE([HAVE_IFUNC], [0], [Define to 0 if the compiler doesn't support ifunc])]
  68 )
  69 AC_COMPILE_IFELSE(
  70   [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
  71                   class D : public C { virtual void g() override {} };]],
  72   [AC_DEFINE([FINAL], [final],
  73              [Define to "final" if the compiler supports C++11 "final"]),
  74    AC_DEFINE([OVERRIDE], [override],
  75              [Define to "override" if the compiler supports C++11 "override"])],
  76   [AC_DEFINE([FINAL], [],
  77              [Define to "final" if the compiler supports C++11 "final"]),
  78    AC_DEFINE([OVERRIDE], [],
  79              [Define to "override" if the compiler supports C++11 "override"])]
  80 )
  81
  82 # Checks for library functions.
  83 AC_CHECK_FUNCS([getdelim \
  84                 gettimeofday \
  85                 memmove \
  86                 memset \
  87                 pow \
  88                 strerror \
  89                 pthread_yield \
  90                 rallocm \
  91                 malloc_size \
  92                 malloc_usable_size \
  93                 memrchr])
  94
  95 if test "$ac_cv_func_pthread_yield" = "no"; then
  96    AC_CHECK_HEADERS([sched.h])
  97    AC_CHECK_FUNCS([sched_yield])
  98 fi
  99
 100 CXX_FLAGS=""
 101 if test "$ac_cv_cxx_compile_cxx0x_cxx" = yes; then
 102    CXX_FLAGS="-std=c++0x"
 103 fi
 104 if test "$ac_cv_cxx_compile_cxx0x_gxx" = yes; then
 105    CXX_FLAGS="-std=gnu++0x"
 106 fi
 107
 108 AC_SUBST(AM_CPPFLAGS, '-I../$(top_srcdir)'" "'-I$(top_srcdir)/io'" "'-I$(top_srcdir)/test'" $CXX_FLAGS $BOOST_CPPFLAGS")
 109 AC_SUBST(AM_LDFLAGS, "$BOOST_LDFLAGS $BOOST_THREAD_LIB $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread")
 110
 111 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 112 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 113 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 114
 115 # Output
 116 AC_CONFIG_FILES([Makefile
 117                  test/Makefile
 118                  test/function_benchmark/Makefile])
 119 AC_OUTPUT