scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with this is that each object file will have a
  10 # section called __mcount_loc that will hold the list of pointers to mcount
  11 # callers. After final linking, the vmlinux will have within .init.data the
  12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13 # Later on boot up, the kernel will read this list, save the locations and turn
  14 # them into nops. When tracing or profiling is later enabled, these locations
  15 # will then be converted back to pointers to some function.
  16 #
  17 # This is no easy feat. This script is called just after the original
  18 # object is compiled and before it is linked.
  19 #
  20 # When parse this object file using 'objdump', the references to the call
  21 # sites are offsets from the section that the call site is in. Hence, all
  22 # functions in a section that has a call site to mcount, will have the
  23 # offset from the beginning of the section and not the beginning of the
  24 # function.
  25 #
  26 # But where this section will reside finally in vmlinx is undetermined at
  27 # this point. So we can't use this kind of offsets to record the final
  28 # address of this call site.
  29 #
  30 # The trick is to change the call offset referring the start of a section to
  31 # referring a function symbol in this section. During the link step, 'ld' will
  32 # compute the final address according to the information we record.
  33 #
  34 # e.g.
  35 #
  36 #  .section ".sched.text", "ax"
  37 #        [...]
  38 #  func1:
  39 #        [...]
  40 #        call mcount  (offset: 0x10)
  41 #        [...]
  42 #        ret
  43 #  .globl fun2
  44 #  func2:             (offset: 0x20)
  45 #        [...]
  46 #        [...]
  47 #        ret
  48 #  func3:
  49 #        [...]
  50 #        call mcount (offset: 0x30)
  51 #        [...]
  52 #
  53 # Both relocation offsets for the mcounts in the above example will be
  54 # offset from .sched.text. If we choose global symbol func2 as a reference and
  55 # make another file called tmp.s with the new offsets:
  56 #
  57 #  .section __mcount_loc
  58 #  .quad  func2 - 0x10
  59 #  .quad  func2 + 0x10
  60 #
  61 # We can then compile this tmp.s into tmp.o, and link it back to the original
  62 # object.
  63 #
  64 # In our algorithm, we will choose the first global function we meet in this
  65 # section as the reference. But this gets hard if there is no global functions
  66 # in this section. In such a case we have to select a local one. E.g. func1:
  67 #
  68 #  .section ".sched.text", "ax"
  69 #  func1:
  70 #        [...]
  71 #        call mcount  (offset: 0x10)
  72 #        [...]
  73 #        ret
  74 #  func2:
  75 #        [...]
  76 #        call mcount (offset: 0x20)
  77 #        [...]
  78 #  .section "other.section"
  79 #
  80 # If we make the tmp.s the same as above, when we link together with
  81 # the original object, we will end up with two symbols for func1:
  82 # one local, one global.  After final compile, we will end up with
  83 # an undefined reference to func1 or a wrong reference to another global
  84 # func1 in other files.
  85 #
  86 # Since local objects can reference local variables, we need to find
  87 # a way to make tmp.o reference the local objects of the original object
  88 # file after it is linked together. To do this, we convert func1
  89 # into a global symbol before linking tmp.o. Then after we link tmp.o
  90 # we will only have a single symbol for func1 that is global.
  91 # We can convert func1 back into a local symbol and we are done.
  92 #
  93 # Here are the steps we take:
  94 #
  95 # 1) Record all the local and weak symbols by using 'nm'
  96 # 2) Use objdump to find all the call site offsets and sections for
  97 #    mcount.
  98 # 3) Compile the list into its own object.
  99 # 4) Do we have to deal with local functions? If not, go to step 8.
 100 # 5) Make an object that converts these local functions to global symbols
 101 #    with objcopy.
 102 # 6) Link together this new object with the list object.
 103 # 7) Convert the local functions back to local symbols and rename
 104 #    the result as the original object.
 105 # 8) Link the object with the list object.
 106 # 9) Move the result back to the original object.
 107 #
 108
 109 use strict;
 110
 111 my $P = $0;
 112 $P =~ s@.*/@@g;
 113
 114 my $V = '0.1';
 115
 116 if ($#ARGV != 11) {
 117         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 118         print "version: $V\n";
 119         exit(1);
 120 }
 121
 122 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 124
 125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 127     exit(0);
 128 }
 129
 130 # Acceptable sections to record.
 131 my %text_sections = (
 132      ".text" => 1,
 133      ".ref.text" => 1,
 134      ".sched.text" => 1,
 135      ".spinlock.text" => 1,
 136      ".irqentry.text" => 1,
 137      ".kprobes.text" => 1,
 138      ".text.unlikely" => 1,
 139 );
 140
 141 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 142 $objdump = 'objdump' if (!$objdump);
 143 $objcopy = 'objcopy' if (!$objcopy);
 144 $cc = 'gcc' if (!$cc);
 145 $ld = 'ld' if (!$ld);
 146 $nm = 'nm' if (!$nm);
 147 $rm = 'rm' if (!$rm);
 148 $mv = 'mv' if (!$mv);
 149
 150 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 151 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 152
 153 my %locals;             # List of local (static) functions
 154 my %weak;               # List of weak functions
 155 my %convert;            # List of local functions used that needs conversion
 156
 157 my $type;
 158 my $local_regex;        # Match a local function (return function)
 159 my $weak_regex;         # Match a weak function (return function)
 160 my $section_regex;      # Find the start of a section
 161 my $function_regex;     # Find the name of a function
 162                         #    (return offset and func name)
 163 my $mcount_regex;       # Find the call site to mcount (return offset)
 164 my $mcount_adjust;      # Address adjustment to mcount offset
 165 my $alignment;          # The .align value to use for $mcount_section
 166 my $section_type;       # Section header plus possible alignment command
 167 my $can_use_local = 0;  # If we can use local function references
 168
 169 # Shut up recordmcount if user has older objcopy
 170 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
 171 my $print_warning = 1;
 172 $print_warning = 0 if ( -f $quiet_recordmcount);
 173
 174 ##
 175 # check_objcopy - whether objcopy supports --globalize-symbols
 176 #
 177 #  --globalize-symbols came out in 2.17, we must test the version
 178 #  of objcopy, and if it is less than 2.17, then we can not
 179 #  record local functions.
 180 sub check_objcopy
 181 {
 182     open (IN, "$objcopy --version |") or die "error running $objcopy";
 183     while (<IN>) {
 184         if (/objcopy.*\s(\d+)\.(\d+)/) {
 185             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 186             last;
 187         }
 188     }
 189     close (IN);
 190
 191     if (!$can_use_local && $print_warning) {
 192         print STDERR "WARNING: could not find objcopy version or version " .
 193             "is less than 2.17.\n" .
 194             "\tLocal function references are disabled.\n";
 195         open (QUIET, ">$quiet_recordmcount");
 196         printf QUIET "Disables the warning from recordmcount.pl\n";
 197         close QUIET;
 198     }
 199 }
 200
 201 if ($arch =~ /(x86(_64)?)|(i386)/) {
 202     if ($bits == 64) {
 203         $arch = "x86_64";
 204     } else {
 205         $arch = "i386";
 206     }
 207 }
 208
 209 #
 210 # We base the defaults off of i386, the other archs may
 211 # feel free to change them in the below if statements.
 212 #
 213 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 214 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 215 $section_regex = "Disassembly of section\\s+(\\S+):";
 216 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 217 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$";
 218 $section_type = '@progbits';
 219 $mcount_adjust = 0;
 220 $type = ".long";
 221
 222 if ($arch eq "x86_64") {
 223     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$";
 224     $type = ".quad";
 225     $alignment = 8;
 226     $mcount_adjust = -1;
 227
 228     # force flags for this arch
 229     $ld .= " -m elf_x86_64";
 230     $objdump .= " -M x86-64";
 231     $objcopy .= " -O elf64-x86-64";
 232     $cc .= " -m64";
 233
 234 } elsif ($arch eq "i386") {
 235     $alignment = 4;
 236     $mcount_adjust = -1;
 237
 238     # force flags for this arch
 239     $ld .= " -m elf_i386";
 240     $objdump .= " -M i386";
 241     $objcopy .= " -O elf32-i386";
 242     $cc .= " -m32";
 243
 244 } elsif ($arch eq "s390" && $bits == 64) {
 245     if ($cc =~ /-DCC_USING_HOTPATCH/) {
 246         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*c0 04 00 00 00 00\\s*brcl\\s*0,[0-9a-f]+ <([^\+]*)>\$";
 247         $mcount_adjust = 0;
 248     } else {
 249         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
 250         $mcount_adjust = -14;
 251     }
 252     $alignment = 8;
 253     $type = ".quad";
 254     $ld .= " -m elf64_s390";
 255     $cc .= " -m64";
 256
 257 } elsif ($arch eq "sh") {
 258     $alignment = 2;
 259
 260     # force flags for this arch
 261     $ld .= " -m shlelf_linux";
 262     $objcopy .= " -O elf32-sh-linux";
 263
 264 } elsif ($arch eq "powerpc") {
 265     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 266     # See comment in the sparc64 section for why we use '\w'.
 267     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?\\w*?)>:";
 268     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 269
 270     if ($bits == 64) {
 271         $type = ".quad";
 272     }
 273
 274 } elsif ($arch eq "arm") {
 275     $alignment = 2;
 276     $section_type = '%progbits';
 277     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
 278                         "\\s+(__gnu_mcount_nc|mcount)\$";
 279
 280 } elsif ($arch eq "arm64") {
 281     $alignment = 3;
 282     $section_type = '%progbits';
 283     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$";
 284     $type = ".quad";
 285 } elsif ($arch eq "ia64") {
 286     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 287     $type = "data8";
 288
 289     if ($is_module eq "0") {
 290         $cc .= " -mconstant-gp";
 291     }
 292 } elsif ($arch eq "sparc64") {
 293     # In the objdump output there are giblets like:
 294     # 0000000000000000 <igmp_net_exit-0x18>:
 295     # As there's some data blobs that get emitted into the
 296     # text section before the first instructions and the first
 297     # real symbols.  We don't want to match that, so to combat
 298     # this we use '\w' so we'll match just plain symbol names,
 299     # and not those that also include hex offsets inside of the
 300     # '<>' brackets.  Actually the generic function_regex setting
 301     # could safely use this too.
 302     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 303
 304     # Sparc64 calls '_mcount' instead of plain 'mcount'.
 305     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 306
 307     $alignment = 8;
 308     $type = ".xword";
 309     $ld .= " -m elf64_sparc";
 310     $cc .= " -m64";
 311     $objcopy .= " -O elf64-sparc";
 312 } elsif ($arch eq "mips") {
 313     # To enable module support, we need to enable the -mlong-calls option
 314     # of gcc for module, after using this option, we can not get the real
 315     # offset of the calling to _mcount, but the offset of the lui
 316     # instruction or the addiu one. herein, we record the address of the
 317     # first one, and then we can replace this instruction by a branch
 318     # instruction to jump over the profiling function to filter the
 319     # indicated functions, or swith back to the lui instruction to trace
 320     # them, which means dynamic tracing.
 321     #
 322     #       c:  3c030000        lui     v1,0x0
 323     #                   c: R_MIPS_HI16  _mcount
 324     #                   c: R_MIPS_NONE  *ABS*
 325     #                   c: R_MIPS_NONE  *ABS*
 326     #      10:  64630000        daddiu  v1,v1,0
 327     #                   10: R_MIPS_LO16 _mcount
 328     #                   10: R_MIPS_NONE *ABS*
 329     #                   10: R_MIPS_NONE *ABS*
 330     #      14:  03e0082d        move    at,ra
 331     #      18:  0060f809        jalr    v1
 332     #
 333     # for the kernel:
 334     #
 335     #     10:   03e0082d        move    at,ra
 336     #     14:   0c000000        jal     0 <loongson_halt>
 337     #                    14: R_MIPS_26   _mcount
 338     #                    14: R_MIPS_NONE *ABS*
 339     #                    14: R_MIPS_NONE *ABS*
 340     #    18:   00020021        nop
 341     if ($is_module eq "0") {
 342             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 343     } else {
 344             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 345     }
 346     $objdump .= " -Melf-trad".$endian."mips ";
 347
 348     if ($endian eq "big") {
 349             $endian = " -EB ";
 350             $ld .= " -melf".$bits."btsmip";
 351     } else {
 352             $endian = " -EL ";
 353             $ld .= " -melf".$bits."ltsmip";
 354     }
 355
 356     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 357     $ld .= $endian;
 358
 359     if ($bits == 64) {
 360             $function_regex =
 361                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 362             $type = ".dword";
 363     }
 364 } elsif ($arch eq "microblaze") {
 365     # Microblaze calls '_mcount' instead of plain 'mcount'.
 366     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 367 } elsif ($arch eq "blackfin") {
 368     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 369     $mcount_adjust = -4;
 370 } elsif ($arch eq "tilegx" || $arch eq "tile") {
 371     # Default to the newer TILE-Gx architecture if only "tile" is given.
 372     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 373     $type = ".quad";
 374     $alignment = 8;
 375 } else {
 376     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 377 }
 378
 379 my $text_found = 0;
 380 my $read_function = 0;
 381 my $opened = 0;
 382 my $mcount_section = "__mcount_loc";
 383
 384 my $dirname;
 385 my $filename;
 386 my $prefix;
 387 my $ext;
 388
 389 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 390     $dirname = $1;
 391     $filename = $2;
 392 } else {
 393     $dirname = ".";
 394     $filename = $inputfile;
 395 }
 396
 397 if ($filename =~ m,^(.*)(\.\S),) {
 398     $prefix = $1;
 399     $ext = $2;
 400 } else {
 401     $prefix = $filename;
 402     $ext = "";
 403 }
 404
 405 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 406 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 407
 408 check_objcopy();
 409
 410 #
 411 # Step 1: find all the local (static functions) and weak symbols.
 412 #         't' is local, 'w/W' is weak
 413 #
 414 open (IN, "$nm $inputfile|") || die "error running $nm";
 415 while (<IN>) {
 416     if (/$local_regex/) {
 417         $locals{$1} = 1;
 418     } elsif (/$weak_regex/) {
 419         $weak{$2} = $1;
 420     }
 421 }
 422 close(IN);
 423
 424 my @offsets;            # Array of offsets of mcount callers
 425 my $ref_func;           # reference function to use for offsets
 426 my $offset = 0;         # offset of ref_func to section beginning
 427
 428 ##
 429 # update_funcs - print out the current mcount callers
 430 #
 431 #  Go through the list of offsets to callers and write them to
 432 #  the output file in a format that can be read by an assembler.
 433 #
 434 sub update_funcs
 435 {
 436     return unless ($ref_func and @offsets);
 437
 438     # Sanity check on weak function. A weak function may be overwritten by
 439     # another function of the same name, making all these offsets incorrect.
 440     if (defined $weak{$ref_func}) {
 441         die "$inputfile: ERROR: referencing weak function" .
 442             " $ref_func for mcount\n";
 443     }
 444
 445     # is this function static? If so, note this fact.
 446     if (defined $locals{$ref_func}) {
 447
 448         # only use locals if objcopy supports globalize-symbols
 449         if (!$can_use_local) {
 450             return;
 451         }
 452         $convert{$ref_func} = 1;
 453     }
 454
 455     # Loop through all the mcount caller offsets and print a reference
 456     # to the caller based from the ref_func.
 457     if (!$opened) {
 458         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 459         $opened = 1;
 460         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 461         print FILE "\t.align $alignment\n" if (defined($alignment));
 462     }
 463     foreach my $cur_offset (@offsets) {
 464         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 465     }
 466 }
 467
 468 #
 469 # Step 2: find the sections and mcount call sites
 470 #
 471 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
 472
 473 my $text;
 474
 475
 476 # read headers first
 477 my $read_headers = 1;
 478
 479 while (<IN>) {
 480
 481     if ($read_headers && /$mcount_section/) {
 482         #
 483         # Somehow the make process can execute this script on an
 484         # object twice. If it does, we would duplicate the mcount
 485         # section and it will cause the function tracer self test
 486         # to fail. Check if the mcount section exists, and if it does,
 487         # warn and exit.
 488         #
 489         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 490             "\tThis may be an indication that your build is corrupted.\n" .
 491             "\tDelete $inputfile and try again. If the same object file\n" .
 492             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 493         exit(-1);
 494     }
 495
 496     # is it a section?
 497     if (/$section_regex/) {
 498         $read_headers = 0;
 499
 500         # Only record text sections that we know are safe
 501         $read_function = defined($text_sections{$1});
 502         # print out any recorded offsets
 503         update_funcs();
 504
 505         # reset all markers and arrays
 506         $text_found = 0;
 507         undef($ref_func);
 508         undef(@offsets);
 509
 510     # section found, now is this a start of a function?
 511     } elsif ($read_function && /$function_regex/) {
 512         $text_found = 1;
 513         $text = $2;
 514
 515         # if this is either a local function or a weak function
 516         # keep looking for functions that are global that
 517         # we can use safely.
 518         if (!defined($locals{$text}) && !defined($weak{$text})) {
 519             $ref_func = $text;
 520             $read_function = 0;
 521             $offset = hex $1;
 522         } else {
 523             # if we already have a function, and this is weak, skip it
 524             if (!defined($ref_func) && !defined($weak{$text}) &&
 525                  # PPC64 can have symbols that start with .L and
 526                  # gcc considers these special. Don't use them!
 527                  $text !~ /^\.L/) {
 528                 $ref_func = $text;
 529                 $offset = hex $1;
 530             }
 531         }
 532     }
 533     # is this a call site to mcount? If so, record it to print later
 534     if ($text_found && /$mcount_regex/) {
 535         push(@offsets, (hex $1) + $mcount_adjust);
 536     }
 537 }
 538
 539 # dump out anymore offsets that may have been found
 540 update_funcs();
 541
 542 # If we did not find any mcount callers, we are done (do nothing).
 543 if (!$opened) {
 544     exit(0);
 545 }
 546
 547 close(FILE);
 548
 549 #
 550 # Step 3: Compile the file that holds the list of call sites to mcount.
 551 #
 552 `$cc -o $mcount_o -c $mcount_s`;
 553
 554 my @converts = keys %convert;
 555
 556 #
 557 # Step 4: Do we have sections that started with local functions?
 558 #
 559 if ($#converts >= 0) {
 560     my $globallist = "";
 561     my $locallist = "";
 562
 563     foreach my $con (@converts) {
 564         $globallist .= " --globalize-symbol $con";
 565         $locallist .= " --localize-symbol $con";
 566     }
 567
 568     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 569     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 570
 571     #
 572     # Step 5: set up each local function as a global
 573     #
 574     `$objcopy $globallist $inputfile $globalobj`;
 575
 576     #
 577     # Step 6: Link the global version to our list.
 578     #
 579     `$ld -r $globalobj $mcount_o -o $globalmix`;
 580
 581     #
 582     # Step 7: Convert the local functions back into local symbols
 583     #
 584     `$objcopy $locallist $globalmix $inputfile`;
 585
 586     # Remove the temp files
 587     `$rm $globalobj $globalmix`;
 588
 589 } else {
 590
 591     my $mix = $dirname . "/.tmp_mx_" . $filename;
 592
 593     #
 594     # Step 8: Link the object with our list of call sites object.
 595     #
 596     `$ld -r $inputfile $mcount_o -o $mix`;
 597
 598     #
 599     # Step 9: Move the result back to the original object.
 600     #
 601     `$mv $mix $inputfile`;
 602 }
 603
 604 # Clean up the temp files
 605 `$rm $mcount_o $mcount_s`;
 606
 607 exit(0);