folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6 AC_INIT(folly, 0.1, folly@fb.com)
   7 AC_CONFIG_SRCDIR([Likely.h])
   8 AC_CONFIG_HEADERS([config.h])
   9 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11
  12 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc])
  13
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AC_PROG_INSTALL
  17 AM_PROG_LIBTOOL
  18
  19 AC_LANG([C++])
  20
  21 # Checks for programs.
  22 AC_PROG_CXX
  23 AC_PROG_CC
  24 AC_CXX_COMPILE_STDCXX_0X
  25
  26 # Be sure to add any -std option to CXXFLAGS before we invoke any
  27 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  28 # before we update CXXFLAGS will not be run with the same options that we use
  29 # during the real build.
  30 STD=""
  31 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  32    STD="-std=c++0x"
  33 fi
  34 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  35    STD="-std=gnu++0x"
  36 fi
  37
  38 CXXFLAGS="$STD $CXXFLAGS"
  39
  40 # Checks for libraries.
  41 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  42              [Please install google-glog library])])
  43 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  44              [Please install google-gflags library])])
  45
  46 # check for boost libs
  47 AX_BOOST_BASE([1.20.0], [], [AC_MSG_ERROR(
  48               [Please install boost >= 1.20.0 (thread, regex, and system)])])
  49 AX_BOOST_THREAD
  50 AX_BOOST_REGEX
  51 AX_BOOST_SYSTEM
  52
  53 # Checks for header files.
  54 AC_HEADER_STDC
  55 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h bits/functexcept.h])
  56
  57 AC_CHECK_HEADER(double-conversion.h, [], [AC_MSG_ERROR(
  58                 [Couldn't find double-conversion.h, please download from \
  59                 http://code.google.com/p/double-conversion/])], [])
  60 AC_CHECK_LIB([double_conversion_pic],[ceil],[],[AC_MSG_ERROR(
  61              [Please install double-conversion library])])
  62
  63 # Checks for typedefs, structures, and compiler characteristics.
  64 AC_HEADER_STDBOOL
  65 AC_C_CONST
  66 AC_C_INLINE
  67 AC_TYPE_SIZE_T
  68 AC_HEADER_TIME
  69 AC_C_VOLATILE
  70 AC_CHECK_TYPE([__int128],
  71   [AC_DEFINE([HAVE_INT128_T], [1], [Define if __int128 exists])],
  72   [AC_DEFINE([HAVE_INT128_T], [0], [Define if __int128 does not exist])])
  73 AC_CHECK_TYPES([ptrdiff_t])
  74 AC_COMPILE_IFELSE(
  75   [AC_LANG_SOURCE[
  76     #pragma GCC diagnostic error "-Wattributes"
  77     extern "C" void (*test_ifunc(void))() { return 0; }
  78     void func() __attribute__((ifunc("test_ifunc")));]
  79   ],
  80   [AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])],
  81   [AC_DEFINE([HAVE_IFUNC], [0], [Define to 0 if the compiler doesn't support ifunc])]
  82 )
  83 AC_COMPILE_IFELSE(
  84   [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
  85                   class D : public C { virtual void g() override {} };]],
  86   [AC_DEFINE([FINAL], [final],
  87              [Define to "final" if the compiler supports C++11 "final"])
  88    AC_DEFINE([OVERRIDE], [override],
  89              [Define to "override" if the compiler supports C++11 "override"])],
  90   [AC_DEFINE([FINAL], [],
  91              [Define to "final" if the compiler supports C++11 "final"])
  92    AC_DEFINE([OVERRIDE], [],
  93              [Define to "override" if the compiler supports C++11 "override"])]
  94 )
  95
  96 AC_COMPILE_IFELSE(
  97   [AC_LANG_SOURCE[
  98     #include <thread>
  99     #include <chrono>
 100     void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 101   [AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 102              [Define to 1 if std::this_thread::sleep_for() is defined.])])
 103
 104 AC_COMPILE_IFELSE(
 105   [AC_LANG_SOURCE[
 106     #include <cstring>
 107     static constexpr int val = strlen("foo");]],
 108   [AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 109              [Define to 1 if strlen(3) is constexpr.])])
 110
 111 AC_COMPILE_IFELSE(
 112   [AC_LANG_SOURCE[
 113     #include <type_traits>
 114     #if !_LIBCPP_VERSION
 115     #error No libc++
 116     #endif
 117     void func() {}]
 118   ],
 119   [AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we're using libc++.])])
 120
 121 AC_COMPILE_IFELSE(
 122   [AC_LANG_SOURCE[
 123     #include <type_traits>
 124     const bool val = std::is_trivially_copyable<bool>::value;]
 125   ],
 126   [AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 127              [Define to 1 if we have a usable std::is_trivially_copyable<T>
 128               implementation.])])
 129
 130 # Figure out if we support weak symbols. If not, we will link in some null
 131 # stubs for functions that would otherwise be weak.
 132 AC_LINK_IFELSE(
 133   [AC_LANG_SOURCE[
 134     extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 135     int main(int argc, char** argv) {
 136         return configure_link_extern_weak_test == nullptr;
 137     }]
 138   ],
 139   [
 140     ac_have_weak_symbols="yes"
 141     AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 142               [Define to 1 if the linker supports weak symbols.])])
 143
 144 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty])
 145 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 146   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 147             [Define to 1 if we have cplus_demangle_v3_callback.])
 148 fi
 149
 150 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 151 # want to link with librt if necessary.
 152 AC_SEARCH_LIBS([clock_gettime], [rt],
 153   AC_DEFINE(
 154     [HAVE_CLOCK_GETTIME],
 155     [1],
 156     [Define to 1 if we support clock_gettime(2).]),
 157   [])
 158
 159 # Checks for library functions.
 160 AC_CHECK_FUNCS([getdelim \
 161                 gettimeofday \
 162                 memmove \
 163                 memset \
 164                 pow \
 165                 strerror \
 166                 pthread_yield \
 167                 rallocm \
 168                 malloc_size \
 169                 malloc_usable_size \
 170                 memrchr])
 171
 172 if test "$ac_cv_func_pthread_yield" = "no"; then
 173    AC_CHECK_HEADERS([sched.h])
 174    AC_CHECK_FUNCS([sched_yield])
 175 fi
 176
 177 AC_SUBST(AM_CPPFLAGS, '-I../$(top_srcdir)'" "'-I$(top_srcdir)/io'" "'-I$(top_srcdir)/test'" $BOOST_CPPFLAGS")
 178 AC_SUBST(AM_LDFLAGS, "$BOOST_LDFLAGS $BOOST_THREAD_LIB $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread")
 179
 180 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 181 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 182 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 183 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS], [test "$ac_have_weak_symbols" = "yes"])
 184 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept" = "yes"])
 185
 186 # Output
 187 AC_CONFIG_FILES([Makefile
 188                  test/Makefile
 189                  test/function_benchmark/Makefile])
 190 AC_OUTPUT