test/Transforms/InstCombine/getelementptr.ll

   1 ; RUN: opt < %s -instcombine -S | FileCheck %s
   2
   3 target datalayout = "e-p:64:64"
   4 %intstruct = type { i32 }
   5 %pair = type { i32, i32 }
   6 %struct.B = type { double }
   7 %struct.A = type { %struct.B, i32, i32 }
   8
   9
  10 @Global = constant [10 x i8] c"helloworld"
  11
  12 ; Test noop elimination
  13 define i32* @test1(i32* %I) {
  14         %A = getelementptr i32* %I, i64 0
  15         ret i32* %A
  16 ; CHECK: @test1
  17 ; CHECK: ret i32* %I
  18 }
  19
  20 ; Test noop elimination
  21 define i32* @test2(i32* %I) {
  22         %A = getelementptr i32* %I
  23         ret i32* %A
  24 ; CHECK: @test2
  25 ; CHECK: ret i32* %I
  26 }
  27
  28 ; Test that two array indexing geps fold
  29 define i32* @test3(i32* %I) {
  30         %A = getelementptr i32* %I, i64 17
  31         %B = getelementptr i32* %A, i64 4
  32         ret i32* %B
  33 ; CHECK: @test3
  34 ; CHECK: getelementptr i32* %I, i64 21
  35 }
  36
  37 ; Test that two getelementptr insts fold
  38 define i32* @test4({ i32 }* %I) {
  39         %A = getelementptr { i32 }* %I, i64 1
  40         %B = getelementptr { i32 }* %A, i64 0, i32 0
  41         ret i32* %B
  42 ; CHECK: @test4
  43 ; CHECK: getelementptr %intstruct* %I, i64 1, i32 0
  44 }
  45
  46 define void @test5(i8 %B) {
  47         ; This should be turned into a constexpr instead of being an instruction
  48         %A = getelementptr [10 x i8]* @Global, i64 0, i64 4
  49         store i8 %B, i8* %A
  50         ret void
  51 ; CHECK: @test5
  52 ; CHECK: store i8 %B, i8* getelementptr inbounds ([10 x i8]* @Global, i64 0, i64 4)
  53 }
  54
  55
  56 define i32* @test7(i32* %I, i64 %C, i64 %D) {
  57         %A = getelementptr i32* %I, i64 %C
  58         %B = getelementptr i32* %A, i64 %D
  59         ret i32* %B
  60 ; CHECK: @test7
  61 ; CHECK: %A.sum = add i64 %C, %D
  62 ; CHECK: getelementptr i32* %I, i64 %A.sum
  63 }
  64
  65 define i8* @test8([10 x i32]* %X) {
  66         ;; Fold into the cast.
  67         %A = getelementptr [10 x i32]* %X, i64 0, i64 0
  68         %B = bitcast i32* %A to i8*
  69         ret i8* %B
  70 ; CHECK: @test8
  71 ; CHECK: bitcast [10 x i32]* %X to i8*
  72 }
  73
  74 define i32 @test9() {
  75         %A = getelementptr { i32, double }* null, i32 0, i32 1
  76         %B = ptrtoint double* %A to i32
  77         ret i32 %B
  78 ; CHECK: @test9
  79 ; CHECK: ret i32 8
  80 }
  81
  82 define i1 @test10({ i32, i32 }* %x, { i32, i32 }* %y) {
  83         %tmp.1 = getelementptr { i32, i32 }* %x, i32 0, i32 1
  84         %tmp.3 = getelementptr { i32, i32 }* %y, i32 0, i32 1
  85         ;; seteq x, y
  86         %tmp.4 = icmp eq i32* %tmp.1, %tmp.3
  87         ret i1 %tmp.4
  88 ; CHECK: @test10
  89 ; CHECK: icmp eq %pair* %x, %y
  90 }
  91
  92 define i1 @test11({ i32, i32 }* %X) {
  93         %P = getelementptr { i32, i32 }* %X, i32 0, i32 0
  94         %Q = icmp eq i32* %P, null
  95         ret i1 %Q
  96 ; CHECK: @test11
  97 ; CHECK: icmp eq %pair* %X, null
  98 }
  99
 100
 101 ; PR4748
 102 define i32 @test12(%struct.A* %a) {
 103 entry:
 104   %g3 = getelementptr %struct.A* %a, i32 0, i32 1
 105   store i32 10, i32* %g3, align 4
 106
 107   %g4 = getelementptr %struct.A* %a, i32 0, i32 0
 108
 109   %new_a = bitcast %struct.B* %g4 to %struct.A*
 110
 111   %g5 = getelementptr %struct.A* %new_a, i32 0, i32 1
 112   %a_a = load i32* %g5, align 4
 113   ret i32 %a_a
 114 ; CHECK:      @test12
 115 ; CHECK:      getelementptr %struct.A* %a, i64 0, i32 1
 116 ; CHECK-NEXT: store i32 10, i32* %g3
 117 ; CHECK-NEXT: ret i32 10
 118 }
 119
 120
 121 ; PR2235
 122 %S = type { i32, [ 100 x i32] }
 123 define i1 @test13(i64 %X, %S* %P) {
 124         %A = getelementptr inbounds %S* %P, i32 0, i32 1, i64 %X
 125         %B = getelementptr inbounds %S* %P, i32 0, i32 0
 126         %C = icmp eq i32* %A, %B
 127         ret i1 %C
 128 ; CHECK: @test13
 129 ; CHECK:    %C = icmp eq i64 %X, -1
 130 }
 131
 132
 133 @G = external global [3 x i8]
 134 define i8* @test14(i32 %Idx) {
 135         %idx = zext i32 %Idx to i64
 136         %tmp = getelementptr i8* getelementptr ([3 x i8]* @G, i32 0, i32 0), i64 %idx
 137         ret i8* %tmp
 138 ; CHECK: @test14
 139 ; CHECK: getelementptr [3 x i8]* @G, i64 0, i64 %idx
 140 }
 141
 142
 143 ; Test folding of constantexpr geps into normal geps.
 144 @Array = external global [40 x i32]
 145 define i32 *@test15(i64 %X) {
 146         %A = getelementptr i32* getelementptr ([40 x i32]* @Array, i64 0, i64 0), i64 %X
 147         ret i32* %A
 148 ; CHECK: @test15
 149 ; CHECK: getelementptr [40 x i32]* @Array, i64 0, i64 %X
 150 }
 151
 152
 153 define i32* @test16(i32* %X, i32 %Idx) {
 154         %R = getelementptr i32* %X, i32 %Idx
 155         ret i32* %R
 156 ; CHECK: @test16
 157 ; CHECK: sext i32 %Idx to i64
 158 }
 159
 160
 161 define i1 @test17(i16* %P, i32 %I, i32 %J) {
 162         %X = getelementptr inbounds i16* %P, i32 %I
 163         %Y = getelementptr inbounds i16* %P, i32 %J
 164         %C = icmp ult i16* %X, %Y
 165         ret i1 %C
 166 ; CHECK: @test17
 167 ; CHECK: %C = icmp slt i32 %I, %J
 168 }
 169
 170 define i1 @test18(i16* %P, i32 %I) {
 171         %X = getelementptr inbounds i16* %P, i32 %I
 172         %C = icmp ult i16* %X, %P
 173         ret i1 %C
 174 ; CHECK: @test18
 175 ; CHECK: %C = icmp slt i32 %I, 0
 176 }
 177
 178 define i32 @test19(i32* %P, i32 %A, i32 %B) {
 179         %tmp.4 = getelementptr inbounds i32* %P, i32 %A
 180         %tmp.9 = getelementptr inbounds i32* %P, i32 %B
 181         %tmp.10 = icmp eq i32* %tmp.4, %tmp.9
 182         %tmp.11 = zext i1 %tmp.10 to i32
 183         ret i32 %tmp.11
 184 ; CHECK: @test19
 185 ; CHECK: icmp eq i32 %A, %B
 186 }
 187
 188 define i32 @test20(i32* %P, i32 %A, i32 %B) {
 189         %tmp.4 = getelementptr inbounds i32* %P, i32 %A
 190         %tmp.6 = icmp eq i32* %tmp.4, %P
 191         %tmp.7 = zext i1 %tmp.6 to i32
 192         ret i32 %tmp.7
 193 ; CHECK: @test20
 194 ; CHECK: icmp eq i32 %A, 0
 195 }
 196
 197
 198 define i32 @test21() {
 199         %pbob1 = alloca %intstruct
 200         %pbob2 = getelementptr %intstruct* %pbob1
 201         %pbobel = getelementptr %intstruct* %pbob2, i64 0, i32 0
 202         %rval = load i32* %pbobel
 203         ret i32 %rval
 204 ; CHECK: @test21
 205 ; CHECK: getelementptr %intstruct* %pbob1, i64 0, i32 0
 206 }
 207
 208
 209 @A = global i32 1               ; <i32*> [#uses=1]
 210 @B = global i32 2               ; <i32*> [#uses=1]
 211
 212 define i1 @test22() {
 213         %C = icmp ult i32* getelementptr (i32* @A, i64 1),
 214                            getelementptr (i32* @B, i64 2)
 215         ret i1 %C
 216 ; CHECK: @test22
 217 ; CHECK: icmp ult (i32* getelementptr inbounds (i32* @A, i64 1), i32* getelementptr (i32* @B, i64 2))
 218 }
 219
 220
 221 %X = type { [10 x i32], float }
 222
 223 define i1 @test23() {
 224         %A = getelementptr %X* null, i64 0, i32 0, i64 0                ; <i32*> [#uses=1]
 225         %B = icmp ne i32* %A, null              ; <i1> [#uses=1]
 226         ret i1 %B
 227 ; CHECK: @test23
 228 ; CHECK: ret i1 false
 229 }
 230
 231 %"java/lang/Object" = type { %struct.llvm_java_object_base }
 232 %"java/lang/StringBuffer" = type { %"java/lang/Object", i32, { %"java/lang/Object", i32, [0 x i16] }*, i1 }
 233 %struct.llvm_java_object_base = type opaque
 234
 235 define void @test24() {
 236 bc0:
 237         %tmp53 = getelementptr %"java/lang/StringBuffer"* null, i32 0, i32 1            ; <i32*> [#uses=1]
 238         store i32 0, i32* %tmp53
 239         ret void
 240 ; CHECK: @test24
 241 ; CHECK: store i32 0, i32* getelementptr (%"java/lang/StringBuffer"* null, i64 0, i32 1)
 242 }
 243
 244 define void @test25() {
 245 entry:
 246         %tmp = getelementptr { i64, i64, i64, i64 }* null, i32 0, i32 3         ; <i64*> [#uses=1]
 247         %tmp.upgrd.1 = load i64* %tmp           ; <i64> [#uses=1]
 248         %tmp8.ui = load i64* null               ; <i64> [#uses=1]
 249         %tmp8 = bitcast i64 %tmp8.ui to i64             ; <i64> [#uses=1]
 250         %tmp9 = and i64 %tmp8, %tmp.upgrd.1             ; <i64> [#uses=1]
 251         %sext = trunc i64 %tmp9 to i32          ; <i32> [#uses=1]
 252         %tmp27.i = sext i32 %sext to i64                ; <i64> [#uses=1]
 253         tail call void @foo25( i32 0, i64 %tmp27.i )
 254         unreachable
 255 ; CHECK: @test25
 256 }
 257
 258 declare void @foo25(i32, i64)
 259
 260
 261 ; PR1637
 262 define i1 @test26(i8* %arr) {
 263         %X = getelementptr i8* %arr, i32 1
 264         %Y = getelementptr i8* %arr, i32 1
 265         %test = icmp uge i8* %X, %Y
 266         ret i1 %test
 267 ; CHECK: @test26
 268 ; CHECK: ret i1 true
 269 }
 270
 271         %struct.__large_struct = type { [100 x i64] }
 272         %struct.compat_siginfo = type { i32, i32, i32, { [29 x i32] } }
 273         %struct.siginfo_t = type { i32, i32, i32, { { i32, i32, [0 x i8], %struct.sigval_t, i32 }, [88 x i8] } }
 274         %struct.sigval_t = type { i8* }
 275
 276 define i32 @test27(%struct.compat_siginfo* %to, %struct.siginfo_t* %from) {
 277 entry:
 278         %from_addr = alloca %struct.siginfo_t*
 279         %tmp344 = load %struct.siginfo_t** %from_addr, align 8
 280         %tmp345 = getelementptr %struct.siginfo_t* %tmp344, i32 0, i32 3
 281         %tmp346 = getelementptr { { i32, i32, [0 x i8], %struct.sigval_t, i32 }, [88 x i8] }* %tmp345, i32 0, i32 0
 282         %tmp346347 = bitcast { i32, i32, [0 x i8], %struct.sigval_t, i32 }* %tmp346 to { i32, i32, %struct.sigval_t }*
 283         %tmp348 = getelementptr { i32, i32, %struct.sigval_t }* %tmp346347, i32 0, i32 2
 284         %tmp349 = getelementptr %struct.sigval_t* %tmp348, i32 0, i32 0
 285         %tmp349350 = bitcast i8** %tmp349 to i32*
 286         %tmp351 = load i32* %tmp349350, align 8
 287         %tmp360 = call i32 asm sideeffect "...",
 288         "=r,ir,*m,i,0,~{dirflag},~{fpsr},~{flags}"( i32 %tmp351,
 289          %struct.__large_struct* null, i32 -14, i32 0 )
 290         unreachable
 291 ; CHECK: @test27
 292 }
 293
 294 ; PR1978
 295         %struct.x = type <{ i8 }>
 296 @.str = internal constant [6 x i8] c"Main!\00"
 297 @.str1 = internal constant [12 x i8] c"destroy %p\0A\00"
 298
 299 define i32 @test28() nounwind  {
 300 entry:
 301         %orientations = alloca [1 x [1 x %struct.x]]
 302         %tmp3 = call i32 @puts( i8* getelementptr ([6 x i8]* @.str, i32 0, i32 0) ) nounwind
 303         %tmp45 = getelementptr inbounds [1 x [1 x %struct.x]]* %orientations, i32 1, i32 0, i32 0
 304         %orientations62 = getelementptr [1 x [1 x %struct.x]]* %orientations, i32 0, i32 0, i32 0
 305         br label %bb10
 306
 307 bb10:
 308         %indvar = phi i32 [ 0, %entry ], [ %indvar.next, %bb10 ]
 309         %tmp.0.reg2mem.0.rec = mul i32 %indvar, -1
 310         %tmp12.rec = add i32 %tmp.0.reg2mem.0.rec, -1
 311         %tmp12 = getelementptr inbounds %struct.x* %tmp45, i32 %tmp12.rec
 312         %tmp16 = call i32 (i8*, ...)* @printf( i8* getelementptr ([12 x i8]* @.str1, i32 0, i32 0), %struct.x* %tmp12 ) nounwind
 313         %tmp84 = icmp eq %struct.x* %tmp12, %orientations62
 314         %indvar.next = add i32 %indvar, 1
 315         br i1 %tmp84, label %bb17, label %bb10
 316
 317 bb17:
 318         ret i32 0
 319 ; CHECK: @test28
 320 ; CHECK: icmp eq i32 %indvar, 0
 321 }
 322
 323 declare i32 @puts(i8*)
 324
 325 declare i32 @printf(i8*, ...)
 326
 327
 328
 329
 330 ; rdar://6762290
 331         %T = type <{ i64, i64, i64 }>
 332 define i32 @test29(i8* %start, i32 %X) nounwind {
 333 entry:
 334         %tmp3 = load i64* null
 335         %add.ptr = getelementptr i8* %start, i64 %tmp3
 336         %tmp158 = load i32* null
 337         %add.ptr159 = getelementptr %T* null, i32 %tmp158
 338         %add.ptr209 = getelementptr i8* %start, i64 0
 339         %add.ptr212 = getelementptr i8* %add.ptr209, i32 %X
 340         %cmp214 = icmp ugt i8* %add.ptr212, %add.ptr
 341         br i1 %cmp214, label %if.then216, label %if.end363
 342
 343 if.then216:
 344         ret i32 1
 345
 346 if.end363:
 347         ret i32 0
 348 ; CHECK: @test29
 349 }
 350
 351
 352 ; PR3694
 353 define i32 @test30(i32 %m, i32 %n) nounwind {
 354 entry:
 355         %0 = alloca i32, i32 %n, align 4
 356         %1 = bitcast i32* %0 to [0 x i32]*
 357         call void @test30f(i32* %0) nounwind
 358         %2 = getelementptr [0 x i32]* %1, i32 0, i32 %m
 359         %3 = load i32* %2, align 4
 360         ret i32 %3
 361 ; CHECK: @test30
 362 ; CHECK: getelementptr i32
 363 }
 364
 365 declare void @test30f(i32*)
 366
 367
 368
 369 define i1 @test31(i32* %A) {
 370         %B = getelementptr i32* %A, i32 1
 371         %C = getelementptr i32* %A, i64 1
 372         %V = icmp eq i32* %B, %C
 373         ret i1 %V
 374 ; CHECK: @test31
 375 ; CHECK: ret i1 true
 376 }
 377
 378
 379 ; PR1345
 380 define i8* @test32(i8* %v) {
 381         %A = alloca [4 x i8*], align 16
 382         %B = getelementptr [4 x i8*]* %A, i32 0, i32 0
 383         store i8* null, i8** %B
 384         %C = bitcast [4 x i8*]* %A to { [16 x i8] }*
 385         %D = getelementptr { [16 x i8] }* %C, i32 0, i32 0, i32 8
 386         %E = bitcast i8* %D to i8**
 387         store i8* %v, i8** %E
 388         %F = getelementptr [4 x i8*]* %A, i32 0, i32 2
 389         %G = load i8** %F
 390         ret i8* %G
 391 ; CHECK: @test32
 392 ; CHECK: %D = getelementptr [4 x i8*]* %A, i64 0, i64 1
 393 ; CHECK: %F = getelementptr [4 x i8*]* %A, i64 0, i64 2
 394 }
 395
 396 ; PR3290
 397 %struct.Key = type { { i32, i32 } }
 398 %struct.anon = type <{ i8, [3 x i8], i32 }>
 399
 400 define i32 *@test33(%struct.Key *%A) {
 401         %B = bitcast %struct.Key* %A to %struct.anon*
 402         %C = getelementptr %struct.anon* %B, i32 0, i32 2
 403         ret i32 *%C
 404 ; CHECK: @test33
 405 ; CHECK: getelementptr %struct.Key* %A, i64 0, i32 0, i32 1
 406 }
 407
 408
 409
 410         %T2 = type { i8*, i8 }
 411 define i8* @test34(i8* %Val, i64 %V) nounwind {
 412 entry:
 413         %A = alloca %T2, align 8
 414         %mrv_gep = bitcast %T2* %A to i64*
 415         %B = getelementptr %T2* %A, i64 0, i32 0
 416
 417         store i64 %V, i64* %mrv_gep
 418         %C = load i8** %B, align 8
 419         ret i8* %C
 420 ; CHECK: @test34
 421 ; CHECK: %V.c = inttoptr i64 %V to i8*
 422 ; CHECK: ret i8* %V.c
 423 }
 424
 425 %t0 = type { i8*, [19 x i8] }
 426 %t1 = type { i8*, [0 x i8] }
 427
 428 @array = external global [11 x i8]
 429
 430 @s = external global %t0
 431 @"\01LC8" = external constant [17 x i8]
 432
 433 ; Instcombine should be able to fold this getelementptr.
 434
 435 define i32 @test35() nounwind {
 436   call i32 (i8*, ...)* @printf(i8* getelementptr ([17 x i8]* @"\01LC8", i32 0, i32 0),
 437              i8* getelementptr (%t1* bitcast (%t0* @s to %t1*), i32 0, i32 1, i32 0)) nounwind
 438   ret i32 0
 439 ; CHECK: @test35
 440 ; CHECK: call i32 (i8*, ...)* @printf(i8* getelementptr inbounds ([17 x i8]* @"\01LC8", i64 0, i64 0), i8* getelementptr inbounds (%t0* @s, i64 0, i32 1, i64 0)) nounwind
 441 }
 442
 443 ; Instcombine should constant-fold the GEP so that indices that have
 444 ; static array extents are within bounds of those array extents.
 445 ; In the below, -1 is not in the range [0,11). After the transformation,
 446 ; the same address is computed, but 3 is in the range of [0,11).
 447
 448 define i8* @test36() nounwind {
 449   ret i8* getelementptr ([11 x i8]* @array, i32 0, i64 -1)
 450 ; CHECK: @test36
 451 ; CHECK: ret i8* getelementptr ([11 x i8]* @array, i64 1676976733973595601, i64 4)
 452 }
 453
 454 ; Instcombine shouldn't assume that gep(A,0,1) != gep(A,1,0).
 455 @A37 = external constant [1 x i8]
 456 define i1 @test37() nounwind {
 457 ; CHECK: @test37
 458 ; CHECK: ret i1 true
 459   %t = icmp eq i8* getelementptr ([1 x i8]* @A37, i64 0, i64 1),
 460                    getelementptr ([1 x i8]* @A37, i64 1, i64 0)
 461   ret i1 %t
 462 }
 463
 464 ; Test index promotion
 465 define i32* @test38(i32* %I, i32 %n) {
 466         %A = getelementptr i32* %I, i32 %n
 467         ret i32* %A
 468 ; CHECK: @test38
 469 ; CHECK: = sext i32 %n to i64
 470 ; CHECK: %A = getelementptr i32* %I, i64 %
 471 }