folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6 AC_INIT(folly, 0.1, folly@fb.com)
   7
   8 m4_define([folly_libtool_current], [1])
   9
  10 # We assume all revisions are backwards incompatible.
  11 LT_VERSION=folly_libtool_current:0:0
  12 AC_SUBST(LT_VERSION)
  13
  14 AC_CONFIG_SRCDIR([Likely.h])
  15 AC_CONFIG_HEADERS([config.h])
  16 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  17 AC_CONFIG_AUX_DIR([build-aux])
  18
  19 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PROG_INSTALL
  24 AM_PROG_LIBTOOL
  25
  26 AC_LANG([C++])
  27
  28 # Checks for programs.
  29 AC_PROG_CXX
  30 AC_PROG_CC
  31 AC_CXX_COMPILE_STDCXX_0X
  32
  33 # Be sure to add any -std option to CXXFLAGS before we invoke any
  34 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  35 # before we update CXXFLAGS will not be run with the same options that we use
  36 # during the real build.
  37 STD=""
  38 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  39    STD="-std=c++0x"
  40 fi
  41 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  42    STD="-std=gnu++0x"
  43 fi
  44
  45 CXXFLAGS="$STD $CXXFLAGS"
  46
  47 # Checks for libraries.
  48 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  49              [Please install google-glog library])])
  50 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  51              [Please install google-gflags library])])
  52
  53 # check for boost libs
  54 AX_BOOST_BASE([1.20.0], [], [AC_MSG_ERROR(
  55               [Please install boost >= 1.20.0 (thread, regex, and system)])])
  56 AX_BOOST_THREAD
  57 AX_BOOST_REGEX
  58 AX_BOOST_SYSTEM
  59 AX_BOOST_FILESYSTEM
  60
  61 # Checks for header files.
  62 AC_HEADER_STDC
  63 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h bits/functexcept.h bits/c++config.h])
  64
  65 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
  66                 [Couldn't find double-conversion.h, please download from \
  67                 http://code.google.com/p/double-conversion/])], [])
  68 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
  69              [Please install double-conversion library])])
  70
  71 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
  72
  73 AC_CHECK_LIB([jemalloc], [rallocm])
  74
  75 # Checks for typedefs, structures, and compiler characteristics.
  76 AC_HEADER_STDBOOL
  77 AC_C_CONST
  78 AC_C_INLINE
  79 AC_TYPE_SIZE_T
  80 AC_HEADER_TIME
  81 AC_C_VOLATILE
  82 AC_CHECK_TYPE([__int128],
  83   [AC_DEFINE([HAVE_INT128_T], [1], [Define if __int128 exists])],
  84   [AC_DEFINE([HAVE_INT128_T], [0], [Define if __int128 does not exist])])
  85 AC_CHECK_TYPES([ptrdiff_t])
  86 AC_COMPILE_IFELSE(
  87   [AC_LANG_SOURCE[
  88     #pragma GCC diagnostic error "-Wattributes"
  89     extern "C" void (*test_ifunc(void))() { return 0; }
  90     void func() __attribute__((ifunc("test_ifunc")));]
  91   ],
  92   [AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])],
  93   [AC_DEFINE([HAVE_IFUNC], [0], [Define to 0 if the compiler doesn't support ifunc])]
  94 )
  95 AC_COMPILE_IFELSE(
  96   [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
  97                   class D : public C { virtual void g() override {} };]],
  98   [AC_DEFINE([FINAL], [final],
  99              [Define to "final" if the compiler supports C++11 "final"])
 100    AC_DEFINE([OVERRIDE], [override],
 101              [Define to "override" if the compiler supports C++11 "override"])],
 102   [AC_DEFINE([FINAL], [],
 103              [Define to "final" if the compiler supports C++11 "final"])
 104    AC_DEFINE([OVERRIDE], [],
 105              [Define to "override" if the compiler supports C++11 "override"])]
 106 )
 107
 108 AC_COMPILE_IFELSE(
 109   [AC_LANG_SOURCE[
 110     #include <thread>
 111     #include <chrono>
 112     void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 113   [AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 114              [Define to 1 if std::this_thread::sleep_for() is defined.])])
 115
 116 AC_COMPILE_IFELSE(
 117   [AC_LANG_SOURCE[
 118     #include <cstring>
 119     static constexpr int val = strlen("foo");]],
 120   [AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 121              [Define to 1 if strlen(3) is constexpr.])])
 122
 123 AC_COMPILE_IFELSE(
 124   [AC_LANG_SOURCE[
 125     #include <type_traits>
 126     #if !_LIBCPP_VERSION
 127     #error No libc++
 128     #endif
 129     void func() {}]
 130   ],
 131   [AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we're using libc++.])])
 132
 133 AC_COMPILE_IFELSE(
 134   [AC_LANG_SOURCE[
 135     #include <type_traits>
 136     const bool val = std::is_trivially_copyable<bool>::value;]
 137   ],
 138   [AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 139              [Define to 1 if we have a usable std::is_trivially_copyable<T>
 140               implementation.])])
 141
 142 # Figure out if we support weak symbols. If not, we will link in some null
 143 # stubs for functions that would otherwise be weak.
 144 AC_LINK_IFELSE(
 145   [AC_LANG_SOURCE[
 146     extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 147     int main(int argc, char** argv) {
 148         return configure_link_extern_weak_test == nullptr;
 149     }]
 150   ],
 151   [
 152     ac_have_weak_symbols="yes"
 153     AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 154               [Define to 1 if the linker supports weak symbols.])])
 155
 156 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty])
 157 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 158   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 159             [Define to 1 if we have cplus_demangle_v3_callback.])
 160 fi
 161
 162 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 163 # want to link with librt if necessary.
 164 AC_SEARCH_LIBS([clock_gettime], [rt],
 165   AC_DEFINE(
 166     [HAVE_CLOCK_GETTIME],
 167     [1],
 168     [Define to 1 if we support clock_gettime(2).]),
 169   [])
 170
 171 # Checks for library functions.
 172 AC_CHECK_FUNCS([getdelim \
 173                 gettimeofday \
 174                 memmove \
 175                 memset \
 176                 pow \
 177                 strerror \
 178                 pthread_yield \
 179                 rallocm \
 180                 malloc_size \
 181                 malloc_usable_size \
 182                 memrchr])
 183
 184 if test "$ac_cv_func_pthread_yield" = "no"; then
 185    AC_CHECK_HEADERS([sched.h])
 186    AC_CHECK_FUNCS([sched_yield])
 187 fi
 188
 189 AC_SUBST(AM_CPPFLAGS, '-I../$(top_srcdir)'" "'-I$(top_srcdir)/io'" "'-I$(top_srcdir)/test'" $BOOST_CPPFLAGS")
 190 AC_SUBST(AM_LDFLAGS, "$BOOST_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread")
 191
 192 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 193 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 194 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 195 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS], [test "$ac_have_weak_symbols" = "yes"])
 196 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept" = "yes"])
 197
 198 # Output
 199 AC_CONFIG_FILES([Makefile
 200                  test/Makefile
 201                  test/function_benchmark/Makefile])
 202 AC_OUTPUT