CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.0 FATAL_ERROR)
   2
   3 # includes
   4 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake" ${CMAKE_MODULE_PATH})
   5 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
   6
   7 # package information
   8 set(PACKAGE_NAME      "folly")
   9 set(PACKAGE_VERSION   "0.58.0-dev")
  10 set(PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  11 set(PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
  12 set(PACKAGE_BUGREPORT "https://github.com/facebook/folly/issues")
  13
  14 # 150+ tests in the root folder anyone? No? I didn't think so.
  15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  16
  17 project(${PACKAGE_NAME} CXX)
  18
  19 if (MSVC_VERSION EQUAL 1910 OR MSVC_VERSION EQUAL 1911)
  20   set(MSVC_IS_2017 ON)
  21 elseif (MSVC_VERSION EQUAL 1900)
  22   set(MSVC_IS_2017 OFF)
  23 else()
  24   message(FATAL_ERROR "This build script only supports building '${MSVC_VERSION}' Folly on 64-bit Windows with Visual Studio 2015 or Visual Studio 2017.")
  25 endif()
  26
  27 # Check architecture OS
  28 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
  29   message(FATAL_ERROR "Folly requires a 64bit OS")
  30 endif()
  31 if(NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
  32   message(FATAL_ERROR "You should only be using CMake to build Folly if you are on Windows!")
  33 endif()
  34
  35 set(FOLLY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/folly")
  36
  37 # Generate a few tables and create the main config file.
  38 find_package(PythonInterp REQUIRED)
  39 add_custom_command(
  40   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
  41   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_escape_tables.py"
  42   DEPENDS ${FOLLY_DIR}/build/generate_escape_tables.py
  43   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  44   COMMENT "Generating the escape tables..." VERBATIM
  45 )
  46 add_custom_command(
  47   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
  48   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_format_tables.py"
  49   DEPENDS ${FOLLY_DIR}/build/generate_format_tables.py
  50   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  51   COMMENT "Generating the format tables..." VERBATIM
  52 )
  53 add_custom_command(
  54   OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp"
  55   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_varint_tables.py"
  56   DEPENDS ${FOLLY_DIR}/build/generate_varint_tables.py
  57   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  58   COMMENT "Generating the group varint tables..." VERBATIM
  59 )
  60
  61 include(folly-deps) # Find the required packages
  62 if (LIBPTHREAD_FOUND)
  63   set(FOLLY_HAVE_PTHREAD ON)
  64 endif()
  65 configure_file(
  66   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-config.h.cmake
  67   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
  68 )
  69
  70 include(FollyCompiler)
  71 include(FollyFunctions)
  72
  73 # Main folly library files
  74 auto_sources(files "*.cpp" "RECURSE" "${FOLLY_DIR}")
  75 auto_sources(hfiles "*.h" "RECURSE" "${FOLLY_DIR}")
  76
  77 # No need for tests or benchmarks, and we can't build most experimental stuff.
  78 REMOVE_MATCHES_FROM_LISTS(files hfiles
  79   MATCHES
  80     "/build/"
  81     "/experimental/exception_tracer/"
  82     "/experimental/hazptr/bench/"
  83     "/experimental/hazptr/example/"
  84     "/experimental/logging/example/"
  85     "/experimental/symbolizer/"
  86     "/futures/exercises/"
  87     "/test/"
  88     "Benchmark.cpp$"
  89     "Test.cpp$"
  90   IGNORE_MATCHES
  91     "/Benchmark.cpp$"
  92 )
  93 list(REMOVE_ITEM files
  94   ${FOLLY_DIR}/Subprocess.cpp
  95   ${FOLLY_DIR}/SingletonStackTrace.cpp
  96   ${FOLLY_DIR}/experimental/JSONSchemaTester.cpp
  97   ${FOLLY_DIR}/experimental/RCUUtils.cpp
  98   ${FOLLY_DIR}/experimental/io/AsyncIO.cpp
  99   ${FOLLY_DIR}/experimental/io/HugePageUtil.cpp
 100   ${FOLLY_DIR}/futures/test/Benchmark.cpp
 101 )
 102 list(REMOVE_ITEM hfiles
 103   ${FOLLY_DIR}/Fingerprint.h
 104   ${FOLLY_DIR}/detail/SlowFingerprint.h
 105   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 106   ${FOLLY_DIR}/experimental/RCURefCount.h
 107   ${FOLLY_DIR}/experimental/RCUUtils.h
 108   ${FOLLY_DIR}/experimental/io/AsyncIO.h
 109 )
 110
 111 add_library(folly_base OBJECT
 112   ${files} ${hfiles}
 113   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
 114   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
 115   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
 116   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
 117 )
 118 auto_source_group(folly ${FOLLY_DIR} ${files} ${hfiles})
 119 apply_folly_compile_options_to_target(folly_base)
 120 target_include_directories(folly_base PUBLIC ${CMAKE_CURRENT_BINARY_DIR})
 121 # Add the generated files to the correct source group.
 122 source_group("folly" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h)
 123 source_group("folly\\build" FILES
 124   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
 125   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 126   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
 127   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
 128 )
 129
 130 set(FOLLY_SHINY_DEPENDENCIES
 131   Boost::chrono
 132   Boost::context
 133   Boost::date_time
 134   Boost::filesystem
 135   Boost::program_options
 136   Boost::regex
 137   Boost::system
 138   OpenSSL::SSL
 139   OpenSSL::Crypto
 140 )
 141
 142 set(FOLLY_LINK_LIBRARIES
 143   ${DOUBLE_CONVERSION_LIBRARY}
 144   ${LIBEVENT_LIB}
 145   ${LIBGFLAGS_LIBRARY}
 146   ${LIBGLOG_LIBRARY}
 147   Iphlpapi.lib
 148   Ws2_32.lib
 149
 150   ${FOLLY_SHINY_DEPENDENCIES}
 151 )
 152
 153 target_include_directories(folly_base
 154   PUBLIC
 155     ${DOUBLE_CONVERSION_INCLUDE_DIR}
 156     ${LIBGFLAGS_INCLUDE_DIR}
 157     ${LIBGLOG_INCLUDE_DIR}
 158     ${LIBEVENT_INCLUDE_DIR}
 159     $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
 160 )
 161
 162 foreach (LIB ${FOLLY_SHINY_DEPENDENCIES})
 163   target_include_directories(folly_base PUBLIC $<TARGET_PROPERTY:${LIB},INCLUDE_DIRECTORIES>)
 164 endforeach()
 165
 166 if (FOLLY_HAVE_PTHREAD)
 167   target_include_directories(folly_base PUBLIC ${LIBPTHREAD_INCLUDE_DIRS})
 168   list(APPEND FOLLY_LINK_LIBRARIES ${LIBPTHREAD_LIBRARIES})
 169 endif()
 170
 171 # Now to generate the fingerprint tables
 172 add_executable(GenerateFingerprintTables
 173   ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp
 174   $<TARGET_OBJECTS:folly_base>
 175 )
 176 target_link_libraries(GenerateFingerprintTables PRIVATE ${FOLLY_LINK_LIBRARIES})
 177 target_include_directories(GenerateFingerprintTables PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 178 add_dependencies(GenerateFingerprintTables folly_base)
 179 apply_folly_compile_options_to_target(GenerateFingerprintTables)
 180 set_property(TARGET GenerateFingerprintTables PROPERTY FOLDER "Build")
 181 source_group("" FILES ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp)
 182
 183 # Compile the fingerprint tables.
 184 add_custom_command(
 185   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 186   COMMAND GenerateFingerprintTables
 187   DEPENDS GenerateFingerprintTables
 188   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
 189   COMMENT "Generating the fingerprint tables..."
 190 )
 191 add_library(folly_fingerprint STATIC
 192   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 193   ${FOLLY_DIR}/Fingerprint.h
 194   ${FOLLY_DIR}/detail/SlowFingerprint.h
 195   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 196   $<TARGET_OBJECTS:folly_base>
 197 )
 198 target_link_libraries(folly_fingerprint PRIVATE ${FOLLY_LINK_LIBRARIES})
 199 target_include_directories(folly_fingerprint PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 200 add_dependencies(folly_fingerprint folly_base)
 201 apply_folly_compile_options_to_target(folly_fingerprint)
 202
 203 # We want to generate a single library and target for folly, but we needed a
 204 # two-stage compile for the fingerprint tables, so we create a phony source
 205 # file that we modify whenever the base libraries change, causing folly to be
 206 # re-linked, making things happy.
 207 add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
 208   COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
 209   DEPENDS folly_base folly_fingerprint
 210 )
 211 add_library(folly ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp $<TARGET_OBJECTS:folly_base>)
 212 apply_folly_compile_options_to_target(folly)
 213 source_group("" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
 214
 215 target_link_libraries(folly PUBLIC ${FOLLY_LINK_LIBRARIES})
 216 target_include_directories(folly PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 217
 218 install(TARGETS folly
 219   EXPORT folly
 220   RUNTIME DESTINATION bin
 221   LIBRARY DESTINATION lib
 222   ARCHIVE DESTINATION lib)
 223 auto_install_files(folly ${FOLLY_DIR}
 224   ${hfiles}
 225   ${FOLLY_DIR}/Fingerprint.h
 226   ${FOLLY_DIR}/detail/SlowFingerprint.h
 227   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 228 )
 229 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h DESTINATION include/folly)
 230 install(
 231   EXPORT folly
 232   DESTINATION share/folly
 233   NAMESPACE Folly::
 234   FILE folly-targets.cmake
 235 )
 236
 237 # We need a wrapper config file to do the find_package calls to ensure
 238 # that all our dependencies are available to link against.
 239 file(
 240   COPY ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-deps.cmake
 241   DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/
 242 )
 243 file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake "\ninclude(folly-targets.cmake)\n")
 244 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake DESTINATION share/folly RENAME folly-config.cmake)
 245
 246 option(BUILD_TESTS "If enabled, compile the tests." OFF)
 247 option(BUILD_BROKEN_TESTS "If enabled, compile tests that are known to be broken." OFF)
 248 option(BUILD_HANGING_TESTS "If enabled, compile tests that are known to hang." OFF)
 249 option(BUILD_SLOW_TESTS "If enabled, compile tests that take a while to run in debug mode." OFF)
 250 if (BUILD_TESTS)
 251   find_package(GMock MODULE REQUIRED)
 252
 253   add_library(folly_test_support
 254     ${FOLLY_DIR}/test/DeterministicSchedule.cpp
 255     ${FOLLY_DIR}/test/DeterministicSchedule.h
 256     ${FOLLY_DIR}/test/SingletonTestStructs.cpp
 257     ${FOLLY_DIR}/test/SocketAddressTestHelper.cpp
 258     ${FOLLY_DIR}/test/SocketAddressTestHelper.h
 259     ${FOLLY_DIR}/experimental/logging/test/TestLogHandler.h
 260     ${FOLLY_DIR}/futures/test/TestExecutor.cpp
 261     ${FOLLY_DIR}/futures/test/TestExecutor.h
 262     ${FOLLY_DIR}/io/async/test/BlockingSocket.h
 263     ${FOLLY_DIR}/io/async/test/MockAsyncServerSocket.h
 264     ${FOLLY_DIR}/io/async/test/MockAsyncSocket.h
 265     ${FOLLY_DIR}/io/async/test/MockAsyncSSLSocket.h
 266     ${FOLLY_DIR}/io/async/test/MockAsyncTransport.h
 267     ${FOLLY_DIR}/io/async/test/MockAsyncUDPSocket.h
 268     ${FOLLY_DIR}/io/async/test/MockTimeoutManager.h
 269     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.cpp
 270     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.h
 271     ${FOLLY_DIR}/io/async/test/SocketPair.cpp
 272     ${FOLLY_DIR}/io/async/test/SocketPair.h
 273     ${FOLLY_DIR}/io/async/test/TestSSLServer.cpp
 274     ${FOLLY_DIR}/io/async/test/TestSSLServer.h
 275     ${FOLLY_DIR}/io/async/test/TimeUtil.cpp
 276     ${FOLLY_DIR}/io/async/test/TimeUtil.h
 277     ${FOLLY_DIR}/io/async/test/UndelayedDestruction.h
 278     ${FOLLY_DIR}/io/async/test/Util.h
 279   )
 280   target_compile_definitions(folly_test_support
 281     PUBLIC
 282       ${LIBGMOCK_DEFINES}
 283   )
 284   target_include_directories(folly_test_support
 285     PUBLIC
 286       ${LIBGMOCK_INCLUDE_DIR}
 287   )
 288   target_link_libraries(folly_test_support
 289     PUBLIC
 290       Boost::thread
 291       folly
 292       ${LIBGMOCK_LIBRARY}
 293   )
 294   apply_folly_compile_options_to_target(folly_test_support)
 295
 296   folly_define_tests(
 297     DIRECTORY compression/test/
 298       TEST compression_test SOURCES CompressionTest.cpp
 299
 300     DIRECTORY concurrency/test/
 301       TEST cache_locality_test SOURCES CacheLocalityTest.cpp
 302
 303       DIRECTORY executors/test/
 304       TEST async_helpers_test SOURCES AsyncTest.cpp
 305       TEST codel_test SOURCES CodelTest.cpp
 306       TEST fiber_io_executor_test SOURCES FiberIOExecutorTest.cpp
 307       TEST global_executor_test SOURCES GlobalExecutorTest.cpp
 308       TEST serial_executor_test SOURCES SerialExecutorTest.cpp
 309       TEST thread_pool_executor_test SOURCES ThreadPoolExecutorTest.cpp
 310       TEST threaded_executor_test SOURCES ThreadedExecutorTest.cpp
 311       TEST unbounded_blocking_queue_test SOURCES UnboundedBlockingQueueTest.cpp
 312
 313     DIRECTORY experimental/test/
 314       TEST autotimer_test SOURCES AutoTimerTest.cpp
 315       TEST bits_test_2 SOURCES BitsTest.cpp
 316       TEST bitvector_test SOURCES BitVectorCodingTest.cpp
 317       TEST dynamic_parser_test SOURCES DynamicParserTest.cpp
 318       TEST eliasfano_test SOURCES EliasFanoCodingTest.cpp
 319       TEST event_count_test SOURCES EventCountTest.cpp
 320       TEST function_scheduler_test_2 SOURCES FunctionSchedulerTest.cpp
 321       TEST future_dag_test SOURCES FutureDAGTest.cpp
 322       TEST json_schema_test SOURCES JSONSchemaTest.cpp
 323       TEST lock_free_ring_buffer_test SOURCES LockFreeRingBufferTest.cpp
 324       #TEST nested_command_line_app_test SOURCES NestedCommandLineAppTest.cpp
 325       #TEST program_options_test SOURCES ProgramOptionsTest.cpp
 326       # Depends on liburcu
 327       #TEST read_mostly_shared_ptr_test SOURCES ReadMostlySharedPtrTest.cpp
 328       #TEST ref_count_test SOURCES RefCountTest.cpp
 329       TEST stringkeyed_test SOURCES StringKeyedTest.cpp
 330       TEST test_util_test SOURCES TestUtilTest.cpp
 331       TEST tuple_ops_test SOURCES TupleOpsTest.cpp
 332
 333     DIRECTORY experimental/io/test/
 334       # Depends on libaio
 335       #TEST async_io_test SOURCES AsyncIOTest.cpp
 336       TEST fs_util_test SOURCES FsUtilTest.cpp
 337
 338     DIRECTORY experimental/logging/test/
 339       TEST async_file_writer_test SOURCES AsyncFileWriterTest.cpp
 340       TEST glog_formatter_test SOURCES GlogFormatterTest.cpp
 341       TEST immediate_file_writer_test SOURCES ImmediateFileWriterTest.cpp
 342       TEST log_category_test SOURCES LogCategoryTest.cpp
 343       TEST logger_db_test SOURCES LoggerDBTest.cpp
 344       TEST logger_test SOURCES LoggerTest.cpp
 345       TEST log_level_test SOURCES LogLevelTest.cpp
 346       TEST log_message_test SOURCES LogMessageTest.cpp
 347       TEST log_name_test SOURCES LogNameTest.cpp
 348       TEST log_stream_test SOURCES LogStreamTest.cpp
 349       TEST printf_test SOURCES PrintfTest.cpp
 350       TEST rate_limiter_test SOURCES RateLimiterTest.cpp
 351       TEST standard_log_handler_test SOURCES StandardLogHandlerTest.cpp
 352       TEST xlog_test
 353         HEADERS
 354           XlogHeader1.h
 355           XlogHeader2.h
 356         SOURCES
 357           XlogFile1.cpp
 358           XlogFile2.cpp
 359           XlogTest.cpp
 360
 361     DIRECTORY fibers/test/
 362       TEST fibers_test SOURCES FibersTest.cpp
 363
 364     DIRECTORY functional/test/
 365       TEST apply_tuple_test SOURCES ApplyTupleTest.cpp
 366
 367     DIRECTORY futures/test/
 368       TEST barrier_test SOURCES BarrierTest.cpp
 369       TEST callback_lifetime_test SOURCES CallbackLifetimeTest.cpp
 370       TEST collect_test SOURCES CollectTest.cpp
 371       TEST context_test SOURCES ContextTest.cpp
 372       TEST core_test SOURCES CoreTest.cpp
 373       TEST ensure_test SOURCES EnsureTest.cpp
 374       TEST executor_test SOURCES ExecutorTest.cpp
 375       TEST fsm_test SOURCES FSMTest.cpp
 376       TEST filter_test SOURCES FilterTest.cpp
 377       TEST future_splitter_test SOURCES FutureSplitterTest.cpp
 378       # MSVC SFINAE bug
 379       #TEST future_test SOURCES FutureTest.cpp
 380       TEST header_compile_test SOURCES HeaderCompileTest.cpp
 381       TEST interrupt_test SOURCES InterruptTest.cpp
 382       TEST map_test SOURCES MapTest.cpp
 383       TEST non_copyable_lambda_test SOURCES NonCopyableLambdaTest.cpp
 384       TEST poll_test SOURCES PollTest.cpp
 385       TEST promise_test SOURCES PromiseTest.cpp
 386       TEST reduce_test SOURCES ReduceTest.cpp
 387       # MSVC SFINAE bug
 388       #TEST retrying_test SOURCES RetryingTest.cpp
 389       TEST self_destruct_test SOURCES SelfDestructTest.cpp
 390       TEST shared_promise_test SOURCES SharedPromiseTest.cpp
 391       TEST test_executor_test SOURCES TestExecutorTest.cpp
 392       TEST then_compile_test
 393         HEADERS
 394           ThenCompileTest.h
 395         SOURCES
 396           ThenCompileTest.cpp
 397       TEST then_test SOURCES ThenTest.cpp
 398       TEST timekeeper_test SOURCES TimekeeperTest.cpp
 399       TEST times_test SOURCES TimesTest.cpp
 400       TEST unwrap_test SOURCES UnwrapTest.cpp
 401       TEST via_test SOURCES ViaTest.cpp
 402       TEST wait_test SOURCES WaitTest.cpp
 403       TEST when_test SOURCES WhenTest.cpp
 404       TEST while_do_test SOURCES WhileDoTest.cpp
 405       TEST will_equal_test SOURCES WillEqualTest.cpp
 406       TEST window_test SOURCES WindowTest.cpp
 407
 408     DIRECTORY gen/test/
 409       # MSVC bug can't resolve initializer_list constructor properly
 410       #TEST base_test SOURCES BaseTest.cpp
 411       TEST combine_test SOURCES CombineTest.cpp
 412       TEST parallel_map_test SOURCES ParallelMapTest.cpp
 413       TEST parallel_test SOURCES ParallelTest.cpp
 414
 415     DIRECTORY hash/test/
 416       TEST spooky_hash_v1_test SOURCES SpookyHashV1Test.cpp
 417       TEST spooky_hash_v2_test SOURCES SpookyHashV2Test.cpp
 418
 419     DIRECTORY io/test/
 420       TEST iobuf_test SOURCES IOBufTest.cpp
 421       TEST iobuf_cursor_test SOURCES IOBufCursorTest.cpp
 422       TEST iobuf_queue_test SOURCES IOBufQueueTest.cpp
 423       TEST record_io_test SOURCES RecordIOTest.cpp
 424       TEST ShutdownSocketSetTest HANGING
 425         SOURCES ShutdownSocketSetTest.cpp
 426
 427     DIRECTORY io/async/test/
 428       TEST async_test
 429         CONTENT_DIR certs/
 430         HEADERS
 431           AsyncSocketTest.h
 432           AsyncSSLSocketTest.h
 433         SOURCES
 434           AsyncPipeTest.cpp
 435           AsyncSocketExceptionTest.cpp
 436           AsyncSocketTest.cpp
 437           AsyncSocketTest2.cpp
 438           AsyncSSLSocketTest.cpp
 439           AsyncSSLSocketTest2.cpp
 440           AsyncSSLSocketWriteTest.cpp
 441           AsyncTransportTest.cpp
 442           # This is disabled because it depends on things that don't exist
 443           # on Windows.
 444           #EventHandlerTest.cpp
 445           # The async signal handler is not supported on Windows.
 446           #AsyncSignalHandlerTest.cpp
 447       TEST async_timeout_test SOURCES AsyncTimeoutTest.cpp
 448       TEST AsyncUDPSocketTest SOURCES AsyncUDPSocketTest.cpp
 449       TEST DelayedDestructionTest SOURCES DelayedDestructionTest.cpp
 450       TEST DelayedDestructionBaseTest SOURCES DelayedDestructionBaseTest.cpp
 451       TEST DestructorCheckTest SOURCES DestructorCheckTest.cpp
 452       TEST EventBaseTest SOURCES EventBaseTest.cpp
 453       TEST EventBaseLocalTest SOURCES EventBaseLocalTest.cpp
 454       TEST HHWheelTimerTest SOURCES HHWheelTimerTest.cpp
 455       TEST HHWheelTimerSlowTests SLOW
 456         SOURCES HHWheelTimerSlowTests.cpp
 457       TEST NotificationQueueTest SOURCES NotificationQueueTest.cpp
 458       TEST RequestContextTest SOURCES RequestContextTest.cpp
 459       TEST ScopedEventBaseThreadTest SOURCES ScopedEventBaseThreadTest.cpp
 460       TEST ssl_session_test SOURCES SSLSessionTest.cpp
 461       TEST writechain_test SOURCES WriteChainAsyncTransportWrapperTest.cpp
 462
 463     DIRECTORY io/async/ssl/test/
 464       TEST ssl_errors_test SOURCES SSLErrorsTest.cpp
 465
 466     DIRECTORY portability/test/
 467       TEST constexpr_test SOURCES ConstexprTest.cpp
 468       TEST libgen-test SOURCES LibgenTest.cpp
 469       TEST time-test SOURCES TimeTest.cpp
 470       TEST openssl_portability_test SOURCES OpenSSLPortabilityTest.cpp
 471
 472     DIRECTORY ssl/test/
 473       TEST openssl_hash_test SOURCES OpenSSLHashTest.cpp
 474
 475     DIRECTORY stats/test/
 476       TEST histogram_test SOURCES HistogramTest.cpp
 477       TEST timeseries_histogram_test SOURCES TimeseriesHistogramTest.cpp
 478       TEST timeseries_test SOURCES TimeseriesTest.cpp
 479
 480     DIRECTORY synchronization/test/
 481       TEST call_once_test SOURCES CallOnceTest.cpp
 482
 483     DIRECTORY system/test/
 484       TEST memory_mapping_test SOURCES MemoryMappingTest.cpp
 485       TEST shell_test SOURCES ShellTest.cpp
 486       #TEST subprocess_test SOURCES SubprocessTest.cpp
 487       TEST thread_id_test SOURCES ThreadIdTest.cpp
 488       TEST thread_name_test SOURCES ThreadNameTest.cpp
 489
 490     DIRECTORY test/
 491       TEST ahm_int_stress_test SOURCES AHMIntStressTest.cpp
 492       TEST arena_test SOURCES ArenaTest.cpp
 493       TEST arena_smartptr_test SOURCES ArenaSmartPtrTest.cpp
 494       TEST array_test SOURCES ArrayTest.cpp
 495       TEST ascii_check_test SOURCES AsciiCaseInsensitiveTest.cpp
 496       TEST atomic_bit_set_test SOURCES AtomicBitSetTest.cpp
 497       TEST atomic_hash_array_test SOURCES AtomicHashArrayTest.cpp
 498       TEST atomic_hash_map_test HANGING
 499         SOURCES AtomicHashMapTest.cpp
 500       TEST atomic_linked_list_test SOURCES AtomicLinkedListTest.cpp
 501       TEST atomic_struct_test SOURCES AtomicStructTest.cpp
 502       TEST atomic_unordered_map_test SOURCES AtomicUnorderedMapTest.cpp
 503       TEST baton_test SOURCES BatonTest.cpp
 504       TEST bit_iterator_test SOURCES BitIteratorTest.cpp
 505       TEST bits_test SOURCES BitsTest.cpp
 506       TEST cacheline_padded_test SOURCES CachelinePaddedTest.cpp
 507       TEST checksum_test SOURCES ChecksumTest.cpp
 508       TEST clock_gettime_wrappers_test SOURCES ClockGettimeWrappersTest.cpp
 509       TEST concurrent_skip_list_test SOURCES ConcurrentSkipListTest.cpp
 510       TEST container_traits_test SOURCES ContainerTraitsTest.cpp
 511       TEST conv_test SOURCES ConvTest.cpp
 512       TEST cpu_id_test SOURCES CpuIdTest.cpp
 513       TEST demangle_test SOURCES DemangleTest.cpp
 514       TEST deterministic_schedule_test SOURCES DeterministicScheduleTest.cpp
 515       TEST discriminated_ptr_test SOURCES DiscriminatedPtrTest.cpp
 516       TEST dynamic_test SOURCES DynamicTest.cpp
 517       TEST dynamic_converter_test SOURCES DynamicConverterTest.cpp
 518       TEST dynamic_other_test SOURCES DynamicOtherTest.cpp
 519       TEST endian_test SOURCES EndianTest.cpp
 520       TEST enumerate_test SOURCES EnumerateTest.cpp
 521       TEST evicting_cache_map_test SOURCES EvictingCacheMapTest.cpp
 522       TEST exception_test SOURCES ExceptionTest.cpp
 523       TEST exception_wrapper_test SOURCES ExceptionWrapperTest.cpp
 524       TEST expected_test SOURCES ExpectedTest.cpp
 525       TEST fbvector_test SOURCES FBVectorTest.cpp
 526       TEST file_test SOURCES FileTest.cpp
 527       #TEST file_lock_test SOURCES FileLockTest.cpp
 528       TEST file_util_test HANGING
 529         SOURCES FileUtilTest.cpp
 530       TEST fingerprint_test SOURCES FingerprintTest.cpp
 531       TEST foreach_test SOURCES ForeachTest.cpp
 532       TEST format_other_test SOURCES FormatOtherTest.cpp
 533       TEST format_test SOURCES FormatTest.cpp
 534       TEST function_scheduler_test SOURCES FunctionSchedulerTest.cpp
 535       TEST function_test BROKEN
 536         SOURCES FunctionTest.cpp
 537       TEST function_ref_test SOURCES FunctionRefTest.cpp
 538       TEST futex_test SOURCES FutexTest.cpp
 539       TEST group_varint_test SOURCES GroupVarintTest.cpp
 540       TEST group_varint_test_ssse3 SOURCES GroupVarintTest.cpp
 541       TEST has_member_fn_traits_test SOURCES HasMemberFnTraitsTest.cpp
 542       TEST hash_test SOURCES HashTest.cpp
 543       TEST indestructible_test SOURCES IndestructibleTest.cpp
 544       TEST indexed_mem_pool_test BROKEN
 545         SOURCES IndexedMemPoolTest.cpp
 546       # MSVC Preprocessor stringizing raw string literals bug
 547       #TEST json_test SOURCES JsonTest.cpp
 548       TEST json_other_test
 549         CONTENT_DIR json_test_data/
 550         SOURCES
 551           JsonOtherTest.cpp
 552       TEST lazy_test SOURCES LazyTest.cpp
 553       TEST lifosem_test SOURCES LifoSemTests.cpp
 554       TEST lock_traits_test SOURCES LockTraitsTest.cpp
 555       TEST locks_test SOURCES SmallLocksTest.cpp SpinLockTest.cpp
 556       TEST logging_test SOURCES LoggingTest.cpp
 557       TEST mallctl_helper_test SOURCES MallctlHelperTest.cpp
 558       TEST math_test SOURCES MathTest.cpp
 559       TEST map_util_test SOURCES MapUtilTest.cpp
 560       TEST memcpy_test SOURCES MemcpyTest.cpp
 561       TEST memory_idler_test SOURCES MemoryIdlerTest.cpp
 562       TEST memory_test SOURCES MemoryTest.cpp
 563       TEST merge SOURCES MergeTest.cpp
 564       TEST move_wrapper_test SOURCES MoveWrapperTest.cpp
 565       TEST mpmc_pipeline_test SOURCES MPMCPipelineTest.cpp
 566       TEST mpmc_queue_test SLOW
 567         SOURCES MPMCQueueTest.cpp
 568       TEST network_address_test HANGING
 569         SOURCES
 570           IPAddressTest.cpp
 571           MacAddressTest.cpp
 572           SocketAddressTest.cpp
 573       TEST optional_test SOURCES OptionalTest.cpp
 574       TEST packed_sync_ptr_test HANGING
 575         SOURCES PackedSyncPtrTest.cpp
 576       TEST padded_test SOURCES PaddedTest.cpp
 577       TEST partial_test SOURCES PartialTest.cpp
 578       TEST portability_test SOURCES PortabilityTest.cpp
 579       TEST producer_consumer_queue_test SLOW
 580         SOURCES ProducerConsumerQueueTest.cpp
 581       TEST r_w_spin_lock_test SOURCES RWSpinLockTest.cpp
 582       TEST random_test SOURCES RandomTest.cpp
 583       TEST range_test SOURCES RangeTest.cpp
 584       TEST safe_assert_test SOURCES SafeAssertTest.cpp
 585       TEST scope_guard_test SOURCES ScopeGuardTest.cpp
 586       # Heavily dependent on drand and srand48
 587       #TEST shared_mutex_test SOURCES SharedMutexTest.cpp
 588       TEST singleton_test SOURCES SingletonTest.cpp
 589       TEST singleton_test_global SOURCES SingletonTestGlobal.cpp
 590       TEST singleton_thread_local_test SOURCES SingletonThreadLocalTest.cpp
 591       TEST singletonvault_c_test SOURCES SingletonVaultCTest.cpp
 592       TEST small_vector_test SOURCES small_vector_test.cpp
 593       TEST sorted_vector_types_test SOURCES sorted_vector_test.cpp
 594       TEST sparse_byte_set_test SOURCES SparseByteSetTest.cpp
 595       TEST string_test SOURCES StringTest.cpp
 596       TEST synchronized_test SOURCES SynchronizedTest.cpp
 597       TEST thread_cached_arena_test SOURCES ThreadCachedArenaTest.cpp
 598       TEST thread_cached_int_test SOURCES ThreadCachedIntTest.cpp
 599       TEST thread_local_test SOURCES ThreadLocalTest.cpp
 600       TEST timeout_queue_test SOURCES TimeoutQueueTest.cpp
 601       TEST token_bucket_test SOURCES TokenBucketTest.cpp
 602       TEST traits_test SOURCES TraitsTest.cpp
 603       TEST try_test SOURCES TryTest.cpp
 604       TEST unit_test SOURCES UnitTest.cpp
 605       TEST uri_test SOURCES UriTest.cpp
 606       TEST varint_test SOURCES VarintTest.cpp
 607   )
 608 endif()