test/Transforms/SROA/big-endian.ll

   1 ; RUN: opt < %s -sroa -S | FileCheck %s
   2 ; RUN: opt < %s -sroa -force-ssa-updater -S | FileCheck %s
   3
   4 target datalayout = "E-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:32:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-n8:16:32:64"
   5
   6 define i8 @test1() {
   7 ; We fully promote these to the i24 load or store size, resulting in just masks
   8 ; and other operations that instcombine will fold, but no alloca. Note this is
   9 ; the same as test12 in basictest.ll, but here we assert big-endian byte
  10 ; ordering.
  11 ;
  12 ; CHECK: @test1
  13
  14 entry:
  15   %a = alloca [3 x i8]
  16   %b = alloca [3 x i8]
  17 ; CHECK-NOT: alloca
  18
  19   %a0ptr = getelementptr [3 x i8]* %a, i64 0, i32 0
  20   store i8 0, i8* %a0ptr
  21   %a1ptr = getelementptr [3 x i8]* %a, i64 0, i32 1
  22   store i8 0, i8* %a1ptr
  23   %a2ptr = getelementptr [3 x i8]* %a, i64 0, i32 2
  24   store i8 0, i8* %a2ptr
  25   %aiptr = bitcast [3 x i8]* %a to i24*
  26   %ai = load i24* %aiptr
  27 ; CHCEK-NOT: store
  28 ; CHCEK-NOT: load
  29 ; CHECK:      %[[mask0:.*]] = and i24 undef, 65535
  30 ; CHECK-NEXT: %[[mask1:.*]] = and i24 %[[mask0]], -65281
  31 ; CHECK-NEXT: %[[mask2:.*]] = and i24 %[[mask1]], -256
  32
  33   %biptr = bitcast [3 x i8]* %b to i24*
  34   store i24 %ai, i24* %biptr
  35   %b0ptr = getelementptr [3 x i8]* %b, i64 0, i32 0
  36   %b0 = load i8* %b0ptr
  37   %b1ptr = getelementptr [3 x i8]* %b, i64 0, i32 1
  38   %b1 = load i8* %b1ptr
  39   %b2ptr = getelementptr [3 x i8]* %b, i64 0, i32 2
  40   %b2 = load i8* %b2ptr
  41 ; CHCEK-NOT: store
  42 ; CHCEK-NOT: load
  43 ; CHECK:      %[[shift0:.*]] = lshr i24 %[[mask2]], 16
  44 ; CHECK-NEXT: %[[trunc0:.*]] = trunc i24 %[[shift0]] to i8
  45 ; CHECK-NEXT: %[[shift1:.*]] = lshr i24 %[[mask2]], 8
  46 ; CHECK-NEXT: %[[trunc1:.*]] = trunc i24 %[[shift1]] to i8
  47 ; CHECK-NEXT: %[[trunc2:.*]] = trunc i24 %[[mask2]] to i8
  48
  49   %bsum0 = add i8 %b0, %b1
  50   %bsum1 = add i8 %bsum0, %b2
  51   ret i8 %bsum1
  52 ; CHECK:      %[[sum0:.*]] = add i8 %[[trunc0]], %[[trunc1]]
  53 ; CHECK-NEXT: %[[sum1:.*]] = add i8 %[[sum0]], %[[trunc2]]
  54 ; CHECK-NEXT: ret i8 %[[sum1]]
  55 }
  56
  57 define i64 @test2() {
  58 ; Test for various mixed sizes of integer loads and stores all getting
  59 ; promoted.
  60 ;
  61 ; CHECK: @test2
  62
  63 entry:
  64   %a = alloca [7 x i8]
  65 ; CHECK-NOT: alloca
  66
  67   %a0ptr = getelementptr [7 x i8]* %a, i64 0, i32 0
  68   %a1ptr = getelementptr [7 x i8]* %a, i64 0, i32 1
  69   %a2ptr = getelementptr [7 x i8]* %a, i64 0, i32 2
  70   %a3ptr = getelementptr [7 x i8]* %a, i64 0, i32 3
  71
  72 ; CHCEK-NOT: store
  73 ; CHCEK-NOT: load
  74
  75   %a0i16ptr = bitcast i8* %a0ptr to i16*
  76   store i16 1, i16* %a0i16ptr
  77 ; CHECK:      %[[mask:.*]] = and i56 undef, 1099511627775
  78 ; CHECK-NEXT: %[[or:.*]] = or i56 %[[mask]], 1099511627776
  79
  80   %a1i4ptr = bitcast i8* %a1ptr to i4*
  81   store i4 1, i4* %a1i4ptr
  82 ; CHECK:      %[[mask:.*]] = and i56 %[[or]], -16492674416641
  83 ; CHECK-NEXT: %[[or:.*]] = or i56 %[[mask]], 1099511627776
  84
  85   store i8 1, i8* %a2ptr
  86 ; CHECK-NEXT: %[[mask:.*]] = and i56 %[[or]], -1095216660481
  87 ; CHECK-NEXT: %[[or:.*]] = or i56 %[[mask]], 4294967296
  88
  89   %a3i24ptr = bitcast i8* %a3ptr to i24*
  90   store i24 1, i24* %a3i24ptr
  91 ; CHECK-NEXT: %[[mask:.*]] = and i56 %[[or]], -4294967041
  92 ; CHECK-NEXT: %[[or:.*]] = or i56 %[[mask]], 256
  93
  94   %a2i40ptr = bitcast i8* %a2ptr to i40*
  95   store i40 1, i40* %a2i40ptr
  96 ; CHECK-NEXT: %[[mask:.*]] = and i56 %[[or]], -1099511627776
  97 ; CHECK-NEXT: %[[or:.*]] = or i56 %[[mask]], 1
  98
  99 ; CHCEK-NOT: store
 100 ; CHCEK-NOT: load
 101
 102   %aiptr = bitcast [7 x i8]* %a to i56*
 103   %ai = load i56* %aiptr
 104   %ret = zext i56 %ai to i64
 105   ret i64 %ret
 106 ; CHECK:      %[[ret:.*]] = zext i56 %[[or]] to i64
 107 ; CHECK-NEXT: ret i64 %[[ret]]
 108 }