lib/Target/X86/X86InstrFormats.td

   1 //===- X86InstrFormats.td - X86 Instruction Formats --------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // X86 Instruction Format Definitions.
  12 //
  13
  14 // Format specifies the encoding used by the instruction.  This is part of the
  15 // ad-hoc solution used to emit machine instruction encodings by our machine
  16 // code emitter.
  17 class Format<bits<6> val> {
  18   bits<6> Value = val;
  19 }
  20
  21 def Pseudo     : Format<0>; def RawFrm     : Format<1>;
  22 def AddRegFrm  : Format<2>; def MRMDestReg : Format<3>;
  23 def MRMDestMem : Format<4>; def MRMSrcReg  : Format<5>;
  24 def MRMSrcMem  : Format<6>;
  25 def MRM0r  : Format<16>; def MRM1r  : Format<17>; def MRM2r  : Format<18>;
  26 def MRM3r  : Format<19>; def MRM4r  : Format<20>; def MRM5r  : Format<21>;
  27 def MRM6r  : Format<22>; def MRM7r  : Format<23>;
  28 def MRM0m  : Format<24>; def MRM1m  : Format<25>; def MRM2m  : Format<26>;
  29 def MRM3m  : Format<27>; def MRM4m  : Format<28>; def MRM5m  : Format<29>;
  30 def MRM6m  : Format<30>; def MRM7m  : Format<31>;
  31 def MRMInitReg : Format<32>;
  32 def MRM_C1 : Format<33>;
  33 def MRM_C2 : Format<34>;
  34 def MRM_C3 : Format<35>;
  35 def MRM_C4 : Format<36>;
  36 def MRM_C8 : Format<37>;
  37 def MRM_C9 : Format<38>;
  38 def MRM_E8 : Format<39>;
  39 def MRM_F0 : Format<40>;
  40 def MRM_F8 : Format<41>;
  41 def MRM_F9 : Format<42>;
  42
  43 // ImmType - This specifies the immediate type used by an instruction. This is
  44 // part of the ad-hoc solution used to emit machine instruction encodings by our
  45 // machine code emitter.
  46 class ImmType<bits<3> val> {
  47   bits<3> Value = val;
  48 }
  49 def NoImm      : ImmType<0>;
  50 def Imm8       : ImmType<1>;
  51 def Imm8PCRel  : ImmType<2>;
  52 def Imm16      : ImmType<3>;
  53 def Imm32      : ImmType<4>;
  54 def Imm32PCRel : ImmType<5>;
  55 def Imm64      : ImmType<6>;
  56
  57 // FPFormat - This specifies what form this FP instruction has.  This is used by
  58 // the Floating-Point stackifier pass.
  59 class FPFormat<bits<3> val> {
  60   bits<3> Value = val;
  61 }
  62 def NotFP      : FPFormat<0>;
  63 def ZeroArgFP  : FPFormat<1>;
  64 def OneArgFP   : FPFormat<2>;
  65 def OneArgFPRW : FPFormat<3>;
  66 def TwoArgFP   : FPFormat<4>;
  67 def CompareFP  : FPFormat<5>;
  68 def CondMovFP  : FPFormat<6>;
  69 def SpecialFP  : FPFormat<7>;
  70
  71 // Class specifying the SSE execution domain, used by the SSEDomainFix pass.
  72 // Keep in sync with tables in X86InstrInfo.cpp.
  73 class Domain<bits<2> val> {
  74   bits<2> Value = val;
  75 }
  76 def GenericDomain   : Domain<0>;
  77 def SSEPackedSingle : Domain<1>;
  78 def SSEPackedDouble : Domain<2>;
  79 def SSEPackedInt    : Domain<3>;
  80
  81 // Prefix byte classes which are used to indicate to the ad-hoc machine code
  82 // emitter that various prefix bytes are required.
  83 class OpSize { bit hasOpSizePrefix = 1; }
  84 class AdSize { bit hasAdSizePrefix = 1; }
  85 class REX_W  { bit hasREX_WPrefix = 1; }
  86 class LOCK   { bit hasLockPrefix = 1; }
  87 class SegFS  { bits<2> SegOvrBits = 1; }
  88 class SegGS  { bits<2> SegOvrBits = 2; }
  89 class TB     { bits<4> Prefix = 1; }
  90 class REP    { bits<4> Prefix = 2; }
  91 class D8     { bits<4> Prefix = 3; }
  92 class D9     { bits<4> Prefix = 4; }
  93 class DA     { bits<4> Prefix = 5; }
  94 class DB     { bits<4> Prefix = 6; }
  95 class DC     { bits<4> Prefix = 7; }
  96 class DD     { bits<4> Prefix = 8; }
  97 class DE     { bits<4> Prefix = 9; }
  98 class DF     { bits<4> Prefix = 10; }
  99 class XD     { bits<4> Prefix = 11; }
 100 class XS     { bits<4> Prefix = 12; }
 101 class T8     { bits<4> Prefix = 13; }
 102 class TA     { bits<4> Prefix = 14; }
 103 class TF     { bits<4> Prefix = 15; }
 104 class VEX    { bit hasVEXPrefix = 1; }
 105 class VEX_4V : VEX { bit hasVEX_4VPrefix = 1; }
 106
 107 class X86Inst<bits<8> opcod, Format f, ImmType i, dag outs, dag ins,
 108               string AsmStr, Domain d = GenericDomain>
 109   : Instruction {
 110   let Namespace = "X86";
 111
 112   bits<8> Opcode = opcod;
 113   Format Form = f;
 114   bits<6> FormBits = Form.Value;
 115   ImmType ImmT = i;
 116
 117   dag OutOperandList = outs;
 118   dag InOperandList = ins;
 119   string AsmString = AsmStr;
 120
 121   //
 122   // Attributes specific to X86 instructions...
 123   //
 124   bit hasOpSizePrefix = 0;  // Does this inst have a 0x66 prefix?
 125   bit hasAdSizePrefix = 0;  // Does this inst have a 0x67 prefix?
 126
 127   bits<4> Prefix = 0;       // Which prefix byte does this inst have?
 128   bit hasREX_WPrefix  = 0;  // Does this inst requires the REX.W prefix?
 129   FPFormat FPForm = NotFP;  // What flavor of FP instruction is this?
 130   bit hasLockPrefix = 0;    // Does this inst have a 0xF0 prefix?
 131   bits<2> SegOvrBits = 0;   // Segment override prefix.
 132   Domain ExeDomain = d;
 133   bit hasVEXPrefix  = 0;    // Does this inst requires a VEX prefix?
 134   bit hasVEX_4VPrefix  = 0; // Does this inst requires the VEX.VVVV field?
 135
 136   // TSFlags layout should be kept in sync with X86InstrInfo.h.
 137   let TSFlags{5-0}   = FormBits;
 138   let TSFlags{6}     = hasOpSizePrefix;
 139   let TSFlags{7}     = hasAdSizePrefix;
 140   let TSFlags{11-8}  = Prefix;
 141   let TSFlags{12}    = hasREX_WPrefix;
 142   let TSFlags{15-13} = ImmT.Value;
 143   let TSFlags{18-16} = FPForm.Value;
 144   let TSFlags{19}    = hasLockPrefix;
 145   let TSFlags{21-20} = SegOvrBits;
 146   let TSFlags{23-22} = ExeDomain.Value;
 147   let TSFlags{31-24} = Opcode;
 148   let TSFlags{32}    = hasVEXPrefix;
 149   let TSFlags{33}    = hasVEX_4VPrefix;
 150 }
 151
 152 class I<bits<8> o, Format f, dag outs, dag ins, string asm,
 153         list<dag> pattern, Domain d = GenericDomain>
 154   : X86Inst<o, f, NoImm, outs, ins, asm, d> {
 155   let Pattern = pattern;
 156   let CodeSize = 3;
 157 }
 158 class Ii8 <bits<8> o, Format f, dag outs, dag ins, string asm,
 159            list<dag> pattern, Domain d = GenericDomain>
 160   : X86Inst<o, f, Imm8, outs, ins, asm, d> {
 161   let Pattern = pattern;
 162   let CodeSize = 3;
 163 }
 164 class Ii8PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 165                list<dag> pattern>
 166   : X86Inst<o, f, Imm8PCRel, outs, ins, asm> {
 167   let Pattern = pattern;
 168   let CodeSize = 3;
 169 }
 170 class Ii16<bits<8> o, Format f, dag outs, dag ins, string asm,
 171            list<dag> pattern>
 172   : X86Inst<o, f, Imm16, outs, ins, asm> {
 173   let Pattern = pattern;
 174   let CodeSize = 3;
 175 }
 176 class Ii32<bits<8> o, Format f, dag outs, dag ins, string asm,
 177            list<dag> pattern>
 178   : X86Inst<o, f, Imm32, outs, ins, asm> {
 179   let Pattern = pattern;
 180   let CodeSize = 3;
 181 }
 182
 183 class Ii32PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 184            list<dag> pattern>
 185   : X86Inst<o, f, Imm32PCRel, outs, ins, asm> {
 186   let Pattern = pattern;
 187   let CodeSize = 3;
 188 }
 189
 190 // FPStack Instruction Templates:
 191 // FPI - Floating Point Instruction template.
 192 class FPI<bits<8> o, Format F, dag outs, dag ins, string asm>
 193   : I<o, F, outs, ins, asm, []> {}
 194
 195 // FpI_ - Floating Point Psuedo Instruction template. Not Predicated.
 196 class FpI_<dag outs, dag ins, FPFormat fp, list<dag> pattern>
 197   : X86Inst<0, Pseudo, NoImm, outs, ins, ""> {
 198   let FPForm = fp;
 199   let Pattern = pattern;
 200 }
 201
 202 // Templates for instructions that use a 16- or 32-bit segmented address as
 203 //  their only operand: lcall (FAR CALL) and ljmp (FAR JMP)
 204 //
 205 //   Iseg16 - 16-bit segment selector, 16-bit offset
 206 //   Iseg32 - 16-bit segment selector, 32-bit offset
 207
 208 class Iseg16 <bits<8> o, Format f, dag outs, dag ins, string asm,
 209               list<dag> pattern> : X86Inst<o, f, NoImm, outs, ins, asm> {
 210   let Pattern = pattern;
 211   let CodeSize = 3;
 212 }
 213
 214 class Iseg32 <bits<8> o, Format f, dag outs, dag ins, string asm,
 215               list<dag> pattern> : X86Inst<o, f, NoImm, outs, ins, asm> {
 216   let Pattern = pattern;
 217   let CodeSize = 3;
 218 }
 219
 220 // SI - SSE 1 & 2 scalar instructions
 221 class SI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 222       : I<o, F, outs, ins, asm, pattern> {
 223   let Predicates = !if(hasVEXPrefix /* VEX_4V */,
 224             !if(!eq(Prefix, 11 /* XD */), [HasAVX, HasSSE2], [HasAVX, HasSSE1]),
 225             !if(!eq(Prefix, 12 /* XS */), [HasSSE1], [HasSSE2]));
 226
 227   // AVX instructions have a 'v' prefix in the mnemonic
 228   let AsmString = !if(hasVEXPrefix, !strconcat("v", asm), asm);
 229 }
 230
 231 // PI - SSE 1 & 2 packed instructions
 232 class PI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern,
 233          Domain d>
 234       : I<o, F, outs, ins, asm, pattern, d> {
 235   let Predicates = !if(hasVEXPrefix /* VEX_4V */,
 236         !if(hasOpSizePrefix /* OpSize */, [HasAVX, HasSSE2], [HasAVX, HasSSE1]),
 237         !if(hasOpSizePrefix /* OpSize */, [HasSSE2], [HasSSE1]));
 238
 239   // AVX instructions have a 'v' prefix in the mnemonic
 240   let AsmString = !if(hasVEXPrefix, !strconcat("v", asm), asm);
 241 }
 242
 243 // PIi8 - SSE 1 & 2 packed instructions with immediate
 244 class PIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 245            list<dag> pattern, Domain d>
 246       : Ii8<o, F, outs, ins, asm, pattern, d> {
 247   let Predicates = !if(hasVEX_4VPrefix /* VEX_4V */,
 248         !if(hasOpSizePrefix /* OpSize */, [HasAVX, HasSSE2], [HasAVX, HasSSE1]),
 249         !if(hasOpSizePrefix /* OpSize */, [HasSSE2], [HasSSE1]));
 250
 251   // AVX instructions have a 'v' prefix in the mnemonic
 252   let AsmString = !if(hasVEX_4VPrefix, !strconcat("v", asm), asm);
 253 }
 254
 255 // SSE1 Instruction Templates:
 256 //
 257 //   SSI   - SSE1 instructions with XS prefix.
 258 //   PSI   - SSE1 instructions with TB prefix.
 259 //   PSIi8 - SSE1 instructions with ImmT == Imm8 and TB prefix.
 260 //   VSSI  - SSE1 instructions with XS prefix in AVX form.
 261 //   VPSI  - SSE1 instructions with TB prefix in AVX form.
 262
 263 class SSI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 264       : I<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE1]>;
 265 class SSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 266             list<dag> pattern>
 267       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE1]>;
 268 class PSI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 269       : I<o, F, outs, ins, asm, pattern, SSEPackedSingle>, TB,
 270         Requires<[HasSSE1]>;
 271 class PSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 272             list<dag> pattern>
 273       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedSingle>, TB,
 274         Requires<[HasSSE1]>;
 275 class VSSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 276            list<dag> pattern>
 277       : I<o, F, outs, ins, !strconcat("v", asm), pattern>, XS, VEX_4V,
 278         Requires<[HasAVX, HasSSE1]>;
 279 class VPSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 280            list<dag> pattern>
 281       : I<o, F, outs, ins, !strconcat("v", asm), pattern, SSEPackedSingle>,
 282         VEX_4V, Requires<[HasAVX, HasSSE1]>;
 283
 284 // SSE2 Instruction Templates:
 285 //
 286 //   SDI    - SSE2 instructions with XD prefix.
 287 //   SDIi8  - SSE2 instructions with ImmT == Imm8 and XD prefix.
 288 //   SSDIi8 - SSE2 instructions with ImmT == Imm8 and XS prefix.
 289 //   PDI    - SSE2 instructions with TB and OpSize prefixes.
 290 //   PDIi8  - SSE2 instructions with ImmT == Imm8 and TB and OpSize prefixes.
 291 //   VSDI   - SSE2 instructions with XD prefix in AVX form.
 292 //   VPDI   - SSE2 instructions with TB and OpSize prefixes in AVX form.
 293
 294 class SDI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 295       : I<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE2]>;
 296 class SDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 297             list<dag> pattern>
 298       : Ii8<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE2]>;
 299 class SSDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 300              list<dag> pattern>
 301       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE2]>;
 302 class PDI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 303       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 304         Requires<[HasSSE2]>;
 305 class PDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 306             list<dag> pattern>
 307       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 308         Requires<[HasSSE2]>;
 309 class VSDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 310            list<dag> pattern>
 311       : I<o, F, outs, ins, !strconcat("v", asm), pattern>, XD, VEX_4V,
 312         Requires<[HasAVX, HasSSE2]>;
 313 class VPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 314            list<dag> pattern>
 315       : I<o, F, outs, ins, !strconcat("v", asm), pattern, SSEPackedDouble>,
 316         VEX_4V, OpSize, Requires<[HasAVX, HasSSE2]>;
 317
 318 // SSE3 Instruction Templates:
 319 //
 320 //   S3I   - SSE3 instructions with TB and OpSize prefixes.
 321 //   S3SI  - SSE3 instructions with XS prefix.
 322 //   S3DI  - SSE3 instructions with XD prefix.
 323
 324 class S3SI<bits<8> o, Format F, dag outs, dag ins, string asm,
 325            list<dag> pattern>
 326       : I<o, F, outs, ins, asm, pattern, SSEPackedSingle>, XS,
 327         Requires<[HasSSE3]>;
 328 class S3DI<bits<8> o, Format F, dag outs, dag ins, string asm,
 329            list<dag> pattern>
 330       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, XD,
 331         Requires<[HasSSE3]>;
 332 class S3I<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 333       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 334         Requires<[HasSSE3]>;
 335
 336
 337 // SSSE3 Instruction Templates:
 338 //
 339 //   SS38I - SSSE3 instructions with T8 prefix.
 340 //   SS3AI - SSSE3 instructions with TA prefix.
 341 //
 342 // Note: SSSE3 instructions have 64-bit and 128-bit versions. The 64-bit version
 343 // uses the MMX registers. We put those instructions here because they better
 344 // fit into the SSSE3 instruction category rather than the MMX category.
 345
 346 class SS38I<bits<8> o, Format F, dag outs, dag ins, string asm,
 347             list<dag> pattern>
 348       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 349         Requires<[HasSSSE3]>;
 350 class SS3AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 351             list<dag> pattern>
 352       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 353         Requires<[HasSSSE3]>;
 354
 355 // SSE4.1 Instruction Templates:
 356 //
 357 //   SS48I - SSE 4.1 instructions with T8 prefix.
 358 //   SS41AIi8 - SSE 4.1 instructions with TA prefix and ImmT == Imm8.
 359 //
 360 class SS48I<bits<8> o, Format F, dag outs, dag ins, string asm,
 361             list<dag> pattern>
 362       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 363         Requires<[HasSSE41]>;
 364 class SS4AIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 365             list<dag> pattern>
 366       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 367         Requires<[HasSSE41]>;
 368
 369 // SSE4.2 Instruction Templates:
 370 //
 371 //   SS428I - SSE 4.2 instructions with T8 prefix.
 372 class SS428I<bits<8> o, Format F, dag outs, dag ins, string asm,
 373              list<dag> pattern>
 374       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 375         Requires<[HasSSE42]>;
 376
 377 //   SS42FI - SSE 4.2 instructions with TF prefix.
 378 class SS42FI<bits<8> o, Format F, dag outs, dag ins, string asm,
 379               list<dag> pattern>
 380       : I<o, F, outs, ins, asm, pattern>, TF, Requires<[HasSSE42]>;
 381
 382 //   SS42AI = SSE 4.2 instructions with TA prefix
 383 class SS42AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 384              list<dag> pattern>
 385       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 386         Requires<[HasSSE42]>;
 387
 388 // AES Instruction Templates:
 389 //
 390 // AES8I
 391 // These use the same encoding as the SSE4.2 T8 and TA encodings.
 392 class AES8I<bits<8> o, Format F, dag outs, dag ins, string asm,
 393             list<dag>pattern>
 394       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 395         Requires<[HasAES]>;
 396
 397 class AESAI<bits<8> o, Format F, dag outs, dag ins, string asm,
 398             list<dag> pattern>
 399       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 400         Requires<[HasAES]>;
 401
 402 // X86-64 Instruction templates...
 403 //
 404
 405 class RI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 406       : I<o, F, outs, ins, asm, pattern>, REX_W;
 407 class RIi8 <bits<8> o, Format F, dag outs, dag ins, string asm,
 408             list<dag> pattern>
 409       : Ii8<o, F, outs, ins, asm, pattern>, REX_W;
 410 class RIi32 <bits<8> o, Format F, dag outs, dag ins, string asm,
 411              list<dag> pattern>
 412       : Ii32<o, F, outs, ins, asm, pattern>, REX_W;
 413
 414 class RIi64<bits<8> o, Format f, dag outs, dag ins, string asm,
 415             list<dag> pattern>
 416   : X86Inst<o, f, Imm64, outs, ins, asm>, REX_W {
 417   let Pattern = pattern;
 418   let CodeSize = 3;
 419 }
 420
 421 class RSSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 422            list<dag> pattern>
 423       : SSI<o, F, outs, ins, asm, pattern>, REX_W;
 424 class RSDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 425            list<dag> pattern>
 426       : SDI<o, F, outs, ins, asm, pattern>, REX_W;
 427 class RPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 428            list<dag> pattern>
 429       : PDI<o, F, outs, ins, asm, pattern>, REX_W;
 430
 431 // MMX Instruction templates
 432 //
 433
 434 // MMXI   - MMX instructions with TB prefix.
 435 // MMXI64 - MMX instructions with TB prefix valid only in 64 bit mode.
 436 // MMX2I  - MMX / SSE2 instructions with TB and OpSize prefixes.
 437 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 438 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 439 // MMXID  - MMX instructions with XD prefix.
 440 // MMXIS  - MMX instructions with XS prefix.
 441 class MMXI<bits<8> o, Format F, dag outs, dag ins, string asm,
 442            list<dag> pattern>
 443       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX]>;
 444 class MMXI64<bits<8> o, Format F, dag outs, dag ins, string asm,
 445              list<dag> pattern>
 446       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX,In64BitMode]>;
 447 class MMXRI<bits<8> o, Format F, dag outs, dag ins, string asm,
 448             list<dag> pattern>
 449       : I<o, F, outs, ins, asm, pattern>, TB, REX_W, Requires<[HasMMX]>;
 450 class MMX2I<bits<8> o, Format F, dag outs, dag ins, string asm,
 451             list<dag> pattern>
 452       : I<o, F, outs, ins, asm, pattern>, TB, OpSize, Requires<[HasMMX]>;
 453 class MMXIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 454              list<dag> pattern>
 455       : Ii8<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX]>;
 456 class MMXID<bits<8> o, Format F, dag outs, dag ins, string asm,
 457             list<dag> pattern>
 458       : Ii8<o, F, outs, ins, asm, pattern>, XD, Requires<[HasMMX]>;
 459 class MMXIS<bits<8> o, Format F, dag outs, dag ins, string asm,
 460             list<dag> pattern>
 461       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasMMX]>;