folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 #declare pkg-config variables
  16 PKG_VERSION=m4_join([.], m4_reverse(m4_translit(folly_version_str, [:], [,])))
  17 AC_SUBST([PKG_VERSION])
  18 AC_SUBST([PKG_CXXFLAGS])
  19 AC_SUBST([PKG_DEPS])
  20 AC_SUBST([PKG_LIBS])
  21
  22 AC_CONFIG_SRCDIR([Likely.h])
  23 AC_CONFIG_HEADERS([config.h])
  24 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  32 AX_CONFIG_FEATURE(
  33         [deprecated-assoc],
  34         [supports deprecated associative containers (hash_map/hash_set)],
  35         [HAVE_DEPRECATED_ASSOC],
  36         [Define if you want to support deprecated associative containers])
  37
  38 AC_PROG_INSTALL
  39 AM_PROG_LIBTOOL
  40
  41 AC_LANG([C++])
  42
  43 # Checks for programs.
  44 AC_PROG_CXX
  45 AC_PROG_CC
  46
  47 AC_CXX_COMPILE_STDCXX_1Y
  48
  49 # Be sure to add any -std option to CXXFLAGS before we invoke any
  50 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  51 # before we update CXXFLAGS will not be run with the same options that we use
  52 # during the real build.
  53 STD=""
  54 if test "x$ac_cv_cxx_compile_cxx1y_cxx" = xyes; then
  55    STD="-std=c++1y"
  56 fi
  57 if test "x$ac_cv_cxx_compile_cxx1y_gxx" = xyes; then
  58    STD="-std=gnu++1y"
  59 fi
  60
  61 CXXFLAGS="$STD $CXXFLAGS"
  62
  63 # expose required -std option via pkg-config
  64 PKG_CXXFLAGS=$STD
  65
  66 # See if -Wshadow-local and -Wshadow-compatible-local are supported
  67 AC_MSG_CHECKING(
  68   [whether -Wshadow-local and -Wshadow-compatible-local are supported])
  69 AC_CACHE_VAL([folly_cv_cxx_shadow_local_support], [
  70   folly_save_CXXFLAGS="$CXXFLAGS"
  71   CXXFLAGS="$CXXFLAGS -Wshadow-local -Wshadow-compatible-local"
  72   AC_COMPILE_IFELSE(
  73     [AC_LANG_PROGRAM([[]], [[]])],
  74     [folly_cv_cxx_shadow_local_support=yes],
  75     [folly_cv_cxx_shadow_local_support=no])
  76   CXXFLAGS="$folly_save_CXXFLAGS"])
  77 AC_MSG_RESULT([$folly_cv_cxx_shadow_local_support])
  78 if test "$folly_cv_cxx_shadow_local_support" = yes; then
  79   AC_DEFINE([HAVE_SHADOW_LOCAL_WARNINGS], [1],
  80   [Define if both -Wshadow-local and -Wshadow-compatible-local are supported.])
  81 fi
  82
  83 # Checks for glog and gflags
  84 # There are no symbols with C linkage, so we do a try-run
  85 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  86                 [Please install google-gflags library])])
  87 AC_CACHE_CHECK(
  88   [for gflags viability],
  89   [folly_cv_prog_cc_gflags],
  90   [AC_RUN_IFELSE(
  91     [AC_LANG_SOURCE[
  92       #include <gflags/gflags.h>
  93       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  94       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  95       int main(int argc, char** argv) {
  96         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  97       }
  98     ]],
  99     [folly_cv_prog_cc_gflags=yes],
 100     [folly_cv_prog_cc_gflags=no]
 101   )]
 102 )
 103
 104 if test "$folly_cv_prog_cc_gflags" != "yes"; then
 105   AC_MSG_ERROR(["gflags invalid, see config.log for details"])
 106 fi
 107 FB_CHECK_PKG_CONFIG([GFLAGS], [gflags])
 108
 109 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
 110                 [Please install google-glog library])])
 111 AC_CACHE_CHECK(
 112   [for glog viability],
 113   [folly_cv_prog_cc_glog],
 114   [AC_RUN_IFELSE(
 115     [AC_LANG_SOURCE[
 116       #include <glog/logging.h>
 117       int main(int argc, char** argv) {
 118         google::InitGoogleLogging(argv[0]);
 119         google::ShutdownGoogleLogging();
 120         return 0;
 121       }
 122     ]],
 123     [folly_cv_prog_cc_glog=yes],
 124     [folly_cv_prog_cc_glog=no]
 125   )]
 126 )
 127
 128 if test "$folly_cv_prog_cc_glog" != "yes"; then
 129   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
 130 fi
 131 FB_CHECK_PKG_CONFIG([GLOG], [libglog])
 132
 133 AS_IF(
 134   [test "x$OPENSSL_INCLUDES" = "x"],
 135   [
 136     AX_CHECK_OPENSSL([], [AC_MSG_ERROR(["Error: libssl required"])])
 137   ],
 138   [
 139     # AX_CHECK_OPENSSL doesn't seem to play nice with builds started
 140     # via build/bootstrap-osx-homebrew.sh
 141     AC_MSG_WARN(["Using existing OpenSSL flags from environment."])
 142     PKG_CXXFLAGS="$PKG_CXXFLAGS $OPENSSL_INCLUDES"
 143   ]
 144 )
 145 FB_CHECK_PKG_CONFIG([OPENSSL], [openssl])
 146
 147 # check for boost libs
 148 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 149               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 150 AX_BOOST_CONTEXT
 151 AX_BOOST_PROGRAM_OPTIONS
 152 AX_BOOST_THREAD
 153 AX_BOOST_REGEX
 154 AX_BOOST_SYSTEM
 155 AX_BOOST_FILESYSTEM
 156 AX_BOOST_CHRONO
 157
 158 # Check for python interpreter
 159 AM_PATH_PYTHON
 160
 161 # Checks for header files.
 162 AC_HEADER_STDC
 163 AC_CHECK_HEADERS([features.h malloc.h bits/functexcept.h bits/c++config.h])
 164
 165 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 166                 [Couldn't find double-conversion.h, please download from \
 167                  https://github.com/google/double-conversion/])], [])
 168 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 169              [Please install double-conversion library])])
 170
 171 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 172 FB_CHECK_PKG_CONFIG([EVENT], [libevent])
 173
 174 AC_ARG_WITH([jemalloc], [
 175   --with-jemalloc     Whether to make folly jemalloc aware
 176 ],[
 177   AC_CHECK_LIB([jemalloc], [xallocx],[
 178     AC_DEFINE([USE_JEMALLOC], [1], [Enable jemalloc])
 179   ],[
 180     AC_MSG_ERROR([--with-jemalloc requested, but jemalloc not found])
 181   ])
 182 ])
 183
 184 # Checks for typedefs, structures, and compiler characteristics.
 185 AC_C_CONST
 186 AC_C_INLINE
 187 AC_TYPE_SIZE_T
 188 AC_HEADER_TIME
 189 AC_C_VOLATILE
 190 AC_CHECK_TYPE([__int128], [folly_cv_prog_cc_int128=yes],
 191     [folly_cv_prog_cc_int128=no])
 192 if test "$folly_cv_prog_cc_int128" = "yes"; then
 193   AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128])
 194   AC_CACHE_CHECK(
 195     [for __int128 type traits],
 196     [folly_cv_prog_cc_int128traits],
 197     [AC_COMPILE_IFELSE(
 198       [AC_LANG_SOURCE([[
 199 #include <type_traits>
 200 static_assert(
 201   ::std::is_same<::std::make_signed<unsigned __int128>::type, __int128>::value,
 202   "signed form of \`unsigned __uint128\` must be \`__int128\`.");
 203       ]])],
 204       [folly_cv_prog_cc_int128traits=yes],
 205       [folly_cv_prog_cc_int128traits=no])
 206     ])
 207   if test "$folly_cv_prog_cc_int128traits" = "no"; then
 208     AC_DEFINE([SUPPLY_MISSING_INT128_TRAITS], [1], [Define if we need the standard integer traits defined for the type `__int128'.])
 209   fi
 210 fi
 211
 212 AC_CHECK_TYPES([pthread_spinlock_t])
 213
 214 AC_CACHE_CHECK(
 215   [for ifunc support],
 216   [folly_cv_prog_cc_ifunc],
 217   [AC_COMPILE_IFELSE(
 218     [AC_LANG_SOURCE[
 219       #pragma GCC diagnostic error "-Wattributes"
 220       extern "C" void (*test_ifunc(void))() { return 0; }
 221       void func() __attribute__((ifunc("test_ifunc")));]
 222     ],
 223     [folly_cv_prog_cc_ifunc=yes],
 224     [folly_cv_prog_cc_ifunc=no])])
 225
 226 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 227   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 228 fi
 229
 230 AC_CACHE_CHECK(
 231   [for final and override support],
 232   [folly_cv_c_final_override],
 233   [AC_COMPILE_IFELSE(
 234     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 235                     class D : public C { virtual void g() override {} };]],
 236     [folly_cv_c_final_override=yes],
 237     [folly_cv_c_final_override=no])])
 238
 239 if test "$folly_cv_c_final_override" = "yes"; then
 240   final_val=final
 241   override_val=override
 242 else
 243   final_val=
 244   override_val=
 245 fi
 246
 247 AC_DEFINE_UNQUOTED(
 248   [FINAL], [$final_val],
 249   [Define to "final" if the compiler supports C++11 "final"])
 250 AC_DEFINE_UNQUOTED(
 251   [OVERRIDE], [$override_val],
 252   [Define to "override" if the compiler supports C++11 "override"])
 253
 254 AC_CACHE_CHECK(
 255   [for constexpr strlen],
 256   [folly_cv_func_constexpr_strlen],
 257   [AC_COMPILE_IFELSE(
 258     [AC_LANG_SOURCE[
 259       #include <cstring>
 260       static constexpr int val = strlen("foo");]],
 261     [folly_cv_func_constexpr_strlen=yes],
 262     [folly_cv_func_constexpr_strlen=no])])
 263
 264 if test "$folly_cv_func_constexpr_strlen" = yes; then
 265     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 266               [Define to 1 if strlen(3) is constexpr.])
 267 fi
 268
 269 AC_CACHE_CHECK(
 270   [for libc++],
 271   [folly_cv_lib_libcpp],
 272   [AC_COMPILE_IFELSE(
 273     [AC_LANG_SOURCE[
 274       #include <type_traits>
 275       #if !_LIBCPP_VERSION
 276       #error No libc++
 277       #endif
 278       void func() {}]
 279     ],
 280     [folly_cv_lib_libcpp=yes],
 281     [folly_cv_lib_libcpp=no])])
 282
 283 if test "$folly_cv_lib_libcpp" = yes; then
 284   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 285 fi
 286
 287 AC_CACHE_CHECK(
 288   [for c++11 atomic support without GNU Atomic library],
 289   [folly_cv_lib_libatomic],
 290   [AC_LINK_IFELSE(
 291     [AC_LANG_SOURCE[
 292       #include <atomic>
 293       int main() {
 294         struct Test { int val; };
 295         std::atomic<Test> s;
 296         s.is_lock_free();
 297       }
 298     ]],
 299     [folly_cv_lib_libatomic=yes],
 300     [folly_cv_lib_libatomic=no])])
 301
 302 if test "$folly_cv_lib_libatomic" = no; then
 303   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 304                   [Please install the GNU Atomic library])])
 305 fi
 306
 307 AC_CACHE_CHECK(
 308   [for liblinux-vdso support],
 309   [folly_cv_lib_liblinux_vdso],
 310   [AC_RUN_IFELSE(
 311     [AC_LANG_PROGRAM[
 312       #include <dlfcn.h>
 313       int main() {
 314         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 315         if (h == nullptr) {
 316           return -1;
 317         }
 318         dlclose(h);
 319         return 0;
 320       }
 321     ]],
 322     [folly_cv_lib_liblinux_vdso=yes],
 323     [folly_cv_lib_liblinux_vdso=no])])
 324
 325 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 326   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 327 fi
 328
 329 AC_DEFINE([HAVE_PTHREAD], [1], [Define to 1 if pthread is avaliable])
 330
 331 AC_CACHE_CHECK(
 332   [for usable std::is_trivially_copyable],
 333   [folly_cv_decl_std_is_trivially_copyable],
 334   [AC_COMPILE_IFELSE(
 335     [AC_LANG_SOURCE[
 336       #include <type_traits>
 337       const bool val = std::is_trivially_copyable<bool>::value;]
 338     ],
 339     [folly_cv_decl_std_is_trivially_copyable=yes],
 340     [folly_cv_decl_std_is_trivially_copyable=no])])
 341
 342 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 343   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 344             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 345              implementation.])
 346 fi
 347
 348 AC_CACHE_CHECK(
 349   [gflags namespace],
 350   [folly_cv_decl_gflags_namespace],
 351   [AC_COMPILE_IFELSE(
 352     [AC_LANG_SOURCE[
 353       #include <gflags/gflags.h>
 354       void foo() { gflags::GetArgv(); }]
 355     ],
 356     [folly_cv_decl_gflags_namespace=gflags],
 357     [AC_COMPILE_IFELSE(
 358       [AC_LANG_SOURCE[
 359         #include <gflags/gflags.h>
 360         void foo() { google::GetArgv(); }]
 361       ],
 362       [folly_cv_decl_gflags_namespace=google],
 363       [folly_cv_decl_gflags_namespace=error])])])
 364
 365 if test "$folly_cv_decl_gflags_namespace" = error; then
 366   AC_MSG_ERROR([Cannot determine gflags namespace])
 367 else
 368   AC_DEFINE_UNQUOTED(
 369     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 370     [Define to gflags namespace (usually "google" or "gflags")])
 371   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 372      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 373                [Define to 1 if the gflags namespace is not "gflags"])
 374   fi
 375 fi
 376
 377 # Figure out if we support weak symbols. If not, we will link in some null
 378 # stubs for functions that would otherwise be weak.
 379 AC_CACHE_CHECK(
 380   [for weak symbol support],
 381   [folly_cv_prog_cc_weak_symbols],
 382   [AC_LINK_IFELSE(
 383     [AC_LANG_SOURCE[
 384       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 385       int main(int argc, char** argv) {
 386           return configure_link_extern_weak_test == nullptr;
 387       }]],
 388     [folly_cv_prog_cc_weak_symbols="yes"],
 389     [folly_cv_prog_cc_weak_symbols="no"])])
 390
 391 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 392   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 393             [Define to 1 if the linker supports weak symbols.])
 394 fi
 395
 396
 397 # Figure out if we support wchar well
 398 AC_CACHE_CHECK(
 399   [for wchar support],
 400   [folly_cv_prog_cc_wchar_support],
 401   [AC_RUN_IFELSE(
 402     [AC_LANG_SOURCE[
 403       #include <cstddef>
 404       #include <cwchar>
 405
 406       int main(int argc, char** argv) {
 407         return wcstol(L"01", nullptr, 10) == 1 ? 0 : 1;
 408       }
 409     ]],
 410     [folly_cv_prog_cc_wchar_support=yes],
 411     [folly_cv_prog_cc_wchar_support=no])])
 412
 413 if test "$folly_cv_prog_cc_wchar_support" = "yes"; then
 414   AC_DEFINE([HAVE_WCHAR_SUPPORT], [1], [Define to 1 if the libc supports wchar well])
 415 fi
 416
 417 # Figure out whether the architecture supports unaligned accesses
 418 AC_CACHE_CHECK(
 419   [for unaligned access support],
 420   [folly_cv_prog_cc_unaligned_access],
 421   [AC_RUN_IFELSE(
 422     [AC_LANG_SOURCE[
 423       int main(int argc, char** argv) {
 424         char buf[64] = {0};
 425         unsigned long *ptr = (unsigned long *)(buf + 1);
 426         *ptr = 0xdeadbeef;
 427         return (*ptr & 0xff) == 0xef ? 0 : 1;
 428       }
 429     ]],
 430     [folly_cv_prog_cc_unaligned_access=yes],
 431     [folly_cv_prog_cc_unaligned_access=no])])
 432
 433 if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
 434   AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
 435 fi
 436
 437 AC_CACHE_CHECK(
 438   [for vsnprintf reporting bad format strings],
 439   [folly_cv_prog_vsnprintf_bad_format],
 440   [AC_RUN_IFELSE(
 441     [AC_LANG_SOURCE[
 442       #include <stdio.h>
 443
 444       int main(int argc, char** argv) {
 445           char buf[256];
 446           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 447       }]],
 448     [folly_cv_prog_vsnprintf_bad_format="yes"],
 449     [folly_cv_prog_vsnprintf_bad_format="no"])])
 450
 451 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 452   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 453             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 454 fi
 455
 456 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 457 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 458   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 459             [Define to 1 if we have cplus_demangle_v3_callback.])
 460 fi
 461
 462 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 463 # want to link with librt if necessary.
 464 AC_SEARCH_LIBS([clock_gettime], [rt],
 465   AC_DEFINE(
 466     [HAVE_CLOCK_GETTIME],
 467     [1],
 468     [Define to 1 if we support clock_gettime(2).]),
 469   [])
 470
 471 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 472 # want to include pthread.h if necessary.
 473 AC_CACHE_CHECK(
 474   [for pthread_atfork support],
 475   [folly_cv_prog_cc_pthread_atfork],
 476   [AC_COMPILE_IFELSE(
 477     [AC_LANG_SOURCE[
 478       #include <pthread.h>
 479       void func() {pthread_atfork(NULL, NULL, NULL);}]
 480     ],
 481     [folly_cv_prog_cc_pthread_atfork=yes],
 482     [folly_cv_prog_cc_pthread_atfork=no])])
 483
 484 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 485   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 486 fi
 487
 488 # Check for XSI-compatible strerror_r as default implementation
 489 AC_CACHE_CHECK(
 490   [for XSI style strerror_r support],
 491   [folly_cv_prog_cc_xsi_strerror_r],
 492   [AC_RUN_IFELSE(
 493     [AC_LANG_SOURCE[
 494       #include <string.h>
 495       #include <errno.h>
 496       int main(int argc, char** argv) {
 497         char buf[1024];
 498         buf[0] = 0;
 499         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 500         return ret;
 501       }
 502     ]],
 503     [folly_cv_prog_cc_xsi_strerror_r=yes],
 504     [folly_cv_prog_cc_xsi_strerror_r=no])])
 505
 506 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 507   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 508 fi
 509
 510 AC_CACHE_CHECK(
 511   [for ext/random and __gnu_cxx::sfmt19937],
 512   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 513   [AC_COMPILE_IFELSE(
 514     [AC_LANG_SOURCE[
 515       #include <ext/random>
 516       int main(int argc, char** argv) {
 517         __gnu_cxx::sfmt19937 rng;
 518         return 0;
 519       }
 520     ]],
 521     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 522     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 523
 524 AC_CACHE_CHECK(
 525   [for VLA (variable-length array) support],
 526   [folly_cv_prog_cc_have_vla],
 527   [AC_COMPILE_IFELSE(
 528     [AC_LANG_SOURCE[
 529       int main(int argc, char** argv) {
 530         unsigned size = argc;
 531         char data[size];
 532         return 0;
 533       }
 534     ]],
 535     [folly_cv_prog_cc_have_vla=yes],
 536     [folly_cv_prog_cc_have_vla=no])])
 537
 538 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 539 AC_DEFINE_UNQUOTED(
 540   [HAVE_VLA],
 541   [$have_vla],
 542   [Define to 1 if the compiler has VLA (variable-length array) support,
 543    otherwise define to 0])
 544
 545 # Checks for library functions.
 546 AC_CHECK_FUNCS([malloc_size \
 547                 malloc_usable_size \
 548                 memrchr \
 549                 pipe2 \
 550                 preadv \
 551                 pwritev \
 552               ])
 553
 554 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 555 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 556 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 557 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 558 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [ZSTD_compressStream]))
 559 AC_CHECK_HEADER([bzlib.h], AC_CHECK_LIB([bz2], [main]))
 560 AC_CHECK_HEADER([linux/membarrier.h], AC_DEFINE([HAVE_LINUX_MEMBARRIER_H], [1], [Define to 1 if membarrier.h is available]))
 561
 562 AC_ARG_ENABLE([follytestmain],
 563    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 564    [use_follytestmain=${enableval}], [use_follytestmain=yes])
 565
 566 # libdwarf used to install in /usr/include, now installs in /usr/include/libdwarf.
 567 AC_CHECK_HEADERS([libdwarf/dwarf.h dwarf.h], [break])
 568 # Check whether we have both the library and the header
 569 have_libdwarf=no
 570 AS_IF([test "x${ac_cv_header_libdwarf_dwarf_h}" = xyes], [have_libdwarf=yes])
 571 AS_IF([test "x${ac_cv_header_dwarf_h}" = xyes], [have_libdwarf=yes])
 572
 573
 574 AC_ARG_ENABLE([mobile],
 575    AS_HELP_STRING([--enable-mobile],
 576                   [enables using main function from folly for tests]),
 577                   [mobile=${enableval}], [mobile=no])
 578 AS_IF([test "x${mobile}" = "xyes"], [
 579     AC_DEFINE([MOBILE], [1],
 580               [Define to 1 for compiler guards for mobile targets.])
 581 ])
 582
 583 # Include directory that contains "folly" so #include <folly/Foo.h> works
 584 AM_CPPFLAGS='-I$(top_srcdir)/..'
 585 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS $OPENSSL_INCLUDES"
 586 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 587 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 588 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 589 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 590
 591 AM_LDFLAGS="$AM_LDFLAGS $OPENSSL_LDFLAGS $OPENSSL_LIBS"
 592
 593 AC_SUBST([AM_CPPFLAGS])
 594 AC_SUBST([AM_LDFLAGS])
 595
 596 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 597 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 598 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 599 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 600 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 601 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 602                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 603 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT_H], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 604 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 605                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 606 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 607 AM_CONDITIONAL([HAVE_LIBDWARF], [test "x${have_libdwarf}" = "xyes"])
 608 AM_CONDITIONAL([HAVE_BOOST_CONTEXT], [test "x${ax_cv_boost_context}" = "xyes"])
 609
 610 # remove pkg-config deps from dependent libraries
 611 # (at least for pkg-config file purposes)
 612 FB_FILTER_PKG_LIBS([$AM_LDFLAGS $LIBS])
 613
 614 # Output
 615 AC_CONFIG_FILES([Makefile
 616                  io/test/Makefile
 617                  libfolly.pc
 618                  test/Makefile
 619                  test/function_benchmark/Makefile
 620                  experimental/Makefile
 621                  experimental/io/test/Makefile
 622                  experimental/symbolizer/Makefile
 623                  init/Makefile])
 624 AC_OUTPUT