tools/llvm-config/llvm-config.in.in

   1 #!@PERL@
   2 ##===- tools/llvm-config ---------------------------------------*- perl -*-===##
   3 #
   4 #                     The LLVM Compiler Infrastructure
   5 #
   6 # This file was developed by Eric Kidd and is distributed under
   7 # the University of Illinois Open Source License. See LICENSE.TXT for details.
   8 #
   9 ##===----------------------------------------------------------------------===##
  10 #
  11 # Synopsis: Prints out compiler options needed to build against an installed
  12 #           copy of LLVM.
  13 #
  14 # Syntax:   llvm-config OPTIONS... [COMPONENTS...]
  15 #
  16 ##===----------------------------------------------------------------------===##
  17
  18 use 5.006;
  19 use strict;
  20 use warnings;
  21
  22 #---- begin autoconf values ----
  23 my $PACKAGE_NAME        = q{@PACKAGE_NAME@};
  24 my $VERSION             = q{@PACKAGE_VERSION@};
  25 my $PREFIX              = q{@LLVM_PREFIX@};
  26 my $LLVM_CONFIGTIME     = q{@LLVM_CONFIGTIME@};
  27 my $LLVM_SRC_ROOT       = q{@abs_top_srcdir@};
  28 my $LLVM_OBJ_ROOT       = q{@abs_top_builddir@};
  29 my $LLVM_ON_WIN32       = q{@LLVM_ON_WIN32@};
  30 my $LLVM_ON_UNIX        = q{@LLVM_ON_UNIX@};
  31 my $LLVMGCCDIR          = q{@LLVMGCCDIR@};
  32 my $LLVMGCC             = q{@LLVMGCC@};
  33 my $LLVMGXX             = q{@LLVMGXX@};
  34 my $LLVMGCC_VERSION     = q{@LLVMGCC_VERSION@};
  35 my $LLVMGCC_MAJVERS     = q{@LLVMGCC_MAJVERS@};
  36 my $ENDIAN              = q{@ENDIAN@};
  37 my $SHLIBEXT            = q{@SHLIBEXT@};
  38 my $EXEEXT              = q{@EXEEXT@};
  39 my $OS                  = q{@OS@};
  40 my $ARCH                = lc(q{@ARCH@});
  41 my $TARGET_TRIPLE       = q{@target@};
  42 my $TARGETS_TO_BUILD    = q{@TARGETS_TO_BUILD@};
  43 my $TARGET_HAS_JIT      = q{@TARGET_HAS_JIT@};
  44 my @TARGETS_BUILT       = map { lc($_) } qw{@TARGETS_TO_BUILD@};
  45 #---- end autoconf values ----
  46
  47 #---- begin Makefile values ----
  48 my $CXXFLAGS            = q{@LLVM_CXXFLAGS@};
  49 my $LDFLAGS             = q{@LLVM_LDFLAGS@};
  50 my $LLVM_BUILDMODE      = q{@LLVM_BUILDMODE@};
  51 #---- end Makefile values ----
  52
  53 # Figure out where llvm-config is being run from.  Primarily, we care if it has
  54 # been installed, or is running from the build directory, which changes the
  55 # locations of some files.
  56
  57 # Convert the current executable name into its directory (e.g. ".").
  58 my ($RUN_DIR) = ($0 =~ /^(.*)\/.*$/);
  59
  60 # Turn the directory into an absolute directory on the file system, also pop up
  61 # from "bin" into the build or prefix dir.
  62 my $ABS_RUN_DIR = `cd $RUN_DIR/..; pwd`;
  63 chomp($ABS_RUN_DIR);
  64
  65 # Compute the absolute object directory build, e.g. "foo/llvm/Debug".
  66 my $ABS_OBJ_ROOT = "$LLVM_OBJ_ROOT/$LLVM_BUILDMODE";
  67 $ABS_OBJ_ROOT = `cd $ABS_OBJ_ROOT; pwd` if (-d $ABS_OBJ_ROOT);
  68 chomp($ABS_OBJ_ROOT);
  69
  70 my $INCLUDEDIR = "$ABS_RUN_DIR/include";
  71 my $LIBDIR     = "$ABS_RUN_DIR/lib";
  72 my $BINDIR     = "$ABS_RUN_DIR/bin";
  73 if ($ABS_RUN_DIR eq $ABS_OBJ_ROOT) {
  74   # If we are running out of the build directory, the include dir is in the
  75   # srcdir.
  76   $INCLUDEDIR = "$LLVM_SRC_ROOT/include";
  77 } else {
  78   # If installed, ignore the prefix the tree was configured with, use the
  79   # current prefix.
  80   $PREFIX = $ABS_RUN_DIR;
  81 }
  82
  83 sub usage;
  84 sub fix_library_names (@);
  85 sub fix_library_files (@);
  86 sub expand_dependecies (@);
  87 sub name_map_entries;
  88
  89 # Parse our command-line arguments.
  90 usage if @ARGV == 0;
  91 my @components;
  92 my $has_opt = 0;
  93 my $want_libs = 0;
  94 my $want_libnames = 0;
  95 my $want_libfiles = 0;
  96 my $want_components = 0;
  97 foreach my $arg (@ARGV) {
  98     if ($arg =~ /^-/) {
  99         if ($arg eq "--version") {
 100             $has_opt = 1; print "$VERSION\n";
 101         } elsif ($arg eq "--prefix") {
 102             $has_opt = 1; print "$PREFIX\n";
 103         } elsif ($arg eq "--bindir") {
 104             $has_opt = 1; print "$BINDIR\n";
 105         } elsif ($arg eq "--includedir") {
 106             $has_opt = 1; print "$INCLUDEDIR\n";
 107         } elsif ($arg eq "--libdir") {
 108             $has_opt = 1; print "$LIBDIR\n";
 109         } elsif ($arg eq "--cxxflags") {
 110             $has_opt = 1; print "-I$INCLUDEDIR $CXXFLAGS\n";
 111         } elsif ($arg eq "--ldflags") {
 112             $has_opt = 1; print "-L$LIBDIR $LDFLAGS\n";
 113         } elsif ($arg eq "--libs") {
 114             $has_opt = 1; $want_libs = 1;
 115         } elsif ($arg eq "--libnames") {
 116             $has_opt = 1; $want_libnames = 1;
 117         } elsif ($arg eq "--libfiles") {
 118             $has_opt = 1; $want_libfiles = 1;
 119         } elsif ($arg eq "--components") {
 120             $has_opt = 1; print join(' ', name_map_entries), "\n";
 121         } elsif ($arg eq "--targets-built") {
 122             $has_opt = 1; print join(' ', @TARGETS_BUILT), "\n";
 123         } elsif ($arg eq "--build-mode") {
 124             $has_opt = 1; print "$LLVM_BUILDMODE\n";
 125         } elsif ($arg eq "--obj-root") {
 126             $has_opt = 1; print `cd $LLVM_OBJ_ROOT/; pwd` . "\n";
 127         } elsif ($arg eq "--src-root") {
 128             $has_opt = 1; print `cd $LLVM_SRC_ROOT/; pwd` . "\n";
 129         } else {
 130             usage();
 131         }
 132     } else {
 133         push @components, $arg;
 134     }
 135 }
 136
 137 # If no options were specified, fail.
 138 usage unless $has_opt;
 139
 140 # If no components were specified, default to 'all'.
 141 if (@components == 0) {
 142     push @components, 'all';
 143 }
 144
 145 # Handle any arguments which require building our dependency graph.
 146 if ($want_libs || $want_libnames || $want_libfiles) {
 147     my @libs = expand_dependecies(@components);
 148     print join(' ', fix_library_names(@libs)), "\n" if ($want_libs);
 149     print join(' ',  @libs), "\n" if ($want_libnames);
 150     print join(' ', fix_library_files(@libs)), "\n" if ($want_libfiles);
 151 }
 152
 153 exit 0;
 154
 155 #==========================================================================
 156 #  Support Routines
 157 #==========================================================================
 158
 159 sub usage {
 160     print STDERR <<__EOD__;
 161 Usage: llvm-config <OPTION>... [<COMPONENT>...]
 162
 163 Get various configuration information needed to compile programs which use
 164 LLVM.  Typically called from 'configure' scripts.  Examples:
 165   llvm-config --cxxflags
 166   llvm-config --ldflags
 167   llvm-config --libs engine bcreader scalaropts
 168
 169 Options:
 170   --version              Print LLVM version.
 171   --prefix               Print the installation prefix.
 172   --src-root             Print the source root LLVM was built from.
 173   --obj-root             Print the object root used to build LLVM.
 174   --bindir               Directory containing LLVM executables.
 175   --includedir           Directory containing LLVM headers.
 176   --libdir               Directory containing LLVM libraries.
 177   --cxxflags             C++ compiler flags for files that include LLVM headers.
 178   --ldflags              Print Linker flags.
 179   --libs                 Libraries needed to link against LLVM components.
 180   --libnames             Bare library names for in-tree builds.
 181   --libfiles             Fully qualified library filenames for makefile depends.
 182   --components           List of all possible components.
 183   --targets-built        List of all targets currently built.
 184   --build-mode           Print build mode of LLVM tree (e.g. Debug or Release).
 185 Typical components:
 186   all                    All LLVM libraries (default).
 187   backend                Either a native backend or the C backend.
 188   engine                 Either a native JIT or a bytecode interpreter.
 189 __EOD__
 190     exit(1);
 191 }
 192
 193 # Use -lfoo instead of libfoo.a whenever possible, and add directories to
 194 # files which can't be found using -L.
 195 sub fix_library_names (@) {
 196     my @libs = @_;
 197     my @result;
 198     foreach my $lib (@libs) {
 199         # Transform the bare library name appropriately.
 200         my ($basename) = ($lib =~ /^lib([^.]*)\.a/);
 201         if (defined $basename) {
 202             push @result, "-l$basename";
 203         } else {
 204             push @result, "$LIBDIR/$lib";
 205         }
 206     }
 207     return @result;
 208 }
 209
 210 # Turn the list of libraries into a list of files.
 211 sub fix_library_files(@) {
 212     my @libs = @_;
 213     my @result;
 214     foreach my $lib (@libs) {
 215         # Transform the bare library name into a filename.
 216         push @result, "$LIBDIR/$lib";
 217     }
 218     return @result;
 219 }
 220
 221 #==========================================================================
 222 #  Library Dependency Analysis
 223 #==========================================================================
 224 #  Given a few human-readable library names, find all their dependencies
 225 #  and sort them into an order which the linker will like.  If we packed
 226 #  our libraries into fewer archives, we could make the linker do much
 227 #  of this work for us.
 228 #
 229 #  Libraries have two different types of names in this code: Human-friendly
 230 #  "component" names entered on the command-line, and the raw file names
 231 #  we use internally (and ultimately pass to the linker).
 232 #
 233 #  To understand this code, you'll need a working knowledge of Perl 5,
 234 #  and possibly some quality time with 'man perlref'.
 235
 236 sub load_dependencies;
 237 sub build_name_map;
 238 sub have_native_backend;
 239 sub find_best_engine;
 240 sub expand_names (@);
 241 sub find_all_required_sets (@);
 242 sub find_all_required_sets_helper ($$@);
 243
 244 # Each "set" contains one or more libraries which must be included as a
 245 # group (due to cyclic dependencies).  Sets are represented as a Perl array
 246 # reference pointing to a list of internal library names.
 247 my @SETS;
 248
 249 # Various mapping tables.
 250 my %LIB_TO_SET_MAP; # Maps internal library names to their sets.
 251 my %SET_DEPS;       # Maps sets to a list of libraries they depend on.
 252 my %NAME_MAP;       # Maps human-entered names to internal names.
 253
 254 # Have our dependencies been loaded yet?
 255 my $DEPENDENCIES_LOADED = 0;
 256
 257 # Given a list of human-friendly component names, translate them into a
 258 # complete set of linker arguments.
 259 sub expand_dependecies (@) {
 260     my @libs = @_;
 261     load_dependencies;
 262     my @required_sets = find_all_required_sets(expand_names(@libs));
 263     my @sorted_sets = topologically_sort_sets(@required_sets);
 264
 265     # Expand the library sets into libraries.
 266     my @result;
 267     foreach my $set (@sorted_sets) { push @result, @{$set}; }
 268     return @result;
 269 }
 270
 271 # Load in the raw dependency data stored at the end of this file.
 272 sub load_dependencies {
 273     return if $DEPENDENCIES_LOADED;
 274     $DEPENDENCIES_LOADED = 1;
 275     while (<DATA>) {
 276         # Parse our line.
 277         my ($libs, $deps) = /^(^[^:]+): ?(.*)$/;
 278         die "Malformed dependency data" unless defined $deps;
 279         my @libs = split(' ', $libs);
 280         my @deps = split(' ', $deps);
 281
 282         # Record our dependency data.
 283         my $set = \@libs;
 284         push @SETS, $set;
 285         foreach my $lib (@libs) { $LIB_TO_SET_MAP{$lib} = $set; }
 286         $SET_DEPS{$set} = \@deps;
 287     }
 288     build_name_map;
 289 }
 290
 291 # Build a map converting human-friendly component names into internal
 292 # library names.
 293 sub build_name_map {
 294     # Add entries for all the actual libraries.
 295     foreach my $set (@SETS) {
 296         foreach my $lib (sort @$set) {
 297             my $short_name = $lib;
 298             $short_name =~ s/^(lib)?LLVM([^.]*)\..*$/$2/;
 299             $short_name =~ tr/A-Z/a-z/;
 300             $NAME_MAP{$short_name} = [$lib];
 301         }
 302     }
 303
 304     # Add virtual entries.
 305     $NAME_MAP{'native'}  = have_native_backend() ? [$ARCH] : [];
 306     $NAME_MAP{'backend'} = have_native_backend() ? ['native'] : ['cbackend'];
 307     $NAME_MAP{'engine'}  = find_best_engine;
 308     $NAME_MAP{'all'}     = [name_map_entries];   # Must be last.
 309 }
 310
 311 # Return true if we have a native backend to use.
 312 sub have_native_backend {
 313     my %BUILT;
 314     foreach my $target (@TARGETS_BUILT) { $BUILT{$target} = 1; }
 315     return defined $NAME_MAP{$ARCH} && defined $BUILT{$ARCH};
 316 }
 317
 318 # Find a working subclass of ExecutionEngine for this platform.
 319 sub find_best_engine {
 320     if (have_native_backend && $TARGET_HAS_JIT) {
 321         return ['jit', 'native'];
 322     } else {
 323         return ['interpreter'];
 324     }
 325 }
 326
 327 # Get all the human-friendly component names.
 328 sub name_map_entries {
 329     load_dependencies;
 330     return sort keys %NAME_MAP;
 331 }
 332
 333 # Map human-readable names to internal library names.
 334 sub expand_names (@) {
 335     my @names = @_;
 336     my @result;
 337     foreach my $name (@names) {
 338         if (defined $LIB_TO_SET_MAP{$name}) {
 339             # We've hit bottom: An actual library name.
 340             push @result, $name;
 341         } elsif (defined $NAME_MAP{$name}) {
 342             # We've found a short name to expand.
 343             push @result, expand_names(@{$NAME_MAP{$name}});
 344         } else {
 345             print STDERR "llvm-config: unknown component name: $name\n";
 346             exit(1);
 347         }
 348     }
 349     return @result;
 350 }
 351
 352 # Given a list of internal library names, return all sets of libraries which
 353 # will need to be included by the linker (in no particular order).
 354 sub find_all_required_sets (@) {
 355     my @libs = @_;
 356     my %sets_added;
 357     my @result;
 358     find_all_required_sets_helper(\%sets_added, \@result, @libs);
 359     return @result;
 360 }
 361
 362 # Recursive closures are pretty broken in Perl, so we're going to separate
 363 # this function from find_all_required_sets and pass in the state we need
 364 # manually, as references.  Yes, this is fairly unpleasant.
 365 sub find_all_required_sets_helper ($$@) {
 366     my ($sets_added, $result, @libs) = @_;
 367     foreach my $lib (@libs) {
 368         my $set = $LIB_TO_SET_MAP{$lib};
 369         next if defined $$sets_added{$set};
 370         $$sets_added{$set} = 1;
 371         push @$result, $set;
 372         find_all_required_sets_helper($sets_added, $result, @{$SET_DEPS{$set}});
 373     }
 374 }
 375
 376 # Print a list of sets, with a label.  Used for debugging.
 377 sub print_sets ($@) {
 378     my ($label, @sets) = @_;
 379     my @output;
 380     foreach my $set (@sets) { push @output, join(',', @$set); }
 381     print "$label: ", join(';', @output), "\n";
 382 }
 383
 384 # Returns true if $lib is a key in $added.
 385 sub has_lib_been_added ($$) {
 386     my ($added, $lib) = @_;
 387     return defined $$added{$LIB_TO_SET_MAP{$lib}};
 388 }
 389
 390 # Returns true if all the dependencies of $set appear in $added.
 391 sub have_all_deps_been_added ($$) {
 392     my ($added, $set) = @_;
 393     #print_sets("  Checking", $set);
 394     #print_sets("     Wants", $SET_DEPS{$set});
 395     foreach my $lib (@{$SET_DEPS{$set}}) {
 396         return 0 unless has_lib_been_added($added, $lib);
 397     }
 398     return 1;
 399 }
 400
 401 # Given a list of sets, topologically sort them using dependencies.
 402 sub topologically_sort_sets (@) {
 403     my @sets = @_;
 404     my %added;
 405     my @result;
 406     SCAN: while (@sets) { # We'll delete items from @sets as we go.
 407         #print_sets("So far", reverse(@result));
 408         #print_sets("Remaining", @sets);
 409         for (my $i = 0; $i < @sets; ++$i) {
 410             my $set = $sets[$i];
 411             if (have_all_deps_been_added(\%added, $set)) {
 412                 push @result, $set;
 413                 $added{$set} = 1;
 414                 #print "Removing $i.\n";
 415                 splice(@sets, $i, 1);
 416                 next SCAN; # Restart our scan.
 417             }
 418         }
 419         die "Can't find a library with no dependencies";
 420     }
 421     return reverse(@result);
 422 }
 423
 424 # Our library dependency data will be added after the '__END__' token, and will
 425 # be read through the magic <DATA> filehandle.
 426 __END__