folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6 AC_INIT(folly, 0.1, folly@fb.com)
   7 AC_CONFIG_SRCDIR([Likely.h])
   8 AC_CONFIG_HEADERS([config.h])
   9 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11
  12 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc])
  13
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AC_PROG_INSTALL
  17 AM_PROG_LIBTOOL
  18
  19 AC_LANG([C++])
  20
  21 # Checks for programs.
  22 AC_PROG_CXX
  23 AC_PROG_CC
  24 AC_CXX_COMPILE_STDCXX_0X
  25
  26 # Be sure to add any -std option to CXXFLAGS before we invoke any
  27 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  28 # before we update CXXFLAGS will not be run with the same options that we use
  29 # during the real build.
  30 STD=""
  31 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  32    STD="-std=c++0x"
  33 fi
  34 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  35    STD="-std=gnu++0x"
  36 fi
  37
  38 CXXFLAGS="$STD $CXXFLAGS"
  39
  40 # Checks for libraries.
  41 AC_CHECK_LIB([glog],[openlog],[],[AC_MSG_ERROR(
  42              [Please install google-glog library])])
  43 AC_CHECK_LIB([gflags],[getenv],[],[AC_MSG_ERROR(
  44              [Please install google-gflags library])])
  45
  46 # check for boost libs
  47 AX_BOOST_BASE([1.20.0], [], [AC_MSG_ERROR(
  48               [Please install boost >= 1.20.0 (thread, regex, and system)])])
  49 AX_BOOST_THREAD
  50 AX_BOOST_REGEX
  51 AX_BOOST_SYSTEM
  52
  53 # Checks for header files.
  54 AC_HEADER_STDC
  55 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h emmintrin.h byteswap.h bits/functexcept.h])
  56
  57 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
  58                 [Couldn't find double-conversion.h, please download from \
  59                 http://code.google.com/p/double-conversion/])], [])
  60 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
  61              [Please install double-conversion library])])
  62
  63 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
  64
  65 # Checks for typedefs, structures, and compiler characteristics.
  66 AC_HEADER_STDBOOL
  67 AC_C_CONST
  68 AC_C_INLINE
  69 AC_TYPE_SIZE_T
  70 AC_HEADER_TIME
  71 AC_C_VOLATILE
  72 AC_CHECK_TYPE([__int128],
  73   [AC_DEFINE([HAVE_INT128_T], [1], [Define if __int128 exists])],
  74   [AC_DEFINE([HAVE_INT128_T], [0], [Define if __int128 does not exist])])
  75 AC_CHECK_TYPES([ptrdiff_t])
  76 AC_COMPILE_IFELSE(
  77   [AC_LANG_SOURCE[
  78     #pragma GCC diagnostic error "-Wattributes"
  79     extern "C" void (*test_ifunc(void))() { return 0; }
  80     void func() __attribute__((ifunc("test_ifunc")));]
  81   ],
  82   [AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])],
  83   [AC_DEFINE([HAVE_IFUNC], [0], [Define to 0 if the compiler doesn't support ifunc])]
  84 )
  85 AC_COMPILE_IFELSE(
  86   [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
  87                   class D : public C { virtual void g() override {} };]],
  88   [AC_DEFINE([FINAL], [final],
  89              [Define to "final" if the compiler supports C++11 "final"])
  90    AC_DEFINE([OVERRIDE], [override],
  91              [Define to "override" if the compiler supports C++11 "override"])],
  92   [AC_DEFINE([FINAL], [],
  93              [Define to "final" if the compiler supports C++11 "final"])
  94    AC_DEFINE([OVERRIDE], [],
  95              [Define to "override" if the compiler supports C++11 "override"])]
  96 )
  97
  98 AC_COMPILE_IFELSE(
  99   [AC_LANG_SOURCE[
 100     #include <thread>
 101     #include <chrono>
 102     void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 103   [AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 104              [Define to 1 if std::this_thread::sleep_for() is defined.])])
 105
 106 AC_COMPILE_IFELSE(
 107   [AC_LANG_SOURCE[
 108     #include <cstring>
 109     static constexpr int val = strlen("foo");]],
 110   [AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 111              [Define to 1 if strlen(3) is constexpr.])])
 112
 113 AC_COMPILE_IFELSE(
 114   [AC_LANG_SOURCE[
 115     #include <type_traits>
 116     #if !_LIBCPP_VERSION
 117     #error No libc++
 118     #endif
 119     void func() {}]
 120   ],
 121   [AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we're using libc++.])])
 122
 123 AC_COMPILE_IFELSE(
 124   [AC_LANG_SOURCE[
 125     #include <type_traits>
 126     const bool val = std::is_trivially_copyable<bool>::value;]
 127   ],
 128   [AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 129              [Define to 1 if we have a usable std::is_trivially_copyable<T>
 130               implementation.])])
 131
 132 # Figure out if we support weak symbols. If not, we will link in some null
 133 # stubs for functions that would otherwise be weak.
 134 AC_LINK_IFELSE(
 135   [AC_LANG_SOURCE[
 136     extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 137     int main(int argc, char** argv) {
 138         return configure_link_extern_weak_test == nullptr;
 139     }]
 140   ],
 141   [
 142     ac_have_weak_symbols="yes"
 143     AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 144               [Define to 1 if the linker supports weak symbols.])])
 145
 146 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty])
 147 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 148   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 149             [Define to 1 if we have cplus_demangle_v3_callback.])
 150 fi
 151
 152 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 153 # want to link with librt if necessary.
 154 AC_SEARCH_LIBS([clock_gettime], [rt],
 155   AC_DEFINE(
 156     [HAVE_CLOCK_GETTIME],
 157     [1],
 158     [Define to 1 if we support clock_gettime(2).]),
 159   [])
 160
 161 # Checks for library functions.
 162 AC_CHECK_FUNCS([getdelim \
 163                 gettimeofday \
 164                 memmove \
 165                 memset \
 166                 pow \
 167                 strerror \
 168                 pthread_yield \
 169                 rallocm \
 170                 malloc_size \
 171                 malloc_usable_size \
 172                 memrchr])
 173
 174 if test "$ac_cv_func_pthread_yield" = "no"; then
 175    AC_CHECK_HEADERS([sched.h])
 176    AC_CHECK_FUNCS([sched_yield])
 177 fi
 178
 179 AC_SUBST(AM_CPPFLAGS, '-I../$(top_srcdir)'" "'-I$(top_srcdir)/io'" "'-I$(top_srcdir)/test'" $BOOST_CPPFLAGS")
 180 AC_SUBST(AM_LDFLAGS, "$BOOST_LDFLAGS $BOOST_THREAD_LIB $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread")
 181
 182 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 183 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 184 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 185 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS], [test "$ac_have_weak_symbols" = "yes"])
 186 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept" = "yes"])
 187
 188 # Output
 189 AC_CONFIG_FILES([Makefile
 190                  test/Makefile
 191                  test/function_benchmark/Makefile])
 192 AC_OUTPUT