test/Transforms/InstCombine/objsize.ll

   1 ; Test a pile of objectsize bounds checking.
   2 ; RUN: opt < %s -instcombine -S | FileCheck %s
   3 ; We need target data to get the sizes of the arrays and structures.
   4 target datalayout = "e-p:32:32:32-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:32:64-f32:32:32-f64:32:64-v64:64:64-v128:128:128-a0:0:64-f80:128:128"
   5
   6 @a = private global [60 x i8] zeroinitializer, align 1 ; <[60 x i8]*>
   7 @.str = private constant [8 x i8] c"abcdefg\00"   ; <[8 x i8]*>
   8
   9 define i32 @foo() nounwind {
  10 ; CHECK: @foo
  11 ; CHECK-NEXT: ret i32 60
  12   %1 = call i32 @llvm.objectsize.i32(i8* getelementptr inbounds ([60 x i8]* @a, i32 0, i32 0), i1 false, i32 0)
  13   ret i32 %1
  14 }
  15
  16 define i8* @bar() nounwind {
  17 ; CHECK: @bar
  18 entry:
  19   %retval = alloca i8*
  20   %0 = call i32 @llvm.objectsize.i32(i8* getelementptr inbounds ([60 x i8]* @a, i32 0, i32 0), i1 false, i32 0)
  21   %cmp = icmp ne i32 %0, -1
  22 ; CHECK: br i1 true
  23   br i1 %cmp, label %cond.true, label %cond.false
  24
  25 cond.true:
  26   %1 = load i8** %retval
  27   ret i8* %1
  28
  29 cond.false:
  30   %2 = load i8** %retval
  31   ret i8* %2
  32 }
  33
  34 define i32 @f() nounwind {
  35 ; CHECK: @f
  36 ; CHECK-NEXT: ret i32 0
  37   %1 = call i32 @llvm.objectsize.i32(i8* getelementptr ([60 x i8]* @a, i32 1, i32 0), i1 false, i32 0)
  38   ret i32 %1
  39 }
  40
  41 @window = external global [0 x i8]
  42
  43 define i1 @baz() nounwind {
  44 ; CHECK: @baz
  45 ; CHECK-NEXT: objectsize
  46   %1 = tail call i32 @llvm.objectsize.i32(i8* getelementptr inbounds ([0 x i8]* @window, i32 0, i32 0), i1 false, i32 0)
  47   %2 = icmp eq i32 %1, -1
  48   ret i1 %2
  49 }
  50
  51 define void @test1(i8* %q, i32 %x) nounwind noinline {
  52 ; CHECK: @test1
  53 ; CHECK: objectsize.i32
  54 entry:
  55   %0 = call i32 @llvm.objectsize.i32(i8* getelementptr inbounds ([0 x i8]* @window, i32 0, i32 10), i1 false, i32 0) ; <i64> [#uses=1]
  56   %1 = icmp eq i32 %0, -1                         ; <i1> [#uses=1]
  57   br i1 %1, label %"47", label %"46"
  58
  59 "46":                                             ; preds = %entry
  60   unreachable
  61
  62 "47":                                             ; preds = %entry
  63   unreachable
  64 }
  65
  66 @.str5 = private constant [9 x i32] [i32 97, i32 98, i32 99, i32 100, i32 0, i32
  67  101, i32 102, i32 103, i32 0], align 4
  68 define i32 @test2() nounwind {
  69 ; CHECK: @test2
  70 ; CHECK-NEXT: ret i32 34
  71   %1 = call i32 @llvm.objectsize.i32(i8* getelementptr (i8* bitcast ([9 x i32]* @.str5 to i8*), i32 2), i1 false, i32 0)
  72   ret i32 %1
  73 }
  74
  75 ; rdar://7674946
  76 @array = internal global [480 x float] zeroinitializer ; <[480 x float]*> [#uses=1]
  77
  78 declare i8* @__memcpy_chk(i8*, i8*, i32, i32) nounwind
  79
  80 declare i32 @llvm.objectsize.i32(i8*, i1, i32) nounwind readonly
  81
  82 declare i8* @__inline_memcpy_chk(i8*, i8*, i32) nounwind inlinehint
  83
  84 define void @test3() nounwind {
  85 ; CHECK: @test3
  86 entry:
  87   br i1 undef, label %bb11, label %bb12
  88
  89 bb11:
  90   %0 = getelementptr inbounds float* getelementptr inbounds ([480 x float]* @array, i32 0, i32 128), i32 -127 ; <float*> [#uses=1]
  91   %1 = bitcast float* %0 to i8*                   ; <i8*> [#uses=1]
  92   %2 = call i32 @llvm.objectsize.i32(i8* %1, i1 false, i32 0) ; <i32> [#uses=1]
  93   %3 = call i8* @__memcpy_chk(i8* undef, i8* undef, i32 512, i32 %2) nounwind ; <i8*> [#uses=0]
  94 ; CHECK: unreachable
  95   unreachable
  96
  97 bb12:
  98   %4 = getelementptr inbounds float* getelementptr inbounds ([480 x float]* @array, i32 0, i32 128), i32 -127 ; <float*> [#uses=1]
  99   %5 = bitcast float* %4 to i8*                   ; <i8*> [#uses=1]
 100   %6 = call i8* @__inline_memcpy_chk(i8* %5, i8* undef, i32 512) nounwind inlinehint ; <i8*> [#uses=0]
 101 ; CHECK: @__inline_memcpy_chk
 102   unreachable
 103 }
 104
 105 ; rdar://7718857
 106
 107 %struct.data = type { [100 x i32], [100 x i32], [1024 x i8] }
 108
 109 define i32 @test4() nounwind ssp {
 110 ; CHECK: @test4
 111 entry:
 112   %0 = alloca %struct.data, align 8
 113   %1 = bitcast %struct.data* %0 to i8*
 114   %2 = call i32 @llvm.objectsize.i32(i8* %1, i1 false, i32 0) nounwind
 115 ; CHECK-NOT: @llvm.objectsize
 116 ; CHECK: @llvm.memset.p0i8.i32(i8* %1, i8 0, i32 1824, i32 8, i1 false)
 117   %3 = call i8* @__memset_chk(i8* %1, i32 0, i32 1824, i32 %2) nounwind
 118   ret i32 0
 119 }
 120
 121 ; rdar://7782496
 122 @s = external global i8*
 123
 124 define void @test5(i32 %n) nounwind ssp {
 125 ; CHECK: @test5
 126 entry:
 127   %0 = tail call noalias i8* @malloc(i32 20) nounwind
 128   %1 = tail call i32 @llvm.objectsize.i32(i8* %0, i1 false, i32 0)
 129   %2 = load i8** @s, align 8
 130 ; CHECK-NOT: @llvm.objectsize
 131 ; CHECK: @llvm.memcpy.p0i8.p0i8.i32(i8* %0, i8* %1, i32 10, i32 1, i1 false)
 132   %3 = tail call i8* @__memcpy_chk(i8* %0, i8* %2, i32 10, i32 %1) nounwind
 133   ret void
 134 }
 135
 136 define void @test6(i32 %n) nounwind ssp {
 137 ; CHECK: @test6
 138 entry:
 139   %0 = tail call noalias i8* @malloc(i32 20) nounwind
 140   %1 = tail call i32 @llvm.objectsize.i32(i8* %0, i1 false, i32 0)
 141   %2 = load i8** @s, align 8
 142 ; CHECK-NOT: @llvm.objectsize
 143 ; CHECK: @__memcpy_chk(i8* %0, i8* %1, i32 30, i32 20)
 144   %3 = tail call i8* @__memcpy_chk(i8* %0, i8* %2, i32 30, i32 %1) nounwind
 145   ret void
 146 }
 147
 148 declare i8* @__memset_chk(i8*, i32, i32, i32) nounwind
 149
 150 declare noalias i8* @malloc(i32) nounwind
 151
 152 define i32 @test7() {
 153 ; CHECK: @test7
 154   %alloc = call noalias i8* @malloc(i32 48) nounwind
 155   %gep = getelementptr inbounds i8* %alloc, i32 16
 156   %objsize = call i32 @llvm.objectsize.i32(i8* %gep, i1 false, i32 0) nounwind readonly
 157 ; CHECK-NEXT: ret i32 32
 158   ret i32 %objsize
 159 }
 160
 161 declare noalias i8* @calloc(i32, i32) nounwind
 162
 163 define i32 @test8() {
 164 ; CHECK: @test8
 165   %alloc = call noalias i8* @calloc(i32 5, i32 7) nounwind
 166   %gep = getelementptr inbounds i8* %alloc, i32 5
 167   %objsize = call i32 @llvm.objectsize.i32(i8* %gep, i1 false, i32 0) nounwind readonly
 168 ; CHECK-NEXT: ret i32 30
 169   ret i32 %objsize
 170 }
 171
 172 ; CHECK: @test9
 173 define i32 @test9(i32 %x, i32 %y) nounwind {
 174   %a = alloca [3 x [4 x double]], align 8
 175   %1 = getelementptr inbounds [3 x [4 x double]]* %a, i32 0, i32 %x
 176   %2 = getelementptr inbounds [4 x double]* %1, i32 0, i32 %y
 177   %3 = bitcast double* %2 to i8*
 178   %objsize = call i32 @llvm.objectsize.i32(i8* %3, i1 false, i32 2)
 179   ret i32 %objsize
 180 ; CHECK-NEXT: shl i32 %x, 5
 181 ; CHECK-NEXT: shl i32 %y, 3
 182 ; CHECK-NEXT: add i32
 183 ; CHECK-NEXT: sub i32 96,
 184 ; CHECK-NEXT: icmp ugt i32 {{.*}}, 96
 185 ; CHECK-NEXT: select i1 {{.*}}, i32 0,
 186 }
 187
 188 ; CHECK: @test10
 189 define i32 @test10(i32 %x, i32 %y) nounwind {
 190   %alloc = call noalias i8* @calloc(i32 %x, i32 %y) nounwind
 191   %gep = getelementptr inbounds i8* %alloc, i32 5
 192   %objsize = call i32 @llvm.objectsize.i32(i8* %gep, i1 false, i32 2)
 193   ret i32 %objsize
 194 ; CHECK-NEXT: mul i32
 195 ; CHECK-NEXT: add i32 {{.*}}, -5
 196 ; CHECK-NEXT: icmp ult i32 {{.*}}, 5
 197 ; CHECK-NEXT: select i1
 198 ; CHECK-NEXT: ret
 199 }
 200
 201 ; CHECK: @test11
 202 define i32 @test11(i32 %x, i32 %y) nounwind {
 203   %alloc = call i8* @malloc(i32 %x)
 204   %allocd = bitcast i8* %alloc to double*
 205   %gep = getelementptr double* %allocd, i32 %y
 206   %gepi8 = bitcast double* %gep to i8*
 207   %objsize = call i32 @llvm.objectsize.i32(i8* %gepi8, i1 false, i32 2)
 208   ret i32 %objsize
 209 ; CHECK-NEXT: shl i32
 210 ; CHECK-NEXT: sub i32
 211 ; CHECK-NEXT: icmp ugt i32
 212 ; CHECK-NEXT: select i1
 213 ; CHECK-NEXT: ret
 214 }
 215
 216 ; CHECK: @test12
 217 define i32 @test12(i32 %x) nounwind {
 218   %alloc =  alloca i32, i32 %x, align 16
 219   %gep = getelementptr i32* %alloc, i32 7
 220   %gepi8 = bitcast i32* %gep to i8*
 221   %objsize = call i32 @llvm.objectsize.i32(i8* %gepi8, i1 false, i32 2)
 222   ret i32 %objsize
 223 ; CHECK-NEXT: shl i32
 224 ; CHECK-NEXT: add i32 {{.*}}, -28
 225 ; CHECK-NEXT: icmp ult i32 {{.*}}, 28
 226 ; CHECK-NEXT: select i1
 227 ; CHECK-NEXT: ret
 228 }
 229
 230 ; CHECK: @test13
 231 define i32 @test13(i32 %x, i32 %y) nounwind {
 232   %alloc = call i8* @calloc(i32 %x, i32 %y)
 233   %alloc2 = call i8* @malloc(i32 %x)
 234   %objsize = call i32 @llvm.objectsize.i32(i8* %alloc, i1 false, i32 1)
 235   %objsize2 = call i32 @llvm.objectsize.i32(i8* %alloc2, i1 false, i32 1)
 236   %add = add i32 %objsize, %objsize2
 237   ret i32 %add
 238 ; CHECK: objectsize
 239 ; CHECK: objectsize
 240 ; CHECK: add
 241 }
 242
 243 ; CHECK: @overflow
 244 define i32 @overflow() {
 245   %alloc = call noalias i8* @malloc(i32 21) nounwind
 246   %gep = getelementptr inbounds i8* %alloc, i32 50
 247   %objsize = call i32 @llvm.objectsize.i32(i8* %gep, i1 false, i32 0) nounwind readonly
 248 ; CHECK-NEXT: ret i32 0
 249   ret i32 %objsize
 250 }