folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 #declare pkg-config variables
  16 PKG_VERSION=m4_join([.], m4_reverse(m4_translit(folly_version_str, [:], [,])))
  17 AC_SUBST([PKG_VERSION])
  18 AC_SUBST([PKG_CXXFLAGS])
  19 AC_SUBST([PKG_DEPS])
  20 AC_SUBST([PKG_LIBS])
  21
  22 AC_CONFIG_SRCDIR([Likely.h])
  23 AC_CONFIG_HEADERS([config.h])
  24 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  32 AX_CONFIG_FEATURE(
  33         [deprecated-assoc],
  34         [supports deprecated associative containers (hash_map/hash_set)],
  35         [HAVE_DEPRECATED_ASSOC],
  36         [Define if you want to support deprecated associative containers])
  37
  38 AC_PROG_INSTALL
  39 AM_PROG_LIBTOOL
  40
  41 AC_LANG([C++])
  42
  43 # Checks for programs.
  44 AC_PROG_CXX
  45 AC_PROG_CC
  46
  47 AC_CXX_COMPILE_STDCXX_1Y
  48
  49 # Be sure to add any -std option to CXXFLAGS before we invoke any
  50 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  51 # before we update CXXFLAGS will not be run with the same options that we use
  52 # during the real build.
  53 STD=""
  54 if test "x$ac_cv_cxx_compile_cxx1y_cxx" = xyes; then
  55    STD="-std=c++1y"
  56 fi
  57 if test "x$ac_cv_cxx_compile_cxx1y_gxx" = xyes; then
  58    STD="-std=gnu++1y"
  59 fi
  60
  61 CXXFLAGS="$STD $CXXFLAGS"
  62
  63 # expose required -std option via pkg-config
  64 PKG_CXXFLAGS=$STD
  65
  66 # See if -Wshadow-local and -Wshadow-compatible-local are supported
  67 AC_MSG_CHECKING(
  68   [whether -Wshadow-local and -Wshadow-compatible-local are supported])
  69 AC_CACHE_VAL([folly_cv_cxx_shadow_local_support], [
  70   folly_save_CXXFLAGS="$CXXFLAGS"
  71   CXXFLAGS="$CXXFLAGS -Wshadow-local -Wshadow-compatible-local"
  72   AC_COMPILE_IFELSE(
  73     [AC_LANG_PROGRAM([[]], [[]])],
  74     [folly_cv_cxx_shadow_local_support=yes],
  75     [folly_cv_cxx_shadow_local_support=no])
  76   CXXFLAGS="$folly_save_CXXFLAGS"])
  77 AC_MSG_RESULT([$folly_cv_cxx_shadow_local_support])
  78 if test "$folly_cv_cxx_shadow_local_support" = yes; then
  79   AC_DEFINE([HAVE_SHADOW_LOCAL_WARNINGS], [1],
  80   [Define if both -Wshadow-local and -Wshadow-compatible-local are supported.])
  81 fi
  82
  83 # Checks for glog and gflags
  84 # There are no symbols with C linkage, so we do a try-run
  85 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  86                 [Please install google-gflags library])])
  87 AC_CACHE_CHECK(
  88   [for gflags viability],
  89   [folly_cv_prog_cc_gflags],
  90   [AC_RUN_IFELSE(
  91     [AC_LANG_SOURCE[
  92       #include <gflags/gflags.h>
  93       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  94       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  95       int main(int argc, char** argv) {
  96         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  97       }
  98     ]],
  99     [folly_cv_prog_cc_gflags=yes],
 100     [folly_cv_prog_cc_gflags=no]
 101   )]
 102 )
 103
 104 if test "$folly_cv_prog_cc_gflags" != "yes"; then
 105   AC_MSG_ERROR(["gflags invalid, see config.log for details"])
 106 fi
 107 FB_CHECK_PKG_CONFIG([GFLAGS], [gflags])
 108
 109 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
 110                 [Please install google-glog library])])
 111 AC_CACHE_CHECK(
 112   [for glog viability],
 113   [folly_cv_prog_cc_glog],
 114   [AC_RUN_IFELSE(
 115     [AC_LANG_SOURCE[
 116       #include <glog/logging.h>
 117       int main(int argc, char** argv) {
 118         google::InitGoogleLogging(argv[0]);
 119         google::ShutdownGoogleLogging();
 120         return 0;
 121       }
 122     ]],
 123     [folly_cv_prog_cc_glog=yes],
 124     [folly_cv_prog_cc_glog=no]
 125   )]
 126 )
 127
 128 if test "$folly_cv_prog_cc_glog" != "yes"; then
 129   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
 130 fi
 131 FB_CHECK_PKG_CONFIG([GLOG], [libglog])
 132
 133 AS_IF(
 134   [test "x$OPENSSL_INCLUDES" = "x"],
 135   [
 136     AX_CHECK_OPENSSL([], [AC_MSG_ERROR(["Error: libssl required"])])
 137   ],
 138   [
 139     # AX_CHECK_OPENSSL doesn't seem to play nice with builds started
 140     # via build/bootstrap-osx-homebrew.sh
 141     AC_MSG_WARN(["Using existing OpenSSL flags from environment."])
 142     PKG_CXXFLAGS="$PKG_CXXFLAGS $OPENSSL_INCLUDES"
 143   ]
 144 )
 145 FB_CHECK_PKG_CONFIG([OPENSSL], [openssl])
 146
 147 # check for boost libs
 148 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 149               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 150 AX_BOOST_CONTEXT
 151 AX_BOOST_PROGRAM_OPTIONS
 152 AX_BOOST_THREAD
 153 AX_BOOST_REGEX
 154 AX_BOOST_SYSTEM
 155 AX_BOOST_FILESYSTEM
 156 AX_BOOST_CHRONO
 157
 158 # Check for python interpreter
 159 AM_PATH_PYTHON
 160
 161 # Checks for header files.
 162 AC_HEADER_STDC
 163 AC_CHECK_HEADERS([features.h malloc.h bits/functexcept.h bits/c++config.h])
 164
 165 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 166                 [Couldn't find double-conversion.h, please download from \
 167                  https://github.com/google/double-conversion/])], [])
 168 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 169              [Please install double-conversion library])])
 170
 171 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 172 FB_CHECK_PKG_CONFIG([EVENT], [libevent])
 173
 174 AC_ARG_WITH([jemalloc], [
 175   --with-jemalloc     Whether to make folly jemalloc aware
 176 ],[
 177   AC_CHECK_LIB([jemalloc], [xallocx],[
 178     AC_DEFINE([USE_JEMALLOC], [1], [Enable jemalloc])
 179   ],[
 180     AC_MSG_ERROR([--with-jemalloc requested, but jemalloc not found])
 181   ])
 182 ])
 183
 184 # Checks for typedefs, structures, and compiler characteristics.
 185 AC_C_CONST
 186 AC_C_INLINE
 187 AC_TYPE_SIZE_T
 188 AC_HEADER_TIME
 189 AC_C_VOLATILE
 190 AC_CHECK_TYPE([__int128], [folly_cv_prog_cc_int128=yes],
 191     [folly_cv_prog_cc_int128=no])
 192 if test "$folly_cv_prog_cc_int128" = "yes"; then
 193   AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128])
 194   AC_CACHE_CHECK(
 195     [for __int128 type traits],
 196     [folly_cv_prog_cc_int128traits],
 197     [AC_COMPILE_IFELSE(
 198       [AC_LANG_SOURCE([[
 199 #include <type_traits>
 200 static_assert(
 201   ::std::is_same<::std::make_signed<unsigned __int128>::type, __int128>::value,
 202   "signed form of \`unsigned __uint128\` must be \`__int128\`.");
 203       ]])],
 204       [folly_cv_prog_cc_int128traits=yes],
 205       [folly_cv_prog_cc_int128traits=no])
 206     ])
 207   if test "$folly_cv_prog_cc_int128traits" = "no"; then
 208     AC_DEFINE([SUPPLY_MISSING_INT128_TRAITS], [1], [Define if we need the standard integer traits defined for the type `__int128'.])
 209   fi
 210 fi
 211
 212 AC_CHECK_TYPES([pthread_spinlock_t])
 213
 214 AC_CACHE_CHECK(
 215   [for ifunc support],
 216   [folly_cv_prog_cc_ifunc],
 217   [AC_COMPILE_IFELSE(
 218     [AC_LANG_SOURCE[
 219       #pragma GCC diagnostic error "-Wattributes"
 220       extern "C" void (*test_ifunc(void))() { return 0; }
 221       void func() __attribute__((ifunc("test_ifunc")));]
 222     ],
 223     [folly_cv_prog_cc_ifunc=yes],
 224     [folly_cv_prog_cc_ifunc=no])])
 225
 226 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 227   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 228 fi
 229
 230 AC_CACHE_CHECK(
 231   [for final and override support],
 232   [folly_cv_c_final_override],
 233   [AC_COMPILE_IFELSE(
 234     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 235                     class D : public C { virtual void g() override {} };]],
 236     [folly_cv_c_final_override=yes],
 237     [folly_cv_c_final_override=no])])
 238
 239 if test "$folly_cv_c_final_override" = "yes"; then
 240   final_val=final
 241   override_val=override
 242 else
 243   final_val=
 244   override_val=
 245 fi
 246
 247 AC_DEFINE_UNQUOTED(
 248   [FINAL], [$final_val],
 249   [Define to "final" if the compiler supports C++11 "final"])
 250 AC_DEFINE_UNQUOTED(
 251   [OVERRIDE], [$override_val],
 252   [Define to "override" if the compiler supports C++11 "override"])
 253
 254 AC_CACHE_CHECK(
 255   [for libc++],
 256   [folly_cv_lib_libcpp],
 257   [AC_COMPILE_IFELSE(
 258     [AC_LANG_SOURCE[
 259       #include <type_traits>
 260       #if !_LIBCPP_VERSION
 261       #error No libc++
 262       #endif
 263       void func() {}]
 264     ],
 265     [folly_cv_lib_libcpp=yes],
 266     [folly_cv_lib_libcpp=no])])
 267
 268 if test "$folly_cv_lib_libcpp" = yes; then
 269   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 270 fi
 271
 272 AC_CACHE_CHECK(
 273   [for c++11 atomic support without GNU Atomic library],
 274   [folly_cv_lib_libatomic],
 275   [AC_LINK_IFELSE(
 276     [AC_LANG_SOURCE[
 277       #include <atomic>
 278       int main() {
 279         struct Test { int val; };
 280         std::atomic<Test> s;
 281         s.is_lock_free();
 282       }
 283     ]],
 284     [folly_cv_lib_libatomic=yes],
 285     [folly_cv_lib_libatomic=no])])
 286
 287 if test "$folly_cv_lib_libatomic" = no; then
 288   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 289                   [Please install the GNU Atomic library])])
 290 fi
 291
 292 if test "$build_os" = "linux-gnu"; then
 293   AC_HAVE_LIBRARY([dl],[],[AC_MSG_ERROR(
 294                   [Folly depends on libdl])])
 295 fi
 296
 297 AC_CACHE_CHECK(
 298   [for liblinux-vdso support],
 299   [folly_cv_lib_liblinux_vdso],
 300   [AC_RUN_IFELSE(
 301     [AC_LANG_SOURCE[
 302       #include <dlfcn.h>
 303       int main() {
 304         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 305         if (h == nullptr) {
 306           return -1;
 307         }
 308         dlclose(h);
 309         return 0;
 310       }
 311     ]],
 312     [folly_cv_lib_liblinux_vdso=yes],
 313     [folly_cv_lib_liblinux_vdso=no])])
 314
 315 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 316   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 317 fi
 318
 319 AC_DEFINE([HAVE_PTHREAD], [1], [Define to 1 if pthread is avaliable])
 320
 321 AC_CACHE_CHECK(
 322   [for usable std::is_trivially_copyable],
 323   [folly_cv_decl_std_is_trivially_copyable],
 324   [AC_COMPILE_IFELSE(
 325     [AC_LANG_SOURCE[
 326       #include <type_traits>
 327       const bool val = std::is_trivially_copyable<bool>::value;]
 328     ],
 329     [folly_cv_decl_std_is_trivially_copyable=yes],
 330     [folly_cv_decl_std_is_trivially_copyable=no])])
 331
 332 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 333   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 334             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 335              implementation.])
 336 fi
 337
 338 AC_CACHE_CHECK(
 339   [gflags namespace],
 340   [folly_cv_decl_gflags_namespace],
 341   [AC_COMPILE_IFELSE(
 342     [AC_LANG_SOURCE[
 343       #include <gflags/gflags.h>
 344       void foo() { gflags::GetArgv(); }]
 345     ],
 346     [folly_cv_decl_gflags_namespace=gflags],
 347     [AC_COMPILE_IFELSE(
 348       [AC_LANG_SOURCE[
 349         #include <gflags/gflags.h>
 350         void foo() { google::GetArgv(); }]
 351       ],
 352       [folly_cv_decl_gflags_namespace=google],
 353       [folly_cv_decl_gflags_namespace=error])])])
 354
 355 if test "$folly_cv_decl_gflags_namespace" = error; then
 356   AC_MSG_ERROR([Cannot determine gflags namespace])
 357 else
 358   AC_DEFINE_UNQUOTED(
 359     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 360     [Define to gflags namespace (usually "google" or "gflags")])
 361   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 362      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 363                [Define to 1 if the gflags namespace is not "gflags"])
 364   fi
 365 fi
 366
 367 # Figure out if we support weak symbols. If not, we will link in some null
 368 # stubs for functions that would otherwise be weak.
 369 AC_CACHE_CHECK(
 370   [for weak symbol support],
 371   [folly_cv_prog_cc_weak_symbols],
 372   [AC_LINK_IFELSE(
 373     [AC_LANG_SOURCE[
 374       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 375       int main(int argc, char** argv) {
 376           return configure_link_extern_weak_test == nullptr;
 377       }]],
 378     [folly_cv_prog_cc_weak_symbols="yes"],
 379     [folly_cv_prog_cc_weak_symbols="no"])])
 380
 381 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 382   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 383             [Define to 1 if the linker supports weak symbols.])
 384 fi
 385
 386
 387 # Figure out if we support wchar well
 388 AC_CACHE_CHECK(
 389   [for wchar support],
 390   [folly_cv_prog_cc_wchar_support],
 391   [AC_RUN_IFELSE(
 392     [AC_LANG_SOURCE[
 393       #include <cstddef>
 394       #include <cwchar>
 395
 396       int main(int argc, char** argv) {
 397         return wcstol(L"01", nullptr, 10) == 1 ? 0 : 1;
 398       }
 399     ]],
 400     [folly_cv_prog_cc_wchar_support=yes],
 401     [folly_cv_prog_cc_wchar_support=no])])
 402
 403 if test "$folly_cv_prog_cc_wchar_support" = "yes"; then
 404   AC_DEFINE([HAVE_WCHAR_SUPPORT], [1], [Define to 1 if the libc supports wchar well])
 405 fi
 406
 407 # Figure out whether the architecture supports unaligned accesses
 408 AC_CACHE_CHECK(
 409   [for unaligned access support],
 410   [folly_cv_prog_cc_unaligned_access],
 411   [AC_RUN_IFELSE(
 412     [AC_LANG_SOURCE[
 413       int main(int argc, char** argv) {
 414         char buf[64] = {0};
 415         unsigned long *ptr = (unsigned long *)(buf + 1);
 416         *ptr = 0xdeadbeef;
 417         return (*ptr & 0xff) == 0xef ? 0 : 1;
 418       }
 419     ]],
 420     [folly_cv_prog_cc_unaligned_access=yes],
 421     [folly_cv_prog_cc_unaligned_access=no])])
 422
 423 if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
 424   AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
 425 fi
 426
 427 AC_CACHE_CHECK(
 428   [for vsnprintf reporting bad format strings],
 429   [folly_cv_prog_vsnprintf_bad_format],
 430   [AC_RUN_IFELSE(
 431     [AC_LANG_SOURCE[
 432       #include <stdio.h>
 433
 434       int main(int argc, char** argv) {
 435           char buf[256];
 436           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 437       }]],
 438     [folly_cv_prog_vsnprintf_bad_format="yes"],
 439     [folly_cv_prog_vsnprintf_bad_format="no"])])
 440
 441 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 442   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 443             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 444 fi
 445
 446 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 447 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 448   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 449             [Define to 1 if we have cplus_demangle_v3_callback.])
 450 fi
 451
 452 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 453 # want to link with librt if necessary.
 454 AC_SEARCH_LIBS([clock_gettime], [rt],
 455   AC_DEFINE(
 456     [HAVE_CLOCK_GETTIME],
 457     [1],
 458     [Define to 1 if we support clock_gettime(2).]),
 459   [])
 460
 461 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 462 # want to include pthread.h if necessary.
 463 AC_CACHE_CHECK(
 464   [for pthread_atfork support],
 465   [folly_cv_prog_cc_pthread_atfork],
 466   [AC_COMPILE_IFELSE(
 467     [AC_LANG_SOURCE[
 468       #include <pthread.h>
 469       void func() {pthread_atfork(NULL, NULL, NULL);}]
 470     ],
 471     [folly_cv_prog_cc_pthread_atfork=yes],
 472     [folly_cv_prog_cc_pthread_atfork=no])])
 473
 474 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 475   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 476 fi
 477
 478 # Check for XSI-compatible strerror_r as default implementation
 479 AC_CACHE_CHECK(
 480   [for XSI style strerror_r support],
 481   [folly_cv_prog_cc_xsi_strerror_r],
 482   [AC_RUN_IFELSE(
 483     [AC_LANG_SOURCE[
 484       #include <string.h>
 485       #include <errno.h>
 486       int main(int argc, char** argv) {
 487         char buf[1024];
 488         buf[0] = 0;
 489         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 490         return ret;
 491       }
 492     ]],
 493     [folly_cv_prog_cc_xsi_strerror_r=yes],
 494     [folly_cv_prog_cc_xsi_strerror_r=no])])
 495
 496 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 497   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 498 fi
 499
 500 AC_CACHE_CHECK(
 501   [for ext/random and __gnu_cxx::sfmt19937],
 502   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 503   [AC_COMPILE_IFELSE(
 504     [AC_LANG_SOURCE[
 505       #include <ext/random>
 506       int main(int argc, char** argv) {
 507         __gnu_cxx::sfmt19937 rng;
 508         return 0;
 509       }
 510     ]],
 511     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 512     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 513
 514 AC_CACHE_CHECK(
 515   [for VLA (variable-length array) support],
 516   [folly_cv_prog_cc_have_vla],
 517   [AC_COMPILE_IFELSE(
 518     [AC_LANG_SOURCE[
 519       int main(int argc, char** argv) {
 520         unsigned size = argc;
 521         char data[size];
 522         return 0;
 523       }
 524     ]],
 525     [folly_cv_prog_cc_have_vla=yes],
 526     [folly_cv_prog_cc_have_vla=no])])
 527
 528 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 529 AC_DEFINE_UNQUOTED(
 530   [HAVE_VLA],
 531   [$have_vla],
 532   [Define to 1 if the compiler has VLA (variable-length array) support,
 533    otherwise define to 0])
 534
 535 # Checks for library functions.
 536 AC_CHECK_FUNCS([malloc_size \
 537                 malloc_usable_size \
 538                 memrchr \
 539                 pipe2 \
 540                 preadv \
 541                 pwritev \
 542               ])
 543
 544 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 545 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 546 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 547 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 548 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [ZSTD_compressStream]))
 549 AC_CHECK_HEADER([bzlib.h], AC_CHECK_LIB([bz2], [main]))
 550 AC_CHECK_HEADER([linux/membarrier.h], AC_DEFINE([HAVE_LINUX_MEMBARRIER_H], [1], [Define to 1 if membarrier.h is available]))
 551
 552 AC_ARG_ENABLE([follytestmain],
 553    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 554    [use_follytestmain=${enableval}], [use_follytestmain=yes])
 555
 556 # libdwarf used to install in /usr/include, now installs in /usr/include/libdwarf.
 557 AC_CHECK_HEADERS([libdwarf/dwarf.h dwarf.h], [break])
 558 # Check whether we have both the library and the header
 559 have_libdwarf=no
 560 AS_IF([test "x${ac_cv_header_libdwarf_dwarf_h}" = xyes], [have_libdwarf=yes])
 561 AS_IF([test "x${ac_cv_header_dwarf_h}" = xyes], [have_libdwarf=yes])
 562
 563
 564 AC_ARG_ENABLE([mobile],
 565    AS_HELP_STRING([--enable-mobile],
 566                   [enables using main function from folly for tests]),
 567                   [mobile=${enableval}], [mobile=no])
 568 AS_IF([test "x${mobile}" = "xyes"], [
 569     AC_DEFINE([MOBILE], [1],
 570               [Define to 1 for compiler guards for mobile targets.])
 571 ])
 572
 573 AC_ARG_ENABLE([exception-tracer],
 574     AS_HELP_STRING([--enable-exception-tracer], [enables building exception tracer]),
 575     [build_exception_tracer=${enableval}], [build_exception_tracer=no])
 576
 577 # Include directory that contains "folly" so #include <folly/Foo.h> works
 578 AM_CPPFLAGS='-I$(top_srcdir)/..'
 579 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS $OPENSSL_INCLUDES"
 580 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 581 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 582 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 583 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 584
 585 AM_LDFLAGS="$AM_LDFLAGS $OPENSSL_LDFLAGS $OPENSSL_LIBS"
 586
 587 AC_SUBST([AM_CPPFLAGS])
 588 AC_SUBST([AM_LDFLAGS])
 589
 590 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 591 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 592 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 593 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 594 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 595 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 596                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 597 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT_H], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 598 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 599                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 600 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 601 AM_CONDITIONAL([HAVE_LIBDWARF], [test "x${have_libdwarf}" = "xyes"])
 602 AM_CONDITIONAL([HAVE_BOOST_CONTEXT], [test "x${ax_cv_boost_context}" = "xyes"])
 603 AM_CONDITIONAL([EXCEPTION_TRACER], [test "x${build_exception_tracer}" = "xyes"])
 604
 605 # remove pkg-config deps from dependent libraries
 606 # (at least for pkg-config file purposes)
 607 FB_FILTER_PKG_LIBS([$AM_LDFLAGS $LIBS])
 608
 609 # Output
 610 AC_CONFIG_FILES([Makefile
 611                  io/test/Makefile
 612                  libfolly.pc
 613                  test/Makefile
 614                  test/function_benchmark/Makefile
 615                  experimental/Makefile
 616                  experimental/io/test/Makefile
 617                  experimental/symbolizer/Makefile
 618                  init/Makefile])
 619
 620 AM_COND_IF([EXCEPTION_TRACER],
 621            [AC_CONFIG_FILES([experimental/exception_tracer/Makefile])])
 622 AC_OUTPUT