folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST(LT_VERSION)
  14
  15 AC_CONFIG_SRCDIR([Likely.h])
  16 AC_CONFIG_HEADERS([config.h])
  17 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  18 AC_CONFIG_AUX_DIR([build-aux])
  19
  20 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  21
  22 AC_CONFIG_MACRO_DIR([m4])
  23
  24 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  25 AX_CONFIG_FEATURE(
  26         [deprecated-assoc],
  27         [supports deprecated associative containers (hash_map/hash_set)],
  28         [HAVE_DEPRECATED_ASSOC],
  29         [Define if you want to support deprecated associative containers])
  30
  31 AC_PROG_INSTALL
  32 AM_PROG_LIBTOOL
  33
  34 AC_LANG([C++])
  35
  36 # Checks for programs.
  37 AC_PROG_CXX
  38 AC_PROG_CC
  39 AC_CXX_COMPILE_STDCXX_0X
  40
  41 # Be sure to add any -std option to CXXFLAGS before we invoke any
  42 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  43 # before we update CXXFLAGS will not be run with the same options that we use
  44 # during the real build.
  45 STD=""
  46 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  47    STD="-std=c++0x"
  48 fi
  49 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  50    STD="-std=gnu++0x"
  51 fi
  52
  53 CXXFLAGS="$STD $CXXFLAGS"
  54
  55 # Checks for libraries.
  56 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  57              [Please install google-glog library])])
  58 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  59              [Please install google-gflags library])])
  60
  61 # check for boost libs
  62 AX_BOOST_BASE([1.20.0], [], [AC_MSG_ERROR(
  63               [Please install boost >= 1.20.0 (thread, regex, and system)])])
  64 AX_BOOST_THREAD
  65 AX_BOOST_REGEX
  66 AX_BOOST_SYSTEM
  67 AX_BOOST_FILESYSTEM
  68
  69 # Checks for header files.
  70 AC_HEADER_STDC
  71 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h bits/functexcept.h bits/c++config.h])
  72
  73 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
  74                 [Couldn't find double-conversion.h, please download from \
  75                 http://code.google.com/p/double-conversion/])], [])
  76 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
  77              [Please install double-conversion library])])
  78
  79 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
  80
  81 AC_CHECK_LIB([jemalloc], [rallocm])
  82
  83 # Checks for typedefs, structures, and compiler characteristics.
  84 AC_HEADER_STDBOOL
  85 AC_C_CONST
  86 AC_C_INLINE
  87 AC_TYPE_SIZE_T
  88 AC_HEADER_TIME
  89 AC_C_VOLATILE
  90 AC_CHECK_TYPE([__int128],
  91   [AC_DEFINE([HAVE_INT128_T], [1], [Define if __int128 exists])],
  92   [AC_DEFINE([HAVE_INT128_T], [0], [Define if __int128 does not exist])])
  93 AC_CHECK_TYPES([ptrdiff_t])
  94
  95 AC_CACHE_CHECK(
  96   [for ifunc support],
  97   [folly_cv_prog_cc_ifunc],
  98   [AC_COMPILE_IFELSE(
  99     [AC_LANG_SOURCE[
 100       #pragma GCC diagnostic error "-Wattributes"
 101       extern "C" void (*test_ifunc(void))() { return 0; }
 102       void func() __attribute__((ifunc("test_ifunc")));]
 103     ],
 104     [folly_cv_prog_cc_ifunc=yes],
 105     [folly_cv_prog_cc_ifunc=no])])
 106
 107 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 108   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 109 fi
 110
 111 AC_CACHE_CHECK(
 112   [for final and override support],
 113   [folly_cv_c_final_override],
 114   [AC_COMPILE_IFELSE(
 115     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 116                     class D : public C { virtual void g() override {} };]],
 117     [folly_cv_c_final_override=yes],
 118     [folly_cv_c_final_override=no])])
 119
 120 if test "$folly_cv_c_final_override" = "yes"; then
 121   final_val=final
 122   override_val=override
 123 else
 124   final_val=
 125   override_val=
 126 fi
 127
 128 AC_DEFINE_UNQUOTED(
 129   [FINAL], [$final_val],
 130   [Define to "final" if the compiler supports C++11 "final"])
 131 AC_DEFINE_UNQUOTED(
 132   [OVERRIDE], [$override_val],
 133   [Define to "override" if the compiler supports C++11 "override"])
 134
 135 AC_CACHE_CHECK(
 136   [for std::this_thread::sleep_for],
 137   [folly_cv_func_this_thread_sleep_for],
 138   [AC_COMPILE_IFELSE(
 139     [AC_LANG_SOURCE[
 140       #include <thread>
 141       #include <chrono>
 142       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 143     [folly_cv_func_this_thread_sleep_for=yes],
 144     [folly_cv_func_this_thread_sleep_for=no])])
 145
 146 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 147     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 148               [Define to 1 if std::this_thread::sleep_for() is defined.])
 149 fi
 150
 151 AC_CACHE_CHECK(
 152   [for constexpr strlen],
 153   [folly_cv_func_constexpr_strlen],
 154   [AC_COMPILE_IFELSE(
 155     [AC_LANG_SOURCE[
 156       #include <cstring>
 157       static constexpr int val = strlen("foo");]],
 158     [folly_cv_func_constexpr_strlen=yes],
 159     [folly_cv_func_constexpr_strlen=no])])
 160
 161 if test "$folly_cv_func_constexpr_strlen" = yes; then
 162     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 163               [Define to 1 if strlen(3) is constexpr.])
 164 fi
 165
 166 AC_CACHE_CHECK(
 167   [for libc++],
 168   [folly_cv_lib_libcpp],
 169   [AC_COMPILE_IFELSE(
 170     [AC_LANG_SOURCE[
 171       #include <type_traits>
 172       #if !_LIBCPP_VERSION
 173       #error No libc++
 174       #endif
 175       void func() {}]
 176     ],
 177     [folly_cv_lib_libcpp=yes],
 178     [folly_cv_lib_libcpp=no])])
 179
 180 if test "$folly_cv_lib_libcpp" = yes; then
 181   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we're using libc++.])
 182 fi
 183
 184 AC_CACHE_CHECK(
 185   [for usable std::is_trivially_copyable],
 186   [folly_cv_decl_std_is_trivially_copyable],
 187   [AC_COMPILE_IFELSE(
 188     [AC_LANG_SOURCE[
 189       #include <type_traits>
 190       const bool val = std::is_trivially_copyable<bool>::value;]
 191     ],
 192     [folly_cv_decl_std_is_trivially_copyable=yes],
 193     [folly_cv_decl_std_is_trivially_copyable=no])])
 194
 195 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 196   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 197             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 198              implementation.])
 199 fi
 200
 201 AC_CACHE_CHECK(
 202   [gflags namespace],
 203   [folly_cv_decl_gflags_namespace],
 204   [AC_COMPILE_IFELSE(
 205     [AC_LANG_SOURCE[
 206       #include <gflags/gflags.h>
 207       void foo() { gflags::GetArgv(); }]
 208     ],
 209     [folly_cv_decl_gflags_namespace=gflags],
 210     [AC_COMPILE_IFELSE(
 211       [AC_LANG_SOURCE[
 212         #include <gflags/gflags.h>
 213         void foo() { google::GetArgv(); }]
 214       ],
 215       [folly_cv_decl_gflags_namespace=google],
 216       [folly_cv_decl_gflags_namespace=error])])])
 217
 218 if test "$folly_cv_decl_gflags_namespace" = error; then
 219   AC_MSG_ERROR([Cannot determine gflags namespace])
 220 else
 221   AC_DEFINE_UNQUOTED(
 222     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 223     [Define to gflags namespace (usually "google" or "gflags")])
 224   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 225      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 226                [Define to 1 if the gflags namespace is not "gflags"])
 227   fi
 228 fi
 229
 230 # Figure out if we support weak symbols. If not, we will link in some null
 231 # stubs for functions that would otherwise be weak.
 232 AC_CACHE_CHECK(
 233   [for weak symbol support],
 234   [folly_cv_prog_cc_weak_symbols],
 235   [AC_LINK_IFELSE(
 236     [AC_LANG_SOURCE[
 237       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 238       int main(int argc, char** argv) {
 239           return configure_link_extern_weak_test == nullptr;
 240       }]],
 241     [folly_cv_prog_cc_weak_symbols="yes"],
 242     [folly_cv_prog_cc_weak_symbols="no"])])
 243
 244 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 245   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 246             [Define to 1 if the linker supports weak symbols.])
 247 fi
 248
 249 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 250 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 251   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 252             [Define to 1 if we have cplus_demangle_v3_callback.])
 253 fi
 254
 255 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 256 # want to link with librt if necessary.
 257 AC_SEARCH_LIBS([clock_gettime], [rt],
 258   AC_DEFINE(
 259     [HAVE_CLOCK_GETTIME],
 260     [1],
 261     [Define to 1 if we support clock_gettime(2).]),
 262   [])
 263
 264 # Checks for library functions.
 265 AC_CHECK_FUNCS([getdelim \
 266                 gettimeofday \
 267                 memmove \
 268                 memset \
 269                 pow \
 270                 strerror \
 271                 pthread_yield \
 272                 rallocm \
 273                 malloc_size \
 274                 malloc_usable_size \
 275                 memrchr \
 276                 pipe2])
 277
 278 if test "$ac_cv_func_pthread_yield" = "no"; then
 279    AC_CHECK_HEADERS([sched.h])
 280    AC_CHECK_FUNCS([sched_yield])
 281 fi
 282
 283 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 284 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 285 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 286 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 287
 288 # Include directory that contains "folly" so #include <folly/Foo.h> works
 289 AM_CPPFLAGS='-I$(top_srcdir)/..'
 290 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 291 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 292 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 293
 294 AC_SUBST([AM_CPPFLAGS])
 295 AC_SUBST([AM_LDFLAGS])
 296
 297 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 298 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 299 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 300 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 301                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 302 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept" = "yes"])
 303
 304 # Output
 305 AC_CONFIG_FILES([Makefile
 306                  test/Makefile
 307                  test/function_benchmark/Makefile])
 308 AC_OUTPUT