test/Analysis/DSGraph/GlobalsGraphFuncPtr.ll

   1 ; Test resolvable and unresolvable calls through function pointers:
   2 ; -- both should be retained in function graphs until resolved or until main
   3 ; -- former should get resolved in or before main() and never appear in GG
   4 ; -- latter should remain unresolved in main() and copied to GG
   5 ; -- globals in GG pointed to by latter should be marked I, but not other nodes
   6 ;
   7 ; FIXME: KnownPtr should be just S.
   8 ; RUN: analyze %s -datastructure-gc -dsgc-check-flags=KnownPtr:SI,UnknownPtr:SI -dsgc-dspass=bu
   9
  10 %Z = internal global int 0
  11 %X = internal global int 0
  12 %M = internal global int 0
  13 %.str_1 = internal constant [9 x sbyte] c"&Z = %p\0A\00"
  14
  15 implementation
  16
  17 declare int %printf(sbyte*, ...)
  18 declare void %exit_dummy(int*)
  19
  20 internal void %makeCalls(void (int*)* %GpKnown.1, void (int*)* %GpUnknown.1,
  21                          int* %GpKnownPtr, int* %GpUnknownPtr) {
  22         %tmp.0 = load int* %Z
  23         %tmp.1.not = setne int %tmp.0, 0
  24         br bool %tmp.1.not, label %else, label %then
  25
  26 then:
  27         ; pass to exit_dummy: never resolved
  28         call void %GpUnknown.1( int* %GpUnknownPtr )
  29         %tmp.61 = load int* %Z
  30         %inc1 = add int %tmp.61, 1
  31         store int %inc1, int* %Z
  32         %tmp.71 = call int (sbyte*, ...)* %printf( sbyte* getelementptr ([9 x sbyte]* %.str_1, long 0, long 0), int* %Z )
  33         ret void
  34
  35 else:
  36         ; pass to knownF: resolved in main
  37         call void %GpKnown.1( int* %GpKnownPtr )
  38         %tmp.6 = load int* %Z
  39         %inc = add int %tmp.6, 1
  40         store int %inc, int* %Z
  41
  42         ; "known external": resolved here
  43         %tmp.7 = call int (sbyte*, ...)* %printf( sbyte* getelementptr ([9 x sbyte]* %.str_1, long 0, long 0), int* %Z )
  44         ret void
  45 }
  46
  47 internal void %knownF(int* %Y.1) {
  48         %tmp.1 = seteq int* %Y.1, null
  49         br bool %tmp.1, label %then, label %UnifiedExitNode
  50
  51 then:
  52         call void %knownF( int* %Y.1 )   ; direct call to self: resolved here
  53         br label %UnifiedExitNode
  54
  55 UnifiedExitNode:
  56         ret void
  57 }
  58
  59 int %main(int %argc.1) {
  60         %KnownPtr = alloca int
  61         %UnknownPtr = alloca int
  62         store int 1, int* %Z
  63         call void %makeCalls( void (int*)* %knownF, void (int*)* %exit_dummy,
  64                               int* %KnownPtr, int* %UnknownPtr )
  65         ret int 0
  66 }
  67