move CallOnce to synchronization/
[folly.git] / CMakeLists.txt
1 cmake_minimum_required(VERSION 3.4.0 FATAL_ERROR)
2
3 # includes
4 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake" ${CMAKE_MODULE_PATH})
5 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
6
7 # package information
8 set(PACKAGE_NAME      "folly")
9 set(PACKAGE_VERSION   "0.58.0-dev")
10 set(PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
11 set(PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
12 set(PACKAGE_BUGREPORT "https://github.com/facebook/folly/issues")
13
14 # 150+ tests in the root folder anyone? No? I didn't think so.
15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
16
17 project(${PACKAGE_NAME} CXX)
18
19 if (MSVC_VERSION EQUAL 1910 OR MSVC_VERSION EQUAL 1911)
20   set(MSVC_IS_2017 ON)
21 elseif (MSVC_VERSION EQUAL 1900)
22   set(MSVC_IS_2017 OFF)
23 else()
24   message(FATAL_ERROR "This build script only supports building '${MSVC_VERSION}' Folly on 64-bit Windows with Visual Studio 2015 or Visual Studio 2017.")
25 endif()
26
27 # Check architecture OS
28 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
29   message(FATAL_ERROR "Folly requires a 64bit OS")
30 endif()
31 if(NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
32   message(FATAL_ERROR "You should only be using CMake to build Folly if you are on Windows!")
33 endif()
34
35 set(FOLLY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/folly")
36
37 # Generate a few tables and create the main config file.
38 find_package(PythonInterp REQUIRED)
39 add_custom_command(
40   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
41   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_escape_tables.py"
42   DEPENDS ${FOLLY_DIR}/build/generate_escape_tables.py
43   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
44   COMMENT "Generating the escape tables..." VERBATIM
45 )
46 add_custom_command(
47   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
48   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_format_tables.py"
49   DEPENDS ${FOLLY_DIR}/build/generate_format_tables.py
50   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
51   COMMENT "Generating the format tables..." VERBATIM
52 )
53 add_custom_command(
54   OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp"
55   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_varint_tables.py"
56   DEPENDS ${FOLLY_DIR}/build/generate_varint_tables.py
57   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
58   COMMENT "Generating the group varint tables..." VERBATIM
59 )
60
61 include(folly-deps) # Find the required packages
62 if (LIBPTHREAD_FOUND)
63   set(FOLLY_HAVE_PTHREAD ON)
64 endif()
65 configure_file(
66   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-config.h.cmake
67   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
68 )
69
70 include(FollyCompiler)
71 include(FollyFunctions)
72
73 # Main folly library files
74 auto_sources(files "*.cpp" "RECURSE" "${FOLLY_DIR}")
75 auto_sources(hfiles "*.h" "RECURSE" "${FOLLY_DIR}")
76
77 # No need for tests or benchmarks, and we can't build most experimental stuff.
78 REMOVE_MATCHES_FROM_LISTS(files hfiles
79   MATCHES
80     "/build/"
81     "/experimental/exception_tracer/"
82     "/experimental/hazptr/bench/"
83     "/experimental/hazptr/example/"
84     "/experimental/logging/example/"
85     "/experimental/symbolizer/"
86     "/futures/exercises/"
87     "/test/"
88     "Benchmark.cpp$"
89     "Test.cpp$"
90   IGNORE_MATCHES
91     "/Benchmark.cpp$"
92 )
93 list(REMOVE_ITEM files
94   ${FOLLY_DIR}/Subprocess.cpp
95   ${FOLLY_DIR}/SingletonStackTrace.cpp
96   ${FOLLY_DIR}/experimental/JSONSchemaTester.cpp
97   ${FOLLY_DIR}/experimental/RCUUtils.cpp
98   ${FOLLY_DIR}/experimental/io/AsyncIO.cpp
99   ${FOLLY_DIR}/experimental/io/HugePageUtil.cpp
100   ${FOLLY_DIR}/futures/test/Benchmark.cpp
101 )
102 list(REMOVE_ITEM hfiles
103   ${FOLLY_DIR}/Fingerprint.h
104   ${FOLLY_DIR}/detail/SlowFingerprint.h
105   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
106   ${FOLLY_DIR}/experimental/RCURefCount.h
107   ${FOLLY_DIR}/experimental/RCUUtils.h
108   ${FOLLY_DIR}/experimental/io/AsyncIO.h
109 )
110
111 add_library(folly_base OBJECT
112   ${files} ${hfiles}
113   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
114   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
115   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
116   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
117 )
118 auto_source_group(folly ${FOLLY_DIR} ${files} ${hfiles})
119 apply_folly_compile_options_to_target(folly_base)
120 target_include_directories(folly_base PUBLIC ${CMAKE_CURRENT_BINARY_DIR})
121 # Add the generated files to the correct source group.
122 source_group("folly" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h)
123 source_group("folly\\build" FILES
124   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
125   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
126   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
127   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
128 )
129
130 set(FOLLY_SHINY_DEPENDENCIES
131   Boost::chrono
132   Boost::context
133   Boost::date_time
134   Boost::filesystem
135   Boost::program_options
136   Boost::regex
137   Boost::system
138   OpenSSL::SSL
139   OpenSSL::Crypto
140 )
141
142 set(FOLLY_LINK_LIBRARIES
143   ${DOUBLE_CONVERSION_LIBRARY}
144   ${LIBEVENT_LIB}
145   ${LIBGFLAGS_LIBRARY}
146   ${LIBGLOG_LIBRARY}
147   Iphlpapi.lib
148   Ws2_32.lib
149
150   ${FOLLY_SHINY_DEPENDENCIES}
151 )
152
153 target_include_directories(folly_base
154   PUBLIC
155     ${DOUBLE_CONVERSION_INCLUDE_DIR}
156     ${LIBGFLAGS_INCLUDE_DIR}
157     ${LIBGLOG_INCLUDE_DIR}
158     ${LIBEVENT_INCLUDE_DIR}
159     $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
160 )
161
162 foreach (LIB ${FOLLY_SHINY_DEPENDENCIES})
163   target_include_directories(folly_base PUBLIC $<TARGET_PROPERTY:${LIB},INCLUDE_DIRECTORIES>)
164 endforeach()
165
166 if (FOLLY_HAVE_PTHREAD)
167   target_include_directories(folly_base PUBLIC ${LIBPTHREAD_INCLUDE_DIRS})
168   list(APPEND FOLLY_LINK_LIBRARIES ${LIBPTHREAD_LIBRARIES})
169 endif()
170
171 # Now to generate the fingerprint tables
172 add_executable(GenerateFingerprintTables
173   ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp
174   $<TARGET_OBJECTS:folly_base>
175 )
176 target_link_libraries(GenerateFingerprintTables PRIVATE ${FOLLY_LINK_LIBRARIES})
177 target_include_directories(GenerateFingerprintTables PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
178 add_dependencies(GenerateFingerprintTables folly_base)
179 apply_folly_compile_options_to_target(GenerateFingerprintTables)
180 set_property(TARGET GenerateFingerprintTables PROPERTY FOLDER "Build")
181 source_group("" FILES ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp)
182
183 # Compile the fingerprint tables.
184 add_custom_command(
185   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
186   COMMAND GenerateFingerprintTables
187   DEPENDS GenerateFingerprintTables
188   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
189   COMMENT "Generating the fingerprint tables..."
190 )
191 add_library(folly_fingerprint STATIC
192   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
193   ${FOLLY_DIR}/Fingerprint.h
194   ${FOLLY_DIR}/detail/SlowFingerprint.h
195   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
196   $<TARGET_OBJECTS:folly_base>
197 )
198 target_link_libraries(folly_fingerprint PRIVATE ${FOLLY_LINK_LIBRARIES})
199 target_include_directories(folly_fingerprint PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
200 add_dependencies(folly_fingerprint folly_base)
201 apply_folly_compile_options_to_target(folly_fingerprint)
202
203 # We want to generate a single library and target for folly, but we needed a
204 # two-stage compile for the fingerprint tables, so we create a phony source
205 # file that we modify whenever the base libraries change, causing folly to be
206 # re-linked, making things happy.
207 add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
208   COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
209   DEPENDS folly_base folly_fingerprint
210 )
211 add_library(folly ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp $<TARGET_OBJECTS:folly_base>)
212 apply_folly_compile_options_to_target(folly)
213 source_group("" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
214
215 target_link_libraries(folly PUBLIC ${FOLLY_LINK_LIBRARIES})
216 target_include_directories(folly PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
217
218 install(TARGETS folly
219   EXPORT folly
220   RUNTIME DESTINATION bin
221   LIBRARY DESTINATION lib
222   ARCHIVE DESTINATION lib)
223 auto_install_files(folly ${FOLLY_DIR}
224   ${hfiles}
225   ${FOLLY_DIR}/Fingerprint.h
226   ${FOLLY_DIR}/detail/SlowFingerprint.h
227   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
228 )
229 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h DESTINATION include/folly)
230 install(
231   EXPORT folly
232   DESTINATION share/folly
233   NAMESPACE Folly::
234   FILE folly-targets.cmake
235 )
236
237 # We need a wrapper config file to do the find_package calls to ensure
238 # that all our dependencies are available to link against.
239 file(
240   COPY ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-deps.cmake
241   DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/
242 )
243 file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake "\ninclude(folly-targets.cmake)\n")
244 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake DESTINATION share/folly RENAME folly-config.cmake)
245
246 option(BUILD_TESTS "If enabled, compile the tests." OFF)
247 option(BUILD_BROKEN_TESTS "If enabled, compile tests that are known to be broken." OFF)
248 option(BUILD_HANGING_TESTS "If enabled, compile tests that are known to hang." OFF)
249 option(BUILD_SLOW_TESTS "If enabled, compile tests that take a while to run in debug mode." OFF)
250 if (BUILD_TESTS)
251   find_package(GMock MODULE REQUIRED)
252
253   add_library(folly_test_support
254     ${FOLLY_DIR}/test/DeterministicSchedule.cpp
255     ${FOLLY_DIR}/test/DeterministicSchedule.h
256     ${FOLLY_DIR}/test/SingletonTestStructs.cpp
257     ${FOLLY_DIR}/test/SocketAddressTestHelper.cpp
258     ${FOLLY_DIR}/test/SocketAddressTestHelper.h
259     ${FOLLY_DIR}/experimental/logging/test/TestLogHandler.h
260     ${FOLLY_DIR}/futures/test/TestExecutor.cpp
261     ${FOLLY_DIR}/futures/test/TestExecutor.h
262     ${FOLLY_DIR}/io/async/test/BlockingSocket.h
263     ${FOLLY_DIR}/io/async/test/MockAsyncServerSocket.h
264     ${FOLLY_DIR}/io/async/test/MockAsyncSocket.h
265     ${FOLLY_DIR}/io/async/test/MockAsyncSSLSocket.h
266     ${FOLLY_DIR}/io/async/test/MockAsyncTransport.h
267     ${FOLLY_DIR}/io/async/test/MockAsyncUDPSocket.h
268     ${FOLLY_DIR}/io/async/test/MockTimeoutManager.h
269     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.cpp
270     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.h
271     ${FOLLY_DIR}/io/async/test/SocketPair.cpp
272     ${FOLLY_DIR}/io/async/test/SocketPair.h
273     ${FOLLY_DIR}/io/async/test/TestSSLServer.cpp
274     ${FOLLY_DIR}/io/async/test/TestSSLServer.h
275     ${FOLLY_DIR}/io/async/test/TimeUtil.cpp
276     ${FOLLY_DIR}/io/async/test/TimeUtil.h
277     ${FOLLY_DIR}/io/async/test/UndelayedDestruction.h
278     ${FOLLY_DIR}/io/async/test/Util.h
279   )
280   target_compile_definitions(folly_test_support
281     PUBLIC
282       ${LIBGMOCK_DEFINES}
283   )
284   target_include_directories(folly_test_support
285     PUBLIC
286       ${LIBGMOCK_INCLUDE_DIR}
287   )
288   target_link_libraries(folly_test_support
289     PUBLIC
290       Boost::thread
291       folly
292       ${LIBGMOCK_LIBRARY}
293   )
294   apply_folly_compile_options_to_target(folly_test_support)
295
296   folly_define_tests(
297     DIRECTORY concurrency/test/
298       TEST cache_locality_test SOURCES CacheLocalityTest.cpp
299
300       DIRECTORY executors/test/
301       TEST async_helpers_test SOURCES AsyncTest.cpp
302       TEST codel_test SOURCES CodelTest.cpp
303       TEST fiber_io_executor_test SOURCES FiberIOExecutorTest.cpp
304       TEST global_executor_test SOURCES GlobalExecutorTest.cpp
305       TEST serial_executor_test SOURCES SerialExecutorTest.cpp
306       TEST thread_pool_executor_test SOURCES ThreadPoolExecutorTest.cpp
307       TEST threaded_executor_test SOURCES ThreadedExecutorTest.cpp
308       TEST unbounded_blocking_queue_test SOURCES UnboundedBlockingQueueTest.cpp
309
310     DIRECTORY experimental/test/
311       TEST autotimer_test SOURCES AutoTimerTest.cpp
312       TEST bits_test_2 SOURCES BitsTest.cpp
313       TEST bitvector_test SOURCES BitVectorCodingTest.cpp
314       TEST dynamic_parser_test SOURCES DynamicParserTest.cpp
315       TEST eliasfano_test SOURCES EliasFanoCodingTest.cpp
316       TEST event_count_test SOURCES EventCountTest.cpp
317       TEST function_scheduler_test_2 SOURCES FunctionSchedulerTest.cpp
318       TEST future_dag_test SOURCES FutureDAGTest.cpp
319       TEST json_schema_test SOURCES JSONSchemaTest.cpp
320       TEST lock_free_ring_buffer_test SOURCES LockFreeRingBufferTest.cpp
321       #TEST nested_command_line_app_test SOURCES NestedCommandLineAppTest.cpp
322       #TEST program_options_test SOURCES ProgramOptionsTest.cpp
323       # Depends on liburcu
324       #TEST read_mostly_shared_ptr_test SOURCES ReadMostlySharedPtrTest.cpp
325       #TEST ref_count_test SOURCES RefCountTest.cpp
326       TEST stringkeyed_test SOURCES StringKeyedTest.cpp
327       TEST test_util_test SOURCES TestUtilTest.cpp
328       TEST tuple_ops_test SOURCES TupleOpsTest.cpp
329
330     DIRECTORY experimental/io/test/
331       # Depends on libaio
332       #TEST async_io_test SOURCES AsyncIOTest.cpp
333       TEST fs_util_test SOURCES FsUtilTest.cpp
334
335     DIRECTORY experimental/logging/test/
336       TEST async_file_writer_test SOURCES AsyncFileWriterTest.cpp
337       TEST glog_formatter_test SOURCES GlogFormatterTest.cpp
338       TEST immediate_file_writer_test SOURCES ImmediateFileWriterTest.cpp
339       TEST log_category_test SOURCES LogCategoryTest.cpp
340       TEST logger_db_test SOURCES LoggerDBTest.cpp
341       TEST logger_test SOURCES LoggerTest.cpp
342       TEST log_level_test SOURCES LogLevelTest.cpp
343       TEST log_message_test SOURCES LogMessageTest.cpp
344       TEST log_name_test SOURCES LogNameTest.cpp
345       TEST log_stream_test SOURCES LogStreamTest.cpp
346       TEST printf_test SOURCES PrintfTest.cpp
347       TEST rate_limiter_test SOURCES RateLimiterTest.cpp
348       TEST standard_log_handler_test SOURCES StandardLogHandlerTest.cpp
349       TEST xlog_test
350         HEADERS
351           XlogHeader1.h
352           XlogHeader2.h
353         SOURCES
354           XlogFile1.cpp
355           XlogFile2.cpp
356           XlogTest.cpp
357
358     DIRECTORY fibers/test/
359       TEST fibers_test SOURCES FibersTest.cpp
360
361     DIRECTORY functional/test/
362       TEST apply_tuple_test SOURCES ApplyTupleTest.cpp
363
364     DIRECTORY futures/test/
365       TEST barrier_test SOURCES BarrierTest.cpp
366       TEST callback_lifetime_test SOURCES CallbackLifetimeTest.cpp
367       TEST collect_test SOURCES CollectTest.cpp
368       TEST context_test SOURCES ContextTest.cpp
369       TEST core_test SOURCES CoreTest.cpp
370       TEST ensure_test SOURCES EnsureTest.cpp
371       TEST executor_test SOURCES ExecutorTest.cpp
372       TEST fsm_test SOURCES FSMTest.cpp
373       TEST filter_test SOURCES FilterTest.cpp
374       TEST future_splitter_test SOURCES FutureSplitterTest.cpp
375       # MSVC SFINAE bug
376       #TEST future_test SOURCES FutureTest.cpp
377       TEST header_compile_test SOURCES HeaderCompileTest.cpp
378       TEST interrupt_test SOURCES InterruptTest.cpp
379       TEST map_test SOURCES MapTest.cpp
380       TEST non_copyable_lambda_test SOURCES NonCopyableLambdaTest.cpp
381       TEST poll_test SOURCES PollTest.cpp
382       TEST promise_test SOURCES PromiseTest.cpp
383       TEST reduce_test SOURCES ReduceTest.cpp
384       # MSVC SFINAE bug
385       #TEST retrying_test SOURCES RetryingTest.cpp
386       TEST self_destruct_test SOURCES SelfDestructTest.cpp
387       TEST shared_promise_test SOURCES SharedPromiseTest.cpp
388       TEST test_executor_test SOURCES TestExecutorTest.cpp
389       TEST then_compile_test
390         HEADERS
391           ThenCompileTest.h
392         SOURCES
393           ThenCompileTest.cpp
394       TEST then_test SOURCES ThenTest.cpp
395       TEST timekeeper_test SOURCES TimekeeperTest.cpp
396       TEST times_test SOURCES TimesTest.cpp
397       TEST unwrap_test SOURCES UnwrapTest.cpp
398       TEST via_test SOURCES ViaTest.cpp
399       TEST wait_test SOURCES WaitTest.cpp
400       TEST when_test SOURCES WhenTest.cpp
401       TEST while_do_test SOURCES WhileDoTest.cpp
402       TEST will_equal_test SOURCES WillEqualTest.cpp
403       TEST window_test SOURCES WindowTest.cpp
404
405     DIRECTORY gen/test/
406       # MSVC bug can't resolve initializer_list constructor properly
407       #TEST base_test SOURCES BaseTest.cpp
408       TEST combine_test SOURCES CombineTest.cpp
409       TEST parallel_map_test SOURCES ParallelMapTest.cpp
410       TEST parallel_test SOURCES ParallelTest.cpp
411
412     DIRECTORY hash/test/
413       TEST spooky_hash_v1_test SOURCES SpookyHashV1Test.cpp
414       TEST spooky_hash_v2_test SOURCES SpookyHashV2Test.cpp
415
416     DIRECTORY io/test/
417       TEST compression_test SOURCES CompressionTest.cpp
418       TEST iobuf_test SOURCES IOBufTest.cpp
419       TEST iobuf_cursor_test SOURCES IOBufCursorTest.cpp
420       TEST iobuf_queue_test SOURCES IOBufQueueTest.cpp
421       TEST record_io_test SOURCES RecordIOTest.cpp
422       TEST ShutdownSocketSetTest HANGING
423         SOURCES ShutdownSocketSetTest.cpp
424
425     DIRECTORY io/async/test/
426       TEST async_test
427         CONTENT_DIR certs/
428         HEADERS
429           AsyncSocketTest.h
430           AsyncSSLSocketTest.h
431         SOURCES
432           AsyncPipeTest.cpp
433           AsyncSocketExceptionTest.cpp
434           AsyncSocketTest.cpp
435           AsyncSocketTest2.cpp
436           AsyncSSLSocketTest.cpp
437           AsyncSSLSocketTest2.cpp
438           AsyncSSLSocketWriteTest.cpp
439           AsyncTransportTest.cpp
440           # This is disabled because it depends on things that don't exist
441           # on Windows.
442           #EventHandlerTest.cpp
443           # The async signal handler is not supported on Windows.
444           #AsyncSignalHandlerTest.cpp
445       TEST async_timeout_test SOURCES AsyncTimeoutTest.cpp
446       TEST AsyncUDPSocketTest SOURCES AsyncUDPSocketTest.cpp
447       TEST DelayedDestructionTest SOURCES DelayedDestructionTest.cpp
448       TEST DelayedDestructionBaseTest SOURCES DelayedDestructionBaseTest.cpp
449       TEST DestructorCheckTest SOURCES DestructorCheckTest.cpp
450       TEST EventBaseTest SOURCES EventBaseTest.cpp
451       TEST EventBaseLocalTest SOURCES EventBaseLocalTest.cpp
452       TEST HHWheelTimerTest SOURCES HHWheelTimerTest.cpp
453       TEST HHWheelTimerSlowTests SLOW
454         SOURCES HHWheelTimerSlowTests.cpp
455       TEST NotificationQueueTest SOURCES NotificationQueueTest.cpp
456       TEST RequestContextTest SOURCES RequestContextTest.cpp
457       TEST ScopedEventBaseThreadTest SOURCES ScopedEventBaseThreadTest.cpp
458       TEST ssl_session_test SOURCES SSLSessionTest.cpp
459       TEST writechain_test SOURCES WriteChainAsyncTransportWrapperTest.cpp
460
461     DIRECTORY io/async/ssl/test/
462       TEST ssl_errors_test SOURCES SSLErrorsTest.cpp
463
464     DIRECTORY portability/test/
465       TEST constexpr_test SOURCES ConstexprTest.cpp
466       TEST libgen-test SOURCES LibgenTest.cpp
467       TEST time-test SOURCES TimeTest.cpp
468       TEST openssl_portability_test SOURCES OpenSSLPortabilityTest.cpp
469
470     DIRECTORY ssl/test/
471       TEST openssl_hash_test SOURCES OpenSSLHashTest.cpp
472
473     DIRECTORY stats/test/
474       TEST histogram_test SOURCES HistogramTest.cpp
475       TEST timeseries_histogram_test SOURCES TimeseriesHistogramTest.cpp
476       TEST timeseries_test SOURCES TimeseriesTest.cpp
477
478     DIRECTORY synchronization/test/
479       TEST call_once_test SOURCES CallOnceTest.cpp
480
481     DIRECTORY test/
482       TEST ahm_int_stress_test SOURCES AHMIntStressTest.cpp
483       TEST arena_test SOURCES ArenaTest.cpp
484       TEST arena_smartptr_test SOURCES ArenaSmartPtrTest.cpp
485       TEST array_test SOURCES ArrayTest.cpp
486       TEST ascii_check_test SOURCES AsciiCaseInsensitiveTest.cpp
487       TEST atomic_bit_set_test SOURCES AtomicBitSetTest.cpp
488       TEST atomic_hash_array_test SOURCES AtomicHashArrayTest.cpp
489       TEST atomic_hash_map_test HANGING
490         SOURCES AtomicHashMapTest.cpp
491       TEST atomic_linked_list_test SOURCES AtomicLinkedListTest.cpp
492       TEST atomic_struct_test SOURCES AtomicStructTest.cpp
493       TEST atomic_unordered_map_test SOURCES AtomicUnorderedMapTest.cpp
494       TEST baton_test SOURCES BatonTest.cpp
495       TEST bit_iterator_test SOURCES BitIteratorTest.cpp
496       TEST bits_test SOURCES BitsTest.cpp
497       TEST cacheline_padded_test SOURCES CachelinePaddedTest.cpp
498       TEST checksum_test SOURCES ChecksumTest.cpp
499       TEST clock_gettime_wrappers_test SOURCES ClockGettimeWrappersTest.cpp
500       TEST concurrent_skip_list_test SOURCES ConcurrentSkipListTest.cpp
501       TEST container_traits_test SOURCES ContainerTraitsTest.cpp
502       TEST conv_test SOURCES ConvTest.cpp
503       TEST cpu_id_test SOURCES CpuIdTest.cpp
504       TEST demangle_test SOURCES DemangleTest.cpp
505       TEST deterministic_schedule_test SOURCES DeterministicScheduleTest.cpp
506       TEST discriminated_ptr_test SOURCES DiscriminatedPtrTest.cpp
507       TEST dynamic_test SOURCES DynamicTest.cpp
508       TEST dynamic_converter_test SOURCES DynamicConverterTest.cpp
509       TEST dynamic_other_test SOURCES DynamicOtherTest.cpp
510       TEST endian_test SOURCES EndianTest.cpp
511       TEST enumerate_test SOURCES EnumerateTest.cpp
512       TEST evicting_cache_map_test SOURCES EvictingCacheMapTest.cpp
513       TEST exception_test SOURCES ExceptionTest.cpp
514       TEST exception_wrapper_test SOURCES ExceptionWrapperTest.cpp
515       TEST expected_test SOURCES ExpectedTest.cpp
516       TEST fbvector_test SOURCES FBVectorTest.cpp
517       TEST file_test SOURCES FileTest.cpp
518       #TEST file_lock_test SOURCES FileLockTest.cpp
519       TEST file_util_test HANGING
520         SOURCES FileUtilTest.cpp
521       TEST fingerprint_test SOURCES FingerprintTest.cpp
522       TEST foreach_test SOURCES ForeachTest.cpp
523       TEST format_other_test SOURCES FormatOtherTest.cpp
524       TEST format_test SOURCES FormatTest.cpp
525       TEST function_scheduler_test SOURCES FunctionSchedulerTest.cpp
526       TEST function_test BROKEN
527         SOURCES FunctionTest.cpp
528       TEST function_ref_test SOURCES FunctionRefTest.cpp
529       TEST futex_test SOURCES FutexTest.cpp
530       TEST group_varint_test SOURCES GroupVarintTest.cpp
531       TEST group_varint_test_ssse3 SOURCES GroupVarintTest.cpp
532       TEST has_member_fn_traits_test SOURCES HasMemberFnTraitsTest.cpp
533       TEST hash_test SOURCES HashTest.cpp
534       TEST indestructible_test SOURCES IndestructibleTest.cpp
535       TEST indexed_mem_pool_test BROKEN
536         SOURCES IndexedMemPoolTest.cpp
537       # MSVC Preprocessor stringizing raw string literals bug
538       #TEST json_test SOURCES JsonTest.cpp
539       TEST json_other_test
540         CONTENT_DIR json_test_data/
541         SOURCES
542           JsonOtherTest.cpp
543       TEST lazy_test SOURCES LazyTest.cpp
544       TEST lifosem_test SOURCES LifoSemTests.cpp
545       TEST lock_traits_test SOURCES LockTraitsTest.cpp
546       TEST locks_test SOURCES SmallLocksTest.cpp SpinLockTest.cpp
547       TEST logging_test SOURCES LoggingTest.cpp
548       TEST mallctl_helper_test SOURCES MallctlHelperTest.cpp
549       TEST math_test SOURCES MathTest.cpp
550       TEST map_util_test SOURCES MapUtilTest.cpp
551       TEST memcpy_test SOURCES MemcpyTest.cpp
552       TEST memory_idler_test SOURCES MemoryIdlerTest.cpp
553       TEST memory_mapping_test SOURCES MemoryMappingTest.cpp
554       TEST memory_test SOURCES MemoryTest.cpp
555       TEST merge SOURCES MergeTest.cpp
556       TEST move_wrapper_test SOURCES MoveWrapperTest.cpp
557       TEST mpmc_pipeline_test SOURCES MPMCPipelineTest.cpp
558       TEST mpmc_queue_test SLOW
559         SOURCES MPMCQueueTest.cpp
560       TEST network_address_test HANGING
561         SOURCES
562           IPAddressTest.cpp
563           MacAddressTest.cpp
564           SocketAddressTest.cpp
565       TEST optional_test SOURCES OptionalTest.cpp
566       TEST packed_sync_ptr_test HANGING
567         SOURCES PackedSyncPtrTest.cpp
568       TEST padded_test SOURCES PaddedTest.cpp
569       TEST partial_test SOURCES PartialTest.cpp
570       TEST portability_test SOURCES PortabilityTest.cpp
571       TEST producer_consumer_queue_test SLOW
572         SOURCES ProducerConsumerQueueTest.cpp
573       TEST r_w_spin_lock_test SOURCES RWSpinLockTest.cpp
574       TEST random_test SOURCES RandomTest.cpp
575       TEST range_test SOURCES RangeTest.cpp
576       TEST safe_assert_test SOURCES SafeAssertTest.cpp
577       TEST scope_guard_test SOURCES ScopeGuardTest.cpp
578       # Heavily dependent on drand and srand48
579       #TEST shared_mutex_test SOURCES SharedMutexTest.cpp
580       TEST shell_test SOURCES ShellTest.cpp
581       TEST singleton_test SOURCES SingletonTest.cpp
582       TEST singleton_test_global SOURCES SingletonTestGlobal.cpp
583       TEST singleton_thread_local_test SOURCES SingletonThreadLocalTest.cpp
584       TEST singletonvault_c_test SOURCES SingletonVaultCTest.cpp
585       TEST small_vector_test SOURCES small_vector_test.cpp
586       TEST sorted_vector_types_test SOURCES sorted_vector_test.cpp
587       TEST sparse_byte_set_test SOURCES SparseByteSetTest.cpp
588       TEST string_test SOURCES StringTest.cpp
589       #TEST subprocess_test SOURCES SubprocessTest.cpp
590       TEST synchronized_test SOURCES SynchronizedTest.cpp
591       TEST thread_cached_arena_test SOURCES ThreadCachedArenaTest.cpp
592       TEST thread_cached_int_test SOURCES ThreadCachedIntTest.cpp
593       TEST thread_id_test SOURCES ThreadIdTest.cpp
594       TEST thread_local_test SOURCES ThreadLocalTest.cpp
595       TEST thread_name_test SOURCES ThreadNameTest.cpp
596       TEST timeout_queue_test SOURCES TimeoutQueueTest.cpp
597       TEST token_bucket_test SOURCES TokenBucketTest.cpp
598       TEST traits_test SOURCES TraitsTest.cpp
599       TEST try_test SOURCES TryTest.cpp
600       TEST unit_test SOURCES UnitTest.cpp
601       TEST uri_test SOURCES UriTest.cpp
602       TEST varint_test SOURCES VarintTest.cpp
603   )
604 endif()