folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6 AC_INIT(folly, 0.1, folly@fb.com)
   7 AC_CONFIG_SRCDIR([Likely.h])
   8 AC_CONFIG_HEADERS([config.h])
   9 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11
  12 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  13
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AC_PROG_INSTALL
  17 AM_PROG_LIBTOOL
  18
  19 AC_LANG([C++])
  20
  21 # Checks for programs.
  22 AC_PROG_CXX
  23 AC_PROG_CC
  24 AC_CXX_COMPILE_STDCXX_0X
  25
  26 # Checks for libraries.
  27 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  28              [Please install google-glog library])])
  29 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  30              [Please install google-gflags library])])
  31
  32 # check for boost libs
  33 AX_BOOST_BASE
  34 AX_BOOST_THREAD
  35 AX_BOOST_REGEX
  36 AX_BOOST_SYSTEM
  37
  38 # Checks for header files.
  39 AC_HEADER_STDC
  40 AC_CHECK_HEADERS([fcntl.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h features.h malloc.h])
  41
  42 AC_CHECK_HEADER(double-conversion.h, [], [AC_MSG_ERROR(
  43                 [Couldn't find double-conversion.h, please download from \
  44                 http://code.google.com/p/double-conversion/])], [])
  45 AC_CHECK_LIB([double_conversion_pic],[ceil],[],[AC_MSG_ERROR(
  46              [Please install double-conversion library])])
  47
  48 # Checks for typedefs, structures, and compiler characteristics.
  49 AC_HEADER_STDBOOL
  50 AC_C_CONST
  51 AC_C_INLINE
  52 AC_TYPE_SIZE_T
  53 AC_HEADER_TIME
  54 AC_C_VOLATILE
  55 AC_CHECK_TYPE([__int128],
  56   [AC_DEFINE([HAVE_INT128_T], [1], [Define if __int128 exists])],
  57   [AC_DEFINE([HAVE_INT128_T], [0], [Define if __int128 does not exist])])
  58 AC_CHECK_TYPES([ptrdiff_t])
  59
  60 # Checks for library functions.
  61 AC_CHECK_FUNCS([getdelim \
  62                 gettimeofday \
  63                 memmove \
  64                 memset \
  65                 pow \
  66                 strerror \
  67                 pthread_yield \
  68                 rallocm \
  69                 malloc_size \
  70                 malloc_usable_size])
  71
  72 if test "$ac_cv_func_pthread_yield" = "no"; then
  73    AC_CHECK_HEADERS([sched.h])
  74    AC_CHECK_FUNCS([sched_yield])
  75 fi
  76
  77 CXX_FLAGS=""
  78 if test "$ac_cv_cxx_compile_cxx0x_cxx" = yes; then
  79    CXX_FLAGS="-std=c++0x"
  80 fi
  81 if test "$ac_cv_cxx_compile_cxx0x_gxx" = yes; then
  82    CXX_FLAGS="-std=gnu++0x"
  83 fi
  84
  85 AC_SUBST(AM_CPPFLAGS, '-I../$(top_srcdir)'" "'-I$(top_srcdir)/io'" "'-I$(top_srcdir)/test'" -lstdc++ $CXX_FLAGS $BOOST_CPPFLAGS")
  86 AC_SUBST(AM_CXXFLAGS, "$BOOST_THREAD_LIB $BOOST_SYSTEM_LIB")
  87
  88 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
  89 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
  90
  91 # Output
  92 AC_CONFIG_FILES([Makefile
  93                  test/Makefile
  94                  test/function_benchmark/Makefile])
  95 AC_OUTPUT