folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 #declare pkg-config variables
  16 PKG_VERSION=m4_join([.], m4_reverse(m4_translit(folly_version_str, [:], [,])))
  17 AC_SUBST([PKG_VERSION])
  18 AC_SUBST([PKG_CXXFLAGS])
  19 AC_SUBST([PKG_DEPS])
  20 AC_SUBST([PKG_LIBS])
  21
  22 AC_CONFIG_SRCDIR([Likely.h])
  23 AC_CONFIG_HEADERS([config.h])
  24 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  32 AX_CONFIG_FEATURE(
  33         [deprecated-assoc],
  34         [supports deprecated associative containers (hash_map/hash_set)],
  35         [HAVE_DEPRECATED_ASSOC],
  36         [Define if you want to support deprecated associative containers])
  37
  38 AC_PROG_INSTALL
  39 AM_PROG_LIBTOOL
  40
  41 AC_LANG([C++])
  42
  43 # Checks for programs.
  44 AC_PROG_CXX
  45 AC_PROG_CC
  46
  47 AC_CXX_COMPILE_STDCXX_1Y
  48
  49 # Be sure to add any -std option to CXXFLAGS before we invoke any
  50 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  51 # before we update CXXFLAGS will not be run with the same options that we use
  52 # during the real build.
  53 STD=""
  54 if test "x$ac_cv_cxx_compile_cxx1y_cxx" = xyes; then
  55    STD="-std=c++1y"
  56 fi
  57 if test "x$ac_cv_cxx_compile_cxx1y_gxx" = xyes; then
  58    STD="-std=gnu++1y"
  59 fi
  60
  61 CXXFLAGS="$STD $CXXFLAGS"
  62
  63 # expose required -std option via pkg-config
  64 PKG_CXXFLAGS=$STD
  65
  66 # Checks for glog and gflags
  67 # There are no symbols with C linkage, so we do a try-run
  68 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  69                 [Please install google-gflags library])])
  70 AC_CACHE_CHECK(
  71   [for gflags viability],
  72   [folly_cv_prog_cc_gflags],
  73   [AC_RUN_IFELSE(
  74     [AC_LANG_SOURCE[
  75       #include <gflags/gflags.h>
  76       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  77       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  78       int main(int argc, char** argv) {
  79         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  80       }
  81     ]],
  82     [folly_cv_prog_cc_gflags=yes],
  83     [folly_cv_prog_cc_gflags=no]
  84   )]
  85 )
  86
  87 if test "$folly_cv_prog_cc_gflags" != "yes"; then
  88   AC_MSG_ERROR(["libgflags invalid, see config.log for details"])
  89 fi
  90 FB_CHECK_PKG_CONFIG([GFLAGS], [libgflags])
  91
  92 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
  93                 [Please install google-glog library])])
  94 AC_CACHE_CHECK(
  95   [for glog viability],
  96   [folly_cv_prog_cc_glog],
  97   [AC_RUN_IFELSE(
  98     [AC_LANG_SOURCE[
  99       #include <glog/logging.h>
 100       int main(int argc, char** argv) {
 101         google::InitGoogleLogging(argv[0]);
 102         google::ShutdownGoogleLogging();
 103         return 0;
 104       }
 105     ]],
 106     [folly_cv_prog_cc_glog=yes],
 107     [folly_cv_prog_cc_glog=no]
 108   )]
 109 )
 110
 111 if test "$folly_cv_prog_cc_glog" != "yes"; then
 112   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
 113 fi
 114 FB_CHECK_PKG_CONFIG([GLOG], [libglog])
 115
 116 AX_CHECK_OPENSSL([],
 117         [AC_MSG_ERROR(["Error: libssl required"])])
 118 FB_CHECK_PKG_CONFIG([OPENSSL], [openssl])
 119
 120 # check for boost libs
 121 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 122               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 123 AX_BOOST_CONTEXT
 124 AX_BOOST_PROGRAM_OPTIONS
 125 AX_BOOST_THREAD
 126 AX_BOOST_REGEX
 127 AX_BOOST_SYSTEM
 128 AX_BOOST_FILESYSTEM
 129 AX_BOOST_CHRONO
 130
 131 # Check for python interpreter
 132 AM_PATH_PYTHON
 133
 134 # Checks for header files.
 135 AC_HEADER_STDC
 136 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h sched.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h byteswap.h bits/functexcept.h bits/c++config.h])
 137
 138 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 139                 [Couldn't find double-conversion.h, please download from \
 140                  https://github.com/google/double-conversion/])], [])
 141 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 142              [Please install double-conversion library])])
 143
 144 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 145 FB_CHECK_PKG_CONFIG([EVENT], [libevent])
 146
 147 AC_CHECK_LIB([jemalloc], [xallocx])
 148
 149 # Checks for typedefs, structures, and compiler characteristics.
 150 AC_HEADER_STDBOOL
 151 AC_C_CONST
 152 AC_C_INLINE
 153 AC_TYPE_SIZE_T
 154 AC_HEADER_TIME
 155 AC_C_VOLATILE
 156 AC_CHECK_TYPE([__int128], AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128]))
 157 AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
 158
 159 AC_CACHE_CHECK(
 160   [for ifunc support],
 161   [folly_cv_prog_cc_ifunc],
 162   [AC_COMPILE_IFELSE(
 163     [AC_LANG_SOURCE[
 164       #pragma GCC diagnostic error "-Wattributes"
 165       extern "C" void (*test_ifunc(void))() { return 0; }
 166       void func() __attribute__((ifunc("test_ifunc")));]
 167     ],
 168     [folly_cv_prog_cc_ifunc=yes],
 169     [folly_cv_prog_cc_ifunc=no])])
 170
 171 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 172   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 173 fi
 174
 175 AC_CACHE_CHECK(
 176   [for final and override support],
 177   [folly_cv_c_final_override],
 178   [AC_COMPILE_IFELSE(
 179     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 180                     class D : public C { virtual void g() override {} };]],
 181     [folly_cv_c_final_override=yes],
 182     [folly_cv_c_final_override=no])])
 183
 184 if test "$folly_cv_c_final_override" = "yes"; then
 185   final_val=final
 186   override_val=override
 187 else
 188   final_val=
 189   override_val=
 190 fi
 191
 192 AC_DEFINE_UNQUOTED(
 193   [FINAL], [$final_val],
 194   [Define to "final" if the compiler supports C++11 "final"])
 195 AC_DEFINE_UNQUOTED(
 196   [OVERRIDE], [$override_val],
 197   [Define to "override" if the compiler supports C++11 "override"])
 198
 199 AC_CACHE_CHECK(
 200   [for std::this_thread::sleep_for],
 201   [folly_cv_func_this_thread_sleep_for],
 202   [AC_COMPILE_IFELSE(
 203     [AC_LANG_SOURCE[
 204       #include <thread>
 205       #include <chrono>
 206       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 207     [folly_cv_func_this_thread_sleep_for=yes],
 208     [folly_cv_func_this_thread_sleep_for=no])])
 209
 210 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 211     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 212               [Define to 1 if std::this_thread::sleep_for() is defined.])
 213 fi
 214
 215 AC_CACHE_CHECK(
 216   [for constexpr strlen],
 217   [folly_cv_func_constexpr_strlen],
 218   [AC_COMPILE_IFELSE(
 219     [AC_LANG_SOURCE[
 220       #include <cstring>
 221       static constexpr int val = strlen("foo");]],
 222     [folly_cv_func_constexpr_strlen=yes],
 223     [folly_cv_func_constexpr_strlen=no])])
 224
 225 if test "$folly_cv_func_constexpr_strlen" = yes; then
 226     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 227               [Define to 1 if strlen(3) is constexpr.])
 228 fi
 229
 230 AC_CACHE_CHECK(
 231   [for libc++],
 232   [folly_cv_lib_libcpp],
 233   [AC_COMPILE_IFELSE(
 234     [AC_LANG_SOURCE[
 235       #include <type_traits>
 236       #if !_LIBCPP_VERSION
 237       #error No libc++
 238       #endif
 239       void func() {}]
 240     ],
 241     [folly_cv_lib_libcpp=yes],
 242     [folly_cv_lib_libcpp=no])])
 243
 244 if test "$folly_cv_lib_libcpp" = yes; then
 245   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 246 fi
 247
 248 AC_CACHE_CHECK(
 249   [for c++11 atomic support without GNU Atomic library],
 250   [folly_cv_lib_libatomic],
 251   [AC_LINK_IFELSE(
 252     [AC_LANG_SOURCE[
 253       #include <atomic>
 254       int main() {
 255         struct Test { int val; };
 256         std::atomic<Test> s;
 257         s.is_lock_free();
 258       }
 259     ]],
 260     [folly_cv_lib_libatomic=yes],
 261     [folly_cv_lib_libatomic=no])])
 262
 263 if test "$folly_cv_lib_libatomic" = no; then
 264   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 265                   [Please install the GNU Atomic library])])
 266 fi
 267
 268 AC_CACHE_CHECK(
 269   [for liblinux-vdso support],
 270   [folly_cv_lib_liblinux_vdso],
 271   [AC_RUN_IFELSE(
 272     [AC_LANG_PROGRAM[
 273       #include <dlfcn.h>
 274       int main() {
 275         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 276         if (h == nullptr) {
 277           return -1;
 278         }
 279         dlclose(h);
 280         return 0;
 281       }
 282     ]],
 283     [folly_cv_lib_liblinux_vdso=yes],
 284     [folly_cv_lib_liblinux_vdso=no])])
 285
 286 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 287   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 288 fi
 289
 290 AC_CACHE_CHECK(
 291   [for usable std::is_trivially_copyable],
 292   [folly_cv_decl_std_is_trivially_copyable],
 293   [AC_COMPILE_IFELSE(
 294     [AC_LANG_SOURCE[
 295       #include <type_traits>
 296       const bool val = std::is_trivially_copyable<bool>::value;]
 297     ],
 298     [folly_cv_decl_std_is_trivially_copyable=yes],
 299     [folly_cv_decl_std_is_trivially_copyable=no])])
 300
 301 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 302   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 303             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 304              implementation.])
 305 fi
 306
 307 AC_CACHE_CHECK(
 308   [gflags namespace],
 309   [folly_cv_decl_gflags_namespace],
 310   [AC_COMPILE_IFELSE(
 311     [AC_LANG_SOURCE[
 312       #include <gflags/gflags.h>
 313       void foo() { gflags::GetArgv(); }]
 314     ],
 315     [folly_cv_decl_gflags_namespace=gflags],
 316     [AC_COMPILE_IFELSE(
 317       [AC_LANG_SOURCE[
 318         #include <gflags/gflags.h>
 319         void foo() { google::GetArgv(); }]
 320       ],
 321       [folly_cv_decl_gflags_namespace=google],
 322       [folly_cv_decl_gflags_namespace=error])])])
 323
 324 if test "$folly_cv_decl_gflags_namespace" = error; then
 325   AC_MSG_ERROR([Cannot determine gflags namespace])
 326 else
 327   AC_DEFINE_UNQUOTED(
 328     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 329     [Define to gflags namespace (usually "google" or "gflags")])
 330   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 331      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 332                [Define to 1 if the gflags namespace is not "gflags"])
 333   fi
 334 fi
 335
 336 # Figure out if we support weak symbols. If not, we will link in some null
 337 # stubs for functions that would otherwise be weak.
 338 AC_CACHE_CHECK(
 339   [for weak symbol support],
 340   [folly_cv_prog_cc_weak_symbols],
 341   [AC_LINK_IFELSE(
 342     [AC_LANG_SOURCE[
 343       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 344       int main(int argc, char** argv) {
 345           return configure_link_extern_weak_test == nullptr;
 346       }]],
 347     [folly_cv_prog_cc_weak_symbols="yes"],
 348     [folly_cv_prog_cc_weak_symbols="no"])])
 349
 350 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 351   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 352             [Define to 1 if the linker supports weak symbols.])
 353 fi
 354
 355
 356 # Figure out if we support wchar well
 357 AC_CACHE_CHECK(
 358   [for wchar support],
 359   [folly_cv_prog_cc_wchar_support],
 360   [AC_RUN_IFELSE(
 361     [AC_LANG_SOURCE[
 362       #include <cstddef>
 363       #include <cwchar>
 364
 365       int main(int argc, char** argv) {
 366         return wcstol(L"01", nullptr, 10) == 1 ? 0 : 1;
 367       }
 368     ]],
 369     [folly_cv_prog_cc_wchar_support=yes],
 370     [folly_cv_prog_cc_wchar_support=no])])
 371
 372 if test "$folly_cv_prog_cc_wchar_support" = "yes"; then
 373   AC_DEFINE([HAVE_WCHAR_SUPPORT], [1], [Define to 1 if the libc supports wchar well])
 374 fi
 375
 376 # Figure out whether the architecture supports unaligned accesses
 377 AC_CACHE_CHECK(
 378   [for unaligned access support],
 379   [folly_cv_prog_cc_unaligned_access],
 380   [AC_RUN_IFELSE(
 381     [AC_LANG_SOURCE[
 382       int main(int argc, char** argv) {
 383         char buf[64] = {0};
 384         unsigned long *ptr = (unsigned long *)(buf + 1);
 385         *ptr = 0xdeadbeef;
 386         return (*ptr & 0xff) == 0xef ? 0 : 1;
 387       }
 388     ]],
 389     [folly_cv_prog_cc_unaligned_access=yes],
 390     [folly_cv_prog_cc_unaligned_access=no])])
 391
 392 if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
 393   AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
 394 fi
 395
 396 AC_CACHE_CHECK(
 397   [for vsnprintf reporting bad format strings],
 398   [folly_cv_prog_vsnprintf_bad_format],
 399   [AC_RUN_IFELSE(
 400     [AC_LANG_SOURCE[
 401       #include <stdio.h>
 402
 403       int main(int argc, char** argv) {
 404           char buf[256];
 405           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 406       }]],
 407     [folly_cv_prog_vsnprintf_bad_format="yes"],
 408     [folly_cv_prog_vsnprintf_bad_format="no"])])
 409
 410 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 411   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 412             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 413 fi
 414
 415 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 416 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 417   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 418             [Define to 1 if we have cplus_demangle_v3_callback.])
 419 fi
 420
 421 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 422 # want to link with librt if necessary.
 423 AC_SEARCH_LIBS([clock_gettime], [rt],
 424   AC_DEFINE(
 425     [HAVE_CLOCK_GETTIME],
 426     [1],
 427     [Define to 1 if we support clock_gettime(2).]),
 428   [])
 429
 430 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 431 # want to include pthread.h if necessary.
 432 AC_CACHE_CHECK(
 433   [for pthread_atfork support],
 434   [folly_cv_prog_cc_pthread_atfork],
 435   [AC_COMPILE_IFELSE(
 436     [AC_LANG_SOURCE[
 437       #include <pthread.h>
 438       void func() {pthread_atfork(NULL, NULL, NULL);}]
 439     ],
 440     [folly_cv_prog_cc_pthread_atfork=yes],
 441     [folly_cv_prog_cc_pthread_atfork=no])])
 442
 443 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 444   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 445 fi
 446
 447 # Check for XSI-compatible strerror_r as default implementation
 448 AC_CACHE_CHECK(
 449   [for XSI style strerror_r support],
 450   [folly_cv_prog_cc_xsi_strerror_r],
 451   [AC_RUN_IFELSE(
 452     [AC_LANG_SOURCE[
 453       #include <string.h>
 454       #include <errno.h>
 455       int main(int argc, char** argv) {
 456         char buf[1024];
 457         buf[0] = 0;
 458         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 459         return ret;
 460       }
 461     ]],
 462     [folly_cv_prog_cc_xsi_strerror_r=yes],
 463     [folly_cv_prog_cc_xsi_strerror_r=no])])
 464
 465 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 466   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 467 fi
 468
 469 AC_CACHE_CHECK(
 470   [for ext/random and __gnu_cxx::sfmt19937],
 471   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 472   [AC_COMPILE_IFELSE(
 473     [AC_LANG_SOURCE[
 474       #include <ext/random>
 475       int main(int argc, char** argv) {
 476         __gnu_cxx::sfmt19937 rng;
 477         return 0;
 478       }
 479     ]],
 480     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 481     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 482
 483 AC_CACHE_CHECK(
 484   [for VLA (variable-length array) support],
 485   [folly_cv_prog_cc_have_vla],
 486   [AC_COMPILE_IFELSE(
 487     [AC_LANG_SOURCE[
 488       int main(int argc, char** argv) {
 489         unsigned size = argc;
 490         char data[size];
 491         return 0;
 492       }
 493     ]],
 494     [folly_cv_prog_cc_have_vla=yes],
 495     [folly_cv_prog_cc_have_vla=no])])
 496
 497 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 498 AC_DEFINE_UNQUOTED(
 499   [HAVE_VLA],
 500   [$have_vla],
 501   [Define to 1 if the compiler has VLA (variable-length array) support,
 502    otherwise define to 0])
 503
 504 # Checks for library functions.
 505 AC_CHECK_FUNCS([getdelim \
 506                 gettimeofday \
 507                 memmove \
 508                 memset \
 509                 pow \
 510                 strerror \
 511                 sched_yield \
 512                 malloc_size \
 513                 malloc_usable_size \
 514                 memrchr \
 515                 pipe2 \
 516                 preadv \
 517                 pwritev \
 518               ])
 519
 520 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 521 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 522 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 523 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 524 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [main]))
 525 AC_CHECK_HEADER([linux/membarrier.h], AC_DEFINE([HAVE_LINUX_MEMBARRIER_H], [1], [Define to 1 if membarrier.h is available]))
 526
 527 AC_ARG_ENABLE([follytestmain],
 528    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 529    [follytestmain=${enableval}], [follytestmain=no])
 530
 531 use_follytestmain=yes
 532 if test "x${follytestmain}" = "xyes"; then
 533    AC_CHECK_HEADERS([libdwarf.h dwarf.h],, AC_MSG_ERROR([Please install libdwarf development package]))
 534    AC_CHECK_HEADERS([libelf.h elf.h],, AC_MSG_ERROR([Please install libelf development package]))
 535    AC_CHECK_HEADERS([libunwind.h],, AC_MSG_ERROR([Please install libinwind development package]))
 536 else
 537    AC_CHECK_HEADERS([libdwarf.h dwarf.h],, [use_follytestmain=no])
 538    AC_CHECK_HEADERS([libelf.h elf.h],, [use_follytestmain=no])
 539    AC_CHECK_HEADERS([libunwind.h],, [use_follytestmain=no])
 540 fi
 541
 542 AC_ARG_ENABLE([mobile],
 543    AS_HELP_STRING([--enable-mobile],
 544                   [enables using main function from folly for tests]),
 545                   [mobile=${enableval}], [mobile=no])
 546 AS_IF([test "x${mobile}" = "xyes"], [
 547     AC_DEFINE([MOBILE], [1],
 548               [Define to 1 for compiler guards for mobile targets.])
 549 ])
 550
 551 # Include directory that contains "folly" so #include <folly/Foo.h> works
 552 AM_CPPFLAGS='-I$(top_srcdir)/..'
 553 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 554 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 555 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 556 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 557 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 558
 559 AM_LDFLAGS="$AM_LDFLAGS $OPENSSL_LDFLAGS $OPENSSL_LIBS"
 560
 561 AC_SUBST([AM_CPPFLAGS])
 562 AC_SUBST([AM_LDFLAGS])
 563
 564 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 565 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 566 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 567 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 568 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 569 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 570                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 571 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT_H], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 572 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 573                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 574 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 575 AM_CONDITIONAL([HAVE_BOOST_CONTEXT], [test "x${ax_cv_boost_context}" = "xyes"])
 576
 577 # remove pkg-config deps from dependent libraries
 578 # (at least for pkg-config file purposes)
 579 FB_FILTER_PKG_LIBS([$AM_LDFLAGS $LIBS])
 580
 581 # Output
 582 AC_CONFIG_FILES([Makefile
 583                  libfolly.pc
 584                  test/Makefile
 585                  test/function_benchmark/Makefile
 586                  experimental/Makefile
 587                  experimental/symbolizer/Makefile
 588                  init/Makefile])
 589 AC_OUTPUT