tools/llvm-config/llvm-config.in.in

   1 #!@PERL@
   2 ##===- tools/llvm-config ---------------------------------------*- perl -*-===##
   3 #
   4 #                     The LLVM Compiler Infrastructure
   5 #
   6 # This file was developed by Eric Kidd and is distributed under
   7 # the University of Illinois Open Source License. See LICENSE.TXT for details.
   8 #
   9 ##===----------------------------------------------------------------------===##
  10 #
  11 # Synopsis: Prints out compiler options needed to build against an installed
  12 #           copy of LLVM.
  13 #
  14 # Syntax:   llvm-config OPTIONS... [COMPONENTS...]
  15 #
  16 ##===----------------------------------------------------------------------===##
  17
  18 use 5.006;
  19 use strict;
  20 use warnings;
  21
  22 #---- begin autoconf values ----
  23 my $PACKAGE_NAME        = q{@PACKAGE_NAME@};
  24 my $VERSION             = q{@PACKAGE_VERSION@};
  25 my $PREFIX              = q{@LLVM_PREFIX@};
  26 my $LLVM_CONFIGTIME     = q{@LLVM_CONFIGTIME@};
  27 my $LLVM_SRC_ROOT       = q{@abs_top_srcdir@};
  28 my $LLVM_OBJ_ROOT       = q{@abs_top_builddir@};
  29 my $LLVM_ON_WIN32       = q{@LLVM_ON_WIN32@};
  30 my $LLVM_ON_UNIX        = q{@LLVM_ON_UNIX@};
  31 my $LLVMGCCDIR          = q{@LLVMGCCDIR@};
  32 my $LLVMGCC             = q{@LLVMGCC@};
  33 my $LLVMGXX             = q{@LLVMGXX@};
  34 my $LLVMGCC_VERSION     = q{@LLVMGCC_VERSION@};
  35 my $LLVMGCC_MAJVERS     = q{@LLVMGCC_MAJVERS@};
  36 my $ENDIAN              = q{@ENDIAN@};
  37 my $SHLIBEXT            = q{@SHLIBEXT@};
  38 my $EXEEXT              = q{@EXEEXT@};
  39 my $OS                  = q{@OS@};
  40 my $ARCH                = lc(q{@ARCH@});
  41 my $TARGET_TRIPLE       = q{@target@};
  42 my $TARGETS_TO_BUILD    = q{@TARGETS_TO_BUILD@};
  43 my $TARGET_HAS_JIT      = q{@TARGET_HAS_JIT@};
  44 my @TARGETS_BUILT       = map { lc($_) } qw{@TARGETS_TO_BUILD@};
  45 #---- end autoconf values ----
  46
  47 #---- begin Makefile values ----
  48 my $CXXFLAGS            = q{@LLVM_CXXFLAGS@};
  49 my $LDFLAGS             = q{@LLVM_LDFLAGS@};
  50 my $LLVM_BUILDMODE      = q{@LLVM_BUILDMODE@};
  51 #---- end Makefile values ----
  52
  53 # Figure out where llvm-config is being run from.  Primarily, we care if it has
  54 # been installed, or is running from the build directory, which changes the
  55 # locations of some files.
  56
  57 # Convert the current executable name into its directory (e.g. ".").
  58 my ($RUN_DIR) = ($0 =~ /^(.*)\/.*$/);
  59
  60 # Turn the directory into an absolute directory on the file system, also pop up
  61 # from "bin" into the build or prefix dir.
  62 my $ABS_RUN_DIR = `cd $RUN_DIR/..; pwd`;
  63 chomp($ABS_RUN_DIR);
  64
  65 # Compute the absolute object directory build, e.g. "foo/llvm/Debug".
  66 my $ABS_OBJ_ROOT = `cd $LLVM_OBJ_ROOT/$LLVM_BUILDMODE; pwd`;
  67 chomp($ABS_OBJ_ROOT);
  68
  69 my $INCLUDEDIR = "$ABS_RUN_DIR/include";
  70 my $LIBDIR     = "$ABS_RUN_DIR/lib";
  71 my $BINDIR     = "$ABS_RUN_DIR/bin";
  72 if ($ABS_RUN_DIR eq $ABS_OBJ_ROOT) {
  73   # If we are running out of the build directory, the include dir is in the
  74   # srcdir.
  75   $INCLUDEDIR = "$LLVM_SRC_ROOT/include";
  76 } else {
  77   # If installed, ignore the prefix the tree was configured with, use the
  78   # current prefix.
  79   $PREFIX = $ABS_RUN_DIR;
  80 }
  81
  82 sub usage;
  83 sub fix_library_names (@);
  84 sub expand_dependecies (@);
  85 sub name_map_entries;
  86
  87 # Parse our command-line arguments.
  88 usage if @ARGV == 0;
  89 my @components;
  90 my $has_opt = 0;
  91 my $want_libs = 0;
  92 my $want_libnames = 0;
  93 my $want_components = 0;
  94 foreach my $arg (@ARGV) {
  95     if ($arg =~ /^-/) {
  96         if ($arg eq "--version") {
  97             $has_opt = 1; print "$VERSION\n";
  98         } elsif ($arg eq "--prefix") {
  99             $has_opt = 1; print "$PREFIX\n";
 100         } elsif ($arg eq "--bindir") {
 101             $has_opt = 1; print "$BINDIR\n";
 102         } elsif ($arg eq "--includedir") {
 103             $has_opt = 1; print "$INCLUDEDIR\n";
 104         } elsif ($arg eq "--libdir") {
 105             $has_opt = 1; print "$LIBDIR\n";
 106         } elsif ($arg eq "--cxxflags") {
 107             $has_opt = 1; print "-I$INCLUDEDIR $CXXFLAGS\n";
 108         } elsif ($arg eq "--ldflags") {
 109             $has_opt = 1; print "-L$LIBDIR $LDFLAGS\n";
 110         } elsif ($arg eq "--libs") {
 111             $has_opt = 1; $want_libs = 1;
 112         } elsif ($arg eq "--libnames") {
 113             $has_opt = 1; $want_libnames = 1;
 114         } elsif ($arg eq "--components") {
 115             $has_opt = 1; print join(' ', name_map_entries), "\n";
 116         } elsif ($arg eq "--targets-built") {
 117             $has_opt = 1; print join(' ', @TARGETS_BUILT), "\n";
 118         } elsif ($arg eq "--build-mode") {
 119             $has_opt = 1; print "$LLVM_BUILDMODE\n";
 120         } elsif ($arg eq "--obj-root") {
 121             $has_opt = 1; print `cd $LLVM_OBJ_ROOT/; pwd` . "\n";
 122         } elsif ($arg eq "--src-root") {
 123             $has_opt = 1; print `cd $LLVM_SRC_ROOT/; pwd` . "\n";
 124         } else {
 125             usage();
 126         }
 127     } else {
 128         push @components, $arg;
 129     }
 130 }
 131
 132 # If no options were specified, fail.
 133 usage unless $has_opt;
 134
 135 # If no components were specified, default to 'all'.
 136 if (@components == 0) {
 137     push @components, 'all';
 138 }
 139
 140 # Handle any arguments which require building our dependency graph.
 141 if ($want_libs || $want_libnames) {
 142     my @libs = expand_dependecies(@components);
 143     if ($want_libs) {
 144         print join(' ', fix_library_names(@libs)), "\n";
 145     }
 146     if ($want_libnames) {
 147         print join(' ',  @libs), "\n";
 148     }
 149 }
 150
 151 exit 0;
 152
 153 #==========================================================================
 154 #  Support Routines
 155 #==========================================================================
 156
 157 sub usage {
 158     print STDERR <<__EOD__;
 159 Usage: llvm-config <OPTION>... [<COMPONENT>...]
 160
 161 Get various configuration information needed to compile programs which use
 162 LLVM.  Typically called from 'configure' scripts.  Examples:
 163   llvm-config --cxxflags
 164   llvm-config --ldflags
 165   llvm-config --libs engine bcreader scalaropts
 166
 167 Options:
 168   --version              Print LLVM version.
 169   --prefix               Print the installation prefix.
 170   --src-root             Print the source root LLVM was built from.
 171   --obj-root             Print the object root used to build LLVM.
 172   --bindir               Directory containing LLVM executables.
 173   --includedir           Directory containing LLVM headers.
 174   --libdir               Directory containing LLVM libraries.
 175   --cxxflags             C++ compiler flags for files that include LLVM headers.
 176   --ldflags              Print Linker flags.
 177   --libs                 Libraries needed to link against LLVM components.
 178   --libnames             Bare library names for in-tree builds.
 179   --components           List of all possible components.
 180   --targets-built        List of all targets currently built.
 181   --build-mode           Print build mode of LLVM tree (e.g. Debug or Release).
 182 Typical components:
 183   all                    All LLVM libraries (default).
 184   backend                Either a native backend or the C backend.
 185   engine                 Either a native JIT or a bytecode interpreter.
 186 __EOD__
 187     exit(1);
 188 }
 189
 190 # Use -lfoo instead of libfoo.a whenever possible, and add directories to
 191 # files which can't be found using -L.
 192 sub fix_library_names (@) {
 193     my @libs = @_;
 194     my @result;
 195     foreach my $lib (@libs) {
 196         # Transform the bare library name appropriately.
 197         my ($basename) = ($lib =~ /^lib([^.]*)\.a/);
 198         if (defined $basename) {
 199             push @result, "-l$basename";
 200         } else {
 201             push @result, "$LIBDIR/$lib";
 202         }
 203     }
 204     return @result;
 205 }
 206
 207
 208 #==========================================================================
 209 #  Library Dependency Analysis
 210 #==========================================================================
 211 #  Given a few human-readable library names, find all their dependencies
 212 #  and sort them into an order which the linker will like.  If we packed
 213 #  our libraries into fewer archives, we could make the linker do much
 214 #  of this work for us.
 215 #
 216 #  Libraries have two different types of names in this code: Human-friendly
 217 #  "component" names entered on the command-line, and the raw file names
 218 #  we use internally (and ultimately pass to the linker).
 219 #
 220 #  To understand this code, you'll need a working knowledge of Perl 5,
 221 #  and possibly some quality time with 'man perlref'.
 222
 223 sub load_dependencies;
 224 sub build_name_map;
 225 sub have_native_backend;
 226 sub find_best_engine;
 227 sub expand_names (@);
 228 sub find_all_required_sets (@);
 229 sub find_all_required_sets_helper ($$@);
 230
 231 # Each "set" contains one or more libraries which must be included as a
 232 # group (due to cyclic dependencies).  Sets are represented as a Perl array
 233 # reference pointing to a list of internal library names.
 234 my @SETS;
 235
 236 # Various mapping tables.
 237 my %LIB_TO_SET_MAP; # Maps internal library names to their sets.
 238 my %SET_DEPS;       # Maps sets to a list of libraries they depend on.
 239 my %NAME_MAP;       # Maps human-entered names to internal names.
 240
 241 # Have our dependencies been loaded yet?
 242 my $DEPENDENCIES_LOADED = 0;
 243
 244 # Given a list of human-friendly component names, translate them into a
 245 # complete set of linker arguments.
 246 sub expand_dependecies (@) {
 247     my @libs = @_;
 248     load_dependencies;
 249     my @required_sets = find_all_required_sets(expand_names(@libs));
 250     my @sorted_sets = topologically_sort_sets(@required_sets);
 251
 252     # Expand the library sets into libraries.
 253     my @result;
 254     foreach my $set (@sorted_sets) { push @result, @{$set}; }
 255     return @result;
 256 }
 257
 258 # Load in the raw dependency data stored at the end of this file.
 259 sub load_dependencies {
 260     return if $DEPENDENCIES_LOADED;
 261     $DEPENDENCIES_LOADED = 1;
 262     while (<DATA>) {
 263         # Parse our line.
 264         my ($libs, $deps) = /^(^[^:]+): ?(.*)$/;
 265         die "Malformed dependency data" unless defined $deps;
 266         my @libs = split(' ', $libs);
 267         my @deps = split(' ', $deps);
 268
 269         # Record our dependency data.
 270         my $set = \@libs;
 271         push @SETS, $set;
 272         foreach my $lib (@libs) { $LIB_TO_SET_MAP{$lib} = $set; }
 273         $SET_DEPS{$set} = \@deps;
 274     }
 275     build_name_map;
 276 }
 277
 278 # Build a map converting human-friendly component names into internal
 279 # library names.
 280 sub build_name_map {
 281     # Add entries for all the actual libraries.
 282     foreach my $set (@SETS) {
 283         foreach my $lib (sort @$set) {
 284             my $short_name = $lib;
 285             $short_name =~ s/^(lib)?LLVM([^.]*)\..*$/$2/;
 286             $short_name =~ tr/A-Z/a-z/;
 287             $NAME_MAP{$short_name} = [$lib];
 288         }
 289     }
 290
 291     # Add virtual entries.
 292     $NAME_MAP{'native'}  = have_native_backend() ? [$ARCH] : [];
 293     $NAME_MAP{'backend'} = have_native_backend() ? ['native'] : ['cbackend'];
 294     $NAME_MAP{'engine'}  = find_best_engine;
 295     $NAME_MAP{'all'}     = [name_map_entries];   # Must be last.
 296 }
 297
 298 # Return true if we have a native backend to use.
 299 sub have_native_backend {
 300     my %BUILT;
 301     foreach my $target (@TARGETS_BUILT) { $BUILT{$target} = 1; }
 302     return defined $NAME_MAP{$ARCH} && defined $BUILT{$ARCH};
 303 }
 304
 305 # Find a working subclass of ExecutionEngine for this platform.
 306 sub find_best_engine {
 307     if (have_native_backend && $TARGET_HAS_JIT) {
 308         return ['jit', 'native'];
 309     } else {
 310         return ['interpreter'];
 311     }
 312 }
 313
 314 # Get all the human-friendly component names.
 315 sub name_map_entries {
 316     load_dependencies;
 317     return sort keys %NAME_MAP;
 318 }
 319
 320 # Map human-readable names to internal library names.
 321 sub expand_names (@) {
 322     my @names = @_;
 323     my @result;
 324     foreach my $name (@names) {
 325         if (defined $LIB_TO_SET_MAP{$name}) {
 326             # We've hit bottom: An actual library name.
 327             push @result, $name;
 328         } elsif (defined $NAME_MAP{$name}) {
 329             # We've found a short name to expand.
 330             push @result, expand_names(@{$NAME_MAP{$name}});
 331         } else {
 332             print STDERR "llvm-config: unknown component name: $name\n";
 333             exit(1);
 334         }
 335     }
 336     return @result;
 337 }
 338
 339 # Given a list of internal library names, return all sets of libraries which
 340 # will need to be included by the linker (in no particular order).
 341 sub find_all_required_sets (@) {
 342     my @libs = @_;
 343     my %sets_added;
 344     my @result;
 345     find_all_required_sets_helper(\%sets_added, \@result, @libs);
 346     return @result;
 347 }
 348
 349 # Recursive closures are pretty broken in Perl, so we're going to separate
 350 # this function from find_all_required_sets and pass in the state we need
 351 # manually, as references.  Yes, this is fairly unpleasant.
 352 sub find_all_required_sets_helper ($$@) {
 353     my ($sets_added, $result, @libs) = @_;
 354     foreach my $lib (@libs) {
 355         my $set = $LIB_TO_SET_MAP{$lib};
 356         next if defined $$sets_added{$set};
 357         $$sets_added{$set} = 1;
 358         push @$result, $set;
 359         find_all_required_sets_helper($sets_added, $result, @{$SET_DEPS{$set}});
 360     }
 361 }
 362
 363 # Print a list of sets, with a label.  Used for debugging.
 364 sub print_sets ($@) {
 365     my ($label, @sets) = @_;
 366     my @output;
 367     foreach my $set (@sets) { push @output, join(',', @$set); }
 368     print "$label: ", join(';', @output), "\n";
 369 }
 370
 371 # Returns true if $lib is a key in $added.
 372 sub has_lib_been_added ($$) {
 373     my ($added, $lib) = @_;
 374     return defined $$added{$LIB_TO_SET_MAP{$lib}};
 375 }
 376
 377 # Returns true if all the dependencies of $set appear in $added.
 378 sub have_all_deps_been_added ($$) {
 379     my ($added, $set) = @_;
 380     #print_sets("  Checking", $set);
 381     #print_sets("     Wants", $SET_DEPS{$set});
 382     foreach my $lib (@{$SET_DEPS{$set}}) {
 383         return 0 unless has_lib_been_added($added, $lib);
 384     }
 385     return 1;
 386 }
 387
 388 # Given a list of sets, topologically sort them using dependencies.
 389 sub topologically_sort_sets (@) {
 390     my @sets = @_;
 391     my %added;
 392     my @result;
 393     SCAN: while (@sets) { # We'll delete items from @sets as we go.
 394         #print_sets("So far", reverse(@result));
 395         #print_sets("Remaining", @sets);
 396         for (my $i = 0; $i < @sets; ++$i) {
 397             my $set = $sets[$i];
 398             if (have_all_deps_been_added(\%added, $set)) {
 399                 push @result, $set;
 400                 $added{$set} = 1;
 401                 #print "Removing $i.\n";
 402                 splice(@sets, $i, 1);
 403                 next SCAN; # Restart our scan.
 404             }
 405         }
 406         die "Can't find a library with no dependencies";
 407     }
 408     return reverse(@result);
 409 }
 410
 411 # Our library dependency data will be added after the '__END__' token, and will
 412 # be read through the magic <DATA> filehandle.
 413 __END__