tools/llvm-config/CMakeLists.txt

   1 include(TestBigEndian)
   2
   3 include(FindPerl)
   4 if( NOT PERL_FOUND )
   5   message(FATAL_ERROR "Perl required but not found!")
   6 endif( NOT PERL_FOUND )
   7
   8 set(PERL ${PERL_EXECUTABLE})
   9 set(VERSION PACKAGE_VERSION)
  10 set(PREFIX ${LLVM_BINARY_DIR}) # TODO: Root for `make install'.
  11 set(abs_top_srcdir ${LLVM_MAIN_SRC_DIR})
  12 set(abs_top_builddir ${LLVM_BINARY_DIR})
  13 execute_process(COMMAND date
  14   OUTPUT_VARIABLE LLVM_CONFIGTIME
  15   OUTPUT_STRIP_TRAILING_WHITESPACE)
  16 # LLVM_ON_UNIX and LLVM_ON_WIN32 already set.
  17 # those are set to blank by `autoconf' on MinGW, so it seems they are not required:
  18 #set(LLVMGCCDIR "")
  19 #set(LLVMGCC "")
  20 #set(LLVMGXX "")
  21 #set(LLVMGCC_VERSION "")
  22 #set(LLVMGCC_MAJVERS "")
  23 test_big_endian(IS_BIG_ENDIAN)
  24 if( IS_BIG_ENDIAN )
  25   set(ENDIAN "big")
  26 else( IS_BIG_ENDIAN )
  27   set(ENDIAN "little")
  28 endif( IS_BIG_ENDIAN )
  29 set(SHLIBEXT ${LTDL_SHLIB_EXT})
  30 #EXEEXT already set.
  31 set(OS "${CMAKE_SYSTEM}")
  32 set(ARCH "${LLVM_NATIVE_ARCH}")
  33
  34 get_system_libs(LLVM_SYSTEM_LIBS_LIST)
  35 foreach(l ${LLVM_SYSTEM_LIBS_LIST})
  36   set(LLVM_SYSTEM_LIBS ${LLVM_SYSTEM_LIBS} "-l${l}")
  37 endforeach()
  38
  39 include(GetTargetTriple)
  40 get_target_triple(target)
  41
  42 foreach(c ${LLVM_TARGETS_TO_BUILD})
  43   set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
  44 endforeach(c)
  45 set(TARGETS_TO_BUILD ${TARGETS_BUILT})
  46 set(TARGET_HAS_JIT "1")  # TODO
  47
  48 # Avoids replacement at config-time:
  49 set(LLVM_CPPFLAGS "@LLVM_CPPFLAGS@")
  50 set(LLVM_CFLAGS "@LLVM_CFLAGS@")
  51 set(LLVM_CXXFLAGS "@LLVM_CXXFLAGS@")
  52 set(LLVM_LDFLAGS "@LLVM_LDFLAGS@")
  53 set(LIBS "@LIBS@")
  54 set(LLVM_BUILDMODE "@LLVM_BUILDMODE@")
  55
  56 configure_file(
  57   ${CMAKE_CURRENT_SOURCE_DIR}/llvm-config.in.in
  58   ${CMAKE_CURRENT_BINARY_DIR}/llvm-config.in
  59   @ONLY
  60 )
  61
  62 set(LIBDEPS ${CMAKE_CURRENT_BINARY_DIR}/LibDeps.txt)
  63 set(LIBDEPS_TMP ${CMAKE_CURRENT_BINARY_DIR}/LibDeps.txt.tmp)
  64 set(FINAL_LIBDEPS ${CMAKE_CURRENT_BINARY_DIR}/FinalLibDeps.txt)
  65 set(LLVM_CONFIG ${LLVM_TOOLS_BINARY_DIR}/llvm-config)
  66 set(LLVM_CONFIG_IN ${CMAKE_CURRENT_BINARY_DIR}/llvm-config.in)
  67
  68 if( CMAKE_CROSSCOMPILING )
  69   set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM ONLY)
  70 endif()
  71
  72 find_program(NM_PATH nm PATH_SUFFIXES /bin)
  73
  74 if( NOT NM_PATH )
  75   message(FATAL_ERROR "`nm' not found")
  76 endif()
  77
  78 add_custom_command(OUTPUT ${LIBDEPS_TMP}
  79   COMMAND ${PERL_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/GenLibDeps.pl -flat ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR} ${NM_PATH} > ${LIBDEPS_TMP}
  80   DEPENDS ${llvm_libs}
  81   COMMENT "Regenerating ${LIBDEPS_TMP}")
  82
  83 add_custom_command(OUTPUT ${LIBDEPS}
  84   COMMAND ${CMAKE_COMMAND} -E copy_if_different ${LIBDEPS_TMP} ${LIBDEPS}
  85   DEPENDS ${LIBDEPS_TMP}
  86   COMMENT "Updated ${LIBDEPS} because dependencies changed")
  87
  88 add_custom_command(OUTPUT ${FINAL_LIBDEPS}
  89   COMMAND ${PERL_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/find-cycles.pl < ${LIBDEPS} > ${FINAL_LIBDEPS} || ${CMAKE_COMMAND} -E remove -f ${FINAL_LIBDEPS}
  90   DEPENDS ${LIBDEPS}
  91   COMMENT "Checking for cyclic dependencies between LLVM libraries.")
  92
  93 set(C_FLGS "${CMAKE_C_FLAGS_${uppercase_CMAKE_BUILD_TYPE}} ${LLVM_DEFINITIONS}")
  94 set(CXX_FLGS "${CMAKE_CXX_FLAGS_${uppercase_CMAKE_BUILD_TYPE}} ${LLVM_DEFINITIONS}")
  95 set(CPP_FLGS "${CMAKE_CPP_FLAGS_${uppercase_CMAKE_BUILD_TYPE}} ${LLVM_DEFINITIONS}")
  96
  97 add_custom_command(OUTPUT ${LLVM_CONFIG}
  98   COMMAND echo 's!@LLVM_CPPFLAGS@!${CPP_FLGS}!' > temp.sed
  99   COMMAND echo 's!@LLVM_CFLAGS@!${C_FLGS}!' >> temp.sed
 100   COMMAND echo 's!@LLVM_CXXFLAGS@!${CXX_FLGS}!' >> temp.sed
 101   # TODO: Use general flags for linking! not just for shared libs:
 102   COMMAND echo 's!@LLVM_LDFLAGS@!${CMAKE_SHARED_LINKER_FLAGS}!' >> temp.sed
 103   COMMAND echo 's!@LIBS@!${LLVM_SYSTEM_LIBS}!' >> temp.sed
 104   COMMAND echo 's!@LLVM_BUILDMODE@!${CMAKE_BUILD_TYPE}!' >> temp.sed
 105   COMMAND sed -f temp.sed < ${LLVM_CONFIG_IN} > ${LLVM_CONFIG}
 106   COMMAND ${CMAKE_COMMAND} -E remove -f temp.sed
 107   COMMAND cat ${FINAL_LIBDEPS} >> ${LLVM_CONFIG}
 108   COMMAND chmod +x ${LLVM_CONFIG}
 109   DEPENDS ${FINAL_LIBDEPS} ${LLVM_CONFIG_IN}
 110   COMMENT "Building llvm-config script."
 111   )
 112
 113 add_custom_target(llvm-config.target ALL
 114   DEPENDS ${LLVM_CONFIG})
 115
 116 add_dependencies(llvm-config.target ${llvm_lib_targets})
 117
 118 # Make sure that llvm-config builds before the llvm tools, so we have
 119 # LibDeps.txt and can use it for updating the hard-coded library
 120 # dependencies on cmake/modules/LLVMLibDeps.cmake when the tools'
 121 # build fail due to outdated dependencies:
 122 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} llvm-config.target)
 123
 124 install(FILES ${LLVM_CONFIG}
 125   PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE
 126   WORLD_READ WORLD_EXECUTE
 127   DESTINATION bin)
 128
 129
 130 # Regeneration of library dependencies.
 131
 132 # See the comments at the end of cmake/modules/LLVMConfig.cmake for
 133 # notes and guidelines.
 134
 135 set(LLVMLibDeps ${LLVM_MAIN_SRC_DIR}/cmake/modules/LLVMLibDeps.cmake)
 136 set(LLVMLibDeps_TMP ${CMAKE_CURRENT_BINARY_DIR}/LLVMLibDeps.cmake.tmp)
 137
 138 add_custom_command(OUTPUT ${LLVMLibDeps_TMP}
 139   COMMAND sed -e s'@\\.a@@g' -e s'@\\.so@@g' -e 's@libLLVM@LLVM@g' -e 's@: @ @' -e 's@\\\(.*\\\)@set\(MSVC_LIB_DEPS_\\1\)@' ${FINAL_LIBDEPS} > ${LLVMLibDeps_TMP}
 140   COMMAND ${CMAKE_COMMAND} -E copy_if_different ${LLVMLibDeps_TMP} ${LLVMLibDeps}
 141   DEPENDS ${FINAL_LIBDEPS}
 142   COMMENT "Updating cmake library dependencies file ${LLVMLibDeps}"
 143   )
 144
 145 if( LLVM_TARGETS_TO_BUILD STREQUAL LLVM_ALL_TARGETS )
 146   add_custom_target(llvmlibdeps.target ALL DEPENDS ${LLVMLibDeps_TMP})
 147   add_dependencies(llvmlibdeps.target llvm-config.target)
 148   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} llvmlibdeps.target)
 149 endif()
 150
 151 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)