CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.0 FATAL_ERROR)
   2
   3 # includes
   4 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake" ${CMAKE_MODULE_PATH})
   5 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
   6
   7 # package information
   8 set(PACKAGE_NAME      "folly")
   9 set(PACKAGE_VERSION   "0.58.0-dev")
  10 set(PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  11 set(PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
  12 set(PACKAGE_BUGREPORT "https://github.com/facebook/folly/issues")
  13
  14 # 150+ tests in the root folder anyone? No? I didn't think so.
  15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  16
  17 project(${PACKAGE_NAME} CXX)
  18
  19 if (MSVC_VERSION EQUAL 1910 OR MSVC_VERSION EQUAL 1911)
  20   set(MSVC_IS_2017 ON)
  21 elseif (MSVC_VERSION EQUAL 1900)
  22   set(MSVC_IS_2017 OFF)
  23 else()
  24   message(FATAL_ERROR "This build script only supports building '${MSVC_VERSION}' Folly on 64-bit Windows with Visual Studio 2015 or Visual Studio 2017.")
  25 endif()
  26
  27 # Check architecture OS
  28 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
  29   message(FATAL_ERROR "Folly requires a 64bit OS")
  30 endif()
  31 if(NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
  32   message(FATAL_ERROR "You should only be using CMake to build Folly if you are on Windows!")
  33 endif()
  34
  35 set(FOLLY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/folly")
  36
  37 # Generate a few tables and create the main config file.
  38 find_package(PythonInterp REQUIRED)
  39 add_custom_command(
  40   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
  41   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_escape_tables.py"
  42   DEPENDS ${FOLLY_DIR}/build/generate_escape_tables.py
  43   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  44   COMMENT "Generating the escape tables..." VERBATIM
  45 )
  46 add_custom_command(
  47   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
  48   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_format_tables.py"
  49   DEPENDS ${FOLLY_DIR}/build/generate_format_tables.py
  50   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  51   COMMENT "Generating the format tables..." VERBATIM
  52 )
  53 add_custom_command(
  54   OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp"
  55   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_varint_tables.py"
  56   DEPENDS ${FOLLY_DIR}/build/generate_varint_tables.py
  57   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  58   COMMENT "Generating the group varint tables..." VERBATIM
  59 )
  60
  61 include(folly-deps) # Find the required packages
  62 if (LIBPTHREAD_FOUND)
  63   set(FOLLY_HAVE_PTHREAD ON)
  64 endif()
  65 configure_file(
  66   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-config.h.cmake
  67   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
  68 )
  69
  70 include(FollyCompiler)
  71 include(FollyFunctions)
  72
  73 # Main folly library files
  74 auto_sources(files "*.cpp" "RECURSE" "${FOLLY_DIR}")
  75 auto_sources(hfiles "*.h" "RECURSE" "${FOLLY_DIR}")
  76
  77 # No need for tests or benchmarks, and we can't build most experimental stuff.
  78 REMOVE_MATCHES_FROM_LISTS(files hfiles
  79   MATCHES
  80     "/build/"
  81     "/experimental/exception_tracer/"
  82     "/experimental/hazptr/bench/"
  83     "/experimental/hazptr/example/"
  84     "/experimental/logging/example/"
  85     "/experimental/symbolizer/"
  86     "/futures/exercises/"
  87     "/test/"
  88     "Benchmark.cpp$"
  89     "Test.cpp$"
  90   IGNORE_MATCHES
  91     "/Benchmark.cpp$"
  92 )
  93 list(REMOVE_ITEM files
  94   ${FOLLY_DIR}/Subprocess.cpp
  95   ${FOLLY_DIR}/SingletonStackTrace.cpp
  96   ${FOLLY_DIR}/experimental/JSONSchemaTester.cpp
  97   ${FOLLY_DIR}/experimental/RCUUtils.cpp
  98   ${FOLLY_DIR}/experimental/io/AsyncIO.cpp
  99   ${FOLLY_DIR}/experimental/io/HugePageUtil.cpp
 100   ${FOLLY_DIR}/futures/test/Benchmark.cpp
 101 )
 102 list(REMOVE_ITEM hfiles
 103   ${FOLLY_DIR}/Fingerprint.h
 104   ${FOLLY_DIR}/detail/SlowFingerprint.h
 105   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 106   ${FOLLY_DIR}/experimental/RCURefCount.h
 107   ${FOLLY_DIR}/experimental/RCUUtils.h
 108   ${FOLLY_DIR}/experimental/io/AsyncIO.h
 109 )
 110
 111 add_library(folly_base OBJECT
 112   ${files} ${hfiles}
 113   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
 114   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
 115   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
 116   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
 117 )
 118 auto_source_group(folly ${FOLLY_DIR} ${files} ${hfiles})
 119 apply_folly_compile_options_to_target(folly_base)
 120 target_include_directories(folly_base PUBLIC ${CMAKE_CURRENT_BINARY_DIR})
 121 # Add the generated files to the correct source group.
 122 source_group("folly" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h)
 123 source_group("folly\\build" FILES
 124   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
 125   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 126   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
 127   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
 128 )
 129
 130 set(FOLLY_SHINY_DEPENDENCIES
 131   Boost::chrono
 132   Boost::context
 133   Boost::date_time
 134   Boost::filesystem
 135   Boost::program_options
 136   Boost::regex
 137   Boost::system
 138   OpenSSL::SSL
 139   OpenSSL::Crypto
 140 )
 141
 142 set(FOLLY_LINK_LIBRARIES
 143   ${DOUBLE_CONVERSION_LIBRARY}
 144   ${LIBEVENT_LIB}
 145   ${LIBGFLAGS_LIBRARY}
 146   ${LIBGLOG_LIBRARY}
 147   Ws2_32.lib
 148
 149   ${FOLLY_SHINY_DEPENDENCIES}
 150 )
 151
 152 target_include_directories(folly_base
 153   PUBLIC
 154     ${DOUBLE_CONVERSION_INCLUDE_DIR}
 155     ${LIBGFLAGS_INCLUDE_DIR}
 156     ${LIBGLOG_INCLUDE_DIR}
 157     ${LIBEVENT_INCLUDE_DIR}
 158     $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
 159 )
 160
 161 foreach (LIB ${FOLLY_SHINY_DEPENDENCIES})
 162   target_include_directories(folly_base PUBLIC $<TARGET_PROPERTY:${LIB},INCLUDE_DIRECTORIES>)
 163 endforeach()
 164
 165 if (FOLLY_HAVE_PTHREAD)
 166   target_include_directories(folly_base PUBLIC ${LIBPTHREAD_INCLUDE_DIRS})
 167   list(APPEND FOLLY_LINK_LIBRARIES ${LIBPTHREAD_LIBRARIES})
 168 endif()
 169
 170 # Now to generate the fingerprint tables
 171 add_executable(GenerateFingerprintTables
 172   ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp
 173   $<TARGET_OBJECTS:folly_base>
 174 )
 175 target_link_libraries(GenerateFingerprintTables PRIVATE ${FOLLY_LINK_LIBRARIES})
 176 target_include_directories(GenerateFingerprintTables PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 177 add_dependencies(GenerateFingerprintTables folly_base)
 178 apply_folly_compile_options_to_target(GenerateFingerprintTables)
 179 set_property(TARGET GenerateFingerprintTables PROPERTY FOLDER "Build")
 180 source_group("" FILES ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp)
 181
 182 # Compile the fingerprint tables.
 183 add_custom_command(
 184   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 185   COMMAND GenerateFingerprintTables
 186   DEPENDS GenerateFingerprintTables
 187   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
 188   COMMENT "Generating the fingerprint tables..."
 189 )
 190 add_library(folly_fingerprint STATIC
 191   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 192   ${FOLLY_DIR}/Fingerprint.h
 193   ${FOLLY_DIR}/detail/SlowFingerprint.h
 194   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 195   $<TARGET_OBJECTS:folly_base>
 196 )
 197 target_link_libraries(folly_fingerprint PRIVATE ${FOLLY_LINK_LIBRARIES})
 198 target_include_directories(folly_fingerprint PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 199 add_dependencies(folly_fingerprint folly_base)
 200 apply_folly_compile_options_to_target(folly_fingerprint)
 201
 202 # We want to generate a single library and target for folly, but we needed a
 203 # two-stage compile for the fingerprint tables, so we create a phony source
 204 # file that we modify whenever the base libraries change, causing folly to be
 205 # re-linked, making things happy.
 206 add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
 207   COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
 208   DEPENDS folly_base folly_fingerprint
 209 )
 210 add_library(folly ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp $<TARGET_OBJECTS:folly_base>)
 211 apply_folly_compile_options_to_target(folly)
 212 source_group("" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
 213
 214 target_link_libraries(folly PUBLIC ${FOLLY_LINK_LIBRARIES})
 215 target_include_directories(folly PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 216
 217 install(TARGETS folly
 218   EXPORT folly
 219   RUNTIME DESTINATION bin
 220   LIBRARY DESTINATION lib
 221   ARCHIVE DESTINATION lib)
 222 auto_install_files(folly ${FOLLY_DIR}
 223   ${hfiles}
 224   ${FOLLY_DIR}/Fingerprint.h
 225   ${FOLLY_DIR}/detail/SlowFingerprint.h
 226   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 227 )
 228 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h DESTINATION include/folly)
 229 install(
 230   EXPORT folly
 231   DESTINATION share/folly
 232   NAMESPACE Folly::
 233   FILE folly-targets.cmake
 234 )
 235
 236 # We need a wrapper config file to do the find_package calls to ensure
 237 # that all our dependencies are available to link against.
 238 file(
 239   COPY ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-deps.cmake
 240   DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/
 241 )
 242 file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake "\ninclude(folly-targets.cmake)\n")
 243 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake DESTINATION share/folly RENAME folly-config.cmake)
 244
 245 option(BUILD_TESTS "If enabled, compile the tests." OFF)
 246 option(BUILD_HANGING_TESTS "If enabled, compile tests that are known to hang." OFF)
 247 option(BUILD_SLOW_TESTS "If enabled, compile tests that take a while to run in debug mode." OFF)
 248 if (BUILD_TESTS)
 249   find_package(GMock MODULE REQUIRED)
 250
 251   add_library(folly_test_support
 252     ${FOLLY_DIR}/test/DeterministicSchedule.cpp
 253     ${FOLLY_DIR}/test/DeterministicSchedule.h
 254     ${FOLLY_DIR}/test/SingletonTestStructs.cpp
 255     ${FOLLY_DIR}/test/SocketAddressTestHelper.cpp
 256     ${FOLLY_DIR}/test/SocketAddressTestHelper.h
 257     ${FOLLY_DIR}/experimental/logging/test/TestLogHandler.h
 258     ${FOLLY_DIR}/futures/test/TestExecutor.cpp
 259     ${FOLLY_DIR}/futures/test/TestExecutor.h
 260     ${FOLLY_DIR}/io/async/test/BlockingSocket.h
 261     ${FOLLY_DIR}/io/async/test/MockAsyncServerSocket.h
 262     ${FOLLY_DIR}/io/async/test/MockAsyncSocket.h
 263     ${FOLLY_DIR}/io/async/test/MockAsyncSSLSocket.h
 264     ${FOLLY_DIR}/io/async/test/MockAsyncTransport.h
 265     ${FOLLY_DIR}/io/async/test/MockAsyncUDPSocket.h
 266     ${FOLLY_DIR}/io/async/test/MockTimeoutManager.h
 267     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.cpp
 268     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.h
 269     ${FOLLY_DIR}/io/async/test/SocketPair.cpp
 270     ${FOLLY_DIR}/io/async/test/SocketPair.h
 271     ${FOLLY_DIR}/io/async/test/TestSSLServer.cpp
 272     ${FOLLY_DIR}/io/async/test/TestSSLServer.h
 273     ${FOLLY_DIR}/io/async/test/TimeUtil.cpp
 274     ${FOLLY_DIR}/io/async/test/TimeUtil.h
 275     ${FOLLY_DIR}/io/async/test/UndelayedDestruction.h
 276     ${FOLLY_DIR}/io/async/test/Util.h
 277   )
 278   target_compile_definitions(folly_test_support
 279     PUBLIC
 280       ${LIBGMOCK_DEFINES}
 281   )
 282   target_include_directories(folly_test_support
 283     PUBLIC
 284       ${LIBGMOCK_INCLUDE_DIR}
 285   )
 286   target_link_libraries(folly_test_support
 287     PUBLIC
 288       Boost::thread
 289       folly
 290       ${LIBGMOCK_LIBRARY}
 291   )
 292   apply_folly_compile_options_to_target(folly_test_support)
 293
 294   folly_define_tests(
 295     DIRECTORY concurrency/
 296       TEST cache_locality_test SOURCES CacheLocalityTest.cpp
 297     DIRECTORY experimental/test/
 298       TEST autotimer_test SOURCES AutoTimerTest.cpp
 299       TEST bits_test_2 SOURCES BitsTest.cpp
 300       TEST bitvector_test SOURCES BitVectorCodingTest.cpp
 301       TEST dynamic_parser_test SOURCES DynamicParserTest.cpp
 302       TEST eliasfano_test SOURCES EliasFanoCodingTest.cpp
 303       TEST event_count_test SOURCES EventCountTest.cpp
 304       TEST function_scheduler_test_2 SOURCES FunctionSchedulerTest.cpp
 305       TEST future_dag_test SOURCES FutureDAGTest.cpp
 306       TEST json_schema_test SOURCES JSONSchemaTest.cpp
 307       TEST lock_free_ring_buffer_test SOURCES LockFreeRingBufferTest.cpp
 308       #TEST nested_command_line_app_test SOURCES NestedCommandLineAppTest.cpp
 309       #TEST program_options_test SOURCES ProgramOptionsTest.cpp
 310       # Depends on liburcu
 311       #TEST read_mostly_shared_ptr_test SOURCES ReadMostlySharedPtrTest.cpp
 312       #TEST ref_count_test SOURCES RefCountTest.cpp
 313       TEST stringkeyed_test SOURCES StringKeyedTest.cpp
 314       TEST test_util_test SOURCES TestUtilTest.cpp
 315       TEST tuple_ops_test SOURCES TupleOpsTest.cpp
 316
 317     DIRECTORY experimental/io/test/
 318       # Depends on libaio
 319       #TEST async_io_test SOURCES AsyncIOTest.cpp
 320       TEST fs_util_test SOURCES FsUtilTest.cpp
 321
 322     DIRECTORY experimental/logging/test/
 323       TEST async_file_writer_test SOURCES AsyncFileWriterTest.cpp
 324       TEST glog_formatter_test SOURCES GlogFormatterTest.cpp
 325       TEST immediate_file_writer_test SOURCES ImmediateFileWriterTest.cpp
 326       TEST log_category_test SOURCES LogCategoryTest.cpp
 327       TEST logger_db_test SOURCES LoggerDBTest.cpp
 328       TEST logger_test SOURCES LoggerTest.cpp
 329       TEST log_level_test SOURCES LogLevelTest.cpp
 330       TEST log_message_test SOURCES LogMessageTest.cpp
 331       TEST log_name_test SOURCES LogNameTest.cpp
 332       TEST log_stream_test SOURCES LogStreamTest.cpp
 333       TEST printf_test SOURCES PrintfTest.cpp
 334       TEST rate_limiter_test SOURCES RateLimiterTest.cpp
 335       TEST standard_log_handler_test SOURCES StandardLogHandlerTest.cpp
 336       TEST xlog_test
 337         HEADERS
 338           XlogHeader1.h
 339           XlogHeader2.h
 340         SOURCES
 341           XlogFile1.cpp
 342           XlogFile2.cpp
 343           XlogTest.cpp
 344
 345     DIRECTORY fibers/test/
 346       TEST fibers_test SOURCES FibersTest.cpp
 347
 348     DIRECTORY futures/test/
 349       TEST barrier_test SOURCES BarrierTest.cpp
 350       TEST collect_test SOURCES CollectTest.cpp
 351       TEST context_test SOURCES ContextTest.cpp
 352       TEST core_test SOURCES CoreTest.cpp
 353       TEST ensure_test SOURCES EnsureTest.cpp
 354       TEST executor_test SOURCES ExecutorTest.cpp
 355       TEST fsm_test SOURCES FSMTest.cpp
 356       TEST filter_test SOURCES FilterTest.cpp
 357       TEST future_splitter_test SOURCES FutureSplitterTest.cpp
 358       # MSVC SFINAE bug
 359       #TEST future_test SOURCES FutureTest.cpp
 360       TEST header_compile_test SOURCES HeaderCompileTest.cpp
 361       TEST interrupt_test SOURCES InterruptTest.cpp
 362       TEST map_test SOURCES MapTest.cpp
 363       TEST non_copyable_lambda_test SOURCES NonCopyableLambdaTest.cpp
 364       TEST poll_test SOURCES PollTest.cpp
 365       TEST promise_test SOURCES PromiseTest.cpp
 366       TEST reduce_test SOURCES ReduceTest.cpp
 367       # MSVC SFINAE bug
 368       #TEST retrying_test SOURCES RetryingTest.cpp
 369       TEST self_destruct_test SOURCES SelfDestructTest.cpp
 370       TEST shared_promise_test SOURCES SharedPromiseTest.cpp
 371       TEST test_executor_test SOURCES TestExecutorTest.cpp
 372       TEST then_compile_test
 373         HEADERS
 374           ThenCompileTest.h
 375         SOURCES
 376           ThenCompileTest.cpp
 377       TEST then_test SOURCES ThenTest.cpp
 378       TEST timekeeper_test SOURCES TimekeeperTest.cpp
 379       TEST times_test SOURCES TimesTest.cpp
 380       TEST unwrap_test SOURCES UnwrapTest.cpp
 381       TEST via_test SOURCES ViaTest.cpp
 382       TEST wait_test SOURCES WaitTest.cpp
 383       TEST when_test SOURCES WhenTest.cpp
 384       TEST while_do_test SOURCES WhileDoTest.cpp
 385       TEST will_equal_test SOURCES WillEqualTest.cpp
 386       TEST window_test SOURCES WindowTest.cpp
 387
 388     DIRECTORY gen/test/
 389       # MSVC bug can't resolve initializer_list constructor properly
 390       #TEST base_test SOURCES BaseTest.cpp
 391       TEST combine_test SOURCES CombineTest.cpp
 392       TEST parallel_map_test SOURCES ParallelMapTest.cpp
 393       TEST parallel_test SOURCES ParallelTest.cpp
 394
 395     DIRECTORY io/test/
 396       TEST compression_test SOURCES CompressionTest.cpp
 397       TEST iobuf_test SOURCES IOBufTest.cpp
 398       TEST iobuf_cursor_test SOURCES IOBufCursorTest.cpp
 399       TEST iobuf_queue_test SOURCES IOBufQueueTest.cpp
 400       TEST record_io_test SOURCES RecordIOTest.cpp
 401       TEST ShutdownSocketSetTest HANGING
 402         SOURCES ShutdownSocketSetTest.cpp
 403
 404     DIRECTORY io/async/test/
 405       TEST async_test
 406         CONTENT_DIR certs/
 407         HEADERS
 408           AsyncSocketTest.h
 409           AsyncSSLSocketTest.h
 410         SOURCES
 411           AsyncPipeTest.cpp
 412           AsyncSignalHandlerTest.cpp
 413           AsyncSocketExceptionTest.cpp
 414           AsyncSocketTest.cpp
 415           AsyncSocketTest2.cpp
 416           AsyncSSLSocketTest.cpp
 417           AsyncSSLSocketTest2.cpp
 418           AsyncSSLSocketWriteTest.cpp
 419           AsyncTransportTest.cpp
 420           # This is disabled because it depends on things that don't exist
 421           # on Windows.
 422           #EventHandlerTest.cpp
 423       TEST async_timeout_test SOURCES AsyncTimeoutTest.cpp
 424       TEST AsyncUDPSocketTest SOURCES AsyncUDPSocketTest.cpp
 425       TEST DelayedDestructionTest SOURCES DelayedDestructionTest.cpp
 426       TEST DelayedDestructionBaseTest SOURCES DelayedDestructionBaseTest.cpp
 427       TEST DestructorCheckTest SOURCES DestructorCheckTest.cpp
 428       TEST EventBaseTest SOURCES EventBaseTest.cpp
 429       TEST EventBaseLocalTest SOURCES EventBaseLocalTest.cpp
 430       TEST HHWheelTimerTest SOURCES HHWheelTimerTest.cpp
 431       TEST HHWheelTimerSlowTests SLOW
 432         SOURCES HHWheelTimerSlowTests.cpp
 433       TEST NotificationQueueTest SOURCES NotificationQueueTest.cpp
 434       TEST RequestContextTest SOURCES RequestContextTest.cpp
 435       TEST ScopedEventBaseThreadTest SOURCES ScopedEventBaseThreadTest.cpp
 436       TEST ssl_session_test SOURCES SSLSessionTest.cpp
 437       TEST writechain_test SOURCES WriteChainAsyncTransportWrapperTest.cpp
 438
 439     DIRECTORY io/async/ssl/test/
 440       TEST ssl_errors_test SOURCES SSLErrorsTest.cpp
 441
 442     DIRECTORY portability/test/
 443       TEST constexpr_test SOURCES ConstexprTest.cpp
 444       TEST libgen-test SOURCES LibgenTest.cpp
 445       TEST time-test SOURCES TimeTest.cpp
 446
 447     DIRECTORY ssl/test/
 448       TEST openssl_hash_test SOURCES OpenSSLHashTest.cpp
 449
 450     DIRECTORY stats/test/
 451       TEST histogram_test SOURCES HistogramTest.cpp
 452       TEST timeseries_histogram_test SOURCES TimeseriesHistogramTest.cpp
 453       TEST timeseries_test SOURCES TimeseriesTest.cpp
 454
 455     DIRECTORY test/
 456       TEST ahm_int_stress_test SOURCES AHMIntStressTest.cpp
 457       TEST apply_tuple_test SOURCES ApplyTupleTest.cpp
 458       TEST arena_test SOURCES ArenaTest.cpp
 459       TEST arena_smartptr_test SOURCES ArenaSmartPtrTest.cpp
 460       TEST array_test SOURCES ArrayTest.cpp
 461       TEST ascii_check_test SOURCES AsciiCaseInsensitiveTest.cpp
 462       TEST atomic_bit_set_test SOURCES AtomicBitSetTest.cpp
 463       TEST atomic_hash_array_test SOURCES AtomicHashArrayTest.cpp
 464       TEST atomic_hash_map_test HANGING
 465         SOURCES AtomicHashMapTest.cpp
 466       TEST atomic_linked_list_test SOURCES AtomicLinkedListTest.cpp
 467       TEST atomic_struct_test SOURCES AtomicStructTest.cpp
 468       TEST atomic_unordered_map_test SOURCES AtomicUnorderedMapTest.cpp
 469       TEST baton_test SOURCES BatonTest.cpp
 470       TEST bit_iterator_test SOURCES BitIteratorTest.cpp
 471       TEST bits_test SOURCES BitsTest.cpp
 472       TEST cacheline_padded_test SOURCES CachelinePaddedTest.cpp
 473       TEST call_once_test SOURCES CallOnceTest.cpp
 474       TEST checksum_test SOURCES ChecksumTest.cpp
 475       TEST clock_gettime_wrappers_test SOURCES ClockGettimeWrappersTest.cpp
 476       TEST concurrent_skip_list_test SOURCES ConcurrentSkipListTest.cpp
 477       TEST container_traits_test SOURCES ContainerTraitsTest.cpp
 478       TEST conv_test SOURCES ConvTest.cpp
 479       TEST cpu_id_test SOURCES CpuIdTest.cpp
 480       TEST demangle_test SOURCES DemangleTest.cpp
 481       TEST deterministic_schedule_test SOURCES DeterministicScheduleTest.cpp
 482       TEST discriminated_ptr_test SOURCES DiscriminatedPtrTest.cpp
 483       TEST dynamic_test SOURCES DynamicTest.cpp
 484       TEST dynamic_converter_test SOURCES DynamicConverterTest.cpp
 485       TEST dynamic_other_test SOURCES DynamicOtherTest.cpp
 486       TEST endian_test SOURCES EndianTest.cpp
 487       TEST enumerate_test SOURCES EnumerateTest.cpp
 488       TEST evicting_cache_map_test SOURCES EvictingCacheMapTest.cpp
 489       TEST exception_test SOURCES ExceptionTest.cpp
 490       TEST exception_wrapper_test SOURCES ExceptionWrapperTest.cpp
 491       TEST expected_test SOURCES ExpectedTest.cpp
 492       TEST fbvector_test SOURCES FBVectorTest.cpp
 493       TEST file_test SOURCES FileTest.cpp
 494       #TEST file_lock_test SOURCES FileLockTest.cpp
 495       TEST file_util_test HANGING
 496         SOURCES FileUtilTest.cpp
 497       TEST fingerprint_test SOURCES FingerprintTest.cpp
 498       TEST foreach_test SOURCES ForeachTest.cpp
 499       TEST format_other_test SOURCES FormatOtherTest.cpp
 500       TEST format_test SOURCES FormatTest.cpp
 501       TEST function_scheduler_test SOURCES FunctionSchedulerTest.cpp
 502       TEST function_test SOURCES FunctionTest.cpp
 503       TEST function_ref_test SOURCES FunctionRefTest.cpp
 504       TEST futex_test SOURCES FutexTest.cpp
 505       TEST group_varint_test SOURCES GroupVarintTest.cpp
 506       TEST group_varint_test_ssse3 SOURCES GroupVarintTest.cpp
 507       TEST has_member_fn_traits_test SOURCES HasMemberFnTraitsTest.cpp
 508       TEST hash_test SOURCES HashTest.cpp
 509       TEST indestructible_test SOURCES IndestructibleTest.cpp
 510       TEST indexed_mem_pool_test SOURCES IndexedMemPoolTest.cpp
 511       # MSVC Preprocessor stringizing raw string literals bug
 512       #TEST json_test SOURCES JsonTest.cpp
 513       TEST json_other_test
 514         CONTENT_DIR json_test_data/
 515         SOURCES
 516           JsonOtherTest.cpp
 517       TEST lazy_test SOURCES LazyTest.cpp
 518       TEST lifosem_test SOURCES LifoSemTests.cpp
 519       TEST lock_traits_test SOURCES LockTraitsTest.cpp
 520       TEST locks_test SOURCES SmallLocksTest.cpp SpinLockTest.cpp
 521       TEST logging_test SOURCES LoggingTest.cpp
 522       TEST mallctl_helper_test SOURCES MallctlHelperTest.cpp
 523       TEST math_test SOURCES MathTest.cpp
 524       TEST map_util_test SOURCES MapUtilTest.cpp
 525       TEST memcpy_test SOURCES MemcpyTest.cpp
 526       TEST memory_idler_test SOURCES MemoryIdlerTest.cpp
 527       TEST memory_mapping_test SOURCES MemoryMappingTest.cpp
 528       TEST memory_test SOURCES MemoryTest.cpp
 529       TEST merge SOURCES MergeTest.cpp
 530       TEST move_wrapper_test SOURCES MoveWrapperTest.cpp
 531       TEST mpmc_pipeline_test SOURCES MPMCPipelineTest.cpp
 532       TEST mpmc_queue_test SLOW
 533         SOURCES MPMCQueueTest.cpp
 534       TEST network_address_test HANGING
 535         SOURCES
 536           IPAddressTest.cpp
 537           MacAddressTest.cpp
 538           SocketAddressTest.cpp
 539       TEST optional_test SOURCES OptionalTest.cpp
 540       TEST packed_sync_ptr_test HANGING
 541         SOURCES PackedSyncPtrTest.cpp
 542       TEST padded_test SOURCES PaddedTest.cpp
 543       TEST partial_test SOURCES PartialTest.cpp
 544       TEST portability_test SOURCES PortabilityTest.cpp
 545       TEST producer_consumer_queue_test SLOW
 546         SOURCES ProducerConsumerQueueTest.cpp
 547       TEST r_w_spin_lock_test SOURCES RWSpinLockTest.cpp
 548       TEST random_test SOURCES RandomTest.cpp
 549       TEST range_test SOURCES RangeTest.cpp
 550       TEST safe_assert_test SOURCES SafeAssertTest.cpp
 551       TEST scope_guard_test SOURCES ScopeGuardTest.cpp
 552       # Heavily dependent on drand and srand48
 553       #TEST shared_mutex_test SOURCES SharedMutexTest.cpp
 554       TEST shell_test SOURCES ShellTest.cpp
 555       TEST singleton_test SOURCES SingletonTest.cpp
 556       TEST singleton_test_global SOURCES SingletonTestGlobal.cpp
 557       TEST singleton_thread_local_test SOURCES SingletonThreadLocalTest.cpp
 558       TEST singletonvault_c_test SOURCES SingletonVaultCTest.cpp
 559       TEST small_vector_test SOURCES small_vector_test.cpp
 560       TEST sorted_vector_types_test SOURCES sorted_vector_test.cpp
 561       TEST sparse_byte_set_test SOURCES SparseByteSetTest.cpp
 562       TEST spooky_hash_v1_test SOURCES SpookyHashV1Test.cpp
 563       TEST spooky_hash_v2_test SOURCES SpookyHashV2Test.cpp
 564       TEST string_test SOURCES StringTest.cpp
 565       #TEST subprocess_test SOURCES SubprocessTest.cpp
 566       TEST synchronized_test SOURCES SynchronizedTest.cpp
 567       TEST thread_cached_arena_test SOURCES ThreadCachedArenaTest.cpp
 568       TEST thread_cached_int_test SOURCES ThreadCachedIntTest.cpp
 569       TEST thread_id_test SOURCES ThreadIdTest.cpp
 570       TEST thread_local_test SOURCES ThreadLocalTest.cpp
 571       TEST thread_name_test SOURCES ThreadNameTest.cpp
 572       TEST timeout_queue_test SOURCES TimeoutQueueTest.cpp
 573       TEST token_bucket_test SOURCES TokenBucketTest.cpp
 574       TEST traits_test SOURCES TraitsTest.cpp
 575       TEST try_test SOURCES TryTest.cpp
 576       TEST unit_test SOURCES UnitTest.cpp
 577       TEST uri_test SOURCES UriTest.cpp
 578       TEST varint_test SOURCES VarintTest.cpp
 579   )
 580 endif()