test/Transforms/InstCombine/getelementptr.ll

   1 ; RUN: llvm-as < %s | opt -instcombine | llvm-dis | FileCheck %s
   2
   3 %pair = type { i32, i32 }
   4 @Global = constant [10 x i8] c"helloworld"
   5
   6 ; Test noop elimination
   7 define i32* @test1(i32* %I) {
   8         %A = getelementptr i32* %I, i64 0
   9         ret i32* %A
  10 ; CHECK: @test1
  11 ; CHECK: ret i32* %I
  12 }
  13
  14 ; Test noop elimination
  15 define i32* @test2(i32* %I) {
  16         %A = getelementptr i32* %I
  17         ret i32* %A
  18 ; CHECK: @test2
  19 ; CHECK: ret i32* %I
  20 }
  21
  22 ; Test that two array indexing geps fold
  23 define i32* @test3(i32* %I) {
  24         %A = getelementptr i32* %I, i64 17
  25         %B = getelementptr i32* %A, i64 4
  26         ret i32* %B
  27 ; CHECK: @test3
  28 ; CHECK: getelementptr i32* %I, i64 21
  29 }
  30
  31 ; Test that two getelementptr insts fold
  32 define i32* @test4({ i32 }* %I) {
  33         %A = getelementptr { i32 }* %I, i64 1
  34         %B = getelementptr { i32 }* %A, i64 0, i32 0
  35         ret i32* %B
  36 ; CHECK: @test4
  37 ; CHECK: getelementptr %0* %I, i64 1, i32 0
  38 }
  39
  40 define void @test5(i8 %B) {
  41         ; This should be turned into a constexpr instead of being an instruction
  42         %A = getelementptr [10 x i8]* @Global, i64 0, i64 4
  43         store i8 %B, i8* %A
  44         ret void
  45 ; CHECK: @test5
  46 ; CHECK: store i8 %B, i8* getelementptr inbounds ([10 x i8]* @Global, i64 0, i64 4)
  47 }
  48
  49 define i32* @test6() {
  50         %M = malloc [4 x i32]
  51         %A = getelementptr [4 x i32]* %M, i64 0, i64 0
  52         %B = getelementptr i32* %A, i64 2
  53         ret i32* %B
  54 ; CHECK: @test6
  55 ; CHECK: getelementptr [4 x i32]* %M, i64 0, i64 2
  56 }
  57
  58 define i32* @test7(i32* %I, i64 %C, i64 %D) {
  59         %A = getelementptr i32* %I, i64 %C              ; <i32*> [#uses=1]
  60         %B = getelementptr i32* %A, i64 %D              ; <i32*> [#uses=1]
  61         ret i32* %B
  62 ; CHECK: @test7
  63 ; CHECK: %A.sum = add i64 %C, %D
  64 ; CHECK: getelementptr i32* %I, i64 %A.sum
  65 }
  66
  67 define i8* @test8([10 x i32]* %X) {
  68         ;; Fold into the cast.
  69         %A = getelementptr [10 x i32]* %X, i64 0, i64 0         ; <i32*> [#uses=1]
  70         %B = bitcast i32* %A to i8*             ; <i8*> [#uses=1]
  71         ret i8* %B
  72 ; CHECK: @test8
  73 ; CHECK: bitcast [10 x i32]* %X to i8*
  74 }
  75
  76 define i32 @test9() {
  77         %A = getelementptr { i32, double }* null, i32 0, i32 1          ; <double*> [#uses=1]
  78         %B = ptrtoint double* %A to i32         ; <i32> [#uses=1]
  79         ret i32 %B
  80 ; CHECK: @test9
  81 ; CHECK: ret i32 8
  82 }
  83
  84 define i1 @test10({ i32, i32 }* %x, { i32, i32 }* %y) {
  85         %tmp.1 = getelementptr { i32, i32 }* %x, i32 0, i32 1           ; <i32*> [#uses=1]
  86         %tmp.3 = getelementptr { i32, i32 }* %y, i32 0, i32 1           ; <i32*> [#uses=1]
  87         ;; seteq x, y
  88         %tmp.4 = icmp eq i32* %tmp.1, %tmp.3            ; <i1> [#uses=1]
  89         ret i1 %tmp.4
  90 ; CHECK: @test10
  91 ; CHECK: icmp eq %pair* %x, %y
  92 }
  93
  94 define i1 @test11({ i32, i32 }* %X) {
  95         %P = getelementptr { i32, i32 }* %X, i32 0, i32 0               ; <i32*> [#uses=1]
  96         %Q = icmp eq i32* %P, null              ; <i1> [#uses=1]
  97         ret i1 %Q
  98 ; CHECK: @test11
  99 ; CHECK: icmp eq %pair* %X, null
 100 }