folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 AC_CONFIG_SRCDIR([Likely.h])
  16 AC_CONFIG_HEADERS([config.h])
  17 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  18 AC_CONFIG_AUX_DIR([build-aux])
  19
  20 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  21
  22 AC_CONFIG_MACRO_DIR([m4])
  23
  24 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  25 AX_CONFIG_FEATURE(
  26         [deprecated-assoc],
  27         [supports deprecated associative containers (hash_map/hash_set)],
  28         [HAVE_DEPRECATED_ASSOC],
  29         [Define if you want to support deprecated associative containers])
  30
  31 AC_PROG_INSTALL
  32 AM_PROG_LIBTOOL
  33
  34 AC_LANG([C++])
  35
  36 # Checks for programs.
  37 AC_PROG_CXX
  38 AC_PROG_CC
  39 AC_CXX_COMPILE_STDCXX_0X
  40
  41 # Be sure to add any -std option to CXXFLAGS before we invoke any
  42 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  43 # before we update CXXFLAGS will not be run with the same options that we use
  44 # during the real build.
  45 STD=""
  46 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  47    STD="-std=c++0x"
  48 fi
  49 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  50    STD="-std=gnu++0x"
  51 fi
  52
  53 CXXFLAGS="$STD $CXXFLAGS"
  54
  55 # Checks for libraries.
  56 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  57              [Please install google-glog library])])
  58 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  59              [Please install google-gflags library])])
  60
  61 AC_CHECK_LIB(ssl,
  62         SSL_ctrl,
  63         [],
  64         [AC_MSG_ERROR(["Error: libssl required"])])
  65
  66 # check for boost libs
  67 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
  68               [Please install boost >= 1.51.0 (context, thread, regex, and system)])])
  69 AX_BOOST_CONTEXT
  70 AX_BOOST_THREAD
  71 AX_BOOST_REGEX
  72 AX_BOOST_SYSTEM
  73 AX_BOOST_FILESYSTEM
  74
  75 # Checks for header files.
  76 AC_HEADER_STDC
  77 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h bits/functexcept.h bits/c++config.h])
  78
  79 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
  80                 [Couldn't find double-conversion.h, please download from \
  81                  https://github.com/floitsch/double-conversion/])], [])
  82 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
  83              [Please install double-conversion library])])
  84
  85 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
  86
  87 AC_CHECK_LIB([jemalloc], [xallocx])
  88
  89 # Checks for typedefs, structures, and compiler characteristics.
  90 AC_HEADER_STDBOOL
  91 AC_C_CONST
  92 AC_C_INLINE
  93 AC_TYPE_SIZE_T
  94 AC_HEADER_TIME
  95 AC_C_VOLATILE
  96 AC_CHECK_TYPE([__int128], AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128]))
  97 AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
  98
  99 AC_CACHE_CHECK(
 100   [for ifunc support],
 101   [folly_cv_prog_cc_ifunc],
 102   [AC_COMPILE_IFELSE(
 103     [AC_LANG_SOURCE[
 104       #pragma GCC diagnostic error "-Wattributes"
 105       extern "C" void (*test_ifunc(void))() { return 0; }
 106       void func() __attribute__((ifunc("test_ifunc")));]
 107     ],
 108     [folly_cv_prog_cc_ifunc=yes],
 109     [folly_cv_prog_cc_ifunc=no])])
 110
 111 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 112   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 113 fi
 114
 115 AC_CACHE_CHECK(
 116   [for final and override support],
 117   [folly_cv_c_final_override],
 118   [AC_COMPILE_IFELSE(
 119     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 120                     class D : public C { virtual void g() override {} };]],
 121     [folly_cv_c_final_override=yes],
 122     [folly_cv_c_final_override=no])])
 123
 124 if test "$folly_cv_c_final_override" = "yes"; then
 125   final_val=final
 126   override_val=override
 127 else
 128   final_val=
 129   override_val=
 130 fi
 131
 132 AC_DEFINE_UNQUOTED(
 133   [FINAL], [$final_val],
 134   [Define to "final" if the compiler supports C++11 "final"])
 135 AC_DEFINE_UNQUOTED(
 136   [OVERRIDE], [$override_val],
 137   [Define to "override" if the compiler supports C++11 "override"])
 138
 139 AC_CACHE_CHECK(
 140   [for std::this_thread::sleep_for],
 141   [folly_cv_func_this_thread_sleep_for],
 142   [AC_COMPILE_IFELSE(
 143     [AC_LANG_SOURCE[
 144       #include <thread>
 145       #include <chrono>
 146       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 147     [folly_cv_func_this_thread_sleep_for=yes],
 148     [folly_cv_func_this_thread_sleep_for=no])])
 149
 150 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 151     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 152               [Define to 1 if std::this_thread::sleep_for() is defined.])
 153 fi
 154
 155 AC_CACHE_CHECK(
 156   [for constexpr strlen],
 157   [folly_cv_func_constexpr_strlen],
 158   [AC_COMPILE_IFELSE(
 159     [AC_LANG_SOURCE[
 160       #include <cstring>
 161       static constexpr int val = strlen("foo");]],
 162     [folly_cv_func_constexpr_strlen=yes],
 163     [folly_cv_func_constexpr_strlen=no])])
 164
 165 if test "$folly_cv_func_constexpr_strlen" = yes; then
 166     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 167               [Define to 1 if strlen(3) is constexpr.])
 168 fi
 169
 170 AC_CACHE_CHECK(
 171   [for libc++],
 172   [folly_cv_lib_libcpp],
 173   [AC_COMPILE_IFELSE(
 174     [AC_LANG_SOURCE[
 175       #include <type_traits>
 176       #if !_LIBCPP_VERSION
 177       #error No libc++
 178       #endif
 179       void func() {}]
 180     ],
 181     [folly_cv_lib_libcpp=yes],
 182     [folly_cv_lib_libcpp=no])])
 183
 184 if test "$folly_cv_lib_libcpp" = yes; then
 185   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we're using libc++.])
 186 fi
 187
 188 AC_CACHE_CHECK(
 189   [for usable std::is_trivially_copyable],
 190   [folly_cv_decl_std_is_trivially_copyable],
 191   [AC_COMPILE_IFELSE(
 192     [AC_LANG_SOURCE[
 193       #include <type_traits>
 194       const bool val = std::is_trivially_copyable<bool>::value;]
 195     ],
 196     [folly_cv_decl_std_is_trivially_copyable=yes],
 197     [folly_cv_decl_std_is_trivially_copyable=no])])
 198
 199 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 200   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 201             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 202              implementation.])
 203 fi
 204
 205 AC_CACHE_CHECK(
 206   [gflags namespace],
 207   [folly_cv_decl_gflags_namespace],
 208   [AC_COMPILE_IFELSE(
 209     [AC_LANG_SOURCE[
 210       #include <gflags/gflags.h>
 211       void foo() { gflags::GetArgv(); }]
 212     ],
 213     [folly_cv_decl_gflags_namespace=gflags],
 214     [AC_COMPILE_IFELSE(
 215       [AC_LANG_SOURCE[
 216         #include <gflags/gflags.h>
 217         void foo() { google::GetArgv(); }]
 218       ],
 219       [folly_cv_decl_gflags_namespace=google],
 220       [folly_cv_decl_gflags_namespace=error])])])
 221
 222 if test "$folly_cv_decl_gflags_namespace" = error; then
 223   AC_MSG_ERROR([Cannot determine gflags namespace])
 224 else
 225   AC_DEFINE_UNQUOTED(
 226     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 227     [Define to gflags namespace (usually "google" or "gflags")])
 228   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 229      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 230                [Define to 1 if the gflags namespace is not "gflags"])
 231   fi
 232 fi
 233
 234 # Figure out if we support weak symbols. If not, we will link in some null
 235 # stubs for functions that would otherwise be weak.
 236 AC_CACHE_CHECK(
 237   [for weak symbol support],
 238   [folly_cv_prog_cc_weak_symbols],
 239   [AC_LINK_IFELSE(
 240     [AC_LANG_SOURCE[
 241       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 242       int main(int argc, char** argv) {
 243           return configure_link_extern_weak_test == nullptr;
 244       }]],
 245     [folly_cv_prog_cc_weak_symbols="yes"],
 246     [folly_cv_prog_cc_weak_symbols="no"])])
 247
 248 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 249   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 250             [Define to 1 if the linker supports weak symbols.])
 251 fi
 252
 253 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 254 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 255   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 256             [Define to 1 if we have cplus_demangle_v3_callback.])
 257 fi
 258
 259 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 260 # want to link with librt if necessary.
 261 AC_SEARCH_LIBS([clock_gettime], [rt],
 262   AC_DEFINE(
 263     [HAVE_CLOCK_GETTIME],
 264     [1],
 265     [Define to 1 if we support clock_gettime(2).]),
 266   [])
 267
 268 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 269 # want to include pthread.h if necessary.
 270 AC_CACHE_CHECK(
 271   [for pthread_atfork support],
 272   [folly_cv_prog_cc_pthread_atfork],
 273   [AC_COMPILE_IFELSE(
 274     [AC_LANG_SOURCE[
 275       #include <pthread.h>
 276       void func() {pthread_atfork(NULL, NULL, NULL);}]
 277     ],
 278     [folly_cv_prog_cc_pthread_atfork=yes],
 279     [folly_cv_prog_cc_pthread_atfork=no])])
 280
 281 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 282   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 283 fi
 284
 285 # Checks for library functions.
 286 AC_CHECK_FUNCS([getdelim \
 287                 gettimeofday \
 288                 memmove \
 289                 memset \
 290                 pow \
 291                 strerror \
 292                 pthread_yield \
 293                 malloc_size \
 294                 malloc_usable_size \
 295                 memrchr \
 296                 pipe2])
 297
 298 if test "$ac_cv_func_pthread_yield" = "no"; then
 299    AC_CHECK_HEADERS([sched.h])
 300    AC_CHECK_FUNCS([sched_yield])
 301 fi
 302
 303 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 304 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 305 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 306 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 307
 308 # Include directory that contains "folly" so #include <folly/Foo.h> works
 309 AM_CPPFLAGS='-I$(top_srcdir)/..'
 310 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 311 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 312 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 313
 314 AC_SUBST([AM_CPPFLAGS])
 315 AC_SUBST([AM_LDFLAGS])
 316
 317 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 318 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 319 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 320 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 321                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 322 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 323
 324 # Output
 325 AC_CONFIG_FILES([Makefile
 326                  test/Makefile
 327                  test/function_benchmark/Makefile])
 328 AC_OUTPUT