arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/cache.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/memory.h>
  10 #include <asm/page.h>
  11
  12 #define PROC_INFO                                                       \
  13         . = ALIGN(4);                                                   \
  14         VMLINUX_SYMBOL(__proc_info_begin) = .;                          \
  15         *(.proc.info.init)                                              \
  16         VMLINUX_SYMBOL(__proc_info_end) = .;
  17
  18 #define IDMAP_TEXT                                                      \
  19         ALIGN_FUNCTION();                                               \
  20         VMLINUX_SYMBOL(__idmap_text_start) = .;                         \
  21         *(.idmap.text)                                                  \
  22         VMLINUX_SYMBOL(__idmap_text_end) = .;                           \
  23         . = ALIGN(32);                                                  \
  24         VMLINUX_SYMBOL(__hyp_idmap_text_start) = .;                     \
  25         *(.hyp.idmap.text)                                              \
  26         VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;
  27
  28 #ifdef CONFIG_HOTPLUG_CPU
  29 #define ARM_CPU_DISCARD(x)
  30 #define ARM_CPU_KEEP(x)         x
  31 #else
  32 #define ARM_CPU_DISCARD(x)      x
  33 #define ARM_CPU_KEEP(x)
  34 #endif
  35
  36 #if (defined(CONFIG_SMP_ON_UP) && !defined(CONFIG_DEBUG_SPINLOCK)) || \
  37         defined(CONFIG_GENERIC_BUG)
  38 #define ARM_EXIT_KEEP(x)        x
  39 #define ARM_EXIT_DISCARD(x)
  40 #else
  41 #define ARM_EXIT_KEEP(x)
  42 #define ARM_EXIT_DISCARD(x)     x
  43 #endif
  44
  45 OUTPUT_ARCH(arm)
  46 ENTRY(stext)
  47
  48 #ifndef __ARMEB__
  49 jiffies = jiffies_64;
  50 #else
  51 jiffies = jiffies_64 + 4;
  52 #endif
  53
  54 SECTIONS
  55 {
  56         /*
  57          * XXX: The linker does not define how output sections are
  58          * assigned to input sections when there are multiple statements
  59          * matching the same input section name.  There is no documented
  60          * order of matching.
  61          *
  62          * unwind exit sections must be discarded before the rest of the
  63          * unwind sections get included.
  64          */
  65         /DISCARD/ : {
  66                 *(.ARM.exidx.exit.text)
  67                 *(.ARM.extab.exit.text)
  68                 ARM_CPU_DISCARD(*(.ARM.exidx.cpuexit.text))
  69                 ARM_CPU_DISCARD(*(.ARM.extab.cpuexit.text))
  70                 ARM_EXIT_DISCARD(EXIT_TEXT)
  71                 ARM_EXIT_DISCARD(EXIT_DATA)
  72                 EXIT_CALL
  73 #ifndef CONFIG_HOTPLUG
  74                 *(.ARM.exidx.devexit.text)
  75                 *(.ARM.extab.devexit.text)
  76 #endif
  77 #ifndef CONFIG_MMU
  78                 *(.fixup)
  79                 *(__ex_table)
  80 #endif
  81 #ifndef CONFIG_SMP_ON_UP
  82                 *(.alt.smp.init)
  83 #endif
  84                 *(.pie.*)
  85                 *(.ARM.exidx.pie.*.text)
  86                 *(.discard)
  87                 *(.discard.*)
  88         }
  89
  90 #ifdef CONFIG_XIP_KERNEL
  91         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  92 #else
  93         . = PAGE_OFFSET + TEXT_OFFSET;
  94 #endif
  95         .head.text : {
  96                 _text = .;
  97                 HEAD_TEXT
  98         }
  99         .text : {                       /* Real text segment            */
 100                 _stext = .;             /* Text and read-only data      */
 101                         __exception_text_start = .;
 102                         *(.exception.text)
 103                         __exception_text_end = .;
 104                         IRQENTRY_TEXT
 105                         TEXT_TEXT
 106                         SCHED_TEXT
 107                         LOCK_TEXT
 108                         KPROBES_TEXT
 109                         IDMAP_TEXT
 110 #ifdef CONFIG_MMU
 111                         *(.fixup)
 112 #endif
 113                         *(.gnu.warning)
 114                         *(.glue_7)
 115                         *(.glue_7t)
 116                 . = ALIGN(4);
 117                 *(.got)                 /* Global offset table          */
 118                         ARM_CPU_KEEP(PROC_INFO)
 119         }
 120
 121         RO_DATA(PAGE_SIZE)
 122
 123         . = ALIGN(4);
 124         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
 125                 __start___ex_table = .;
 126 #ifdef CONFIG_MMU
 127                 *(__ex_table)
 128 #endif
 129                 __stop___ex_table = .;
 130         }
 131
 132 #ifdef CONFIG_ARM_UNWIND
 133         /*
 134          * Stack unwinding tables
 135          */
 136         . = ALIGN(8);
 137         .ARM.unwind_idx : {
 138                 __start_unwind_idx = .;
 139                 *(.ARM.exidx*)
 140                 __stop_unwind_idx = .;
 141         }
 142         .ARM.unwind_tab : {
 143                 __start_unwind_tab = .;
 144                 *(.ARM.extab*)
 145                 __stop_unwind_tab = .;
 146         }
 147 #endif
 148
 149         NOTES
 150
 151         _etext = .;                     /* End of text and rodata section */
 152
 153 #ifndef CONFIG_XIP_KERNEL
 154         . = ALIGN(PAGE_SIZE);
 155         __init_begin = .;
 156 #endif
 157         /*
 158          * The vectors and stubs are relocatable code, and the
 159          * only thing that matters is their relative offsets
 160          */
 161         __vectors_start = .;
 162         .vectors 0 : AT(__vectors_start) {
 163                 *(.vectors)
 164         }
 165         . = __vectors_start + SIZEOF(.vectors);
 166         __vectors_end = .;
 167
 168         __stubs_start = .;
 169         .stubs 0x1000 : AT(__stubs_start) {
 170                 *(.stubs)
 171         }
 172         . = __stubs_start + SIZEOF(.stubs);
 173         __stubs_end = .;
 174
 175         INIT_TEXT_SECTION(8)
 176         .exit.text : {
 177                 ARM_EXIT_KEEP(EXIT_TEXT)
 178         }
 179         .init.proc.info : {
 180                 ARM_CPU_DISCARD(PROC_INFO)
 181         }
 182         .init.arch.info : {
 183                 __arch_info_begin = .;
 184                 *(.arch.info.init)
 185                 __arch_info_end = .;
 186         }
 187         .init.tagtable : {
 188                 __tagtable_begin = .;
 189                 *(.taglist.init)
 190                 __tagtable_end = .;
 191         }
 192 #ifdef CONFIG_SMP_ON_UP
 193         .init.smpalt : {
 194                 __smpalt_begin = .;
 195                 *(.alt.smp.init)
 196                 __smpalt_end = .;
 197         }
 198 #endif
 199         .init.pv_table : {
 200                 __pv_table_begin = .;
 201                 *(.pv_table)
 202                 __pv_table_end = .;
 203         }
 204         .init.data : {
 205 #ifndef CONFIG_XIP_KERNEL
 206                 INIT_DATA
 207 #endif
 208                 INIT_SETUP(16)
 209                 INIT_CALLS
 210                 CON_INITCALL
 211                 SECURITY_INITCALL
 212                 INIT_RAM_FS
 213         }
 214 #ifndef CONFIG_XIP_KERNEL
 215         .exit.data : {
 216                 ARM_EXIT_KEEP(EXIT_DATA)
 217         }
 218 #endif
 219
 220 #ifdef CONFIG_SMP
 221         PERCPU_SECTION(L1_CACHE_BYTES)
 222 #endif
 223
 224 #ifdef CONFIG_XIP_KERNEL
 225         __data_loc = ALIGN(4);          /* location in binary */
 226         . = PAGE_OFFSET + TEXT_OFFSET;
 227 #else
 228         __init_end = .;
 229         . = ALIGN(THREAD_SIZE);
 230         __data_loc = .;
 231 #endif
 232
 233         .data : AT(__data_loc) {
 234                 _data = .;              /* address in memory */
 235                 _sdata = .;
 236
 237                 /*
 238                  * first, the init task union, aligned
 239                  * to an 8192 byte boundary.
 240                  */
 241                 INIT_TASK_DATA(THREAD_SIZE)
 242
 243 #ifdef CONFIG_XIP_KERNEL
 244                 . = ALIGN(PAGE_SIZE);
 245                 __init_begin = .;
 246                 INIT_DATA
 247                 ARM_EXIT_KEEP(EXIT_DATA)
 248                 . = ALIGN(PAGE_SIZE);
 249                 __init_end = .;
 250 #endif
 251
 252                 NOSAVE_DATA
 253                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 254                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 255
 256                 /*
 257                  * and the usual data section
 258                  */
 259                 DATA_DATA
 260                 CONSTRUCTORS
 261
 262                 _edata = .;
 263         }
 264         _edata_loc = __data_loc + SIZEOF(.data);
 265
 266 #ifdef CONFIG_HAVE_TCM
 267         /*
 268          * We align everything to a page boundary so we can
 269          * free it after init has commenced and TCM contents have
 270          * been copied to its destination.
 271          */
 272         .tcm_start : {
 273                 . = ALIGN(PAGE_SIZE);
 274                 __tcm_start = .;
 275                 __itcm_start = .;
 276         }
 277
 278         /*
 279          * Link these to the ITCM RAM
 280          * Put VMA to the TCM address and LMA to the common RAM
 281          * and we'll upload the contents from RAM to TCM and free
 282          * the used RAM after that.
 283          */
 284         .text_itcm ITCM_OFFSET : AT(__itcm_start)
 285         {
 286                 __sitcm_text = .;
 287                 *(.tcm.text)
 288                 *(.tcm.rodata)
 289                 . = ALIGN(4);
 290                 __eitcm_text = .;
 291         }
 292
 293         /*
 294          * Reset the dot pointer, this is needed to create the
 295          * relative __dtcm_start below (to be used as extern in code).
 296          */
 297         . = ADDR(.tcm_start) + SIZEOF(.tcm_start) + SIZEOF(.text_itcm);
 298
 299         .dtcm_start : {
 300                 __dtcm_start = .;
 301         }
 302
 303         /* TODO: add remainder of ITCM as well, that can be used for data! */
 304         .data_dtcm DTCM_OFFSET : AT(__dtcm_start)
 305         {
 306                 . = ALIGN(4);
 307                 __sdtcm_data = .;
 308                 *(.tcm.data)
 309                 . = ALIGN(4);
 310                 __edtcm_data = .;
 311         }
 312
 313         /* Reset the dot pointer or the linker gets confused */
 314         . = ADDR(.dtcm_start) + SIZEOF(.data_dtcm);
 315
 316         /* End marker for freeing TCM copy in linked object */
 317         .tcm_end : AT(ADDR(.dtcm_start) + SIZEOF(.data_dtcm)){
 318                 . = ALIGN(PAGE_SIZE);
 319                 __tcm_end = .;
 320         }
 321 #endif
 322
 323         BSS_SECTION(0, 0, 0)
 324         _end = .;
 325
 326         STABS_DEBUG
 327         .comment 0 : { *(.comment) }
 328 }
 329
 330 /*
 331  * These must never be empty
 332  * If you have to comment these two assert statements out, your
 333  * binutils is too old (for other reasons as well)
 334  */
 335 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 336 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
 337 /*
 338  * The HYP init code can't be more than a page long.
 339  * The above comment applies as well.
 340  */
 341 ASSERT(((__hyp_idmap_text_end - __hyp_idmap_text_start) <= PAGE_SIZE), "HYP init code too big")