CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.0 FATAL_ERROR)
   2
   3 # includes
   4 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake" ${CMAKE_MODULE_PATH})
   5 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
   6
   7 # package information
   8 set(PACKAGE_NAME      "folly")
   9 set(PACKAGE_VERSION   "0.58.0-dev")
  10 set(PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  11 set(PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
  12 set(PACKAGE_BUGREPORT "https://github.com/facebook/folly/issues")
  13
  14 # 150+ tests in the root folder anyone? No? I didn't think so.
  15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  16
  17 project(${PACKAGE_NAME} CXX)
  18
  19 if (MSVC_VERSION GREATER_EQUAL 1910 AND MSVC_VERSION LESS 1920)
  20   set(MSVC_IS_2017 ON)
  21 elseif (MSVC_VERSION EQUAL 1900)
  22   set(MSVC_IS_2017 OFF)
  23 else()
  24   message(FATAL_ERROR "This build script only supports building Folly on 64-bit Windows with Visual Studio 2015 or Visual Studio 2017. MSVC version '${MSVC_VERSION}' is not supported.")
  25 endif()
  26
  27 # Check architecture OS
  28 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
  29   message(FATAL_ERROR "Folly requires a 64bit OS")
  30 endif()
  31 if(NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
  32   message(FATAL_ERROR "You should only be using CMake to build Folly if you are on Windows!")
  33 endif()
  34
  35 set(FOLLY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/folly")
  36
  37 # Generate a few tables and create the main config file.
  38 find_package(PythonInterp REQUIRED)
  39 add_custom_command(
  40   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
  41   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_escape_tables.py"
  42   DEPENDS ${FOLLY_DIR}/build/generate_escape_tables.py
  43   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  44   COMMENT "Generating the escape tables..." VERBATIM
  45 )
  46 add_custom_command(
  47   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
  48   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_format_tables.py"
  49   DEPENDS ${FOLLY_DIR}/build/generate_format_tables.py
  50   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  51   COMMENT "Generating the format tables..." VERBATIM
  52 )
  53 add_custom_command(
  54   OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp"
  55   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_varint_tables.py"
  56   DEPENDS ${FOLLY_DIR}/build/generate_varint_tables.py
  57   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  58   COMMENT "Generating the group varint tables..." VERBATIM
  59 )
  60
  61 include(folly-deps) # Find the required packages
  62 if (LIBPTHREAD_FOUND)
  63   set(FOLLY_HAVE_PTHREAD ON)
  64 endif()
  65 configure_file(
  66   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-config.h.cmake
  67   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
  68 )
  69
  70 include(FollyCompiler)
  71 include(FollyFunctions)
  72
  73 # Main folly library files
  74 auto_sources(files "*.cpp" "RECURSE" "${FOLLY_DIR}")
  75 auto_sources(hfiles "*.h" "RECURSE" "${FOLLY_DIR}")
  76
  77 # No need for tests or benchmarks, and we can't build most experimental stuff.
  78 REMOVE_MATCHES_FROM_LISTS(files hfiles
  79   MATCHES
  80     "/build/"
  81     "/experimental/exception_tracer/"
  82     "/experimental/hazptr/bench/"
  83     "/experimental/hazptr/example/"
  84     "/experimental/logging/example/"
  85     "/experimental/symbolizer/"
  86     "/futures/exercises/"
  87     "/test/"
  88     "/tools/"
  89     "Benchmark.cpp$"
  90     "Test.cpp$"
  91   IGNORE_MATCHES
  92     "/Benchmark.cpp$"
  93 )
  94 list(REMOVE_ITEM files
  95   ${FOLLY_DIR}/Poly.cpp
  96   ${FOLLY_DIR}/Subprocess.cpp
  97   ${FOLLY_DIR}/SingletonStackTrace.cpp
  98   ${FOLLY_DIR}/experimental/JSONSchemaTester.cpp
  99   ${FOLLY_DIR}/experimental/RCUUtils.cpp
 100   ${FOLLY_DIR}/experimental/io/AsyncIO.cpp
 101   ${FOLLY_DIR}/experimental/io/HugePageUtil.cpp
 102   ${FOLLY_DIR}/futures/test/Benchmark.cpp
 103 )
 104 list(REMOVE_ITEM hfiles
 105   ${FOLLY_DIR}/Fingerprint.h
 106   ${FOLLY_DIR}/Poly.h
 107   ${FOLLY_DIR}/Poly-inl.h
 108   ${FOLLY_DIR}/detail/PolyDetail.h
 109   ${FOLLY_DIR}/detail/TypeList.h
 110   ${FOLLY_DIR}/detail/SlowFingerprint.h
 111   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 112   ${FOLLY_DIR}/experimental/RCURefCount.h
 113   ${FOLLY_DIR}/experimental/RCUUtils.h
 114   ${FOLLY_DIR}/experimental/io/AsyncIO.h
 115   ${FOLLY_DIR}/poly/Nullable.h
 116   ${FOLLY_DIR}/poly/Regular.h
 117 )
 118
 119 add_library(folly_base OBJECT
 120   ${files} ${hfiles}
 121   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
 122   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
 123   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
 124   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
 125 )
 126 auto_source_group(folly ${FOLLY_DIR} ${files} ${hfiles})
 127 apply_folly_compile_options_to_target(folly_base)
 128 target_include_directories(folly_base PUBLIC ${CMAKE_CURRENT_BINARY_DIR})
 129 # Add the generated files to the correct source group.
 130 source_group("folly" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h)
 131 source_group("folly\\build" FILES
 132   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
 133   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 134   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
 135   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
 136 )
 137
 138 set(FOLLY_SHINY_DEPENDENCIES
 139   Boost::chrono
 140   Boost::context
 141   Boost::date_time
 142   Boost::filesystem
 143   Boost::program_options
 144   Boost::regex
 145   Boost::system
 146   OpenSSL::SSL
 147   OpenSSL::Crypto
 148 )
 149
 150 set(FOLLY_LINK_LIBRARIES
 151   ${DOUBLE_CONVERSION_LIBRARY}
 152 )
 153
 154 set(FOLLY_INCLUDE_DIRECTORIES
 155   ${DOUBLE_CONVERSION_INCLUDE_DIR}
 156 )
 157
 158 if(TARGET gflags)
 159   set(FOLLY_SHINY_DEPENDENCIES ${FOLLY_SHINY_DEPENDENCIES} gflags)
 160 else()
 161   set(FOLLY_LINK_LIBRARIES ${FOLLY_LINK_LIBRARIES} ${LIBGFLAGS_LIBRARY})
 162   set(FOLLY_INCLUDE_DIRECTORIES ${FOLLY_INCLUDE_DIRECTORIES} ${LIBGFLAGS_INCLUDE_DIR})
 163 endif()
 164
 165 if(TARGET glog::glog)
 166   set(FOLLY_SHINY_DEPENDENCIES ${FOLLY_SHINY_DEPENDENCIES} glog::glog)
 167 else()
 168   set(FOLLY_LINK_LIBRARIES ${FOLLY_LINK_LIBRARIES} ${LIBGLOG_LIBRARY})
 169   set(FOLLY_INCLUDE_DIRECTORIES ${FOLLY_INCLUDE_DIRECTORIES} ${LIBGLOG_INCLUDE_DIR})
 170 endif()
 171
 172 if(TARGET event)
 173   set(FOLLY_SHINY_DEPENDENCIES ${FOLLY_SHINY_DEPENDENCIES} event)
 174 else()
 175   set(FOLLY_LINK_LIBRARIES ${FOLLY_LINK_LIBRARIES} ${LIBEVENT_LIB})
 176   set(FOLLY_INCLUDE_DIRECTORIES ${FOLLY_INCLUDE_DIRECTORIES} ${LIBEVENT_INCLUDE_DIR})
 177 endif()
 178
 179
 180 set(FOLLY_LINK_LIBRARIES
 181   ${FOLLY_LINK_LIBRARIES}
 182   Iphlpapi.lib
 183   Ws2_32.lib
 184
 185   ${FOLLY_SHINY_DEPENDENCIES}
 186 )
 187
 188 target_include_directories(folly_base
 189   PUBLIC
 190     ${FOLLY_INCLUDE_DIRECTORIES}
 191     $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
 192 )
 193
 194 foreach (LIB ${FOLLY_SHINY_DEPENDENCIES})
 195   target_include_directories(folly_base PUBLIC $<TARGET_PROPERTY:${LIB},INCLUDE_DIRECTORIES>)
 196   target_compile_definitions(folly_base PUBLIC $<TARGET_PROPERTY:${LIB},INTERFACE_COMPILE_DEFINITIONS>)
 197 endforeach()
 198
 199 if (FOLLY_HAVE_PTHREAD)
 200   target_include_directories(folly_base PUBLIC ${LIBPTHREAD_INCLUDE_DIRS})
 201   list(APPEND FOLLY_LINK_LIBRARIES ${LIBPTHREAD_LIBRARIES})
 202 endif()
 203
 204 # Now to generate the fingerprint tables
 205 add_executable(GenerateFingerprintTables
 206   ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp
 207   $<TARGET_OBJECTS:folly_base>
 208 )
 209 target_link_libraries(GenerateFingerprintTables PRIVATE ${FOLLY_LINK_LIBRARIES})
 210 target_include_directories(GenerateFingerprintTables PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 211 add_dependencies(GenerateFingerprintTables folly_base)
 212 apply_folly_compile_options_to_target(GenerateFingerprintTables)
 213 set_property(TARGET GenerateFingerprintTables PROPERTY FOLDER "Build")
 214 source_group("" FILES ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp)
 215
 216 # Compile the fingerprint tables.
 217 add_custom_command(
 218   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 219   COMMAND GenerateFingerprintTables
 220   DEPENDS GenerateFingerprintTables
 221   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
 222   COMMENT "Generating the fingerprint tables..."
 223 )
 224 add_library(folly_fingerprint STATIC
 225   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 226   ${FOLLY_DIR}/Fingerprint.h
 227   ${FOLLY_DIR}/detail/SlowFingerprint.h
 228   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 229   $<TARGET_OBJECTS:folly_base>
 230 )
 231 target_link_libraries(folly_fingerprint PRIVATE ${FOLLY_LINK_LIBRARIES})
 232 target_include_directories(folly_fingerprint PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 233 add_dependencies(folly_fingerprint folly_base)
 234 apply_folly_compile_options_to_target(folly_fingerprint)
 235
 236 # We want to generate a single library and target for folly, but we needed a
 237 # two-stage compile for the fingerprint tables, so we create a phony source
 238 # file that we modify whenever the base libraries change, causing folly to be
 239 # re-linked, making things happy.
 240 add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
 241   COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
 242   DEPENDS folly_base folly_fingerprint
 243 )
 244 add_library(folly ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp $<TARGET_OBJECTS:folly_base>)
 245 apply_folly_compile_options_to_target(folly)
 246 source_group("" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
 247
 248 target_link_libraries(folly PUBLIC ${FOLLY_LINK_LIBRARIES})
 249 target_include_directories(folly PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 250
 251 install(TARGETS folly
 252   EXPORT folly
 253   RUNTIME DESTINATION bin
 254   LIBRARY DESTINATION lib
 255   ARCHIVE DESTINATION lib)
 256 auto_install_files(folly ${FOLLY_DIR}
 257   ${hfiles}
 258   ${FOLLY_DIR}/Fingerprint.h
 259   ${FOLLY_DIR}/detail/SlowFingerprint.h
 260   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 261 )
 262 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h DESTINATION include/folly)
 263 install(
 264   EXPORT folly
 265   DESTINATION share/folly
 266   NAMESPACE Folly::
 267   FILE folly-targets.cmake
 268 )
 269
 270 # We need a wrapper config file to do the find_package calls to ensure
 271 # that all our dependencies are available to link against.
 272 file(
 273   COPY ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-deps.cmake
 274   DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/
 275 )
 276 file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake "\ninclude(folly-targets.cmake)\n")
 277 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake DESTINATION share/folly RENAME folly-config.cmake)
 278
 279 option(BUILD_TESTS "If enabled, compile the tests." OFF)
 280 option(BUILD_BROKEN_TESTS "If enabled, compile tests that are known to be broken." OFF)
 281 option(BUILD_HANGING_TESTS "If enabled, compile tests that are known to hang." OFF)
 282 option(BUILD_SLOW_TESTS "If enabled, compile tests that take a while to run in debug mode." OFF)
 283 if (BUILD_TESTS)
 284   find_package(GMock MODULE REQUIRED)
 285
 286   add_library(folly_test_support
 287     ${FOLLY_DIR}/test/DeterministicSchedule.cpp
 288     ${FOLLY_DIR}/test/DeterministicSchedule.h
 289     ${FOLLY_DIR}/test/SingletonTestStructs.cpp
 290     ${FOLLY_DIR}/test/SocketAddressTestHelper.cpp
 291     ${FOLLY_DIR}/test/SocketAddressTestHelper.h
 292     ${FOLLY_DIR}/experimental/logging/test/TestLogHandler.h
 293     ${FOLLY_DIR}/futures/test/TestExecutor.cpp
 294     ${FOLLY_DIR}/futures/test/TestExecutor.h
 295     ${FOLLY_DIR}/io/async/test/BlockingSocket.h
 296     ${FOLLY_DIR}/io/async/test/MockAsyncServerSocket.h
 297     ${FOLLY_DIR}/io/async/test/MockAsyncSocket.h
 298     ${FOLLY_DIR}/io/async/test/MockAsyncSSLSocket.h
 299     ${FOLLY_DIR}/io/async/test/MockAsyncTransport.h
 300     ${FOLLY_DIR}/io/async/test/MockAsyncUDPSocket.h
 301     ${FOLLY_DIR}/io/async/test/MockTimeoutManager.h
 302     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.cpp
 303     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.h
 304     ${FOLLY_DIR}/io/async/test/SocketPair.cpp
 305     ${FOLLY_DIR}/io/async/test/SocketPair.h
 306     ${FOLLY_DIR}/io/async/test/TestSSLServer.cpp
 307     ${FOLLY_DIR}/io/async/test/TestSSLServer.h
 308     ${FOLLY_DIR}/io/async/test/TimeUtil.cpp
 309     ${FOLLY_DIR}/io/async/test/TimeUtil.h
 310     ${FOLLY_DIR}/io/async/test/UndelayedDestruction.h
 311     ${FOLLY_DIR}/io/async/test/Util.h
 312   )
 313   target_compile_definitions(folly_test_support
 314     PUBLIC
 315       ${LIBGMOCK_DEFINES}
 316   )
 317   target_include_directories(folly_test_support
 318     PUBLIC
 319       ${LIBGMOCK_INCLUDE_DIR}
 320   )
 321   target_link_libraries(folly_test_support
 322     PUBLIC
 323       Boost::thread
 324       folly
 325       ${LIBGMOCK_LIBRARY}
 326   )
 327   apply_folly_compile_options_to_target(folly_test_support)
 328
 329   folly_define_tests(
 330     DIRECTORY compression/test/
 331       TEST compression_test SOURCES CompressionTest.cpp
 332
 333     DIRECTORY container/test/
 334       TEST array_test SOURCES ArrayTest.cpp
 335       TEST enumerate_test SOURCES EnumerateTest.cpp
 336       TEST evicting_cache_map_test SOURCES EvictingCacheMapTest.cpp
 337       TEST foreach_test SOURCES ForeachTest.cpp
 338       TEST merge_test SOURCES MergeTest.cpp
 339       TEST sparse_byte_set_test SOURCES SparseByteSetTest.cpp
 340
 341     DIRECTORY concurrency/test/
 342       TEST cache_locality_test SOURCES CacheLocalityTest.cpp
 343
 344     DIRECTORY executors/test/
 345       TEST async_helpers_test SOURCES AsyncTest.cpp
 346       TEST codel_test SOURCES CodelTest.cpp
 347       TEST executor_test SOURCES ExecutorTest.cpp
 348       TEST fiber_io_executor_test SOURCES FiberIOExecutorTest.cpp
 349       TEST global_executor_test SOURCES GlobalExecutorTest.cpp
 350       TEST serial_executor_test SOURCES SerialExecutorTest.cpp
 351       TEST thread_pool_executor_test SOURCES ThreadPoolExecutorTest.cpp
 352       TEST threaded_executor_test SOURCES ThreadedExecutorTest.cpp
 353
 354     DIRECTORY executors/task_queue/test/
 355       TEST unbounded_blocking_queue_test SOURCES UnboundedBlockingQueueTest.cpp
 356
 357     DIRECTORY experimental/test/
 358       TEST autotimer_test SOURCES AutoTimerTest.cpp
 359       TEST bits_test_2 SOURCES BitsTest.cpp
 360       TEST bitvector_test SOURCES BitVectorCodingTest.cpp
 361       TEST dynamic_parser_test SOURCES DynamicParserTest.cpp
 362       TEST eliasfano_test SOURCES EliasFanoCodingTest.cpp
 363       TEST event_count_test SOURCES EventCountTest.cpp
 364       TEST function_scheduler_test_2 SOURCES FunctionSchedulerTest.cpp
 365       TEST future_dag_test SOURCES FutureDAGTest.cpp
 366       TEST json_schema_test SOURCES JSONSchemaTest.cpp
 367       TEST lock_free_ring_buffer_test SOURCES LockFreeRingBufferTest.cpp
 368       #TEST nested_command_line_app_test SOURCES NestedCommandLineAppTest.cpp
 369       #TEST program_options_test SOURCES ProgramOptionsTest.cpp
 370       # Depends on liburcu
 371       #TEST read_mostly_shared_ptr_test SOURCES ReadMostlySharedPtrTest.cpp
 372       #TEST ref_count_test SOURCES RefCountTest.cpp
 373       TEST stringkeyed_test SOURCES StringKeyedTest.cpp
 374       TEST test_util_test SOURCES TestUtilTest.cpp
 375       TEST tuple_ops_test SOURCES TupleOpsTest.cpp
 376
 377     DIRECTORY experimental/io/test/
 378       # Depends on libaio
 379       #TEST async_io_test SOURCES AsyncIOTest.cpp
 380       TEST fs_util_test SOURCES FsUtilTest.cpp
 381
 382     DIRECTORY experimental/logging/test/
 383       TEST async_file_writer_test SOURCES AsyncFileWriterTest.cpp
 384       TEST glog_formatter_test SOURCES GlogFormatterTest.cpp
 385       TEST immediate_file_writer_test SOURCES ImmediateFileWriterTest.cpp
 386       TEST log_category_test SOURCES LogCategoryTest.cpp
 387       TEST logger_db_test SOURCES LoggerDBTest.cpp
 388       TEST logger_test SOURCES LoggerTest.cpp
 389       TEST log_level_test SOURCES LogLevelTest.cpp
 390       TEST log_message_test SOURCES LogMessageTest.cpp
 391       TEST log_name_test SOURCES LogNameTest.cpp
 392       TEST log_stream_test SOURCES LogStreamTest.cpp
 393       TEST printf_test SOURCES PrintfTest.cpp
 394       TEST rate_limiter_test SOURCES RateLimiterTest.cpp
 395       TEST standard_log_handler_test SOURCES StandardLogHandlerTest.cpp
 396       TEST xlog_test
 397         HEADERS
 398           XlogHeader1.h
 399           XlogHeader2.h
 400         SOURCES
 401           XlogFile1.cpp
 402           XlogFile2.cpp
 403           XlogTest.cpp
 404
 405     DIRECTORY fibers/test/
 406       TEST fibers_test SOURCES FibersTest.cpp
 407
 408     DIRECTORY functional/test/
 409       TEST apply_tuple_test SOURCES ApplyTupleTest.cpp
 410       TEST partial_test SOURCES PartialTest.cpp
 411
 412     DIRECTORY futures/test/
 413       TEST barrier_test SOURCES BarrierTest.cpp
 414       TEST callback_lifetime_test SOURCES CallbackLifetimeTest.cpp
 415       TEST collect_test SOURCES CollectTest.cpp
 416       TEST context_test SOURCES ContextTest.cpp
 417       TEST core_test SOURCES CoreTest.cpp
 418       TEST ensure_test SOURCES EnsureTest.cpp
 419       TEST fsm_test SOURCES FSMTest.cpp
 420       TEST filter_test SOURCES FilterTest.cpp
 421       TEST future_splitter_test SOURCES FutureSplitterTest.cpp
 422       # MSVC SFINAE bug
 423       #TEST future_test SOURCES FutureTest.cpp
 424       TEST header_compile_test SOURCES HeaderCompileTest.cpp
 425       TEST interrupt_test SOURCES InterruptTest.cpp
 426       TEST map_test SOURCES MapTest.cpp
 427       TEST non_copyable_lambda_test SOURCES NonCopyableLambdaTest.cpp
 428       TEST poll_test SOURCES PollTest.cpp
 429       TEST promise_test SOURCES PromiseTest.cpp
 430       TEST reduce_test SOURCES ReduceTest.cpp
 431       # MSVC SFINAE bug
 432       #TEST retrying_test SOURCES RetryingTest.cpp
 433       TEST self_destruct_test SOURCES SelfDestructTest.cpp
 434       TEST shared_promise_test SOURCES SharedPromiseTest.cpp
 435       TEST test_executor_test SOURCES TestExecutorTest.cpp
 436       TEST then_compile_test
 437         HEADERS
 438           ThenCompileTest.h
 439         SOURCES
 440           ThenCompileTest.cpp
 441       TEST then_test SOURCES ThenTest.cpp
 442       TEST timekeeper_test SOURCES TimekeeperTest.cpp
 443       TEST times_test SOURCES TimesTest.cpp
 444       TEST unwrap_test SOURCES UnwrapTest.cpp
 445       TEST via_test SOURCES ViaTest.cpp
 446       TEST wait_test SOURCES WaitTest.cpp
 447       TEST when_test SOURCES WhenTest.cpp
 448       TEST while_do_test SOURCES WhileDoTest.cpp
 449       TEST will_equal_test SOURCES WillEqualTest.cpp
 450       TEST window_test SOURCES WindowTest.cpp
 451
 452     DIRECTORY gen/test/
 453       # MSVC bug can't resolve initializer_list constructor properly
 454       #TEST base_test SOURCES BaseTest.cpp
 455       TEST combine_test SOURCES CombineTest.cpp
 456       TEST parallel_map_test SOURCES ParallelMapTest.cpp
 457       TEST parallel_test SOURCES ParallelTest.cpp
 458
 459     DIRECTORY hash/test/
 460       TEST checksum_test SOURCES ChecksumTest.cpp
 461       TEST hash_test SOURCES HashTest.cpp
 462       TEST spooky_hash_v1_test SOURCES SpookyHashV1Test.cpp
 463       TEST spooky_hash_v2_test SOURCES SpookyHashV2Test.cpp
 464
 465     DIRECTORY io/test/
 466       TEST iobuf_test SOURCES IOBufTest.cpp
 467       TEST iobuf_cursor_test SOURCES IOBufCursorTest.cpp
 468       TEST iobuf_queue_test SOURCES IOBufQueueTest.cpp
 469       TEST record_io_test SOURCES RecordIOTest.cpp
 470       TEST ShutdownSocketSetTest HANGING
 471         SOURCES ShutdownSocketSetTest.cpp
 472
 473     DIRECTORY io/async/test/
 474       TEST async_test
 475         CONTENT_DIR certs/
 476         HEADERS
 477           AsyncSocketTest.h
 478           AsyncSSLSocketTest.h
 479         SOURCES
 480           AsyncPipeTest.cpp
 481           AsyncSocketExceptionTest.cpp
 482           AsyncSocketTest.cpp
 483           AsyncSocketTest2.cpp
 484           AsyncSSLSocketTest.cpp
 485           AsyncSSLSocketTest2.cpp
 486           AsyncSSLSocketWriteTest.cpp
 487           AsyncTransportTest.cpp
 488           # This is disabled because it depends on things that don't exist
 489           # on Windows.
 490           #EventHandlerTest.cpp
 491           # The async signal handler is not supported on Windows.
 492           #AsyncSignalHandlerTest.cpp
 493       TEST async_timeout_test SOURCES AsyncTimeoutTest.cpp
 494       TEST AsyncUDPSocketTest SOURCES AsyncUDPSocketTest.cpp
 495       TEST DelayedDestructionTest SOURCES DelayedDestructionTest.cpp
 496       TEST DelayedDestructionBaseTest SOURCES DelayedDestructionBaseTest.cpp
 497       TEST DestructorCheckTest SOURCES DestructorCheckTest.cpp
 498       TEST EventBaseTest SOURCES EventBaseTest.cpp
 499       TEST EventBaseLocalTest SOURCES EventBaseLocalTest.cpp
 500       TEST HHWheelTimerTest SOURCES HHWheelTimerTest.cpp
 501       TEST HHWheelTimerSlowTests SLOW
 502         SOURCES HHWheelTimerSlowTests.cpp
 503       TEST NotificationQueueTest SOURCES NotificationQueueTest.cpp
 504       TEST RequestContextTest SOURCES RequestContextTest.cpp
 505       TEST ScopedEventBaseThreadTest SOURCES ScopedEventBaseThreadTest.cpp
 506       TEST ssl_session_test SOURCES SSLSessionTest.cpp
 507       TEST writechain_test SOURCES WriteChainAsyncTransportWrapperTest.cpp
 508
 509     DIRECTORY io/async/ssl/test/
 510       TEST ssl_errors_test SOURCES SSLErrorsTest.cpp
 511
 512     DIRECTORY memory/test/
 513       TEST arena_test SOURCES ArenaTest.cpp
 514       TEST thread_cached_arena_test SOURCES ThreadCachedArenaTest.cpp
 515       TEST mallctl_helper_test SOURCES MallctlHelperTest.cpp
 516
 517     DIRECTORY portability/test/
 518       TEST constexpr_test SOURCES ConstexprTest.cpp
 519       TEST libgen-test SOURCES LibgenTest.cpp
 520       TEST openssl_portability_test SOURCES OpenSSLPortabilityTest.cpp
 521       TEST time-test SOURCES TimeTest.cpp
 522
 523     DIRECTORY ssl/test/
 524       TEST openssl_hash_test SOURCES OpenSSLHashTest.cpp
 525
 526     DIRECTORY stats/test/
 527       TEST histogram_test SOURCES HistogramTest.cpp
 528       TEST timeseries_histogram_test SOURCES TimeseriesHistogramTest.cpp
 529       TEST timeseries_test SOURCES TimeseriesTest.cpp
 530
 531     DIRECTORY synchronization/test/
 532       TEST call_once_test SOURCES CallOnceTest.cpp
 533       TEST lifo_sem_test SOURCES LifoSemTests.cpp
 534
 535     DIRECTORY system/test/
 536       TEST memory_mapping_test SOURCES MemoryMappingTest.cpp
 537       TEST shell_test SOURCES ShellTest.cpp
 538       #TEST subprocess_test SOURCES SubprocessTest.cpp
 539       TEST thread_id_test SOURCES ThreadIdTest.cpp
 540       TEST thread_name_test SOURCES ThreadNameTest.cpp
 541
 542     DIRECTORY test/
 543       TEST ahm_int_stress_test SOURCES AHMIntStressTest.cpp
 544       TEST arena_smartptr_test SOURCES ArenaSmartPtrTest.cpp
 545       TEST ascii_check_test SOURCES AsciiCaseInsensitiveTest.cpp
 546       TEST atomic_bit_set_test SOURCES AtomicBitSetTest.cpp
 547       TEST atomic_hash_array_test SOURCES AtomicHashArrayTest.cpp
 548       TEST atomic_hash_map_test HANGING
 549         SOURCES AtomicHashMapTest.cpp
 550       TEST atomic_linked_list_test SOURCES AtomicLinkedListTest.cpp
 551       TEST atomic_struct_test SOURCES AtomicStructTest.cpp
 552       TEST atomic_unordered_map_test SOURCES AtomicUnorderedMapTest.cpp
 553       TEST baton_test SOURCES BatonTest.cpp
 554       TEST bit_iterator_test SOURCES BitIteratorTest.cpp
 555       TEST bits_test SOURCES BitsTest.cpp
 556       TEST cacheline_padded_test SOURCES CachelinePaddedTest.cpp
 557       TEST clock_gettime_wrappers_test SOURCES ClockGettimeWrappersTest.cpp
 558       TEST concurrent_skip_list_test SOURCES ConcurrentSkipListTest.cpp
 559       TEST container_traits_test SOURCES ContainerTraitsTest.cpp
 560       TEST conv_test SOURCES ConvTest.cpp
 561       TEST cpu_id_test SOURCES CpuIdTest.cpp
 562       TEST demangle_test SOURCES DemangleTest.cpp
 563       TEST deterministic_schedule_test SOURCES DeterministicScheduleTest.cpp
 564       TEST discriminated_ptr_test SOURCES DiscriminatedPtrTest.cpp
 565       TEST dynamic_test SOURCES DynamicTest.cpp
 566       TEST dynamic_converter_test SOURCES DynamicConverterTest.cpp
 567       TEST dynamic_other_test SOURCES DynamicOtherTest.cpp
 568       TEST endian_test SOURCES EndianTest.cpp
 569       TEST exception_test SOURCES ExceptionTest.cpp
 570       TEST exception_wrapper_test SOURCES ExceptionWrapperTest.cpp
 571       TEST expected_test SOURCES ExpectedTest.cpp
 572       TEST fbvector_test SOURCES FBVectorTest.cpp
 573       TEST file_test SOURCES FileTest.cpp
 574       #TEST file_lock_test SOURCES FileLockTest.cpp
 575       TEST file_util_test HANGING
 576         SOURCES FileUtilTest.cpp
 577       TEST fingerprint_test SOURCES FingerprintTest.cpp
 578       TEST format_other_test SOURCES FormatOtherTest.cpp
 579       TEST format_test SOURCES FormatTest.cpp
 580       TEST function_scheduler_test SOURCES FunctionSchedulerTest.cpp
 581       TEST function_test BROKEN
 582         SOURCES FunctionTest.cpp
 583       TEST function_ref_test SOURCES FunctionRefTest.cpp
 584       TEST futex_test SOURCES FutexTest.cpp
 585       TEST group_varint_test SOURCES GroupVarintTest.cpp
 586       TEST group_varint_test_ssse3 SOURCES GroupVarintTest.cpp
 587       TEST has_member_fn_traits_test SOURCES HasMemberFnTraitsTest.cpp
 588       TEST indestructible_test SOURCES IndestructibleTest.cpp
 589       TEST indexed_mem_pool_test BROKEN
 590         SOURCES IndexedMemPoolTest.cpp
 591       # MSVC Preprocessor stringizing raw string literals bug
 592       #TEST json_test SOURCES JsonTest.cpp
 593       TEST json_other_test
 594         CONTENT_DIR json_test_data/
 595         SOURCES
 596           JsonOtherTest.cpp
 597       TEST lazy_test SOURCES LazyTest.cpp
 598       TEST lock_traits_test SOURCES LockTraitsTest.cpp
 599       TEST locks_test SOURCES SmallLocksTest.cpp SpinLockTest.cpp
 600       TEST logging_test SOURCES LoggingTest.cpp
 601       TEST math_test SOURCES MathTest.cpp
 602       TEST map_util_test SOURCES MapUtilTest.cpp
 603       TEST memcpy_test SOURCES MemcpyTest.cpp
 604       TEST memory_idler_test SOURCES MemoryIdlerTest.cpp
 605       TEST memory_test SOURCES MemoryTest.cpp
 606       TEST move_wrapper_test SOURCES MoveWrapperTest.cpp
 607       TEST mpmc_pipeline_test SOURCES MPMCPipelineTest.cpp
 608       TEST mpmc_queue_test SLOW
 609         SOURCES MPMCQueueTest.cpp
 610       TEST network_address_test HANGING
 611         SOURCES
 612           IPAddressTest.cpp
 613           MacAddressTest.cpp
 614           SocketAddressTest.cpp
 615       TEST optional_test SOURCES OptionalTest.cpp
 616       TEST packed_sync_ptr_test HANGING
 617         SOURCES PackedSyncPtrTest.cpp
 618       TEST padded_test SOURCES PaddedTest.cpp
 619       #TEST poly_test SOURCES PolyTest.cpp
 620       TEST portability_test SOURCES PortabilityTest.cpp
 621       TEST producer_consumer_queue_test SLOW
 622         SOURCES ProducerConsumerQueueTest.cpp
 623       TEST r_w_spin_lock_test SOURCES RWSpinLockTest.cpp
 624       TEST random_test SOURCES RandomTest.cpp
 625       TEST range_test SOURCES RangeTest.cpp
 626       TEST safe_assert_test SOURCES SafeAssertTest.cpp
 627       TEST scope_guard_test SOURCES ScopeGuardTest.cpp
 628       # Heavily dependent on drand and srand48
 629       #TEST shared_mutex_test SOURCES SharedMutexTest.cpp
 630       TEST singleton_test SOURCES SingletonTest.cpp
 631       TEST singleton_test_global SOURCES SingletonTestGlobal.cpp
 632       TEST singleton_thread_local_test SOURCES SingletonThreadLocalTest.cpp
 633       TEST singletonvault_c_test SOURCES SingletonVaultCTest.cpp
 634       TEST small_vector_test SOURCES small_vector_test.cpp
 635       TEST sorted_vector_types_test SOURCES sorted_vector_test.cpp
 636       TEST string_test SOURCES StringTest.cpp
 637       TEST synchronized_test SOURCES SynchronizedTest.cpp
 638       TEST thread_cached_int_test SOURCES ThreadCachedIntTest.cpp
 639       TEST thread_local_test SOURCES ThreadLocalTest.cpp
 640       TEST timeout_queue_test SOURCES TimeoutQueueTest.cpp
 641       TEST token_bucket_test SOURCES TokenBucketTest.cpp
 642       TEST traits_test SOURCES TraitsTest.cpp
 643       TEST try_test SOURCES TryTest.cpp
 644       TEST unit_test SOURCES UnitTest.cpp
 645       TEST uri_test SOURCES UriTest.cpp
 646       TEST varint_test SOURCES VarintTest.cpp
 647   )
 648 endif()