lib/Target/X86/X86InstrInfo.td

   1 //===- X86InstrInfo.td - Describe the X86 Instruction Set -------*- C++ -*-===//
   2 //
   3 // This file describes the X86 instruction set, defining the instructions, and
   4 // properties of the instructions which are needed for code generation, machine
   5 // code emission, and analysis.
   6 //
   7 //===----------------------------------------------------------------------===//
   8
   9 // Format specifies the encoding used by the instruction.  This is part of the
  10 // ad-hoc solution used to emit machine instruction encodings by our machine
  11 // code emitter.
  12 class Format<bits<5> val> {
  13   bits<5> Value = val;
  14 }
  15
  16 def Pseudo     : Format<0>; def RawFrm     : Format<1>;
  17 def AddRegFrm  : Format<2>; def MRMDestReg : Format<3>;
  18 def MRMDestMem : Format<4>; def MRMSrcReg  : Format<5>;
  19 def MRMSrcMem  : Format<6>;
  20 def MRMS0r : Format<16>; def MRMS1r : Format<17>; def MRMS2r : Format<18>;
  21 def MRMS3r : Format<19>; def MRMS4r : Format<20>; def MRMS5r : Format<21>;
  22 def MRMS6r : Format<22>; def MRMS7r : Format<23>;
  23 def MRMS0m : Format<24>; def MRMS1m : Format<25>; def MRMS2m : Format<26>;
  24 def MRMS3m : Format<27>; def MRMS4m : Format<28>; def MRMS5m : Format<29>;
  25 def MRMS6m : Format<30>; def MRMS7m : Format<31>;
  26
  27 // ArgType - This specifies the argument type used by an instruction. This is
  28 // part of the ad-hoc solution used to emit machine instruction encodings by our
  29 // machine code emitter.
  30 class ArgType<bits<3> val> {
  31   bits<3> Value = val;
  32 }
  33 def NoArg  : ArgType<0>;
  34 def Arg8   : ArgType<1>;
  35 def Arg16  : ArgType<2>;
  36 def Arg32  : ArgType<3>;
  37 def Arg64  : ArgType<4>;   // 64 bit int argument for FILD64
  38 def ArgF32 : ArgType<5>;
  39 def ArgF64 : ArgType<6>;
  40 def ArgF80 : ArgType<6>;
  41
  42 // FPFormat - This specifies what form this FP instruction has.  This is used by
  43 // the Floating-Point stackifier pass.
  44 class FPFormat<bits<3> val> {
  45   bits<3> Value = val;
  46 }
  47 def NotFP      : FPFormat<0>;
  48 def ZeroArgFP  : FPFormat<1>;
  49 def OneArgFP   : FPFormat<2>;
  50 def OneArgFPRW : FPFormat<3>;
  51 def TwoArgFP   : FPFormat<4>;
  52 def SpecialFP  : FPFormat<5>;
  53
  54
  55 class X86Inst<string nam, bits<8> opcod, Format f, ArgType a> : Instruction {
  56   let Namespace = "X86";
  57
  58   let Name = nam;
  59   bits<8> Opcode = opcod;
  60   Format Form = f;
  61   bits<5> FormBits = Form.Value;
  62   ArgType Type = a;
  63   bits<3> TypeBits = Type.Value;
  64
  65   // Attributes specific to X86 instructions...
  66   bit hasOpSizePrefix = 0; // Does this inst have a 0x66 prefix?
  67   bit printImplicitUses = 0; // Should we print implicit uses of this inst?
  68
  69   bits<4> Prefix = 0;       // Which prefix byte does this inst have?
  70   FPFormat FPForm;          // What flavor of FP instruction is this?
  71   bits<3> FPFormBits = 0;
  72 }
  73
  74 class Imp<list<Register> uses, list<Register> defs> {
  75   list<Register> Uses = uses;
  76   list<Register> Defs = defs;
  77 }
  78
  79
  80 // Prefix byte classes which are used to indicate to the ad-hoc machine code
  81 // emitter that various prefix bytes are required.
  82 class OpSize { bit hasOpSizePrefix = 1; }
  83 class TB     { bits<4> Prefix = 1; }
  84 class D8     { bits<4> Prefix = 2; }
  85 class D9     { bits<4> Prefix = 3; }
  86 class DA     { bits<4> Prefix = 4; }
  87 class DB     { bits<4> Prefix = 5; }
  88 class DC     { bits<4> Prefix = 6; }
  89 class DD     { bits<4> Prefix = 7; }
  90 class DE     { bits<4> Prefix = 8; }
  91 class DF     { bits<4> Prefix = 9; }
  92
  93
  94
  95 //===----------------------------------------------------------------------===//
  96 // Instruction list...
  97 //
  98
  99 def PHI : X86Inst<"PHI", 0, Pseudo, NoArg>;          // PHI node...
 100
 101 def NOOP : X86Inst<"nop", 0x90, RawFrm, NoArg>;    // nop
 102
 103 def ADJCALLSTACKDOWN : X86Inst<"ADJCALLSTACKDOWN", 0, Pseudo, NoArg>;
 104 def ADJCALLSTACKUP   : X86Inst<"ADJCALLSTACKUP",   0, Pseudo, NoArg>;
 105 def IMPLICIT_USE     : X86Inst<"IMPLICIT_USE",     0, Pseudo, NoArg>;
 106
 107 //===----------------------------------------------------------------------===//
 108 //  Control Flow Instructions...
 109 //
 110
 111 // Return instruction...
 112 let isTerminator = 1, isReturn = 1 in
 113   def RET : X86Inst<"ret", 0xC3, RawFrm, NoArg>;
 114
 115 // All branches are RawFrm, Void, Branch, and Terminators
 116 let isBranch = 1, isTerminator = 1 in
 117   class IBr<string name, bits<8> opcode> : X86Inst<name, opcode, RawFrm, NoArg>;
 118
 119 def JMP : IBr<"jmp", 0xE9>;
 120 def JB  : IBr<"jb" , 0x82>, TB;
 121 def JAE : IBr<"jae", 0x83>, TB;
 122 def JE  : IBr<"je" , 0x84>, TB;
 123 def JNE : IBr<"jne", 0x85>, TB;
 124 def JBE : IBr<"jbe", 0x86>, TB;
 125 def JA  : IBr<"ja" , 0x87>, TB;
 126 def JL  : IBr<"jl" , 0x8C>, TB;
 127 def JGE : IBr<"jge", 0x8D>, TB;
 128 def JLE : IBr<"jle", 0x8E>, TB;
 129 def JG  : IBr<"jg" , 0x8F>, TB;
 130
 131
 132 //===----------------------------------------------------------------------===//
 133 //  Call Instructions...
 134 //
 135 let isCall = 1 in
 136   // All calls clobber the non-callee saved registers...
 137   let Defs = [EAX, ECX, EDX, FP0, FP1, FP2, FP3, FP4, FP5, FP6] in {
 138     def CALLpcrel32 : X86Inst<"call", 0xE8, RawFrm, NoArg>;
 139     def CALLr32     : X86Inst<"call", 0xFF, MRMS2r, Arg32>;
 140     def CALLm32     : X86Inst<"call", 0xFF, MRMS2m, Arg32>;
 141   }
 142
 143
 144 //===----------------------------------------------------------------------===//
 145 //  Miscellaneous Instructions...
 146 //
 147 def LEAVE    : X86Inst<"leave", 0xC9, RawFrm, NoArg>, Imp<[EBP], [EBP]>;
 148
 149 let isTwoAddress = 1 in                                      // R32 = bswap R32
 150   def BSWAPr32 : X86Inst<"bswap", 0xC8, AddRegFrm, Arg32>, TB;
 151
 152 def XCHGrr8  : X86Inst<"xchg", 0x86, MRMDestReg, Arg8>;         // xchg R8, R8
 153 def XCHGrr16 : X86Inst<"xchg", 0x87, MRMDestReg, Arg16>, OpSize;// xchg R16, R16
 154 def XCHGrr32 : X86Inst<"xchg", 0x87, MRMDestReg, Arg32>;        // xchg R32, R32
 155
 156 def LEAr16 : X86Inst<"lea", 0x8D, MRMSrcMem, Arg16>, OpSize; // R16 = lea [mem]
 157 def LEAr32 : X86Inst<"lea", 0x8D, MRMSrcMem, Arg32>;         // R32 = lea [mem]
 158
 159 //===----------------------------------------------------------------------===//
 160 //  Move Instructions...
 161 //
 162 def MOVrr8  : X86Inst<"mov", 0x88, MRMDestReg, Arg8>;             // R8 = R8
 163 def MOVrr16 : X86Inst<"mov", 0x89, MRMDestReg, Arg16>, OpSize;    // R16 = R16
 164 def MOVrr32 : X86Inst<"mov", 0x89, MRMDestReg, Arg32>;            // R32 = R32
 165 def MOVir8  : X86Inst<"mov", 0xB0, AddRegFrm , Arg8>;             // R8 = imm8
 166 def MOVir16 : X86Inst<"mov", 0xB8, AddRegFrm , Arg16>, OpSize;    // R16 = imm16
 167 def MOVir32 : X86Inst<"mov", 0xB8, AddRegFrm , Arg32>;            // R32 = imm32
 168 def MOVim8  : X86Inst<"mov", 0xC6, MRMS0m    , Arg8>;             // [mem] = imm8
 169 def MOVim16 : X86Inst<"mov", 0xC7, MRMS0m    , Arg16>, OpSize;    // [mem] = imm16
 170 def MOVim32 : X86Inst<"mov", 0xC7, MRMS0m    , Arg32>;            // [mem] = imm32
 171
 172 def MOVmr8  : X86Inst<"mov", 0x8A, MRMSrcMem , Arg8>;             // R8  = [mem]
 173 def MOVmr16 : X86Inst<"mov", 0x8B, MRMSrcMem , Arg16>, OpSize;    // R16 = [mem]
 174 def MOVmr32 : X86Inst<"mov", 0x8B, MRMSrcMem , Arg32>;            // R32 = [mem]
 175
 176 def MOVrm8  : X86Inst<"mov", 0x88, MRMDestMem, Arg8>;             // [mem] = R8
 177 def MOVrm16 : X86Inst<"mov", 0x89, MRMDestMem, Arg16>, OpSize;    // [mem] = R16
 178 def MOVrm32 : X86Inst<"mov", 0x89, MRMDestMem, Arg32>;            // [mem] = R32
 179
 180 //===----------------------------------------------------------------------===//
 181 //  Fixed-Register Multiplication and Division Instructions...
 182 //
 183
 184 // Extra precision multiplication
 185 def MULr8  : X86Inst<"mul", 0xF6, MRMS4r, Arg8 >, Imp<[AL],[AX]>;               // AL,AH = AL*R8
 186 def MULr16 : X86Inst<"mul", 0xF7, MRMS4r, Arg16>, Imp<[AX],[AX,DX]>, OpSize;    // AX,DX = AX*R16
 187 def MULr32 : X86Inst<"mul", 0xF7, MRMS4r, Arg32>, Imp<[EAX],[EAX,EDX]>;         // EAX,EDX = EAX*R32
 188
 189 // unsigned division/remainder
 190 def DIVr8  : X86Inst<"div", 0xF6, MRMS6r, Arg8 >, Imp<[AX],[AX]>;               // AX/r8 = AL,AH
 191 def DIVr16 : X86Inst<"div", 0xF7, MRMS6r, Arg16>, Imp<[AX,DX],[AX,DX]>, OpSize; // DX:AX/r16 = AX,DX
 192 def DIVr32 : X86Inst<"div", 0xF7, MRMS6r, Arg32>, Imp<[EAX,EDX],[EAX,EDX]>;     // EDX:EAX/r32 = EAX,EDX
 193
 194 // signed division/remainder
 195 def IDIVr8 : X86Inst<"idiv",0xF6, MRMS7r, Arg8 >, Imp<[AX],[AX]>;               // AX/r8 = AL,AH
 196 def IDIVr16: X86Inst<"idiv",0xF7, MRMS7r, Arg16>, Imp<[AX,DX],[AX,DX]>, OpSize; // DX:AX/r16 = AX,DX
 197 def IDIVr32: X86Inst<"idiv",0xF7, MRMS7r, Arg32>, Imp<[EAX,EDX],[EAX,EDX]>;     // EDX:EAX/r32 = EAX,EDX
 198
 199 // Sign-extenders for division
 200 def CBW    : X86Inst<"cbw", 0x98, RawFrm, Arg8 >, Imp<[AL],[AH]>;               // AX = signext(AL)
 201 def CWD    : X86Inst<"cwd", 0x99, RawFrm, Arg8 >, Imp<[AX],[DX]>;               // DX:AX = signext(AX)
 202 def CDQ    : X86Inst<"cdq", 0x99, RawFrm, Arg8 >, Imp<[EAX],[EDX]>;             // EDX:EAX = signext(EAX)
 203
 204
 205 //===----------------------------------------------------------------------===//
 206 //  Two address Instructions...
 207 //
 208 let isTwoAddress = 1 in {  // Define some helper classes to make defs shorter.
 209   class I2A8 <string n, bits<8> o, Format F> : X86Inst<n, o, F, Arg8>;
 210   class I2A16<string n, bits<8> o, Format F> : X86Inst<n, o, F, Arg16>;
 211   class I2A32<string n, bits<8> o, Format F> : X86Inst<n, o, F, Arg32>;
 212 }
 213
 214 // Arithmetic...
 215 def ADDrr8   : I2A8 <"add", 0x00, MRMDestReg>;                // R8 += R8     (set r8  (plus r8 r8))
 216 def ADDrr16  : I2A16<"add", 0x01, MRMDestReg>, OpSize;        // R16 += R16   (set r16 (plus r16 r16))
 217 def ADDrr32  : I2A32<"add", 0x01, MRMDestReg>;                // R32 += R32   (set r32 (plus r32 r32))
 218 def ADDri8   : I2A8 <"add", 0x80, MRMS0r    >;                // R8 += imm8   (set r8  (plus r8 imm8))
 219 def ADDri16  : I2A16<"add", 0x81, MRMS0r    >, OpSize;        // R16 += imm16 (set r16 (plus r16 imm16))
 220 def ADDri32  : I2A32<"add", 0x81, MRMS0r    >;                // R32 += imm32 (set r32 (plus r32 imm32))
 221
 222 def ADCrr32  : I2A32<"adc", 0x11, MRMDestReg>;                // R32 += imm32+Carry
 223
 224 def SUBrr8   : I2A8 <"sub", 0x28, MRMDestReg>;                // R8 -= R8
 225 def SUBrr16  : I2A16<"sub", 0x29, MRMDestReg>, OpSize;        // R16 -= R16
 226 def SUBrr32  : I2A32<"sub", 0x29, MRMDestReg>;                // R32 -= R32
 227 def SUBri8   : I2A8 <"sub", 0x80, MRMS5r    >;                // R8 -= imm8
 228 def SUBri16  : I2A16<"sub", 0x81, MRMS5r    >, OpSize;        // R16 -= imm16
 229 def SUBri32  : I2A32<"sub", 0x81, MRMS5r    >;                // R32 -= imm32
 230
 231 def SBBrr32  : I2A32<"sbb", 0x19, MRMDestReg>;                // R32 -= R32+Carry
 232
 233 def IMULr16  : I2A16<"imul", 0xAF, MRMSrcReg>, TB, OpSize;    // R16 *= R16
 234 def IMULr32  : I2A32<"imul", 0xAF, MRMSrcReg>, TB;            // R32 *= R32
 235
 236 // Logical operators...
 237 def ANDrr8   : I2A8 <"and", 0x20, MRMDestReg>;                // R8  &= R8
 238 def ANDrr16  : I2A16<"and", 0x21, MRMDestReg>, OpSize;        // R16 &= R16
 239 def ANDrr32  : I2A32<"and", 0x21, MRMDestReg>;                // R32 &= R32
 240 def ANDri8   : I2A8 <"and", 0x80, MRMS4r    >;                // R8  &= imm8
 241 def ANDri16  : I2A16<"and", 0x81, MRMS4r    >, OpSize;        // R16 &= imm16
 242 def ANDri32  : I2A32<"and", 0x81, MRMS4r    >;                // R32 &= imm32
 243
 244 def ORrr8    : I2A8 <"or" , 0x08, MRMDestReg>;                // R8  |= R8
 245 def ORrr16   : I2A16<"or" , 0x09, MRMDestReg>, OpSize;        // R16 |= R16
 246 def ORrr32   : I2A32<"or" , 0x09, MRMDestReg>;                // R32 |= R32
 247 def ORri8    : I2A8 <"or" , 0x80, MRMS1r    >;                // R8  |= imm8
 248 def ORri16   : I2A16<"or" , 0x81, MRMS1r    >, OpSize;        // R16 |= imm16
 249 def ORri32   : I2A32<"or" , 0x81, MRMS1r    >;                // R32 |= imm32
 250
 251 def XORrr8   : I2A8 <"xor", 0x30, MRMDestReg>;                // R8  ^= R8
 252 def XORrr16  : I2A16<"xor", 0x31, MRMDestReg>, OpSize;        // R16 ^= R16
 253 def XORrr32  : I2A32<"xor", 0x31, MRMDestReg>;                // R32 ^= R32
 254 def XORri8   : I2A8 <"xor", 0x80, MRMS6r    >;                // R8  ^= imm8
 255 def XORri16  : I2A16<"xor", 0x81, MRMS6r    >, OpSize;        // R16 ^= imm16
 256 def XORri32  : I2A32<"xor", 0x81, MRMS6r    >;                // R32 ^= imm32
 257
 258 // Test instructions are just like AND, except they don't generate a result.
 259 def TESTrr8  : X86Inst<"test", 0x84, MRMDestReg, Arg8 >;          // flags = R8  & R8
 260 def TESTrr16 : X86Inst<"test", 0x85, MRMDestReg, Arg16>, OpSize;  // flags = R16 & R16
 261 def TESTrr32 : X86Inst<"test", 0x85, MRMDestReg, Arg32>;          // flags = R32 & R32
 262 def TESTri8  : X86Inst<"test", 0xF6, MRMS0r    , Arg8 >;          // flags = R8  & imm8
 263 def TESTri16 : X86Inst<"test", 0xF7, MRMS0r    , Arg16>, OpSize;  // flags = R16 & imm16
 264 def TESTri32 : X86Inst<"test", 0xF7, MRMS0r    , Arg32>;          // flags = R32 & imm32
 265
 266 // Shift instructions
 267 class UsesCL { list<Register> Uses = [CL]; bit printImplicitUses = 1; }
 268
 269 def SHLrr8   : I2A8 <"shl", 0xD2, MRMS4r    >        , UsesCL; // R8  <<= cl
 270 def SHLrr16  : I2A8 <"shl", 0xD3, MRMS4r    >, OpSize, UsesCL; // R16 <<= cl
 271 def SHLrr32  : I2A8 <"shl", 0xD3, MRMS4r    >        , UsesCL; // R32 <<= cl
 272 def SHLir8   : I2A8 <"shl", 0xC0, MRMS4r    >;                 // R8  <<= imm8
 273 def SHLir16  : I2A8 <"shl", 0xC1, MRMS4r    >, OpSize;         // R16 <<= imm16
 274 def SHLir32  : I2A8 <"shl", 0xC1, MRMS4r    >;                 // R32 <<= imm32
 275 def SHRrr8   : I2A8 <"shr", 0xD2, MRMS5r    >        , UsesCL; // R8  >>= cl
 276 def SHRrr16  : I2A8 <"shr", 0xD3, MRMS5r    >, OpSize, UsesCL; // R16 >>= cl
 277 def SHRrr32  : I2A8 <"shr", 0xD3, MRMS5r    >        , UsesCL; // R32 >>= cl
 278 def SHRir8   : I2A8 <"shr", 0xC0, MRMS5r    >;                 // R8  >>= imm8
 279 def SHRir16  : I2A8 <"shr", 0xC1, MRMS5r    >, OpSize;         // R16 >>= imm16
 280 def SHRir32  : I2A8 <"shr", 0xC1, MRMS5r    >;                 // R32 >>= imm32
 281 def SARrr8   : I2A8 <"sar", 0xD2, MRMS7r    >        , UsesCL; // R8  >>>= cl
 282 def SARrr16  : I2A8 <"sar", 0xD3, MRMS7r    >, OpSize, UsesCL; // R16 >>>= cl
 283 def SARrr32  : I2A8 <"sar", 0xD3, MRMS7r    >        , UsesCL; // R32 >>>= cl
 284 def SARir8   : I2A8 <"sar", 0xC0, MRMS7r    >;                 // R8  >>>= imm8
 285 def SARir16  : I2A8 <"sar", 0xC1, MRMS7r    >, OpSize;         // R16 >>>= imm16
 286 def SARir32  : I2A8 <"sar", 0xC1, MRMS7r    >;                 // R32 >>>= imm32
 287
 288 def SHLDrr32 : I2A8 <"shld", 0xA5, MRMDestReg>, TB, UsesCL;   // R32 <<= R32,R32 cl
 289 def SHLDir32 : I2A8 <"shld", 0xA4, MRMDestReg>, TB;           // R32 <<= R32,R32 imm8
 290 def SHRDrr32 : I2A8 <"shrd", 0xAD, MRMDestReg>, TB, UsesCL;   // R32 >>= R32,R32 cl
 291 def SHRDir32 : I2A8 <"shrd", 0xAC, MRMDestReg>, TB;           // R32 >>= R32,R32 imm8
 292
 293 // Condition code ops, incl. set if equal/not equal/...
 294 def SAHF     : X86Inst<"sahf" , 0x9E, RawFrm, Arg8>, Imp<[AH],[]>;  // flags = AH
 295 def SETBr    : X86Inst<"setb" , 0x92, MRMS0r, Arg8>, TB;            // R8 = <  unsign
 296 def SETAEr   : X86Inst<"setae", 0x93, MRMS0r, Arg8>, TB;            // R8 = >= unsign
 297 def SETEr    : X86Inst<"sete" , 0x94, MRMS0r, Arg8>, TB;            // R8 = ==
 298 def SETNEr   : X86Inst<"setne", 0x95, MRMS0r, Arg8>, TB;            // R8 = !=
 299 def SETBEr   : X86Inst<"setbe", 0x96, MRMS0r, Arg8>, TB;            // R8 = <= unsign
 300 def SETAr    : X86Inst<"seta" , 0x97, MRMS0r, Arg8>, TB;            // R8 = >  signed
 301 def SETLr    : X86Inst<"setl" , 0x9C, MRMS0r, Arg8>, TB;            // R8 = <  signed
 302 def SETGEr   : X86Inst<"setge", 0x9D, MRMS0r, Arg8>, TB;            // R8 = >= signed
 303 def SETLEr   : X86Inst<"setle", 0x9E, MRMS0r, Arg8>, TB;            // R8 = <= signed
 304 def SETGr    : X86Inst<"setg" , 0x9F, MRMS0r, Arg8>, TB;            // R8 = <  signed
 305
 306 // Conditional moves.  These are modelled as X = cmovXX Y, Z.  Eventually
 307 // register allocated to cmovXX XY, Z
 308 def CMOVErr16 : I2A16<"cmove", 0x44, MRMSrcReg>, TB, OpSize;        // if ==, R16 = R16
 309 def CMOVNErr32: I2A32<"cmovne",0x45, MRMSrcReg>, TB;                // if !=, R32 = R32
 310
 311 // Integer comparisons
 312 def CMPrr8  : X86Inst<"cmp", 0x38, MRMDestReg, Arg8 >;              // compare R8, R8
 313 def CMPrr16 : X86Inst<"cmp", 0x39, MRMDestReg, Arg16>, OpSize;      // compare R16, R16
 314 def CMPrr32 : X86Inst<"cmp", 0x39, MRMDestReg, Arg32>;              // compare R32, R32
 315 def CMPri8  : X86Inst<"cmp", 0x80, MRMS7r    , Arg8 >;              // compare R8, imm8
 316 def CMPri16 : X86Inst<"cmp", 0x81, MRMS7r    , Arg16>, OpSize;      // compare R16, imm16
 317 def CMPri32 : X86Inst<"cmp", 0x81, MRMS7r    , Arg32>;              // compare R32, imm32
 318
 319 // Sign/Zero extenders
 320 def MOVSXr16r8 : X86Inst<"movsx", 0xBE, MRMSrcReg, Arg8>, TB, OpSize; // R16 = signext(R8)
 321 def MOVSXr32r8 : X86Inst<"movsx", 0xBE, MRMSrcReg, Arg8>, TB;         // R32 = signext(R8)
 322 def MOVSXr32r16: X86Inst<"movsx", 0xBF, MRMSrcReg, Arg8>, TB;         // R32 = signext(R16)
 323 def MOVZXr16r8 : X86Inst<"movzx", 0xB6, MRMSrcReg, Arg8>, TB, OpSize; // R16 = zeroext(R8)
 324 def MOVZXr32r8 : X86Inst<"movzx", 0xB6, MRMSrcReg, Arg8>, TB;         // R32 = zeroext(R8)
 325 def MOVZXr32r16: X86Inst<"movzx", 0xB7, MRMSrcReg, Arg8>, TB;         // R32 = zeroext(R16)
 326
 327
 328 //===----------------------------------------------------------------------===//
 329 // Floating point support
 330 //===----------------------------------------------------------------------===//
 331
 332 // FIXME: These need to indicate mod/ref sets for FP regs... & FP 'TOP'
 333
 334 // Floating point pseudo instructions...
 335 class FPInst<string n, bits<8> o, Format F, ArgType t, FPFormat fp>
 336   : X86Inst<n, o, F, t> { let FPForm = fp; let FPFormBits = FPForm.Value; }
 337
 338 def FpMOV : FPInst<"FMOV", 0, Pseudo, ArgF80, SpecialFP>;   // f1 = fmov f2
 339 def FpADD : FPInst<"FADD", 0, Pseudo, ArgF80, TwoArgFP>;    // f1 = fadd f2, f3
 340 def FpSUB : FPInst<"FSUB", 0, Pseudo, ArgF80, TwoArgFP>;    // f1 = fsub f2, f3
 341 def FpMUL : FPInst<"FMUL", 0, Pseudo, ArgF80, TwoArgFP>;    // f1 = fmul f2, f3
 342 def FpDIV : FPInst<"FDIV", 0, Pseudo, ArgF80, TwoArgFP>;    // f1 = fdiv f2, f3
 343
 344 def FpUCOM : FPInst<"FUCOM", 0, Pseudo, ArgF80, TwoArgFP>;  // FPSW = fucom f1, f2
 345
 346 def FpGETRESULT : FPInst<"FGETRESULT",0, Pseudo, ArgF80, SpecialFP>;  // FPR = ST(0)
 347
 348 def FpSETRESULT : FPInst<"FSETRESULT",0, Pseudo, ArgF80, SpecialFP>;  // ST(0) = FPR
 349
 350 // Floating point loads & stores...
 351 def FLDrr   : FPInst<"fld"   , 0xC0, AddRegFrm, ArgF80, NotFP>, D9;   // push(ST(i))
 352 def FLDr32  : FPInst<"fld"   , 0xD9, MRMS0m   , ArgF32, ZeroArgFP>;        // load float
 353 def FLDr64  : FPInst<"fld"   , 0xDD, MRMS0m   , ArgF64, ZeroArgFP>;        // load double
 354 def FLDr80  : FPInst<"fld"   , 0xDB, MRMS5m   , ArgF80, ZeroArgFP>;        // load extended
 355 def FILDr16 : FPInst<"fild"  , 0xDF, MRMS0m   , Arg16 , ZeroArgFP>;        // load signed short
 356 def FILDr32 : FPInst<"fild"  , 0xDB, MRMS0m   , Arg32 , ZeroArgFP>;        // load signed int
 357 def FILDr64 : FPInst<"fild"  , 0xDF, MRMS5m   , Arg64 , ZeroArgFP>;        // load signed long
 358
 359 def FSTr32   : FPInst<"fst" , 0xD9, MRMS2m   , ArgF32, OneArgFP>;          // store float
 360 def FSTr64   : FPInst<"fst" , 0xDD, MRMS2m   , ArgF64, OneArgFP>;          // store double
 361 def FSTPr32  : FPInst<"fstp", 0xD9, MRMS3m   , ArgF32, OneArgFP>;          // store float, pop
 362 def FSTPr64  : FPInst<"fstp", 0xDD, MRMS3m   , ArgF64, OneArgFP>;          // store double, pop
 363 def FSTPr80  : FPInst<"fstp", 0xDB, MRMS7m   , ArgF80, OneArgFP>;          // store extended, pop
 364 def FSTrr    : FPInst<"fst" , 0xD0, AddRegFrm, ArgF80, NotFP   >, DD;      // ST(i) = ST(0)
 365 def FSTPrr   : FPInst<"fstp", 0xD8, AddRegFrm, ArgF80, NotFP   >, DD;      // ST(i) = ST(0), pop
 366
 367 def FISTr16  : FPInst<"fist",    0xDF, MRMS2m, Arg16 , OneArgFP>;          // store signed short
 368 def FISTr32  : FPInst<"fist",    0xDB, MRMS2m, Arg32 , OneArgFP>;          // store signed int
 369 def FISTPr16 : FPInst<"fistp",   0xDF, MRMS3m, Arg16 , NotFP   >;          // store signed short, pop
 370 def FISTPr32 : FPInst<"fistp",   0xDB, MRMS3m, Arg32 , NotFP   >;          // store signed int, pop
 371 def FISTPr64 : FPInst<"fistpll", 0xDF, MRMS7m, Arg64 , OneArgFP>;          // store signed long, pop
 372
 373 def FXCH     : FPInst<"fxch",    0xC8, AddRegFrm, ArgF80, NotFP>, D9;      // fxch ST(i), ST(0)
 374
 375 // Floating point constant loads...
 376 def FLD0 : FPInst<"fldz", 0xEE, RawFrm, ArgF80, ZeroArgFP>, D9;
 377 def FLD1 : FPInst<"fld1", 0xE8, RawFrm, ArgF80, ZeroArgFP>, D9;
 378
 379 // Binary arithmetic operations...
 380 class FPST0rInst<string n, bits<8> o>
 381   : X86Inst<n, o, AddRegFrm, ArgF80>, D8 {
 382   list<Register> Uses = [ST0];
 383   list<Register> Defs = [ST0];
 384 }
 385 class FPrST0Inst<string n, bits<8> o>
 386   : X86Inst<n, o, AddRegFrm, ArgF80>, DC {
 387   bit printImplicitUses = 1;
 388   list<Register> Uses = [ST0];
 389 }
 390 class FPrST0PInst<string n, bits<8> o>
 391   : X86Inst<n, o, AddRegFrm, ArgF80>, DE {
 392   list<Register> Uses = [ST0];
 393 }
 394
 395 def FADDST0r   : FPST0rInst <"fadd",    0xC0>;
 396 def FADDrST0   : FPrST0Inst <"fadd",    0xC0>;
 397 def FADDPrST0  : FPrST0PInst<"faddp",   0xC0>;
 398
 399 def FSUBRST0r  : FPST0rInst <"fsubr",   0xE8>;
 400 def FSUBrST0   : FPrST0Inst <"fsub",    0xE8>;
 401 def FSUBPrST0  : FPrST0PInst<"fsubp",   0xE8>;
 402
 403 def FSUBST0r   : FPST0rInst <"fsub",    0xE0>;
 404 def FSUBRrST0  : FPrST0Inst <"fsubr",   0xE0>;
 405 def FSUBRPrST0 : FPrST0PInst<"fsubrp",  0xE0>;
 406
 407 def FMULST0r   : FPST0rInst <"fmul",    0xC8>;
 408 def FMULrST0   : FPrST0Inst <"fmul",    0xC8>;
 409 def FMULPrST0  : FPrST0PInst<"fmulp",   0xC8>;
 410
 411 def FDIVRST0r  : FPST0rInst <"fdivr",   0xF8>;
 412 def FDIVrST0   : FPrST0Inst <"fdiv",    0xF8>;
 413 def FDIVPrST0  : FPrST0PInst<"fdivp",   0xF8>;
 414
 415 def FDIVST0r   : FPST0rInst <"fdiv",    0xF0>;   // ST(0) = ST(0) / ST(i)
 416 def FDIVRrST0  : FPrST0Inst <"fdivr",   0xF0>;   // ST(i) = ST(0) / ST(i)
 417 def FDIVRPrST0 : FPrST0PInst<"fdivrp",  0xF0>;   // ST(i) = ST(0) / ST(i), pop
 418
 419 // Floating point compares
 420 def FUCOMr    : X86Inst<"fucom"  , 0xE0, AddRegFrm, ArgF80>, DD, Imp<[ST0],[]>;  // FPSW = compare ST(0) with ST(i)
 421 def FUCOMPr   : X86Inst<"fucomp" , 0xE8, AddRegFrm, ArgF80>, DD, Imp<[ST0],[]>;  // FPSW = compare ST(0) with ST(i), pop
 422 def FUCOMPPr  : X86Inst<"fucompp", 0xE9, RawFrm   , ArgF80>, DA, Imp<[ST0],[]>;  // compare ST(0) with ST(1), pop, pop
 423
 424 // Floating point flag ops
 425 def FNSTSWr8  : X86Inst<"fnstsw" , 0xE0, RawFrm   , ArgF80>, DF, Imp<[],[AX]>;   // AX = fp flags
 426 def FNSTCWm16 : X86Inst<"fnstcw" , 0xD9, MRMS7m   , Arg16 >;                     // [mem16] = X87 control world
 427 def FLDCWm16  : X86Inst<"fldcw"  , 0xD9, MRMS5m   , Arg16 >;                     // X87 control world = [mem16]