folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 AC_CONFIG_SRCDIR([Likely.h])
  16 AC_CONFIG_HEADERS([config.h])
  17 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  18 AC_CONFIG_AUX_DIR([build-aux])
  19
  20 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  21
  22 AC_CONFIG_MACRO_DIR([m4])
  23
  24 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  25 AX_CONFIG_FEATURE(
  26         [deprecated-assoc],
  27         [supports deprecated associative containers (hash_map/hash_set)],
  28         [HAVE_DEPRECATED_ASSOC],
  29         [Define if you want to support deprecated associative containers])
  30
  31 AC_PROG_INSTALL
  32 AM_PROG_LIBTOOL
  33
  34 AC_LANG([C++])
  35
  36 # Checks for programs.
  37 AC_PROG_CXX
  38 AC_PROG_CC
  39 AC_CXX_COMPILE_STDCXX_0X
  40
  41 # Be sure to add any -std option to CXXFLAGS before we invoke any
  42 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  43 # before we update CXXFLAGS will not be run with the same options that we use
  44 # during the real build.
  45 STD=""
  46 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  47    STD="-std=c++0x"
  48 fi
  49 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  50    STD="-std=gnu++0x"
  51 fi
  52
  53 CXXFLAGS="$STD $CXXFLAGS"
  54
  55 # Checks for glog and gflags
  56 # There are no symbols with C linkage, so we do a try-run
  57 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
  58                 [Please install google-glog library])])
  59 AC_CACHE_CHECK(
  60   [for glog viability],
  61   [folly_cv_prog_cc_glog],
  62   [AC_RUN_IFELSE(
  63     [AC_LANG_SOURCE[
  64       #include <glog/logging.h>
  65       int main(int argc, char** argv) {
  66         google::InitGoogleLogging(argv[0]);
  67         google::ShutdownGoogleLogging();
  68         return 0;
  69       }
  70     ]],
  71     [folly_cv_prog_cc_glog=yes],
  72     [folly_cv_prog_cc_glog=no]
  73   )]
  74 )
  75
  76 if test "$folly_cv_prog_cc_glog" != "yes"; then
  77   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
  78 fi
  79
  80 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  81                 [Please install google-gflags library])])
  82 AC_CACHE_CHECK(
  83   [for gflags viability],
  84   [folly_cv_prog_cc_gflags],
  85   [AC_RUN_IFELSE(
  86     [AC_LANG_SOURCE[
  87       #include <gflags/gflags.h>
  88       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  89       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  90       int main(int argc, char** argv) {
  91         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  92       }
  93     ]],
  94     [folly_cv_prog_cc_gflags=yes],
  95     [folly_cv_prog_cc_gflags=no]
  96   )]
  97 )
  98
  99 if test "$folly_cv_prog_cc_gflags" != "yes"; then
 100   AC_MSG_ERROR(["libgflags invalid, see config.log for details"])
 101 fi
 102
 103 AC_CHECK_LIB(ssl,
 104         SSL_ctrl,
 105         [],
 106         [AC_MSG_ERROR(["Error: libssl required"])])
 107
 108 # check for boost libs
 109 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 110               [Please install boost >= 1.51.0 (context, thread, program_options, regex, and system)])])
 111 AX_BOOST_CONTEXT
 112 AX_BOOST_PROGRAM_OPTIONS
 113 AX_BOOST_THREAD
 114 AX_BOOST_REGEX
 115 AX_BOOST_SYSTEM
 116 AX_BOOST_FILESYSTEM
 117
 118 # Check for python interpreter
 119 AM_PATH_PYTHON
 120
 121 # Checks for header files.
 122 AC_HEADER_STDC
 123 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h bits/functexcept.h bits/c++config.h])
 124
 125 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 126                 [Couldn't find double-conversion.h, please download from \
 127                  https://github.com/google/double-conversion/])], [])
 128 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 129              [Please install double-conversion library])])
 130
 131 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 132
 133 AC_CHECK_LIB([jemalloc], [xallocx])
 134
 135 # Checks for typedefs, structures, and compiler characteristics.
 136 AC_HEADER_STDBOOL
 137 AC_C_CONST
 138 AC_C_INLINE
 139 AC_TYPE_SIZE_T
 140 AC_HEADER_TIME
 141 AC_C_VOLATILE
 142 AC_CHECK_TYPE([__int128], AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128]))
 143 AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
 144
 145 AC_CACHE_CHECK(
 146   [for ifunc support],
 147   [folly_cv_prog_cc_ifunc],
 148   [AC_COMPILE_IFELSE(
 149     [AC_LANG_SOURCE[
 150       #pragma GCC diagnostic error "-Wattributes"
 151       extern "C" void (*test_ifunc(void))() { return 0; }
 152       void func() __attribute__((ifunc("test_ifunc")));]
 153     ],
 154     [folly_cv_prog_cc_ifunc=yes],
 155     [folly_cv_prog_cc_ifunc=no])])
 156
 157 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 158   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 159 fi
 160
 161 AC_CACHE_CHECK(
 162   [for final and override support],
 163   [folly_cv_c_final_override],
 164   [AC_COMPILE_IFELSE(
 165     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 166                     class D : public C { virtual void g() override {} };]],
 167     [folly_cv_c_final_override=yes],
 168     [folly_cv_c_final_override=no])])
 169
 170 if test "$folly_cv_c_final_override" = "yes"; then
 171   final_val=final
 172   override_val=override
 173 else
 174   final_val=
 175   override_val=
 176 fi
 177
 178 AC_DEFINE_UNQUOTED(
 179   [FINAL], [$final_val],
 180   [Define to "final" if the compiler supports C++11 "final"])
 181 AC_DEFINE_UNQUOTED(
 182   [OVERRIDE], [$override_val],
 183   [Define to "override" if the compiler supports C++11 "override"])
 184
 185 AC_CACHE_CHECK(
 186   [for std::this_thread::sleep_for],
 187   [folly_cv_func_this_thread_sleep_for],
 188   [AC_COMPILE_IFELSE(
 189     [AC_LANG_SOURCE[
 190       #include <thread>
 191       #include <chrono>
 192       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 193     [folly_cv_func_this_thread_sleep_for=yes],
 194     [folly_cv_func_this_thread_sleep_for=no])])
 195
 196 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 197     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 198               [Define to 1 if std::this_thread::sleep_for() is defined.])
 199 fi
 200
 201 AC_CACHE_CHECK(
 202   [for constexpr strlen],
 203   [folly_cv_func_constexpr_strlen],
 204   [AC_COMPILE_IFELSE(
 205     [AC_LANG_SOURCE[
 206       #include <cstring>
 207       static constexpr int val = strlen("foo");]],
 208     [folly_cv_func_constexpr_strlen=yes],
 209     [folly_cv_func_constexpr_strlen=no])])
 210
 211 if test "$folly_cv_func_constexpr_strlen" = yes; then
 212     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 213               [Define to 1 if strlen(3) is constexpr.])
 214 fi
 215
 216 AC_CACHE_CHECK(
 217   [for libc++],
 218   [folly_cv_lib_libcpp],
 219   [AC_COMPILE_IFELSE(
 220     [AC_LANG_SOURCE[
 221       #include <type_traits>
 222       #if !_LIBCPP_VERSION
 223       #error No libc++
 224       #endif
 225       void func() {}]
 226     ],
 227     [folly_cv_lib_libcpp=yes],
 228     [folly_cv_lib_libcpp=no])])
 229
 230 if test "$folly_cv_lib_libcpp" = yes; then
 231   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we're using libc++.])
 232 fi
 233
 234 AC_CACHE_CHECK(
 235   [for usable std::is_trivially_copyable],
 236   [folly_cv_decl_std_is_trivially_copyable],
 237   [AC_COMPILE_IFELSE(
 238     [AC_LANG_SOURCE[
 239       #include <type_traits>
 240       const bool val = std::is_trivially_copyable<bool>::value;]
 241     ],
 242     [folly_cv_decl_std_is_trivially_copyable=yes],
 243     [folly_cv_decl_std_is_trivially_copyable=no])])
 244
 245 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 246   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 247             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 248              implementation.])
 249 fi
 250
 251 AC_CACHE_CHECK(
 252   [gflags namespace],
 253   [folly_cv_decl_gflags_namespace],
 254   [AC_COMPILE_IFELSE(
 255     [AC_LANG_SOURCE[
 256       #include <gflags/gflags.h>
 257       void foo() { gflags::GetArgv(); }]
 258     ],
 259     [folly_cv_decl_gflags_namespace=gflags],
 260     [AC_COMPILE_IFELSE(
 261       [AC_LANG_SOURCE[
 262         #include <gflags/gflags.h>
 263         void foo() { google::GetArgv(); }]
 264       ],
 265       [folly_cv_decl_gflags_namespace=google],
 266       [folly_cv_decl_gflags_namespace=error])])])
 267
 268 if test "$folly_cv_decl_gflags_namespace" = error; then
 269   AC_MSG_ERROR([Cannot determine gflags namespace])
 270 else
 271   AC_DEFINE_UNQUOTED(
 272     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 273     [Define to gflags namespace (usually "google" or "gflags")])
 274   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 275      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 276                [Define to 1 if the gflags namespace is not "gflags"])
 277   fi
 278 fi
 279
 280 # Figure out if we support weak symbols. If not, we will link in some null
 281 # stubs for functions that would otherwise be weak.
 282 AC_CACHE_CHECK(
 283   [for weak symbol support],
 284   [folly_cv_prog_cc_weak_symbols],
 285   [AC_LINK_IFELSE(
 286     [AC_LANG_SOURCE[
 287       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 288       int main(int argc, char** argv) {
 289           return configure_link_extern_weak_test == nullptr;
 290       }]],
 291     [folly_cv_prog_cc_weak_symbols="yes"],
 292     [folly_cv_prog_cc_weak_symbols="no"])])
 293
 294 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 295   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 296             [Define to 1 if the linker supports weak symbols.])
 297 fi
 298
 299 AC_CACHE_CHECK(
 300   [for vsnprintf reporting bad format strings],
 301   [folly_cv_prog_vsnprintf_bad_format],
 302   [AC_RUN_IFELSE(
 303     [AC_LANG_SOURCE[
 304       #include <stdio.h>
 305
 306       int main(int argc, char** argv) {
 307           char buf[256];
 308           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 309       }]],
 310     [folly_cv_prog_vsnprintf_bad_format="yes"],
 311     [folly_cv_prog_vsnprintf_bad_format="no"])])
 312
 313 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 314   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 315             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 316 fi
 317
 318 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 319 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 320   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 321             [Define to 1 if we have cplus_demangle_v3_callback.])
 322 fi
 323
 324 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 325 # want to link with librt if necessary.
 326 AC_SEARCH_LIBS([clock_gettime], [rt],
 327   AC_DEFINE(
 328     [HAVE_CLOCK_GETTIME],
 329     [1],
 330     [Define to 1 if we support clock_gettime(2).]),
 331   [])
 332
 333 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 334 # want to include pthread.h if necessary.
 335 AC_CACHE_CHECK(
 336   [for pthread_atfork support],
 337   [folly_cv_prog_cc_pthread_atfork],
 338   [AC_COMPILE_IFELSE(
 339     [AC_LANG_SOURCE[
 340       #include <pthread.h>
 341       void func() {pthread_atfork(NULL, NULL, NULL);}]
 342     ],
 343     [folly_cv_prog_cc_pthread_atfork=yes],
 344     [folly_cv_prog_cc_pthread_atfork=no])])
 345
 346 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 347   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 348 fi
 349
 350 # Check for XSI-compatible strerror_r as default implementation
 351 AC_CACHE_CHECK(
 352   [for XSI style strerror_r support],
 353   [folly_cv_prog_cc_xsi_strerror_r],
 354   [AC_RUN_IFELSE(
 355     [AC_LANG_SOURCE[
 356       #include <string.h>
 357       #include <errno.h>
 358       int main(int argc, char** argv) {
 359         char buf[1024];
 360         buf[0] = 0;
 361         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 362         return ret;
 363       }
 364     ]],
 365     [folly_cv_prog_cc_xsi_strerror_r=yes],
 366     [folly_cv_prog_cc_xsi_strerror_r=no])])
 367
 368 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 369   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 370 fi
 371
 372 # Checks for library functions.
 373 AC_CHECK_FUNCS([getdelim \
 374                 gettimeofday \
 375                 memmove \
 376                 memset \
 377                 pow \
 378                 strerror \
 379                 pthread_yield \
 380                 malloc_size \
 381                 malloc_usable_size \
 382                 memrchr \
 383                 pipe2])
 384
 385 if test "$ac_cv_func_pthread_yield" = "no"; then
 386    AC_CHECK_HEADERS([sched.h])
 387    AC_CHECK_FUNCS([sched_yield])
 388 fi
 389
 390 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 391 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 392 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 393 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 394
 395 # Include directory that contains "folly" so #include <folly/Foo.h> works
 396 AM_CPPFLAGS='-I$(top_srcdir)/..'
 397 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 398 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 399 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 400
 401 AC_SUBST([AM_CPPFLAGS])
 402 AC_SUBST([AM_LDFLAGS])
 403
 404 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 405 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 406 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 407 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 408                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 409 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 410
 411 # Output
 412 AC_CONFIG_FILES([Makefile
 413                  test/Makefile
 414                  test/function_benchmark/Makefile])
 415 AC_OUTPUT