folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 AC_CONFIG_SRCDIR([Likely.h])
  16 AC_CONFIG_HEADERS([config.h])
  17 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  18 AC_CONFIG_AUX_DIR([build-aux])
  19
  20 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  21
  22 AC_CONFIG_MACRO_DIR([m4])
  23
  24 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  25 AX_CONFIG_FEATURE(
  26         [deprecated-assoc],
  27         [supports deprecated associative containers (hash_map/hash_set)],
  28         [HAVE_DEPRECATED_ASSOC],
  29         [Define if you want to support deprecated associative containers])
  30
  31 AC_PROG_INSTALL
  32 AM_PROG_LIBTOOL
  33
  34 AC_LANG([C++])
  35
  36 # Checks for programs.
  37 AC_PROG_CXX
  38 AC_PROG_CC
  39 AC_CXX_COMPILE_STDCXX_0X
  40
  41 # Be sure to add any -std option to CXXFLAGS before we invoke any
  42 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  43 # before we update CXXFLAGS will not be run with the same options that we use
  44 # during the real build.
  45 STD=""
  46 if test "x$ac_cv_cxx_compile_cxx0x_cxx" = xyes; then
  47    STD="-std=c++0x"
  48 fi
  49 if test "x$ac_cv_cxx_compile_cxx0x_gxx" = xyes; then
  50    STD="-std=gnu++0x"
  51 fi
  52
  53 CXXFLAGS="$STD $CXXFLAGS"
  54
  55 # Checks for glog and gflags
  56 # There are no symbols with C linkage, so we do a try-run
  57 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
  58                 [Please install google-glog library])])
  59 AC_CACHE_CHECK(
  60   [for glog viability],
  61   [folly_cv_prog_cc_glog],
  62   [AC_RUN_IFELSE(
  63     [AC_LANG_SOURCE[
  64       #include <glog/logging.h>
  65       int main(int argc, char** argv) {
  66         google::InitGoogleLogging(argv[0]);
  67         google::ShutdownGoogleLogging();
  68         return 0;
  69       }
  70     ]],
  71     [folly_cv_prog_cc_glog=yes],
  72     [folly_cv_prog_cc_glog=no]
  73   )]
  74 )
  75
  76 if test "$folly_cv_prog_cc_glog" != "yes"; then
  77   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
  78 fi
  79
  80 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  81                 [Please install google-gflags library])])
  82 AC_CACHE_CHECK(
  83   [for gflags viability],
  84   [folly_cv_prog_cc_gflags],
  85   [AC_RUN_IFELSE(
  86     [AC_LANG_SOURCE[
  87       #include <gflags/gflags.h>
  88       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  89       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  90       int main(int argc, char** argv) {
  91         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  92       }
  93     ]],
  94     [folly_cv_prog_cc_gflags=yes],
  95     [folly_cv_prog_cc_gflags=no]
  96   )]
  97 )
  98
  99 if test "$folly_cv_prog_cc_gflags" != "yes"; then
 100   AC_MSG_ERROR(["libgflags invalid, see config.log for details"])
 101 fi
 102
 103 AC_CHECK_LIB(ssl,
 104         SSL_ctrl,
 105         [],
 106         [AC_MSG_ERROR(["Error: libssl required"])])
 107
 108 # check for boost libs
 109 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 110               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 111 AX_BOOST_CONTEXT
 112 AX_BOOST_PROGRAM_OPTIONS
 113 AX_BOOST_THREAD
 114 AX_BOOST_REGEX
 115 AX_BOOST_SYSTEM
 116 AX_BOOST_FILESYSTEM
 117 AX_BOOST_CHRONO
 118
 119 # Check for python interpreter
 120 AM_PATH_PYTHON
 121
 122 # Checks for header files.
 123 AC_HEADER_STDC
 124 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h byteswap.h bits/functexcept.h bits/c++config.h])
 125
 126 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 127                 [Couldn't find double-conversion.h, please download from \
 128                  https://github.com/google/double-conversion/])], [])
 129 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 130              [Please install double-conversion library])])
 131
 132 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 133
 134 AC_CHECK_LIB([jemalloc], [xallocx])
 135
 136 # Checks for typedefs, structures, and compiler characteristics.
 137 AC_HEADER_STDBOOL
 138 AC_C_CONST
 139 AC_C_INLINE
 140 AC_TYPE_SIZE_T
 141 AC_HEADER_TIME
 142 AC_C_VOLATILE
 143 AC_CHECK_TYPE([__int128], AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128]))
 144 AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
 145
 146 AC_CACHE_CHECK(
 147   [for ifunc support],
 148   [folly_cv_prog_cc_ifunc],
 149   [AC_COMPILE_IFELSE(
 150     [AC_LANG_SOURCE[
 151       #pragma GCC diagnostic error "-Wattributes"
 152       extern "C" void (*test_ifunc(void))() { return 0; }
 153       void func() __attribute__((ifunc("test_ifunc")));]
 154     ],
 155     [folly_cv_prog_cc_ifunc=yes],
 156     [folly_cv_prog_cc_ifunc=no])])
 157
 158 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 159   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 160 fi
 161
 162 AC_CACHE_CHECK(
 163   [for final and override support],
 164   [folly_cv_c_final_override],
 165   [AC_COMPILE_IFELSE(
 166     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 167                     class D : public C { virtual void g() override {} };]],
 168     [folly_cv_c_final_override=yes],
 169     [folly_cv_c_final_override=no])])
 170
 171 if test "$folly_cv_c_final_override" = "yes"; then
 172   final_val=final
 173   override_val=override
 174 else
 175   final_val=
 176   override_val=
 177 fi
 178
 179 AC_DEFINE_UNQUOTED(
 180   [FINAL], [$final_val],
 181   [Define to "final" if the compiler supports C++11 "final"])
 182 AC_DEFINE_UNQUOTED(
 183   [OVERRIDE], [$override_val],
 184   [Define to "override" if the compiler supports C++11 "override"])
 185
 186 AC_CACHE_CHECK(
 187   [for std::this_thread::sleep_for],
 188   [folly_cv_func_this_thread_sleep_for],
 189   [AC_COMPILE_IFELSE(
 190     [AC_LANG_SOURCE[
 191       #include <thread>
 192       #include <chrono>
 193       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 194     [folly_cv_func_this_thread_sleep_for=yes],
 195     [folly_cv_func_this_thread_sleep_for=no])])
 196
 197 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 198     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 199               [Define to 1 if std::this_thread::sleep_for() is defined.])
 200 fi
 201
 202 AC_CACHE_CHECK(
 203   [for constexpr strlen],
 204   [folly_cv_func_constexpr_strlen],
 205   [AC_COMPILE_IFELSE(
 206     [AC_LANG_SOURCE[
 207       #include <cstring>
 208       static constexpr int val = strlen("foo");]],
 209     [folly_cv_func_constexpr_strlen=yes],
 210     [folly_cv_func_constexpr_strlen=no])])
 211
 212 if test "$folly_cv_func_constexpr_strlen" = yes; then
 213     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 214               [Define to 1 if strlen(3) is constexpr.])
 215 fi
 216
 217 AC_CACHE_CHECK(
 218   [for libc++],
 219   [folly_cv_lib_libcpp],
 220   [AC_COMPILE_IFELSE(
 221     [AC_LANG_SOURCE[
 222       #include <type_traits>
 223       #if !_LIBCPP_VERSION
 224       #error No libc++
 225       #endif
 226       void func() {}]
 227     ],
 228     [folly_cv_lib_libcpp=yes],
 229     [folly_cv_lib_libcpp=no])])
 230
 231 if test "$folly_cv_lib_libcpp" = yes; then
 232   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 233 fi
 234
 235 AC_CACHE_CHECK(
 236   [for c++11 atomic support without GNU Atomic library],
 237   [folly_cv_lib_libatomic],
 238   [AC_LINK_IFELSE(
 239     [AC_LANG_SOURCE[
 240       #include <atomic>
 241       int main() {
 242         struct Test { int val; };
 243         std::atomic<Test> s;
 244         s.is_lock_free();
 245       }
 246     ]],
 247     [folly_cv_lib_libatomic=yes],
 248     [folly_cv_lib_libatomic=no])])
 249
 250 if test "$folly_cv_lib_libatomic" = no; then
 251   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 252                   [Please install the GNU Atomic library])])
 253 fi
 254
 255 AC_CACHE_CHECK(
 256   [for liblinux-vdso support],
 257   [folly_cv_lib_liblinux_vdso],
 258   [AC_RUN_IFELSE(
 259     [AC_LANG_PROGRAM[
 260       #include <dlfcn.h>
 261       int main() {
 262         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 263         if (h == nullptr) {
 264           return -1;
 265         }
 266         dlclose(h);
 267         return 0;
 268       }
 269     ]],
 270     [folly_cv_lib_liblinux_vdso=yes],
 271     [folly_cv_lib_liblinux_vdso=no])])
 272
 273 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 274   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 275 fi
 276
 277 AC_CACHE_CHECK(
 278   [for usable std::is_trivially_copyable],
 279   [folly_cv_decl_std_is_trivially_copyable],
 280   [AC_COMPILE_IFELSE(
 281     [AC_LANG_SOURCE[
 282       #include <type_traits>
 283       const bool val = std::is_trivially_copyable<bool>::value;]
 284     ],
 285     [folly_cv_decl_std_is_trivially_copyable=yes],
 286     [folly_cv_decl_std_is_trivially_copyable=no])])
 287
 288 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 289   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 290             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 291              implementation.])
 292 fi
 293
 294 AC_CACHE_CHECK(
 295   [gflags namespace],
 296   [folly_cv_decl_gflags_namespace],
 297   [AC_COMPILE_IFELSE(
 298     [AC_LANG_SOURCE[
 299       #include <gflags/gflags.h>
 300       void foo() { gflags::GetArgv(); }]
 301     ],
 302     [folly_cv_decl_gflags_namespace=gflags],
 303     [AC_COMPILE_IFELSE(
 304       [AC_LANG_SOURCE[
 305         #include <gflags/gflags.h>
 306         void foo() { google::GetArgv(); }]
 307       ],
 308       [folly_cv_decl_gflags_namespace=google],
 309       [folly_cv_decl_gflags_namespace=error])])])
 310
 311 if test "$folly_cv_decl_gflags_namespace" = error; then
 312   AC_MSG_ERROR([Cannot determine gflags namespace])
 313 else
 314   AC_DEFINE_UNQUOTED(
 315     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 316     [Define to gflags namespace (usually "google" or "gflags")])
 317   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 318      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 319                [Define to 1 if the gflags namespace is not "gflags"])
 320   fi
 321 fi
 322
 323 # Figure out if we support weak symbols. If not, we will link in some null
 324 # stubs for functions that would otherwise be weak.
 325 AC_CACHE_CHECK(
 326   [for weak symbol support],
 327   [folly_cv_prog_cc_weak_symbols],
 328   [AC_LINK_IFELSE(
 329     [AC_LANG_SOURCE[
 330       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 331       int main(int argc, char** argv) {
 332           return configure_link_extern_weak_test == nullptr;
 333       }]],
 334     [folly_cv_prog_cc_weak_symbols="yes"],
 335     [folly_cv_prog_cc_weak_symbols="no"])])
 336
 337 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 338   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 339             [Define to 1 if the linker supports weak symbols.])
 340 fi
 341
 342 # Figure out whether the architecture supports unaligned reads
 343 AC_CACHE_CHECK(
 344   [for unaligned reads support],
 345   [folly_cv_prog_cc_unaligned_reads],
 346   [AC_RUN_IFELSE(
 347     [AC_LANG_SOURCE[
 348       int main(int argc, char** argv) {
 349         char buf[64] = {0};
 350         unsigned long *ptr = (unsigned long *)(buf + 1);
 351         *ptr = 0xdeadbeef;
 352         return (*ptr & 0xff) == 0xef ? 0 : 1;
 353       }
 354     ]],
 355     [folly_cv_prog_cc_unaligned_reads=yes],
 356     [folly_cv_prog_cc_unaligned_reads=no])])
 357
 358 if test "$folly_cv_prog_cc_unaligned_reads" = "yes"; then
 359   AC_DEFINE([HAVE_UNALIGNED_READS], [1], [Define to 1 if the architecture allows unaligned reads])
 360 fi
 361
 362 AC_CACHE_CHECK(
 363   [for vsnprintf reporting bad format strings],
 364   [folly_cv_prog_vsnprintf_bad_format],
 365   [AC_RUN_IFELSE(
 366     [AC_LANG_SOURCE[
 367       #include <stdio.h>
 368
 369       int main(int argc, char** argv) {
 370           char buf[256];
 371           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 372       }]],
 373     [folly_cv_prog_vsnprintf_bad_format="yes"],
 374     [folly_cv_prog_vsnprintf_bad_format="no"])])
 375
 376 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 377   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 378             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 379 fi
 380
 381 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 382 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 383   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 384             [Define to 1 if we have cplus_demangle_v3_callback.])
 385 fi
 386
 387 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 388 # want to link with librt if necessary.
 389 AC_SEARCH_LIBS([clock_gettime], [rt],
 390   AC_DEFINE(
 391     [HAVE_CLOCK_GETTIME],
 392     [1],
 393     [Define to 1 if we support clock_gettime(2).]),
 394   [])
 395
 396 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 397 # want to include pthread.h if necessary.
 398 AC_CACHE_CHECK(
 399   [for pthread_atfork support],
 400   [folly_cv_prog_cc_pthread_atfork],
 401   [AC_COMPILE_IFELSE(
 402     [AC_LANG_SOURCE[
 403       #include <pthread.h>
 404       void func() {pthread_atfork(NULL, NULL, NULL);}]
 405     ],
 406     [folly_cv_prog_cc_pthread_atfork=yes],
 407     [folly_cv_prog_cc_pthread_atfork=no])])
 408
 409 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 410   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 411 fi
 412
 413 # Check for XSI-compatible strerror_r as default implementation
 414 AC_CACHE_CHECK(
 415   [for XSI style strerror_r support],
 416   [folly_cv_prog_cc_xsi_strerror_r],
 417   [AC_RUN_IFELSE(
 418     [AC_LANG_SOURCE[
 419       #include <string.h>
 420       #include <errno.h>
 421       int main(int argc, char** argv) {
 422         char buf[1024];
 423         buf[0] = 0;
 424         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 425         return ret;
 426       }
 427     ]],
 428     [folly_cv_prog_cc_xsi_strerror_r=yes],
 429     [folly_cv_prog_cc_xsi_strerror_r=no])])
 430
 431 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 432   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 433 fi
 434
 435 AC_CACHE_CHECK(
 436   [for ext/random and __gnu_cxx::sfmt19937],
 437   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 438   [AC_COMPILE_IFELSE(
 439     [AC_LANG_SOURCE[
 440       #include <ext/random>
 441       int main(int argc, char** argv) {
 442         __gnu_cxx::sfmt19937 rng;
 443         return 0;
 444       }
 445     ]],
 446     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 447     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 448
 449 AC_CACHE_CHECK(
 450   [for VLA (variable-length array) support],
 451   [folly_cv_prog_cc_have_vla],
 452   [AC_COMPILE_IFELSE(
 453     [AC_LANG_SOURCE[
 454       int main(int argc, char** argv) {
 455         unsigned size = argc;
 456         char data[size];
 457         return 0;
 458       }
 459     ]],
 460     [folly_cv_prog_cc_have_vla=yes],
 461     [folly_cv_prog_cc_have_vla=no])])
 462
 463 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 464 AC_DEFINE_UNQUOTED(
 465   [HAVE_VLA],
 466   [$have_vla],
 467   [Define to 1 if the compiler has VLA (variable-length array) support,
 468    otherwise define to 0])
 469
 470 # Checks for library functions.
 471 AC_CHECK_FUNCS([getdelim \
 472                 gettimeofday \
 473                 memmove \
 474                 memset \
 475                 pow \
 476                 strerror \
 477                 pthread_yield \
 478                 malloc_size \
 479                 malloc_usable_size \
 480                 memrchr \
 481                 pipe2])
 482
 483 if test "$ac_cv_func_pthread_yield" = "no"; then
 484    AC_CHECK_HEADERS([sched.h])
 485    AC_CHECK_FUNCS([sched_yield])
 486 fi
 487
 488 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 489 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 490 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 491 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 492 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [main]))
 493
 494 AC_ARG_ENABLE([follytestmain],
 495    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 496    [follytestmain=${enableval}], [follytestmain=no])
 497
 498 use_follytestmain=yes
 499 if test "x${follytestmain}" = "xyes"; then
 500    AC_CHECK_HEADERS([libdwarf.h dwarf.h],, AC_MSG_ERROR([Please install libdwarf development package]))
 501    AC_CHECK_HEADERS([libelf.h elf.h],, AC_MSG_ERROR([Please install libelf development package]))
 502    AC_CHECK_HEADERS([libunwind.h],, AC_MSG_ERROR([Please install libinwind development package]))
 503 else
 504    AC_CHECK_HEADERS([libdwarf.h dwarf.h],, [use_follytestmain=no])
 505    AC_CHECK_HEADERS([libelf.h elf.h],, [use_follytestmain=no])
 506    AC_CHECK_HEADERS([libunwind.h],, [use_follytestmain=no])
 507 fi
 508
 509 # Include directory that contains "folly" so #include <folly/Foo.h> works
 510 AM_CPPFLAGS='-I$(top_srcdir)/..'
 511 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 512 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 513 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 514 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 515 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 516
 517 AC_SUBST([AM_CPPFLAGS])
 518 AC_SUBST([AM_LDFLAGS])
 519
 520 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 521 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 522 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 523 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 524 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 525 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 526                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 527 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 528 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 529                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 530 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 531
 532 # Output
 533 AC_CONFIG_FILES([Makefile
 534                  test/Makefile
 535                  test/function_benchmark/Makefile
 536                  experimental/Makefile
 537                  experimental/symbolizer/Makefile
 538                  init/Makefile])
 539 AC_OUTPUT