folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 #declare pkg-config variables
  16 PKG_VERSION=m4_join([.], m4_reverse(m4_translit(folly_version_str, [:], [,])))
  17 AC_SUBST([PKG_VERSION])
  18 AC_SUBST([PKG_CXXFLAGS])
  19 AC_SUBST([PKG_DEPS])
  20 AC_SUBST([PKG_LIBS])
  21
  22 AC_CONFIG_SRCDIR([Likely.h])
  23 AC_CONFIG_HEADERS([config.h])
  24 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  32 AX_CONFIG_FEATURE(
  33         [deprecated-assoc],
  34         [supports deprecated associative containers (hash_map/hash_set)],
  35         [HAVE_DEPRECATED_ASSOC],
  36         [Define if you want to support deprecated associative containers])
  37
  38 AC_PROG_INSTALL
  39 AM_PROG_LIBTOOL
  40
  41 AC_LANG([C++])
  42
  43 # Checks for programs.
  44 AC_PROG_CXX
  45 AC_PROG_CC
  46
  47 AC_CXX_COMPILE_STDCXX_1Y
  48
  49 # Be sure to add any -std option to CXXFLAGS before we invoke any
  50 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  51 # before we update CXXFLAGS will not be run with the same options that we use
  52 # during the real build.
  53 STD=""
  54 if test "x$ac_cv_cxx_compile_cxx1y_cxx" = xyes; then
  55    STD="-std=c++1y"
  56 fi
  57 if test "x$ac_cv_cxx_compile_cxx1y_gxx" = xyes; then
  58    STD="-std=gnu++1y"
  59 fi
  60
  61 CXXFLAGS="$STD $CXXFLAGS"
  62
  63 # expose required -std option via pkg-config
  64 PKG_CXXFLAGS=$STD
  65
  66 # Checks for glog and gflags
  67 # There are no symbols with C linkage, so we do a try-run
  68 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  69                 [Please install google-gflags library])])
  70 AC_CACHE_CHECK(
  71   [for gflags viability],
  72   [folly_cv_prog_cc_gflags],
  73   [AC_RUN_IFELSE(
  74     [AC_LANG_SOURCE[
  75       #include <gflags/gflags.h>
  76       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  77       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  78       int main(int argc, char** argv) {
  79         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  80       }
  81     ]],
  82     [folly_cv_prog_cc_gflags=yes],
  83     [folly_cv_prog_cc_gflags=no]
  84   )]
  85 )
  86
  87 if test "$folly_cv_prog_cc_gflags" != "yes"; then
  88   AC_MSG_ERROR(["libgflags invalid, see config.log for details"])
  89 fi
  90 FB_CHECK_PKG_CONFIG([GFLAGS], [libgflags])
  91
  92 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
  93                 [Please install google-glog library])])
  94 AC_CACHE_CHECK(
  95   [for glog viability],
  96   [folly_cv_prog_cc_glog],
  97   [AC_RUN_IFELSE(
  98     [AC_LANG_SOURCE[
  99       #include <glog/logging.h>
 100       int main(int argc, char** argv) {
 101         google::InitGoogleLogging(argv[0]);
 102         google::ShutdownGoogleLogging();
 103         return 0;
 104       }
 105     ]],
 106     [folly_cv_prog_cc_glog=yes],
 107     [folly_cv_prog_cc_glog=no]
 108   )]
 109 )
 110
 111 if test "$folly_cv_prog_cc_glog" != "yes"; then
 112   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
 113 fi
 114 FB_CHECK_PKG_CONFIG([GLOG], [libglog])
 115
 116 AC_CHECK_LIB(ssl,
 117         SSL_ctrl,
 118         [],
 119         [AC_MSG_ERROR(["Error: libssl required"])])
 120 FB_CHECK_PKG_CONFIG([OPENSSL], [openssl])
 121
 122 # check for boost libs
 123 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 124               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 125 AX_BOOST_CONTEXT
 126 AX_BOOST_PROGRAM_OPTIONS
 127 AX_BOOST_THREAD
 128 AX_BOOST_REGEX
 129 AX_BOOST_SYSTEM
 130 AX_BOOST_FILESYSTEM
 131 AX_BOOST_CHRONO
 132
 133 # Check for python interpreter
 134 AM_PATH_PYTHON
 135
 136 # Checks for header files.
 137 AC_HEADER_STDC
 138 AC_CHECK_HEADERS([fcntl.h features.h inttypes.h limits.h sched.h stdint.h stdlib.h string.h sys/time.h unistd.h mutex.h malloc.h byteswap.h bits/functexcept.h bits/c++config.h])
 139
 140 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 141                 [Couldn't find double-conversion.h, please download from \
 142                  https://github.com/google/double-conversion/])], [])
 143 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 144              [Please install double-conversion library])])
 145
 146 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 147 FB_CHECK_PKG_CONFIG([EVENT], [libevent])
 148
 149 AC_CHECK_LIB([jemalloc], [xallocx])
 150
 151 # Checks for typedefs, structures, and compiler characteristics.
 152 AC_HEADER_STDBOOL
 153 AC_C_CONST
 154 AC_C_INLINE
 155 AC_TYPE_SIZE_T
 156 AC_HEADER_TIME
 157 AC_C_VOLATILE
 158 AC_CHECK_TYPE([__int128], AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128]))
 159 AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
 160
 161 AC_CACHE_CHECK(
 162   [for ifunc support],
 163   [folly_cv_prog_cc_ifunc],
 164   [AC_COMPILE_IFELSE(
 165     [AC_LANG_SOURCE[
 166       #pragma GCC diagnostic error "-Wattributes"
 167       extern "C" void (*test_ifunc(void))() { return 0; }
 168       void func() __attribute__((ifunc("test_ifunc")));]
 169     ],
 170     [folly_cv_prog_cc_ifunc=yes],
 171     [folly_cv_prog_cc_ifunc=no])])
 172
 173 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 174   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 175 fi
 176
 177 AC_CACHE_CHECK(
 178   [for final and override support],
 179   [folly_cv_c_final_override],
 180   [AC_COMPILE_IFELSE(
 181     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 182                     class D : public C { virtual void g() override {} };]],
 183     [folly_cv_c_final_override=yes],
 184     [folly_cv_c_final_override=no])])
 185
 186 if test "$folly_cv_c_final_override" = "yes"; then
 187   final_val=final
 188   override_val=override
 189 else
 190   final_val=
 191   override_val=
 192 fi
 193
 194 AC_DEFINE_UNQUOTED(
 195   [FINAL], [$final_val],
 196   [Define to "final" if the compiler supports C++11 "final"])
 197 AC_DEFINE_UNQUOTED(
 198   [OVERRIDE], [$override_val],
 199   [Define to "override" if the compiler supports C++11 "override"])
 200
 201 AC_CACHE_CHECK(
 202   [for std::this_thread::sleep_for],
 203   [folly_cv_func_this_thread_sleep_for],
 204   [AC_COMPILE_IFELSE(
 205     [AC_LANG_SOURCE[
 206       #include <thread>
 207       #include <chrono>
 208       void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
 209     [folly_cv_func_this_thread_sleep_for=yes],
 210     [folly_cv_func_this_thread_sleep_for=no])])
 211
 212 if test "$folly_cv_func_this_thread_sleep_for" = yes; then
 213     AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
 214               [Define to 1 if std::this_thread::sleep_for() is defined.])
 215 fi
 216
 217 AC_CACHE_CHECK(
 218   [for constexpr strlen],
 219   [folly_cv_func_constexpr_strlen],
 220   [AC_COMPILE_IFELSE(
 221     [AC_LANG_SOURCE[
 222       #include <cstring>
 223       static constexpr int val = strlen("foo");]],
 224     [folly_cv_func_constexpr_strlen=yes],
 225     [folly_cv_func_constexpr_strlen=no])])
 226
 227 if test "$folly_cv_func_constexpr_strlen" = yes; then
 228     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 229               [Define to 1 if strlen(3) is constexpr.])
 230 fi
 231
 232 AC_CACHE_CHECK(
 233   [for libc++],
 234   [folly_cv_lib_libcpp],
 235   [AC_COMPILE_IFELSE(
 236     [AC_LANG_SOURCE[
 237       #include <type_traits>
 238       #if !_LIBCPP_VERSION
 239       #error No libc++
 240       #endif
 241       void func() {}]
 242     ],
 243     [folly_cv_lib_libcpp=yes],
 244     [folly_cv_lib_libcpp=no])])
 245
 246 if test "$folly_cv_lib_libcpp" = yes; then
 247   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 248 fi
 249
 250 AC_CACHE_CHECK(
 251   [for c++11 atomic support without GNU Atomic library],
 252   [folly_cv_lib_libatomic],
 253   [AC_LINK_IFELSE(
 254     [AC_LANG_SOURCE[
 255       #include <atomic>
 256       int main() {
 257         struct Test { int val; };
 258         std::atomic<Test> s;
 259         s.is_lock_free();
 260       }
 261     ]],
 262     [folly_cv_lib_libatomic=yes],
 263     [folly_cv_lib_libatomic=no])])
 264
 265 if test "$folly_cv_lib_libatomic" = no; then
 266   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 267                   [Please install the GNU Atomic library])])
 268 fi
 269
 270 AC_CACHE_CHECK(
 271   [for liblinux-vdso support],
 272   [folly_cv_lib_liblinux_vdso],
 273   [AC_RUN_IFELSE(
 274     [AC_LANG_PROGRAM[
 275       #include <dlfcn.h>
 276       int main() {
 277         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 278         if (h == nullptr) {
 279           return -1;
 280         }
 281         dlclose(h);
 282         return 0;
 283       }
 284     ]],
 285     [folly_cv_lib_liblinux_vdso=yes],
 286     [folly_cv_lib_liblinux_vdso=no])])
 287
 288 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 289   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 290 fi
 291
 292 AC_CACHE_CHECK(
 293   [for usable std::is_trivially_copyable],
 294   [folly_cv_decl_std_is_trivially_copyable],
 295   [AC_COMPILE_IFELSE(
 296     [AC_LANG_SOURCE[
 297       #include <type_traits>
 298       const bool val = std::is_trivially_copyable<bool>::value;]
 299     ],
 300     [folly_cv_decl_std_is_trivially_copyable=yes],
 301     [folly_cv_decl_std_is_trivially_copyable=no])])
 302
 303 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 304   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 305             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 306              implementation.])
 307 fi
 308
 309 AC_CACHE_CHECK(
 310   [gflags namespace],
 311   [folly_cv_decl_gflags_namespace],
 312   [AC_COMPILE_IFELSE(
 313     [AC_LANG_SOURCE[
 314       #include <gflags/gflags.h>
 315       void foo() { gflags::GetArgv(); }]
 316     ],
 317     [folly_cv_decl_gflags_namespace=gflags],
 318     [AC_COMPILE_IFELSE(
 319       [AC_LANG_SOURCE[
 320         #include <gflags/gflags.h>
 321         void foo() { google::GetArgv(); }]
 322       ],
 323       [folly_cv_decl_gflags_namespace=google],
 324       [folly_cv_decl_gflags_namespace=error])])])
 325
 326 if test "$folly_cv_decl_gflags_namespace" = error; then
 327   AC_MSG_ERROR([Cannot determine gflags namespace])
 328 else
 329   AC_DEFINE_UNQUOTED(
 330     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 331     [Define to gflags namespace (usually "google" or "gflags")])
 332   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 333      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 334                [Define to 1 if the gflags namespace is not "gflags"])
 335   fi
 336 fi
 337
 338 # Figure out if we support weak symbols. If not, we will link in some null
 339 # stubs for functions that would otherwise be weak.
 340 AC_CACHE_CHECK(
 341   [for weak symbol support],
 342   [folly_cv_prog_cc_weak_symbols],
 343   [AC_LINK_IFELSE(
 344     [AC_LANG_SOURCE[
 345       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 346       int main(int argc, char** argv) {
 347           return configure_link_extern_weak_test == nullptr;
 348       }]],
 349     [folly_cv_prog_cc_weak_symbols="yes"],
 350     [folly_cv_prog_cc_weak_symbols="no"])])
 351
 352 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 353   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 354             [Define to 1 if the linker supports weak symbols.])
 355 fi
 356
 357
 358 # Figure out if we support wchar well
 359 AC_CACHE_CHECK(
 360   [for wchar support],
 361   [folly_cv_prog_cc_wchar_support],
 362   [AC_RUN_IFELSE(
 363     [AC_LANG_SOURCE[
 364       #include <cstddef>
 365       #include <cwchar>
 366
 367       int main(int argc, char** argv) {
 368         return wcstol(L"01", nullptr, 10) == 1 ? 0 : 1;
 369       }
 370     ]],
 371     [folly_cv_prog_cc_wchar_support=yes],
 372     [folly_cv_prog_cc_wchar_support=no])])
 373
 374 if test "$folly_cv_prog_cc_wchar_support" = "yes"; then
 375   AC_DEFINE([HAVE_WCHAR_SUPPORT], [1], [Define to 1 if the libc supports wchar well])
 376 fi
 377
 378 # Figure out whether the architecture supports unaligned accesses
 379 AC_CACHE_CHECK(
 380   [for unaligned access support],
 381   [folly_cv_prog_cc_unaligned_access],
 382   [AC_RUN_IFELSE(
 383     [AC_LANG_SOURCE[
 384       int main(int argc, char** argv) {
 385         char buf[64] = {0};
 386         unsigned long *ptr = (unsigned long *)(buf + 1);
 387         *ptr = 0xdeadbeef;
 388         return (*ptr & 0xff) == 0xef ? 0 : 1;
 389       }
 390     ]],
 391     [folly_cv_prog_cc_unaligned_access=yes],
 392     [folly_cv_prog_cc_unaligned_access=no])])
 393
 394 if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
 395   AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
 396 fi
 397
 398 AC_CACHE_CHECK(
 399   [for vsnprintf reporting bad format strings],
 400   [folly_cv_prog_vsnprintf_bad_format],
 401   [AC_RUN_IFELSE(
 402     [AC_LANG_SOURCE[
 403       #include <stdio.h>
 404
 405       int main(int argc, char** argv) {
 406           char buf[256];
 407           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 408       }]],
 409     [folly_cv_prog_vsnprintf_bad_format="yes"],
 410     [folly_cv_prog_vsnprintf_bad_format="no"])])
 411
 412 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 413   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 414             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 415 fi
 416
 417 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 418 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 419   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 420             [Define to 1 if we have cplus_demangle_v3_callback.])
 421 fi
 422
 423 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 424 # want to link with librt if necessary.
 425 AC_SEARCH_LIBS([clock_gettime], [rt],
 426   AC_DEFINE(
 427     [HAVE_CLOCK_GETTIME],
 428     [1],
 429     [Define to 1 if we support clock_gettime(2).]),
 430   [])
 431
 432 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 433 # want to include pthread.h if necessary.
 434 AC_CACHE_CHECK(
 435   [for pthread_atfork support],
 436   [folly_cv_prog_cc_pthread_atfork],
 437   [AC_COMPILE_IFELSE(
 438     [AC_LANG_SOURCE[
 439       #include <pthread.h>
 440       void func() {pthread_atfork(NULL, NULL, NULL);}]
 441     ],
 442     [folly_cv_prog_cc_pthread_atfork=yes],
 443     [folly_cv_prog_cc_pthread_atfork=no])])
 444
 445 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 446   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 447 fi
 448
 449 # Check for XSI-compatible strerror_r as default implementation
 450 AC_CACHE_CHECK(
 451   [for XSI style strerror_r support],
 452   [folly_cv_prog_cc_xsi_strerror_r],
 453   [AC_RUN_IFELSE(
 454     [AC_LANG_SOURCE[
 455       #include <string.h>
 456       #include <errno.h>
 457       int main(int argc, char** argv) {
 458         char buf[1024];
 459         buf[0] = 0;
 460         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 461         return ret;
 462       }
 463     ]],
 464     [folly_cv_prog_cc_xsi_strerror_r=yes],
 465     [folly_cv_prog_cc_xsi_strerror_r=no])])
 466
 467 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 468   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 469 fi
 470
 471 AC_CACHE_CHECK(
 472   [for ext/random and __gnu_cxx::sfmt19937],
 473   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 474   [AC_COMPILE_IFELSE(
 475     [AC_LANG_SOURCE[
 476       #include <ext/random>
 477       int main(int argc, char** argv) {
 478         __gnu_cxx::sfmt19937 rng;
 479         return 0;
 480       }
 481     ]],
 482     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 483     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 484
 485 AC_CACHE_CHECK(
 486   [for VLA (variable-length array) support],
 487   [folly_cv_prog_cc_have_vla],
 488   [AC_COMPILE_IFELSE(
 489     [AC_LANG_SOURCE[
 490       int main(int argc, char** argv) {
 491         unsigned size = argc;
 492         char data[size];
 493         return 0;
 494       }
 495     ]],
 496     [folly_cv_prog_cc_have_vla=yes],
 497     [folly_cv_prog_cc_have_vla=no])])
 498
 499 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 500 AC_DEFINE_UNQUOTED(
 501   [HAVE_VLA],
 502   [$have_vla],
 503   [Define to 1 if the compiler has VLA (variable-length array) support,
 504    otherwise define to 0])
 505
 506 # Checks for library functions.
 507 AC_CHECK_FUNCS([getdelim \
 508                 gettimeofday \
 509                 memmove \
 510                 memset \
 511                 pow \
 512                 strerror \
 513                 sched_yield \
 514                 malloc_size \
 515                 malloc_usable_size \
 516                 memrchr \
 517                 pipe2 \
 518                 preadv \
 519                 pwritev \
 520               ])
 521
 522 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 523 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 524 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 525 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 526 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [main]))
 527
 528 AC_ARG_ENABLE([follytestmain],
 529    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 530    [follytestmain=${enableval}], [follytestmain=no])
 531
 532 use_follytestmain=yes
 533 if test "x${follytestmain}" = "xyes"; then
 534    AC_CHECK_HEADERS([libdwarf.h dwarf.h],, AC_MSG_ERROR([Please install libdwarf development package]))
 535    AC_CHECK_HEADERS([libelf.h elf.h],, AC_MSG_ERROR([Please install libelf development package]))
 536    AC_CHECK_HEADERS([libunwind.h],, AC_MSG_ERROR([Please install libinwind development package]))
 537 else
 538    AC_CHECK_HEADERS([libdwarf.h dwarf.h],, [use_follytestmain=no])
 539    AC_CHECK_HEADERS([libelf.h elf.h],, [use_follytestmain=no])
 540    AC_CHECK_HEADERS([libunwind.h],, [use_follytestmain=no])
 541 fi
 542
 543 AC_ARG_ENABLE([mobile],
 544    AS_HELP_STRING([--enable-mobile],
 545                   [enables using main function from folly for tests]),
 546                   [mobile=${enableval}], [mobile=no])
 547 AS_IF([test "x${mobile}" = "xyes"], [
 548     AC_DEFINE([MOBILE], [1],
 549               [Define to 1 for compiler guards for mobile targets.])
 550 ])
 551
 552 # Include directory that contains "folly" so #include <folly/Foo.h> works
 553 AM_CPPFLAGS='-I$(top_srcdir)/..'
 554 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS"
 555 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 556 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 557 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 558 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 559
 560 AC_SUBST([AM_CPPFLAGS])
 561 AC_SUBST([AM_LDFLAGS])
 562
 563 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 564 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 565 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 566 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 567 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 568 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 569                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 570 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT_H], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 571 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 572                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 573 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 574 AM_CONDITIONAL([HAVE_BOOST_CONTEXT], [test "x${ax_cv_boost_context}" = "xyes"])
 575
 576 # remove pkg-config deps from dependent libraries
 577 # (at least for pkg-config file purposes)
 578 FB_FILTER_PKG_LIBS([$AM_LDFLAGS $LIBS])
 579
 580 # Output
 581 AC_CONFIG_FILES([Makefile
 582                  libfolly.pc
 583                  test/Makefile
 584                  test/function_benchmark/Makefile
 585                  experimental/Makefile
 586                  experimental/symbolizer/Makefile
 587                  init/Makefile])
 588 AC_OUTPUT