test/Transforms/LoopVectorize/no_outside_user.ll

   1 ; RUN: opt -S -loop-vectorize -force-vector-unroll=1 -force-vector-width=2 < %s | FileCheck %s
   2
   3 target datalayout = "e-p:32:32:32-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:32:64-f32:32:32-f64:32:64-v64:64:64-v128:128:128-a0:0:64-f80:32:32-n8:16:32-S128"
   4
   5 @f = common global i32 0, align 4
   6 @.str = private unnamed_addr constant [4 x i8] c"%d\0A\00", align 1
   7 @c = common global i32 0, align 4
   8 @a = common global i32 0, align 4
   9 @b = common global i32 0, align 4
  10 @e = common global i32 0, align 4
  11
  12 ; We used to vectorize this loop. But it has a value that is used outside of the
  13 ; and is not a recognized reduction variable "tmp17".
  14
  15 ; CHECK-LABEL: @main(
  16 ; CHECK-NOT: <2 x i32>
  17
  18 define i32 @main()  {
  19 bb:
  20   %b.promoted = load i32* @b, align 4
  21   br label %.lr.ph.i
  22
  23 .lr.ph.i:
  24   %tmp8 = phi i32 [ %tmp18, %bb16 ], [ %b.promoted, %bb ]
  25   %tmp2 = icmp sgt i32 %tmp8, 10
  26   br i1 %tmp2, label %bb16, label %bb10
  27
  28 bb10:
  29   br label %bb16
  30
  31 bb16:
  32   %tmp17 = phi i32 [ 0, %bb10 ], [ 1, %.lr.ph.i ]
  33   %tmp18 = add nsw i32 %tmp8, 1
  34   %tmp19 = icmp slt i32 %tmp18, 4
  35   br i1 %tmp19, label %.lr.ph.i, label %f1.exit.loopexit
  36
  37 f1.exit.loopexit:
  38   %.lcssa = phi i32 [ %tmp17, %bb16 ]
  39   ret i32 %.lcssa
  40 }
  41
  42 ; Don't vectorize this loop. Its phi node (induction variable) has an outside
  43 ; loop user. We currently don't handle this case.
  44 ; PR17179
  45
  46 ; CHECK-LABEL: @test2(
  47 ; CHECK-NOT:  <2 x
  48
  49 @x1 = common global i32 0, align 4
  50 @x2 = common global i32 0, align 4
  51 @x0 = common global i32 0, align 4
  52
  53 define i32 @test2()  {
  54 entry:
  55   store i32 0, i32* @x1, align 4
  56   %0 = load i32* @x0, align 4
  57   br label %for.cond1.preheader
  58
  59 for.cond1.preheader:
  60   %inc7 = phi i32 [ 0, %entry ], [ %inc, %for.cond1.preheader ]
  61   %inc = add nsw i32 %inc7, 1
  62   %cmp = icmp eq i32 %inc, 52
  63   br i1 %cmp, label %for.end5, label %for.cond1.preheader
  64
  65 for.end5:
  66   %inc7.lcssa = phi i32 [ %inc7, %for.cond1.preheader ]
  67   %xor = xor i32 %inc7.lcssa, %0
  68   store i32 52, i32* @x1, align 4
  69   store i32 1, i32* @x2, align 4
  70   ret i32 %xor
  71 }