arch/arm64/kernel/vmlinux.lds.S

   1 /*
   2  * ld script to make ARM Linux kernel
   3  * taken from the i386 version by Russell King
   4  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  */
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/cache.h>
   9 #include <asm/kernel-pgtable.h>
  10 #include <asm/thread_info.h>
  11 #include <asm/memory.h>
  12 #include <asm/page.h>
  13 #include <asm/pgtable.h>
  14
  15 #include "image.h"
  16
  17 /* .exit.text needed in case of alternative patching */
  18 #define ARM_EXIT_KEEP(x)        x
  19 #define ARM_EXIT_DISCARD(x)
  20
  21 OUTPUT_ARCH(aarch64)
  22 ENTRY(_text)
  23
  24 jiffies = jiffies_64;
  25
  26 #define HYPERVISOR_TEXT                                 \
  27         /*                                              \
  28          * Align to 4 KB so that                        \
  29          * a) the HYP vector table is at its minimum    \
  30          *    alignment of 2048 bytes                   \
  31          * b) the HYP init code will not cross a page   \
  32          *    boundary if its size does not exceed      \
  33          *    4 KB (see related ASSERT() below)         \
  34          */                                             \
  35         . = ALIGN(SZ_4K);                               \
  36         VMLINUX_SYMBOL(__hyp_idmap_text_start) = .;     \
  37         *(.hyp.idmap.text)                              \
  38         VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;       \
  39         VMLINUX_SYMBOL(__hyp_text_start) = .;           \
  40         *(.hyp.text)                                    \
  41         VMLINUX_SYMBOL(__hyp_text_end) = .;
  42
  43 #define IDMAP_TEXT                                      \
  44         . = ALIGN(SZ_4K);                               \
  45         VMLINUX_SYMBOL(__idmap_text_start) = .;         \
  46         *(.idmap.text)                                  \
  47         VMLINUX_SYMBOL(__idmap_text_end) = .;
  48
  49 /*
  50  * The size of the PE/COFF section that covers the kernel image, which
  51  * runs from stext to _edata, must be a round multiple of the PE/COFF
  52  * FileAlignment, which we set to its minimum value of 0x200. 'stext'
  53  * itself is 4 KB aligned, so padding out _edata to a 0x200 aligned
  54  * boundary should be sufficient.
  55  */
  56 PECOFF_FILE_ALIGNMENT = 0x200;
  57
  58 #ifdef CONFIG_EFI
  59 #define PECOFF_EDATA_PADDING    \
  60         .pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); }
  61 #else
  62 #define PECOFF_EDATA_PADDING
  63 #endif
  64
  65 #if defined(CONFIG_DEBUG_ALIGN_RODATA)
  66 /*
  67  *  4 KB granule:   1 level 2 entry
  68  * 16 KB granule: 128 level 3 entries, with contiguous bit
  69  * 64 KB granule:  32 level 3 entries, with contiguous bit
  70  */
  71 #define SEGMENT_ALIGN                   SZ_2M
  72 #else
  73 /*
  74  *  4 KB granule:  16 level 3 entries, with contiguous bit
  75  * 16 KB granule:   4 level 3 entries, without contiguous bit
  76  * 64 KB granule:   1 level 3 entry
  77  */
  78 #define SEGMENT_ALIGN                   SZ_64K
  79 #endif
  80
  81 SECTIONS
  82 {
  83         /*
  84          * XXX: The linker does not define how output sections are
  85          * assigned to input sections when there are multiple statements
  86          * matching the same input section name.  There is no documented
  87          * order of matching.
  88          */
  89         /DISCARD/ : {
  90                 ARM_EXIT_DISCARD(EXIT_TEXT)
  91                 ARM_EXIT_DISCARD(EXIT_DATA)
  92                 EXIT_CALL
  93                 *(.discard)
  94                 *(.discard.*)
  95                 *(.interp .dynamic)
  96         }
  97
  98         . = KIMAGE_VADDR + TEXT_OFFSET;
  99
 100         .head.text : {
 101                 _text = .;
 102                 HEAD_TEXT
 103         }
 104         .text : {                       /* Real text segment            */
 105                 _stext = .;             /* Text and read-only data      */
 106                         __exception_text_start = .;
 107                         *(.exception.text)
 108                         __exception_text_end = .;
 109                         IRQENTRY_TEXT
 110                         TEXT_TEXT
 111                         SCHED_TEXT
 112                         LOCK_TEXT
 113                         HYPERVISOR_TEXT
 114                         IDMAP_TEXT
 115                         *(.fixup)
 116                         *(.gnu.warning)
 117                 . = ALIGN(16);
 118                 *(.got)                 /* Global offset table          */
 119         }
 120
 121         . = ALIGN(SEGMENT_ALIGN);
 122         RO_DATA(PAGE_SIZE)              /* everything from this point to */
 123         EXCEPTION_TABLE(8)              /* _etext will be marked RO NX   */
 124         NOTES
 125
 126         . = ALIGN(SEGMENT_ALIGN);
 127         _etext = .;                     /* End of text and rodata section */
 128         __init_begin = .;
 129
 130         INIT_TEXT_SECTION(8)
 131         .exit.text : {
 132                 ARM_EXIT_KEEP(EXIT_TEXT)
 133         }
 134
 135         .init.data : {
 136                 INIT_DATA
 137                 INIT_SETUP(16)
 138                 INIT_CALLS
 139                 CON_INITCALL
 140                 SECURITY_INITCALL
 141                 INIT_RAM_FS
 142         }
 143         .exit.data : {
 144                 ARM_EXIT_KEEP(EXIT_DATA)
 145         }
 146
 147         PERCPU_SECTION(L1_CACHE_BYTES)
 148
 149         . = ALIGN(4);
 150         .altinstructions : {
 151                 __alt_instructions = .;
 152                 *(.altinstructions)
 153                 __alt_instructions_end = .;
 154         }
 155         .altinstr_replacement : {
 156                 *(.altinstr_replacement)
 157         }
 158         .rela : ALIGN(8) {
 159                 __reloc_start = .;
 160                 *(.rela .rela*)
 161                 __reloc_end = .;
 162         }
 163         .dynsym : ALIGN(8) {
 164                 __dynsym_start = .;
 165                 *(.dynsym)
 166         }
 167         .dynstr : {
 168                 *(.dynstr)
 169         }
 170         .hash : {
 171                 *(.hash)
 172         }
 173
 174         . = ALIGN(SEGMENT_ALIGN);
 175         __init_end = .;
 176
 177         _data = .;
 178         _sdata = .;
 179         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
 180         PECOFF_EDATA_PADDING
 181         _edata = .;
 182
 183         BSS_SECTION(0, 0, 0)
 184
 185         . = ALIGN(PAGE_SIZE);
 186         idmap_pg_dir = .;
 187         . += IDMAP_DIR_SIZE;
 188         swapper_pg_dir = .;
 189         . += SWAPPER_DIR_SIZE;
 190
 191         _end = .;
 192
 193         STABS_DEBUG
 194
 195         HEAD_SYMBOLS
 196 }
 197
 198 /*
 199  * The HYP init code and ID map text can't be longer than a page each,
 200  * and should not cross a page boundary.
 201  */
 202 ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 203         "HYP init code too big or misaligned")
 204 ASSERT(__idmap_text_end - (__idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 205         "ID map text too big or misaligned")
 206
 207 /*
 208  * If padding is applied before .head.text, virt<->phys conversions will fail.
 209  */
 210 ASSERT(_text == (KIMAGE_VADDR + TEXT_OFFSET), "HEAD is misaligned")