folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 #declare pkg-config variables
  16 PKG_VERSION=m4_join([.], m4_reverse(m4_translit(folly_version_str, [:], [,])))
  17 AC_SUBST([PKG_VERSION])
  18 AC_SUBST([PKG_CXXFLAGS])
  19 AC_SUBST([PKG_DEPS])
  20 AC_SUBST([PKG_LIBS])
  21
  22 AC_CONFIG_SRCDIR([Likely.h])
  23 AC_CONFIG_HEADERS([config.h])
  24 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  32 AX_CONFIG_FEATURE(
  33         [deprecated-assoc],
  34         [supports deprecated associative containers (hash_map/hash_set)],
  35         [HAVE_DEPRECATED_ASSOC],
  36         [Define if you want to support deprecated associative containers])
  37
  38 AC_PROG_INSTALL
  39 AM_PROG_LIBTOOL
  40
  41 AC_LANG([C++])
  42
  43 # Checks for programs.
  44 AC_PROG_CXX
  45 AC_PROG_CC
  46
  47 AC_CXX_COMPILE_STDCXX_1Y
  48
  49 # Be sure to add any -std option to CXXFLAGS before we invoke any
  50 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  51 # before we update CXXFLAGS will not be run with the same options that we use
  52 # during the real build.
  53 STD=""
  54 if test "x$ac_cv_cxx_compile_cxx1y_cxx" = xyes; then
  55    STD="-std=c++1y"
  56 fi
  57 if test "x$ac_cv_cxx_compile_cxx1y_gxx" = xyes; then
  58    STD="-std=gnu++1y"
  59 fi
  60
  61 CXXFLAGS="$STD $CXXFLAGS"
  62
  63 # expose required -std option via pkg-config
  64 PKG_CXXFLAGS=$STD
  65
  66 # See if -Wshadow-local and -Wshadow-compatible-local are supported
  67 AC_MSG_CHECKING(
  68   [whether -Wshadow-local and -Wshadow-compatible-local are supported])
  69 AC_CACHE_VAL([folly_cv_cxx_shadow_local_support], [
  70   folly_save_CXXFLAGS="$CXXFLAGS"
  71   CXXFLAGS="$CXXFLAGS -Wshadow-local -Wshadow-compatible-local"
  72   AC_COMPILE_IFELSE(
  73     [AC_LANG_PROGRAM([[]], [[]])],
  74     [folly_cv_cxx_shadow_local_support=yes],
  75     [folly_cv_cxx_shadow_local_support=no])
  76   CXXFLAGS="$folly_save_CXXFLAGS"])
  77 AC_MSG_RESULT([$folly_cv_cxx_shadow_local_support])
  78 if test "$folly_cv_cxx_shadow_local_support" = yes; then
  79   AC_DEFINE([HAVE_SHADOW_LOCAL_WARNINGS], [1],
  80   [Define if both -Wshadow-local and -Wshadow-compatible-local are supported.])
  81 fi
  82
  83 # Checks for glog and gflags
  84 # There are no symbols with C linkage, so we do a try-run
  85 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  86                 [Please install google-gflags library])])
  87 AC_CACHE_CHECK(
  88   [for gflags viability],
  89   [folly_cv_prog_cc_gflags],
  90   [AC_RUN_IFELSE(
  91     [AC_LANG_SOURCE[
  92       #include <gflags/gflags.h>
  93       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  94       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  95       int main(int argc, char** argv) {
  96         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  97       }
  98     ]],
  99     [folly_cv_prog_cc_gflags=yes],
 100     [folly_cv_prog_cc_gflags=no]
 101   )]
 102 )
 103
 104 if test "$folly_cv_prog_cc_gflags" != "yes"; then
 105   AC_MSG_ERROR(["libgflags invalid, see config.log for details"])
 106 fi
 107 FB_CHECK_PKG_CONFIG([GFLAGS], [libgflags])
 108
 109 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
 110                 [Please install google-glog library])])
 111 AC_CACHE_CHECK(
 112   [for glog viability],
 113   [folly_cv_prog_cc_glog],
 114   [AC_RUN_IFELSE(
 115     [AC_LANG_SOURCE[
 116       #include <glog/logging.h>
 117       int main(int argc, char** argv) {
 118         google::InitGoogleLogging(argv[0]);
 119         google::ShutdownGoogleLogging();
 120         return 0;
 121       }
 122     ]],
 123     [folly_cv_prog_cc_glog=yes],
 124     [folly_cv_prog_cc_glog=no]
 125   )]
 126 )
 127
 128 if test "$folly_cv_prog_cc_glog" != "yes"; then
 129   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
 130 fi
 131 FB_CHECK_PKG_CONFIG([GLOG], [libglog])
 132
 133 AX_CHECK_OPENSSL([],
 134         [AC_MSG_ERROR(["Error: libssl required"])])
 135 FB_CHECK_PKG_CONFIG([OPENSSL], [openssl])
 136
 137 # check for boost libs
 138 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 139               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 140 AX_BOOST_CONTEXT
 141 AX_BOOST_PROGRAM_OPTIONS
 142 AX_BOOST_THREAD
 143 AX_BOOST_REGEX
 144 AX_BOOST_SYSTEM
 145 AX_BOOST_FILESYSTEM
 146 AX_BOOST_CHRONO
 147
 148 # Check for python interpreter
 149 AM_PATH_PYTHON
 150
 151 # Checks for header files.
 152 AC_HEADER_STDC
 153 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h sched.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h byteswap.h bits/functexcept.h bits/c++config.h])
 154
 155 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 156                 [Couldn't find double-conversion.h, please download from \
 157                  https://github.com/google/double-conversion/])], [])
 158 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 159              [Please install double-conversion library])])
 160
 161 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 162 FB_CHECK_PKG_CONFIG([EVENT], [libevent])
 163
 164 AC_CHECK_LIB([jemalloc], [xallocx])
 165
 166 # Checks for typedefs, structures, and compiler characteristics.
 167 AC_HEADER_STDBOOL
 168 AC_C_CONST
 169 AC_C_INLINE
 170 AC_TYPE_SIZE_T
 171 AC_HEADER_TIME
 172 AC_C_VOLATILE
 173 AC_CHECK_TYPE([__int128], [folly_cv_prog_cc_int128=yes],
 174     [folly_cv_prog_cc_int128=no])
 175 if test "$folly_cv_prog_cc_int128" = "yes"; then
 176   AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128])
 177   AC_CACHE_CHECK(
 178     [for __int128 type traits],
 179     [folly_cv_prog_cc_int128traits],
 180     [AC_COMPILE_IFELSE(
 181       [AC_LANG_SOURCE([[
 182 #include <type_traits>
 183 static_assert(
 184   ::std::is_same<::std::make_signed<unsigned __int128>::type, __int128>::value,
 185   "signed form of `unsigned __uint128` must be `__int128`.");
 186       ]])],
 187       [folly_cv_prog_cc_int128traits=yes],
 188       [folly_cv_prog_cc_int128traits=no])
 189     ])
 190   if test "$folly_cv_prog_cc_int128traits" = "no"; then
 191     AC_DEFINE([SUPPLY_MISSING_INT128_TRAITS], [1], [Define if we need the standard integer traits defined for the type `__int128'.])
 192   fi
 193 fi
 194
 195 AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
 196
 197 AC_CACHE_CHECK(
 198   [for ifunc support],
 199   [folly_cv_prog_cc_ifunc],
 200   [AC_COMPILE_IFELSE(
 201     [AC_LANG_SOURCE[
 202       #pragma GCC diagnostic error "-Wattributes"
 203       extern "C" void (*test_ifunc(void))() { return 0; }
 204       void func() __attribute__((ifunc("test_ifunc")));]
 205     ],
 206     [folly_cv_prog_cc_ifunc=yes],
 207     [folly_cv_prog_cc_ifunc=no])])
 208
 209 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 210   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 211 fi
 212
 213 AC_CACHE_CHECK(
 214   [for final and override support],
 215   [folly_cv_c_final_override],
 216   [AC_COMPILE_IFELSE(
 217     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 218                     class D : public C { virtual void g() override {} };]],
 219     [folly_cv_c_final_override=yes],
 220     [folly_cv_c_final_override=no])])
 221
 222 if test "$folly_cv_c_final_override" = "yes"; then
 223   final_val=final
 224   override_val=override
 225 else
 226   final_val=
 227   override_val=
 228 fi
 229
 230 AC_DEFINE_UNQUOTED(
 231   [FINAL], [$final_val],
 232   [Define to "final" if the compiler supports C++11 "final"])
 233 AC_DEFINE_UNQUOTED(
 234   [OVERRIDE], [$override_val],
 235   [Define to "override" if the compiler supports C++11 "override"])
 236
 237 AC_CACHE_CHECK(
 238   [for std::this_thread::sleep_for],
 239   [folly_cv_func_this_thread_sleep_for],
 240   [AC_COMPILE_IFELSE(
 241     [AC_LANG_SOURCE[
 242       #include <thread>
 243       #include <chrono>
 244       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 245     [folly_cv_func_this_thread_sleep_for=yes],
 246     [folly_cv_func_this_thread_sleep_for=no])])
 247
 248 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 249     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 250               [Define to 1 if std::this_thread::sleep_for() is defined.])
 251 fi
 252
 253 AC_CACHE_CHECK(
 254   [for constexpr strlen],
 255   [folly_cv_func_constexpr_strlen],
 256   [AC_COMPILE_IFELSE(
 257     [AC_LANG_SOURCE[
 258       #include <cstring>
 259       static constexpr int val = strlen("foo");]],
 260     [folly_cv_func_constexpr_strlen=yes],
 261     [folly_cv_func_constexpr_strlen=no])])
 262
 263 if test "$folly_cv_func_constexpr_strlen" = yes; then
 264     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 265               [Define to 1 if strlen(3) is constexpr.])
 266 fi
 267
 268 AC_CACHE_CHECK(
 269   [for libc++],
 270   [folly_cv_lib_libcpp],
 271   [AC_COMPILE_IFELSE(
 272     [AC_LANG_SOURCE[
 273       #include <type_traits>
 274       #if !_LIBCPP_VERSION
 275       #error No libc++
 276       #endif
 277       void func() {}]
 278     ],
 279     [folly_cv_lib_libcpp=yes],
 280     [folly_cv_lib_libcpp=no])])
 281
 282 if test "$folly_cv_lib_libcpp" = yes; then
 283   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 284 fi
 285
 286 AC_CACHE_CHECK(
 287   [for c++11 atomic support without GNU Atomic library],
 288   [folly_cv_lib_libatomic],
 289   [AC_LINK_IFELSE(
 290     [AC_LANG_SOURCE[
 291       #include <atomic>
 292       int main() {
 293         struct Test { int val; };
 294         std::atomic<Test> s;
 295         s.is_lock_free();
 296       }
 297     ]],
 298     [folly_cv_lib_libatomic=yes],
 299     [folly_cv_lib_libatomic=no])])
 300
 301 if test "$folly_cv_lib_libatomic" = no; then
 302   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 303                   [Please install the GNU Atomic library])])
 304 fi
 305
 306 AC_CACHE_CHECK(
 307   [for liblinux-vdso support],
 308   [folly_cv_lib_liblinux_vdso],
 309   [AC_RUN_IFELSE(
 310     [AC_LANG_PROGRAM[
 311       #include <dlfcn.h>
 312       int main() {
 313         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 314         if (h == nullptr) {
 315           return -1;
 316         }
 317         dlclose(h);
 318         return 0;
 319       }
 320     ]],
 321     [folly_cv_lib_liblinux_vdso=yes],
 322     [folly_cv_lib_liblinux_vdso=no])])
 323
 324 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 325   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 326 fi
 327
 328 AC_CACHE_CHECK(
 329   [for usable std::is_trivially_copyable],
 330   [folly_cv_decl_std_is_trivially_copyable],
 331   [AC_COMPILE_IFELSE(
 332     [AC_LANG_SOURCE[
 333       #include <type_traits>
 334       const bool val = std::is_trivially_copyable<bool>::value;]
 335     ],
 336     [folly_cv_decl_std_is_trivially_copyable=yes],
 337     [folly_cv_decl_std_is_trivially_copyable=no])])
 338
 339 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 340   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 341             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 342              implementation.])
 343 fi
 344
 345 AC_CACHE_CHECK(
 346   [gflags namespace],
 347   [folly_cv_decl_gflags_namespace],
 348   [AC_COMPILE_IFELSE(
 349     [AC_LANG_SOURCE[
 350       #include <gflags/gflags.h>
 351       void foo() { gflags::GetArgv(); }]
 352     ],
 353     [folly_cv_decl_gflags_namespace=gflags],
 354     [AC_COMPILE_IFELSE(
 355       [AC_LANG_SOURCE[
 356         #include <gflags/gflags.h>
 357         void foo() { google::GetArgv(); }]
 358       ],
 359       [folly_cv_decl_gflags_namespace=google],
 360       [folly_cv_decl_gflags_namespace=error])])])
 361
 362 if test "$folly_cv_decl_gflags_namespace" = error; then
 363   AC_MSG_ERROR([Cannot determine gflags namespace])
 364 else
 365   AC_DEFINE_UNQUOTED(
 366     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 367     [Define to gflags namespace (usually "google" or "gflags")])
 368   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 369      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 370                [Define to 1 if the gflags namespace is not "gflags"])
 371   fi
 372 fi
 373
 374 # Figure out if we support weak symbols. If not, we will link in some null
 375 # stubs for functions that would otherwise be weak.
 376 AC_CACHE_CHECK(
 377   [for weak symbol support],
 378   [folly_cv_prog_cc_weak_symbols],
 379   [AC_LINK_IFELSE(
 380     [AC_LANG_SOURCE[
 381       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 382       int main(int argc, char** argv) {
 383           return configure_link_extern_weak_test == nullptr;
 384       }]],
 385     [folly_cv_prog_cc_weak_symbols="yes"],
 386     [folly_cv_prog_cc_weak_symbols="no"])])
 387
 388 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 389   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 390             [Define to 1 if the linker supports weak symbols.])
 391 fi
 392
 393
 394 # Figure out if we support wchar well
 395 AC_CACHE_CHECK(
 396   [for wchar support],
 397   [folly_cv_prog_cc_wchar_support],
 398   [AC_RUN_IFELSE(
 399     [AC_LANG_SOURCE[
 400       #include <cstddef>
 401       #include <cwchar>
 402
 403       int main(int argc, char** argv) {
 404         return wcstol(L"01", nullptr, 10) == 1 ? 0 : 1;
 405       }
 406     ]],
 407     [folly_cv_prog_cc_wchar_support=yes],
 408     [folly_cv_prog_cc_wchar_support=no])])
 409
 410 if test "$folly_cv_prog_cc_wchar_support" = "yes"; then
 411   AC_DEFINE([HAVE_WCHAR_SUPPORT], [1], [Define to 1 if the libc supports wchar well])
 412 fi
 413
 414 # Figure out whether the architecture supports unaligned accesses
 415 AC_CACHE_CHECK(
 416   [for unaligned access support],
 417   [folly_cv_prog_cc_unaligned_access],
 418   [AC_RUN_IFELSE(
 419     [AC_LANG_SOURCE[
 420       int main(int argc, char** argv) {
 421         char buf[64] = {0};
 422         unsigned long *ptr = (unsigned long *)(buf + 1);
 423         *ptr = 0xdeadbeef;
 424         return (*ptr & 0xff) == 0xef ? 0 : 1;
 425       }
 426     ]],
 427     [folly_cv_prog_cc_unaligned_access=yes],
 428     [folly_cv_prog_cc_unaligned_access=no])])
 429
 430 if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
 431   AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
 432 fi
 433
 434 AC_CACHE_CHECK(
 435   [for vsnprintf reporting bad format strings],
 436   [folly_cv_prog_vsnprintf_bad_format],
 437   [AC_RUN_IFELSE(
 438     [AC_LANG_SOURCE[
 439       #include <stdio.h>
 440
 441       int main(int argc, char** argv) {
 442           char buf[256];
 443           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 444       }]],
 445     [folly_cv_prog_vsnprintf_bad_format="yes"],
 446     [folly_cv_prog_vsnprintf_bad_format="no"])])
 447
 448 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 449   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 450             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 451 fi
 452
 453 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 454 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 455   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 456             [Define to 1 if we have cplus_demangle_v3_callback.])
 457 fi
 458
 459 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 460 # want to link with librt if necessary.
 461 AC_SEARCH_LIBS([clock_gettime], [rt],
 462   AC_DEFINE(
 463     [HAVE_CLOCK_GETTIME],
 464     [1],
 465     [Define to 1 if we support clock_gettime(2).]),
 466   [])
 467
 468 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 469 # want to include pthread.h if necessary.
 470 AC_CACHE_CHECK(
 471   [for pthread_atfork support],
 472   [folly_cv_prog_cc_pthread_atfork],
 473   [AC_COMPILE_IFELSE(
 474     [AC_LANG_SOURCE[
 475       #include <pthread.h>
 476       void func() {pthread_atfork(NULL, NULL, NULL);}]
 477     ],
 478     [folly_cv_prog_cc_pthread_atfork=yes],
 479     [folly_cv_prog_cc_pthread_atfork=no])])
 480
 481 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 482   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 483 fi
 484
 485 # Check for XSI-compatible strerror_r as default implementation
 486 AC_CACHE_CHECK(
 487   [for XSI style strerror_r support],
 488   [folly_cv_prog_cc_xsi_strerror_r],
 489   [AC_RUN_IFELSE(
 490     [AC_LANG_SOURCE[
 491       #include <string.h>
 492       #include <errno.h>
 493       int main(int argc, char** argv) {
 494         char buf[1024];
 495         buf[0] = 0;
 496         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 497         return ret;
 498       }
 499     ]],
 500     [folly_cv_prog_cc_xsi_strerror_r=yes],
 501     [folly_cv_prog_cc_xsi_strerror_r=no])])
 502
 503 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 504   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 505 fi
 506
 507 AC_CACHE_CHECK(
 508   [for ext/random and __gnu_cxx::sfmt19937],
 509   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 510   [AC_COMPILE_IFELSE(
 511     [AC_LANG_SOURCE[
 512       #include <ext/random>
 513       int main(int argc, char** argv) {
 514         __gnu_cxx::sfmt19937 rng;
 515         return 0;
 516       }
 517     ]],
 518     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 519     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 520
 521 AC_CACHE_CHECK(
 522   [for VLA (variable-length array) support],
 523   [folly_cv_prog_cc_have_vla],
 524   [AC_COMPILE_IFELSE(
 525     [AC_LANG_SOURCE[
 526       int main(int argc, char** argv) {
 527         unsigned size = argc;
 528         char data[size];
 529         return 0;
 530       }
 531     ]],
 532     [folly_cv_prog_cc_have_vla=yes],
 533     [folly_cv_prog_cc_have_vla=no])])
 534
 535 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 536 AC_DEFINE_UNQUOTED(
 537   [HAVE_VLA],
 538   [$have_vla],
 539   [Define to 1 if the compiler has VLA (variable-length array) support,
 540    otherwise define to 0])
 541
 542 # Checks for library functions.
 543 AC_CHECK_FUNCS([getdelim \
 544                 gettimeofday \
 545                 memmove \
 546                 memset \
 547                 pow \
 548                 strerror \
 549                 sched_yield \
 550                 malloc_size \
 551                 malloc_usable_size \
 552                 memrchr \
 553                 pipe2 \
 554                 preadv \
 555                 pwritev \
 556               ])
 557
 558 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 559 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 560 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 561 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 562 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [main]))
 563 AC_CHECK_HEADER([linux/membarrier.h], AC_DEFINE([HAVE_LINUX_MEMBARRIER_H], [1], [Define to 1 if membarrier.h is available]))
 564
 565 AC_ARG_ENABLE([follytestmain],
 566    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 567    [follytestmain=${enableval}], [follytestmain=no])
 568
 569 use_follytestmain=yes
 570 # libdwarf used to install in /usr/include, now installs in /usr/include/libdwarf.
 571 AC_SEARCH_LIBS([dwarf_init], [dwarf])
 572 AC_CHECK_HEADERS([libdwarf/dwarf.h dwarf.h], [break])
 573 # Check whether we have both the library and the header
 574 have_libdwarf=no
 575 AS_IF([test "x${ac_cv_search_dwarf_init}" != xno && test "x${ac_cv_header_libdwarf_dwarf_h}" = xyes], [have_libdwarf=yes])
 576 AS_IF([test "x${ac_cv_search_dwarf_init}" != xno && test "x${ac_cv_header_dwarf_h}" = xyes], [have_libdwarf=yes])
 577 if test "x${follytestmain}" = "xyes"; then
 578    AS_IF([test "x${have_libdwarf}" = xno], [AC_MSG_ERROR([Please install libdwarf development library and headers])])
 579    AC_CHECK_HEADERS([elf.h],, AC_MSG_ERROR([Please install libelf development package]))
 580    AC_CHECK_HEADERS([libunwind.h],, AC_MSG_ERROR([Please install libunwind development package]))
 581 else
 582    AS_IF([test "x${have_libdwarf}" = xno],, [use_follytestmain=no])
 583    AC_CHECK_HEADERS([elf.h],, [use_follytestmain=no])
 584    AC_CHECK_HEADERS([libunwind.h],, [use_follytestmain=no])
 585 fi
 586
 587 AC_ARG_ENABLE([mobile],
 588    AS_HELP_STRING([--enable-mobile],
 589                   [enables using main function from folly for tests]),
 590                   [mobile=${enableval}], [mobile=no])
 591 AS_IF([test "x${mobile}" = "xyes"], [
 592     AC_DEFINE([MOBILE], [1],
 593               [Define to 1 for compiler guards for mobile targets.])
 594 ])
 595
 596 # Include directory that contains "folly" so #include <folly/Foo.h> works
 597 AM_CPPFLAGS='-I$(top_srcdir)/..'
 598 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 599 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 600 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 601 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 602 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 603
 604 AM_LDFLAGS="$AM_LDFLAGS $OPENSSL_LDFLAGS $OPENSSL_LIBS"
 605
 606 AC_SUBST([AM_CPPFLAGS])
 607 AC_SUBST([AM_LDFLAGS])
 608
 609 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 610 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 611 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 612 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 613 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 614 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 615                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 616 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT_H], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 617 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 618                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 619 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 620 AM_CONDITIONAL([HAVE_BOOST_CONTEXT], [test "x${ax_cv_boost_context}" = "xyes"])
 621
 622 # remove pkg-config deps from dependent libraries
 623 # (at least for pkg-config file purposes)
 624 FB_FILTER_PKG_LIBS([$AM_LDFLAGS $LIBS])
 625
 626 # Output
 627 AC_CONFIG_FILES([Makefile
 628                  libfolly.pc
 629                  test/Makefile
 630                  test/function_benchmark/Makefile
 631                  experimental/Makefile
 632                  experimental/symbolizer/Makefile
 633                  init/Makefile])
 634 AC_OUTPUT