tools/llvm-upgrade/UpgradeLexer.l

   1 /*===-- UpgradeLexer.l - Scanner for 1.9 assembly files --------*- C++ -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Reid Spencer and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //  This file implements the flex scanner for LLVM 1.9 assembly languages files.
  11 //
  12 //===----------------------------------------------------------------------===*/
  13
  14 %option prefix="Upgrade"
  15 %option yylineno
  16 %option nostdinit
  17 %option never-interactive
  18 %option batch
  19 %option noyywrap
  20 %option nodefault
  21 %option 8bit
  22 %option outfile="UpgradeLexer.cpp"
  23 %option ecs
  24 %option noreject
  25 %option noyymore
  26
  27 %{
  28 #include "UpgradeInternals.h"
  29 #include "llvm/Module.h"
  30 #include <list>
  31 #include "UpgradeParser.h"
  32 #include <cctype>
  33 #include <cstdlib>
  34
  35 #define YY_INPUT(buf,result,max_size) \
  36 { \
  37   if (LexInput->good() && !LexInput->eof()) { \
  38     LexInput->read(buf,max_size); \
  39     result = LexInput->gcount(); \
  40   } else {\
  41     result = YY_NULL; \
  42   } \
  43 }
  44
  45 #define YY_NEVER_INTERACTIVE 1
  46
  47 // Construct a token value for a non-obsolete token
  48 #define RET_TOK(type, Enum, sym) \
  49   Upgradelval.type = Enum; \
  50   return sym
  51
  52 #define RET_TY(sym,NewTY,sign) \
  53   Upgradelval.PrimType.T = NewTY; \
  54   Upgradelval.PrimType.S = sign; \
  55   return sym
  56
  57 namespace llvm {
  58
  59 // TODO: All of the static identifiers are figured out by the lexer,
  60 // these should be hashed to reduce the lexer size
  61
  62 // UnEscapeLexed - Run through the specified buffer and change \xx codes to the
  63 // appropriate character.  If AllowNull is set to false, a \00 value will cause
  64 // an exception to be thrown.
  65 //
  66 // If AllowNull is set to true, the return value of the function points to the
  67 // last character of the string in memory.
  68 //
  69 char *UnEscapeLexed(char *Buffer, bool AllowNull) {
  70   char *BOut = Buffer;
  71   for (char *BIn = Buffer; *BIn; ) {
  72     if (BIn[0] == '\\' && isxdigit(BIn[1]) && isxdigit(BIn[2])) {
  73       char Tmp = BIn[3]; BIn[3] = 0;     // Terminate string
  74       *BOut = (char)strtol(BIn+1, 0, 16);  // Convert to number
  75       if (!AllowNull && !*BOut)
  76         error("String literal cannot accept \\00 escape!");
  77
  78       BIn[3] = Tmp;                  // Restore character
  79       BIn += 3;                      // Skip over handled chars
  80       ++BOut;
  81     } else {
  82       *BOut++ = *BIn++;
  83     }
  84   }
  85
  86   return BOut;
  87 }
  88
  89 // atoull - Convert an ascii string of decimal digits into the unsigned long
  90 // long representation... this does not have to do input error checking,
  91 // because we know that the input will be matched by a suitable regex...
  92 //
  93 static uint64_t atoull(const char *Buffer) {
  94   uint64_t Result = 0;
  95   for (; *Buffer; Buffer++) {
  96     uint64_t OldRes = Result;
  97     Result *= 10;
  98     Result += *Buffer-'0';
  99     if (Result < OldRes)   // Uh, oh, overflow detected!!!
 100       error("constant bigger than 64 bits detected!");
 101   }
 102   return Result;
 103 }
 104
 105 static uint64_t HexIntToVal(const char *Buffer) {
 106   uint64_t Result = 0;
 107   for (; *Buffer; ++Buffer) {
 108     uint64_t OldRes = Result;
 109     Result *= 16;
 110     char C = *Buffer;
 111     if (C >= '0' && C <= '9')
 112       Result += C-'0';
 113     else if (C >= 'A' && C <= 'F')
 114       Result += C-'A'+10;
 115     else if (C >= 'a' && C <= 'f')
 116       Result += C-'a'+10;
 117
 118     if (Result < OldRes)   // Uh, oh, overflow detected!!!
 119       error("constant bigger than 64 bits detected!");
 120   }
 121   return Result;
 122 }
 123
 124
 125 // HexToFP - Convert the ascii string in hexidecimal format to the floating
 126 // point representation of it.
 127 //
 128 static double HexToFP(const char *Buffer) {
 129   // Behave nicely in the face of C TBAA rules... see:
 130   // http://www.nullstone.com/htmls/category/aliastyp.htm
 131   union {
 132     uint64_t UI;
 133     double FP;
 134   } UIntToFP;
 135   UIntToFP.UI = HexIntToVal(Buffer);
 136
 137   assert(sizeof(double) == sizeof(uint64_t) &&
 138          "Data sizes incompatible on this target!");
 139   return UIntToFP.FP;   // Cast Hex constant to double
 140 }
 141
 142
 143 } // End llvm namespace
 144
 145 using namespace llvm;
 146
 147 %}
 148
 149
 150
 151 /* Comments start with a ; and go till end of line */
 152 Comment    ;.*
 153
 154 /* Variable(Value) identifiers start with a % sign */
 155 VarID       [%@][-a-zA-Z$._][-a-zA-Z$._0-9]*
 156
 157 /* Label identifiers end with a colon */
 158 Label       [-a-zA-Z$._0-9]+:
 159 QuoteLabel \"[^\"]+\":
 160
 161 /* Quoted names can contain any character except " and \ */
 162 StringConstant @?\"[^\"]*\"
 163
 164
 165 /* [PN]Integer: match positive and negative literal integer values that
 166  * are preceeded by a '%' character.  These represent unnamed variable slots.
 167  */
 168 EPInteger     %[0-9]+
 169 ENInteger    %-[0-9]+
 170
 171
 172 /* E[PN]Integer: match positive and negative literal integer values */
 173 PInteger   [0-9]+
 174 NInteger  -[0-9]+
 175
 176 /* FPConstant - A Floating point constant.
 177  */
 178 FPConstant [-+]?[0-9]+[.][0-9]*([eE][-+]?[0-9]+)?
 179
 180 /* HexFPConstant - Floating point constant represented in IEEE format as a
 181  *  hexadecimal number for when exponential notation is not precise enough.
 182  */
 183 HexFPConstant 0x[0-9A-Fa-f]+
 184
 185 /* HexIntConstant - Hexadecimal constant generated by the CFE to avoid forcing
 186  * it to deal with 64 bit numbers.
 187  */
 188 HexIntConstant [us]0x[0-9A-Fa-f]+
 189 %%
 190
 191 {Comment}       { /* Ignore comments for now */ }
 192
 193 begin           { return BEGINTOK; }
 194 end             { return ENDTOK; }
 195 true            { return TRUETOK;  }
 196 false           { return FALSETOK; }
 197 declare         { return DECLARE; }
 198 global          { return GLOBAL; }
 199 constant        { return CONSTANT; }
 200 internal        { return INTERNAL; }
 201 linkonce        { return LINKONCE; }
 202 weak            { return WEAK; }
 203 appending       { return APPENDING; }
 204 dllimport       { return DLLIMPORT; }
 205 dllexport       { return DLLEXPORT; }
 206 extern_weak     { return EXTERN_WEAK; }
 207 uninitialized   { return EXTERNAL; }    /* Deprecated, turn into external */
 208 external        { return EXTERNAL; }
 209 implementation  { return IMPLEMENTATION; }
 210 zeroinitializer { return ZEROINITIALIZER; }
 211 \.\.\.          { return DOTDOTDOT; }
 212 undef           { return UNDEF; }
 213 null            { return NULL_TOK; }
 214 to              { return TO; }
 215 except          { return EXCEPT; }
 216 not             { return NOT; }  /* Deprecated, turned into XOR */
 217 tail            { return TAIL; }
 218 target          { return TARGET; }
 219 triple          { return TRIPLE; }
 220 deplibs         { return DEPLIBS; }
 221 endian          { return ENDIAN; }
 222 pointersize     { return POINTERSIZE; }
 223 datalayout      { return DATALAYOUT; }
 224 little          { return LITTLE; }
 225 big             { return BIG; }
 226 volatile        { return VOLATILE; }
 227 align           { return ALIGN;  }
 228 section         { return SECTION; }
 229 module          { return MODULE; }
 230 asm             { return ASM_TOK; }
 231 sideeffect      { return SIDEEFFECT; }
 232
 233 cc              { return CC_TOK; }
 234 ccc             { return CCC_TOK; }
 235 csretcc         { return CSRETCC_TOK; }
 236 fastcc          { return FASTCC_TOK; }
 237 coldcc          { return COLDCC_TOK; }
 238 x86_stdcallcc   { return X86_STDCALLCC_TOK; }
 239 x86_fastcallcc  { return X86_FASTCALLCC_TOK; }
 240
 241 sbyte           { RET_TY(SBYTE,  Type::Int8Ty,  Signed);  }
 242 ubyte           { RET_TY(UBYTE,  Type::Int8Ty,  Unsigned); }
 243 i8              { RET_TY(UBYTE,  Type::Int8Ty,  Unsigned); }
 244 short           { RET_TY(SHORT,  Type::Int16Ty, Signed);  }
 245 ushort          { RET_TY(USHORT, Type::Int16Ty, Unsigned); }
 246 i16             { RET_TY(USHORT, Type::Int16Ty, Unsigned); }
 247 int             { RET_TY(INT,    Type::Int32Ty, Signed);  }
 248 uint            { RET_TY(UINT,   Type::Int32Ty, Unsigned); }
 249 i32             { RET_TY(UINT,   Type::Int32Ty, Unsigned); }
 250 long            { RET_TY(LONG,   Type::Int64Ty, Signed);  }
 251 ulong           { RET_TY(ULONG,  Type::Int64Ty, Unsigned); }
 252 i64             { RET_TY(ULONG,  Type::Int64Ty, Unsigned); }
 253 void            { RET_TY(VOID,   Type::VoidTy,  Signless  ); }
 254 bool            { RET_TY(BOOL,   Type::Int1Ty,  Unsigned  ); }
 255 i1              { RET_TY(BOOL,   Type::Int1Ty,  Unsigned  ); }
 256 float           { RET_TY(FLOAT,  Type::FloatTy, Signless ); }
 257 double          { RET_TY(DOUBLE, Type::DoubleTy,Signless); }
 258 label           { RET_TY(LABEL,  Type::LabelTy, Signless ); }
 259 type            { return TYPE;   }
 260 opaque          { return OPAQUE; }
 261
 262 add             { RET_TOK(BinaryOpVal, AddOp, ADD); }
 263 sub             { RET_TOK(BinaryOpVal, SubOp, SUB); }
 264 mul             { RET_TOK(BinaryOpVal, MulOp, MUL); }
 265 div             { RET_TOK(BinaryOpVal, DivOp,  DIV); }
 266 udiv            { RET_TOK(BinaryOpVal, UDivOp, UDIV); }
 267 sdiv            { RET_TOK(BinaryOpVal, SDivOp, SDIV); }
 268 fdiv            { RET_TOK(BinaryOpVal, FDivOp, FDIV); }
 269 rem             { RET_TOK(BinaryOpVal, RemOp,  REM); }
 270 urem            { RET_TOK(BinaryOpVal, URemOp, UREM); }
 271 srem            { RET_TOK(BinaryOpVal, SRemOp, SREM); }
 272 frem            { RET_TOK(BinaryOpVal, FRemOp, FREM); }
 273 and             { RET_TOK(BinaryOpVal, AndOp, AND); }
 274 or              { RET_TOK(BinaryOpVal, OrOp , OR ); }
 275 xor             { RET_TOK(BinaryOpVal, XorOp, XOR); }
 276 setne           { RET_TOK(BinaryOpVal, SetNE, SETNE); }
 277 seteq           { RET_TOK(BinaryOpVal, SetEQ, SETEQ); }
 278 setlt           { RET_TOK(BinaryOpVal, SetLT, SETLT); }
 279 setgt           { RET_TOK(BinaryOpVal, SetGT, SETGT); }
 280 setle           { RET_TOK(BinaryOpVal, SetLE, SETLE); }
 281 setge           { RET_TOK(BinaryOpVal, SetGE, SETGE); }
 282 shl             { RET_TOK(BinaryOpVal, ShlOp, SHL); }
 283 shr             { RET_TOK(BinaryOpVal, ShrOp, SHR); }
 284 lshr            { RET_TOK(BinaryOpVal, LShrOp, LSHR); }
 285 ashr            { RET_TOK(BinaryOpVal, AShrOp, ASHR); }
 286
 287 icmp            { RET_TOK(OtherOpVal, ICmpOp, ICMP); }
 288 fcmp            { RET_TOK(OtherOpVal, FCmpOp, FCMP); }
 289
 290 eq              { return EQ; }
 291 ne              { return NE; }
 292 slt             { return SLT; }
 293 sgt             { return SGT; }
 294 sle             { return SLE; }
 295 sge             { return SGE; }
 296 ult             { return ULT; }
 297 ugt             { return UGT; }
 298 ule             { return ULE; }
 299 uge             { return UGE; }
 300 oeq             { return OEQ; }
 301 one             { return ONE; }
 302 olt             { return OLT; }
 303 ogt             { return OGT; }
 304 ole             { return OLE; }
 305 oge             { return OGE; }
 306 ord             { return ORD; }
 307 uno             { return UNO; }
 308 ueq             { return UEQ; }
 309 une             { return UNE; }
 310
 311 phi             { RET_TOK(OtherOpVal, PHIOp, PHI_TOK); }
 312 call            { RET_TOK(OtherOpVal, CallOp, CALL); }
 313 cast            { RET_TOK(CastOpVal, CastOp, CAST);  }
 314 trunc           { RET_TOK(CastOpVal, TruncOp, TRUNC); }
 315 zext            { RET_TOK(CastOpVal, ZExtOp , ZEXT); }
 316 sext            { RET_TOK(CastOpVal, SExtOp, SEXT); }
 317 fptrunc         { RET_TOK(CastOpVal, FPTruncOp, FPTRUNC); }
 318 fpext           { RET_TOK(CastOpVal, FPExtOp, FPEXT); }
 319 fptoui          { RET_TOK(CastOpVal, FPToUIOp, FPTOUI); }
 320 fptosi          { RET_TOK(CastOpVal, FPToSIOp, FPTOSI); }
 321 uitofp          { RET_TOK(CastOpVal, UIToFPOp, UITOFP); }
 322 sitofp          { RET_TOK(CastOpVal, SIToFPOp, SITOFP); }
 323 ptrtoint        { RET_TOK(CastOpVal, PtrToIntOp, PTRTOINT); }
 324 inttoptr        { RET_TOK(CastOpVal, IntToPtrOp, INTTOPTR); }
 325 bitcast         { RET_TOK(CastOpVal, BitCastOp, BITCAST); }
 326 select          { RET_TOK(OtherOpVal, SelectOp, SELECT); }
 327 vanext          { return VANEXT_old; }
 328 vaarg           { return VAARG_old; }
 329 va_arg          { RET_TOK(OtherOpVal, VAArg , VAARG); }
 330 ret             { RET_TOK(TermOpVal, RetOp, RET); }
 331 br              { RET_TOK(TermOpVal, BrOp, BR); }
 332 switch          { RET_TOK(TermOpVal, SwitchOp, SWITCH); }
 333 invoke          { RET_TOK(TermOpVal, InvokeOp, INVOKE); }
 334 unwind          { return UNWIND; }
 335 unreachable     { RET_TOK(TermOpVal, UnreachableOp, UNREACHABLE); }
 336
 337 malloc          { RET_TOK(MemOpVal, MallocOp, MALLOC); }
 338 alloca          { RET_TOK(MemOpVal, AllocaOp, ALLOCA); }
 339 free            { RET_TOK(MemOpVal, FreeOp, FREE); }
 340 load            { RET_TOK(MemOpVal, LoadOp, LOAD); }
 341 store           { RET_TOK(MemOpVal, StoreOp, STORE); }
 342 getelementptr   { RET_TOK(MemOpVal, GetElementPtrOp, GETELEMENTPTR); }
 343
 344 extractelement  { RET_TOK(OtherOpVal, ExtractElementOp, EXTRACTELEMENT); }
 345 insertelement   { RET_TOK(OtherOpVal, InsertElementOp, INSERTELEMENT); }
 346 shufflevector   { RET_TOK(OtherOpVal, ShuffleVectorOp, SHUFFLEVECTOR); }
 347
 348
 349 {VarID}         {
 350                   UnEscapeLexed(yytext+1);
 351                   Upgradelval.StrVal = strdup(yytext+1);             // Skip %
 352                   return VAR_ID;
 353                 }
 354 {Label}         {
 355                   yytext[strlen(yytext)-1] = 0;  // nuke colon
 356                   UnEscapeLexed(yytext);
 357                   Upgradelval.StrVal = strdup(yytext);
 358                   return LABELSTR;
 359                 }
 360 {QuoteLabel}    {
 361                   yytext[strlen(yytext)-2] = 0;  // nuke colon, end quote
 362                   UnEscapeLexed(yytext+1);
 363                   Upgradelval.StrVal = strdup(yytext+1);
 364                   return LABELSTR;
 365                 }
 366
 367 {StringConstant} { // Note that we cannot unescape a string constant here!  The
 368                    // string constant might contain a \00 which would not be
 369                    // understood by the string stuff.  It is valid to make a
 370                    // [sbyte] c"Hello World\00" constant, for example.
 371                    //
 372                    yytext[strlen(yytext)-1] = 0;           // nuke end quote
 373                    Upgradelval.StrVal = strdup(yytext+1);  // Nuke start quote
 374                    return STRINGCONSTANT;
 375                  }
 376
 377
 378 {PInteger}      { Upgradelval.UInt64Val = atoull(yytext); return EUINT64VAL; }
 379 {NInteger}      {
 380                   uint64_t Val = atoull(yytext+1);
 381                   // +1:  we have bigger negative range
 382                   if (Val > (uint64_t)INT64_MAX+1)
 383                     error("Constant too large for signed 64 bits!");
 384                   Upgradelval.SInt64Val = -Val;
 385                   return ESINT64VAL;
 386                 }
 387 {HexIntConstant} {
 388                    Upgradelval.UInt64Val = HexIntToVal(yytext+3);
 389                    return yytext[0] == 's' ? ESINT64VAL : EUINT64VAL;
 390                  }
 391
 392 {EPInteger}     {
 393                   uint64_t Val = atoull(yytext+1);
 394                   if ((unsigned)Val != Val)
 395                     error("Invalid value number (too large)!");
 396                   Upgradelval.UIntVal = unsigned(Val);
 397                   return UINTVAL;
 398                 }
 399 {ENInteger}     {
 400                   uint64_t Val = atoull(yytext+2);
 401                   // +1:  we have bigger negative range
 402                   if (Val > (uint64_t)INT32_MAX+1)
 403                     error("Constant too large for signed 32 bits!");
 404                   Upgradelval.SIntVal = (int)-Val;
 405                   return SINTVAL;
 406                 }
 407
 408 {FPConstant}    { Upgradelval.FPVal = atof(yytext); return FPVAL; }
 409 {HexFPConstant} { Upgradelval.FPVal = HexToFP(yytext); return FPVAL; }
 410
 411 <<EOF>>         {
 412                   /* Make sure to free the internal buffers for flex when we are
 413                    * done reading our input!
 414                    */
 415                   yy_delete_buffer(YY_CURRENT_BUFFER);
 416                   return EOF;
 417                 }
 418
 419 [ \r\t\n]       { /* Ignore whitespace */ }
 420 .               { return yytext[0]; }
 421
 422 %%